New Cycript versions do not toll-free bridge well.

[cydget.git] / LockScreen.mm

/* Cydget - open-source AwayView plugin multiplexer
 * Copyright (C) 2009-2015  Jay Freeman (saurik)
*/

/* GNU General Public License, Version 3 {{{ */
/*
 * Cydget is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published
 * by the Free Software Foundation, either version 3 of the License,
 * or (at your option) any later version.
 *
 * Cydget is distributed in the hope that it will be useful, but
 * WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with Cydget.  If not, see <http://www.gnu.org/licenses/>.
**/
/* }}} */

#include <CydiaSubstrate/CydiaSubstrate.h>
#include <UIKit/UIKit.h>

#include <pthread.h>

#include <SpringBoardUI/SBAwayViewPluginController.h>

#include <WebKit/WebFrame.h>
#include <WebKit/WebView.h>
#include <WebKit/WebPreferences-WebPrivate.h>

#include <WebCycript.h>

#ifdef USE_ICU_REGEX
#include <unicode/uregex.h>
#else
#include <pcre.h>
#endif

_disused static unsigned trace_;

#define _trace() do { \
    NSLog(@"_trace(%u)@%s:%u[%s](%p)\n", \
        trace_++, __FILE__, __LINE__, __FUNCTION__, pthread_self() \
    ); \
} while (false)

typedef uint16_t UChar;

@interface TPBottomLockBar
- (CGFloat) defaultHeight;
@end

@interface UIScroller : UIView
- (void) setDirectionalScrolling:(BOOL)directional;
- (void) setScrollDecelerationFactor:(CGFloat)factor;
- (void) setScrollHysteresis:(CGFloat)hysteresis;
- (void) setThumbDetectionEnabled:(BOOL)enabled;
@end

@interface UIWebDocumentView : UIView
- (CGRect) documentBounds;
- (void) enableReachability;
- (void) loadRequest:(NSURLRequest *)request;
- (void) redrawScaledDocument;
- (void) setAllowsImageSheet:(BOOL)allows;
- (void) setAllowsMessaging:(BOOL)allows;
- (void) setAutoresizes:(BOOL)autoresizes;
- (void) setContentsPosition:(NSInteger)position;
- (void) setDrawsBackground:(BOOL)draws;
- (void) _setDocumentType:(NSInteger)type;
- (void) setDrawsGrid:(BOOL)draws;
- (void) setInitialScale:(float)scale forDocumentTypes:(NSInteger)types;
- (void) setLogsTilingChanges:(BOOL)logs;
- (void) setMinimumScale:(float)scale forDocumentTypes:(NSInteger)types;
- (void) setMinimumSize:(CGSize)size;
- (void) setMaximumScale:(float)scale forDocumentTypes:(NSInteger)tpyes;
- (void) setSmoothsFonts:(BOOL)smooths;
- (void) setTileMinificationFilter:(NSString *)filter;
- (void) setTileSize:(CGSize)size;
- (void) setTilingEnabled:(BOOL)enabled;
- (void) setViewportSize:(CGSize)size forDocumentTypes:(NSInteger)types;
- (void) setZoomsFocusedFormControl:(BOOL)zooms;
- (void) useSelectionAssistantWithMode:(NSInteger)mode;
- (WebView *) webView;
@end

@interface UIView (Apple)
- (UIScroller *) _scroller;
- (void) setClipsSubviews:(BOOL)clips;
- (void) setEnabledGestures:(NSInteger)gestures;
- (void) setFixedBackgroundPattern:(BOOL)fixed;
- (void) setGestureDelegate:(id)delegate;
- (void) setNeedsDisplayOnBoundsChange:(BOOL)needs;
- (void) setValue:(NSValue *)value forGestureAttribute:(NSInteger)attribute;
- (void) setZoomScale:(float)scale duration:(double)duration;
- (void) _setZoomScale:(float)scale duration:(double)duration;
@end

@interface SBLockScreenView : UIView
- (BOOL) mediaControlsHidden;
@end

@interface SBLockScreenNotificationListController : NSObject
- (BOOL) hasAnyContent;
@end

@interface SBLockScreenViewController : UIViewController
- (SBLockScreenView *) lockScreenView;
- (BOOL) isShowingMediaControls;
- (void) _setMediaControlsVisible:(BOOL)visible;
- (SBLockScreenNotificationListController *) _notificationController;
@end

@interface SBLockScreenManager : NSObject
+ (SBLockScreenManager *) sharedInstance;
- (SBLockScreenViewController *) lockScreenViewController;
@end

@protocol CydgetController
- (NSDictionary *) currentConfiguration;
- (NSString *) currentPath;
@end

static Class $CydgetController(objc_getClass("CydgetController"));

MSClassHook(SBLockScreenManager)

#ifdef USE_ICU_REGEX
/* ICU Regular Expression {{{ */
class RegEx {
  private:
    URegularExpression *regex_;

  public:
    RegEx(const char *regex) {
        UParseError error;
        UErrorCode status(U_ZERO_ERROR);
        regex_ = uregex_openC(regex, 0, &error, &status);
        if (U_FAILURE(status))
            @throw [NSException exceptionWithName:NSInvalidArgumentException reason:[NSString stringWithFormat:@"*** RegEx(): [%u] %s", error.offset, u_errorName(status)] userInfo:nil];
    }

    ~RegEx() {
        uregex_close(regex_);
    }

    bool operator ()(NSString *string) {
        return operator ()(reinterpret_cast<const uint16_t *>([string cStringUsingEncoding:NSUTF16StringEncoding]), [string length]);
    }

    bool operator ()(const UChar *data, size_t size) {
        UErrorCode status(U_ZERO_ERROR);
        uregex_setText(regex_, data, size, &status);
        if (!U_SUCCESS(status))
            return false;
        bool matches(uregex_matches(regex_, 0, &status));
        if (!U_SUCCESS(status))
            return false;
        return matches;
    }
};
/* }}} */
#else
/* Perl-Compatible RegEx {{{ */
class RegEx {
  private:
    pcre *code_;
    pcre_extra *study_;
    int capture_;
    int *matches_;
    const char *data_;

  public:
    RegEx(const char *regex) :
        study_(NULL)
    {
        const char *error;
        int offset;
        code_ = pcre_compile(regex, 0, &error, &offset, NULL);

        if (code_ == NULL)
            @throw [NSException exceptionWithName:NSInvalidArgumentException reason:[NSString stringWithFormat:@"*** RegEx(): [%u] %s", offset, error] userInfo:nil];

        pcre_fullinfo(code_, study_, PCRE_INFO_CAPTURECOUNT, &capture_);
        matches_ = new int[(capture_ + 1) * 3];
    }

    ~RegEx() {
        pcre_free(code_);
        delete matches_;
    }

    bool operator ()(NSString *data) {
        // XXX: length is for characters, not for bytes
        return operator ()([data UTF8String], [data length]);
    }

    bool operator ()(const char *data, size_t size) {
        data_ = data;
        return pcre_exec(code_, study_, data, size, 0, 0, matches_, (capture_ + 1) * 3) >= 0;
    }
};
/* }}} */
#endif

static float CYScrollViewDecelerationRateNormal;

@interface UIScrollView (Apple)
- (void) setDecelerationRate:(CGFloat)value;
- (void) setScrollingEnabled:(BOOL)enabled;
- (void) setShowBackgroundShadow:(BOOL)show;
@end

@interface UIWebView (Apple)
- (UIWebDocumentView *) _documentView;
- (void) setDataDetectorTypes:(NSInteger)types;
- (void) _setDrawInWebThread:(BOOL)draw;
- (UIScrollView *) _scrollView;
- (UIScroller *) _scroller;
- (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message;
- (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame;
@end

@interface WebView (Apple)
- (void) _setLayoutInterval:(float)interval;
- (void) _setAllowsMessaging:(BOOL)allows;
- (void) setShouldUpdateWhileOffscreen:(BOOL)update;
@end

@protocol CydgetWebViewDelegate <UIWebViewDelegate>
- (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame;
@end

@class UIWebViewWebViewDelegate;

@interface UIWebView (WebCycript)
- (void) updateStyles;
@end

@interface CydgetWebView : UIWebView {
}

@end

@implementation CydgetWebView

- (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
    NSObject<CydgetWebViewDelegate> *delegate((NSObject<CydgetWebViewDelegate> *) [self delegate]);
    if ([delegate respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
        [delegate webView:view didClearWindowObject:window forFrame:frame];
    if ([UIWebView instancesRespondToSelector:@selector(webView:didClearWindowObject:forFrame:)])
        [super webView:view didClearWindowObject:window forFrame:frame];
}

- (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
    NSLog(@"addMessageToConsole:%@", message);

    if ([UIWebView instancesRespondToSelector:@selector(webView:addMessageToConsole:)])
        [super webView:view addMessageToConsole:message];
}

@end

@interface WebCydgetLockScreenView : UIView <UIWebViewDelegate> {
    CydgetWebView *webview_;
    UIScrollView *scroller_;
    NSString *cycript_;
}

- (void) updateStyles;

@end

@implementation WebCydgetLockScreenView

//#include "UICaboodle/UCInternal.h"

- (void) dealloc {
    [[NSNotificationCenter defaultCenter] removeObserver:self];
    [webview_ setDelegate:nil];
    [webview_ release];
    [super dealloc];
}

- (void) loadRequest:(NSURLRequest *)request {
    [webview_ loadRequest:request];
}

- (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
    [self loadRequest:[NSURLRequest
        requestWithURL:url
        cachePolicy:policy
        timeoutInterval:30.0
    ]];
}

- (void) loadURL:(NSURL *)url {
    [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
}

- (id) initWithURL:(NSURL *)url {
    CGRect frame = [[UIScreen mainScreen] bounds];
    if (kCFCoreFoundationVersionNumber < 800)
        frame.size.height -= 20; //[[[$SBStatusBarController sharedStatusBarController] statusBarView] frame].size.height;

    if ((self = [super initWithFrame:frame]) != nil) {
        CGRect bounds([self bounds]);
        if (kCFCoreFoundationVersionNumber < 800)
            bounds.size.height -= [objc_getClass("TPBottomLockBar") defaultHeight];

        webview_ = [[CydgetWebView alloc] initWithFrame:bounds];
        [webview_ setDelegate:self];
        [self addSubview:webview_];

        if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
            [webview_ setDataDetectorTypes:0x80000000];
        else
            [webview_ setDetectsPhoneNumbers:NO];

        [webview_ setScalesPageToFit:YES];

        if (kCFCoreFoundationVersionNumber < 478.61)
            if ([webview_ respondsToSelector:@selector(_setDrawInWebThread:)])
                [webview_ _setDrawInWebThread:NO];

        UIWebDocumentView *document([webview_ _documentView]);
        WebView *webview([document webView]);
        WebPreferences *preferences([webview preferences]);

        [document setTileSize:CGSizeMake(bounds.size.width, 500)];

        [document setBackgroundColor:[UIColor clearColor]];
        [document setDrawsBackground:NO];

        [webview setPreferencesIdentifier:@"WebCycript"];

        if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
            [webview _setLayoutInterval:0];
        else
            [preferences _setLayoutInterval:0];

        [preferences setCacheModel:WebCacheModelDocumentViewer];
        [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
        [preferences setOfflineWebApplicationCacheEnabled:YES];

        if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
            [webview setShouldUpdateWhileOffscreen:NO];

        if ([document respondsToSelector:@selector(setAllowsMessaging:)])
            [document setAllowsMessaging:YES];
        if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
            [webview _setAllowsMessaging:YES];

        if ([webview_ respondsToSelector:@selector(_scrollView)]) {
            scroller_ = [webview_ _scrollView];

            [scroller_ setDirectionalLockEnabled:YES];
            [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
            [scroller_ setDelaysContentTouches:NO];

            [scroller_ setCanCancelContentTouches:YES];

            [scroller_ setAlwaysBounceVertical:NO];
        } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
            UIScroller *scroller([webview_ _scroller]);
            scroller_ = (UIScrollView *) scroller;

            [scroller setDirectionalScrolling:YES];
            [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
            [scroller setScrollHysteresis:0]; /* 8 */

            [scroller setThumbDetectionEnabled:NO];
        }

        [webview_ setOpaque:NO];
        [webview_ setBackgroundColor:[UIColor clearColor]];

        [scroller_ setFixedBackgroundPattern:YES];
        [scroller_ setBackgroundColor:[UIColor clearColor]];
        [scroller_ setClipsSubviews:NO];

        [scroller_ setBounces:YES];
        [scroller_ setShowBackgroundShadow:NO]; /* YES */

        [self setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
        [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];

        NSDictionary *configuration([$CydgetController currentConfiguration]);
        cycript_ = [configuration objectForKey:@"CycriptURLs"];

        [scroller_ setScrollingEnabled:[[configuration objectForKey:@"Scrollable"] boolValue]];

        [self loadURL:url];

        [[NSNotificationCenter defaultCenter]
            addObserver:self
            selector:@selector(mediaControlsDidSomething:)
            name:@"SBLockScreenViewControllerMediaControlsDidShow"
            object:nil
        ];

        [[NSNotificationCenter defaultCenter]
            addObserver:self
            selector:@selector(mediaControlsDidSomething:)
            name:@"SBLockScreenViewControllerMediaControlsDidHide"
            object:nil
        ];
    } return self;
}

- (void) mediaControlsDidSomething:(NSNotification *)notification {
    [self updateStyles];
}

- (void) webView:(WebView *)webview didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
    if (cycript_ != nil)
        if (NSString *href = [[[[frame dataSource] request] URL] absoluteString])
            if (RegEx([cycript_ UTF8String])(href))
                WebCycriptSetupView(webview);
}

- (void) updateStyles {
    [webview_ updateStyles];
}

@end

@interface WebCycriptLockScreenController : SBAwayViewPluginController {
    NSDictionary *configuration_;
    bool legacy_;
    bool media_;
    bool items_;
    WebCydgetLockScreenView *background_;
    WebCydgetLockScreenView *foreground_;
}

@end

static BOOL CYHaveMediaControls() {
    SBLockScreenView *view([[[$SBLockScreenManager sharedInstance] lockScreenViewController] lockScreenView]);
    return view != nil && ![view mediaControlsHidden];
    //return [[[$SBLockScreenManager sharedInstance] lockScreenViewController] isShowingMediaControls];
}

static BOOL CYHaveNotificationList() {
    SBLockScreenNotificationListController *controller([[[$SBLockScreenManager sharedInstance] lockScreenViewController] _notificationController]);
    return controller != nil && [controller hasAnyContent];
}

static void $UIWebViewWebViewDelegate$webView$addMessageToConsole$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *message) {
    UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
    if ([uiWebView respondsToSelector:@selector(webView:addMessageToConsole:)])
        [uiWebView webView:view addMessageToConsole:message];
}

static void $UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, WebScriptObject *window, WebFrame *frame) {
    UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
    if ([uiWebView respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
        [uiWebView webView:view didClearWindowObject:window forFrame:frame];
}

MSInitialize {
    if (Class $UIWebViewWebViewDelegate = objc_getClass("UIWebViewWebViewDelegate")) {
        class_addMethod($UIWebViewWebViewDelegate, @selector(webView:addMessageToConsole:), (IMP) &$UIWebViewWebViewDelegate$webView$addMessageToConsole$, "v16@0:4@8@12");
        class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didClearWindowObject:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$, "v20@0:4@8@12@16");
    }

    if (CGFloat *_UIScrollViewDecelerationRateNormal = reinterpret_cast<CGFloat *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
        CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
    else // XXX: this actually might be fast on some older systems: we should look into this
        CYScrollViewDecelerationRateNormal = 0.998;

    if (kCFCoreFoundationVersionNumber >= 800) {
        WebCycriptRegisterStyle("-cydget-media-controls", &CYHaveMediaControls);
        WebCycriptRegisterStyle("-cydget-notification-list", &CYHaveNotificationList);
    }
}

@implementation WebCycriptLockScreenController

+ (id) rootViewController {
    return [[[self alloc] init] autorelease];
}

- (void) dealloc {
    [configuration_ release];
    [background_ release];
    [foreground_ release];
    [super dealloc];
}

- (id) init {
    if ((self = [super init]) != nil) {
        configuration_ = [[$CydgetController currentConfiguration] retain];
        legacy_ = [configuration_ objectForKey:@"Background"] == nil;
        media_ = [[configuration_ objectForKey:@"MediaControls"] boolValue];
        items_ = [[configuration_ objectForKey:@"NotificationList"] boolValue];
    } return self;
}

- (void) loadView {
    NSURL *base([NSURL fileURLWithPath:[$CydgetController currentPath]]);

    if (NSString *background = [configuration_ objectForKey:@"Background"])
        background_ = [[WebCydgetLockScreenView alloc] initWithURL:[NSURL URLWithString:background relativeToURL:base]];

    if (NSString *homepage = [configuration_ objectForKey:@"Homepage"]) {
        foreground_ = [[WebCydgetLockScreenView alloc] initWithURL:[NSURL URLWithString:homepage relativeToURL:base]];
        [self setView:foreground_];
    }
}

- (void) purgeView {
    [background_ removeFromSuperview];
    [background_ release];
    background_ = nil;
    [foreground_ removeFromSuperview];
    [foreground_ release];
    foreground_ = nil;
    [super purgeView];
}

- (void) updateStyles {
    [foreground_ updateStyles];
    [background_ updateStyles];
}

- (UIView *) backgroundView {
    return background_;
}

- (BOOL) showAwayItems {
    return YES;
}

- (BOOL) updateHidden {
    if (foreground_ == nil)
        return true;
    bool media(CYHaveMediaControls());
    [foreground_ setHidden:media];
    return media;
}

- (BOOL) showDateView {
    if (kCFCoreFoundationVersionNumber < 800)
        return false;
    [self updateStyles];
    if (!legacy_ && foreground_ == nil)
        return true;
    if (!items_ && CYHaveNotificationList())
        return true;
    return false;
}

- (BOOL) allowsLockScreenMediaControls {
    if (kCFCoreFoundationVersionNumber < 800)
        return true;
    return media_;
}

/*- (BOOL) showHeaderView {
    return YES;
}*/

// 0: view is rendered above head
// 1: view moves as one with head
// 2: view moves up and down only
// 3: view simply never does move
- (NSUInteger) presentationStyle {
    return 1;
}

// 1: light blur
// 2: heavy blur
// 3: just black
// 4: legibility
// 5: no overlay
- (NSUInteger) overlayStyle {
    return legacy_ ? 1 : 4;
}

// 1: blur -> view -> list
// 2: view -> blur -> list
// 3: view. unblur below?!
// 4: blur -> list -> view
- (NSUInteger) notificationBehavior {
    return items_ ? 1 : 2;
}

- (BOOL) viewWantsFullscreenLayout {
    return kCFCoreFoundationVersionNumber >= 800;
}

/*- (BOOL) viewWantsOverlayLayout {
    return kCFCoreFoundationVersionNumber >= 800;
}*/

- (BOOL) shouldDisableOnUnlock {
    return YES;
}

- (BOOL) canBeAlwaysFullscreen {
    return YES;
}

/*- (BOOL) wantsSwipeGestureRecognizer {
    return YES;
}

- (BOOL) handleGesture:(int)arg1 fingerCount:(NSUInteger)fingers {
    return NO;
    return YES;
}*/

// - (void) lockScreenMediaControlsShown:(BOOL)shown;

- (BOOL) handleMenuButtonDoubleTap {
    if (kCFCoreFoundationVersionNumber >= 800) {
        SBLockScreenViewController *controller([[$SBLockScreenManager sharedInstance] lockScreenViewController]);
        [controller _setMediaControlsVisible:![controller isShowingMediaControls]];
    }

    return [super handleMenuButtonDoubleTap];
}

@end