Library.mm

   1 /* Cyrker - Remove Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #define _GNU_SOURCE
  41
  42 #include <substrate.h>
  43 #include "cycript.hpp"
  44
  45 #include "sig/parse.hpp"
  46 #include "sig/ffi_type.hpp"
  47
  48 #include "Pooling.hpp"
  49 #include "Struct.hpp"
  50
  51 #include <unistd.h>
  52
  53 #include <CoreFoundation/CoreFoundation.h>
  54 #include <CoreFoundation/CFLogUtilities.h>
  55
  56 #include <CFNetwork/CFNetwork.h>
  57
  58 #include <WebKit/WebScriptObject.h>
  59
  60 #include <sys/types.h>
  61 #include <sys/socket.h>
  62 #include <netinet/in.h>
  63
  64 #include <iostream>
  65 #include <ext/stdio_filebuf.h>
  66 #include <set>
  67 #include <map>
  68
  69 #include "Parser.hpp"
  70 #include "Cycript.tab.hh"
  71
  72 #undef _assert
  73 #undef _trace
  74
  75 #define _assert(test) do { \
  76     if (!(test)) \
  77         @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"_assert(%s):%s(%u):%s", #test, __FILE__, __LINE__, __FUNCTION__] userInfo:nil]; \
  78 } while (false)
  79
  80 #define _trace() do { \
  81     CFLog(kCFLogLevelNotice, CFSTR("_trace():%u"), __LINE__); \
  82 } while (false)
  83
  84
  85 static JSContextRef Context_;
  86
  87 static JSClassRef Functor_;
  88 static JSClassRef Instance_;
  89 static JSClassRef Pointer_;
  90 static JSClassRef Selector_;
  91
  92 static JSObjectRef Array_;
  93
  94 static JSStringRef name_;
  95 static JSStringRef message_;
  96 static JSStringRef length_;
  97
  98 static Class NSCFBoolean_;
  99
 100 static NSMutableDictionary *Bridge_;
 101
 102 struct Client {
 103     CFHTTPMessageRef message_;
 104     CFSocketRef socket_;
 105 };
 106
 107 JSObjectRef CYMakeObject(JSContextRef context, id object) {
 108     return JSObjectMake(context, Instance_, [object retain]);
 109 }
 110
 111 @interface NSMethodSignature (Cycript)
 112 - (NSString *) _typeString;
 113 @end
 114
 115 @interface NSObject (Cycript)
 116 - (NSString *) cy$toJSON;
 117 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 118 @end
 119
 120 @interface NSString (Cycript)
 121 - (void *) cy$symbol;
 122 @end
 123
 124 @interface NSNumber (Cycript)
 125 - (void *) cy$symbol;
 126 @end
 127
 128 @implementation NSObject (Cycript)
 129
 130 - (NSString *) cy$toJSON {
 131     return [self description];
 132 }
 133
 134 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 135     return CYMakeObject(context, self);
 136 }
 137
 138 @end
 139
 140 @implementation WebUndefined (Cycript)
 141
 142 - (NSString *) cy$toJSON {
 143     return @"undefined";
 144 }
 145
 146 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 147     return JSValueMakeUndefined(context);
 148 }
 149
 150 @end
 151
 152 @implementation NSArray (Cycript)
 153
 154 - (NSString *) cy$toJSON {
 155     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 156     [json appendString:@"["];
 157
 158     bool comma(false);
 159     for (id object in self) {
 160         if (comma)
 161             [json appendString:@","];
 162         else
 163             comma = true;
 164         [json appendString:[object cy$toJSON]];
 165     }
 166
 167     [json appendString:@"]"];
 168     return json;
 169 }
 170
 171 @end
 172
 173 @implementation NSDictionary (Cycript)
 174
 175 - (NSString *) cy$toJSON {
 176     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 177     [json appendString:@"("];
 178     [json appendString:@"{"];
 179
 180     bool comma(false);
 181     for (id key in self) {
 182         if (comma)
 183             [json appendString:@","];
 184         else
 185             comma = true;
 186         [json appendString:[key cy$toJSON]];
 187         [json appendString:@":"];
 188         NSObject *object([self objectForKey:key]);
 189         [json appendString:[object cy$toJSON]];
 190     }
 191
 192     [json appendString:@"})"];
 193     return json;
 194 }
 195
 196 @end
 197
 198 @implementation NSNumber (Cycript)
 199
 200 - (NSString *) cy$toJSON {
 201     return [self class] != NSCFBoolean_ ? [self stringValue] : [self boolValue] ? @"true" : @"false";
 202 }
 203
 204 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 205     return [self class] != NSCFBoolean_ ? JSValueMakeNumber(context, [self doubleValue]) : JSValueMakeBoolean(context, [self boolValue]);
 206 }
 207
 208 - (void *) cy$symbol {
 209     return [self pointerValue];
 210 }
 211
 212 @end
 213
 214 @implementation NSString (Cycript)
 215
 216 - (NSString *) cy$toJSON {
 217     CFMutableStringRef json(CFStringCreateMutableCopy(kCFAllocatorDefault, 0, (CFStringRef) self));
 218
 219     CFStringFindAndReplace(json, CFSTR("\\"), CFSTR("\\\\"), CFRangeMake(0, CFStringGetLength(json)), 0);
 220     CFStringFindAndReplace(json, CFSTR("\""), CFSTR("\\\""), CFRangeMake(0, CFStringGetLength(json)), 0);
 221     CFStringFindAndReplace(json, CFSTR("\t"), CFSTR("\\t"), CFRangeMake(0, CFStringGetLength(json)), 0);
 222     CFStringFindAndReplace(json, CFSTR("\r"), CFSTR("\\r"), CFRangeMake(0, CFStringGetLength(json)), 0);
 223     CFStringFindAndReplace(json, CFSTR("\n"), CFSTR("\\n"), CFRangeMake(0, CFStringGetLength(json)), 0);
 224
 225     CFStringInsert(json, 0, CFSTR("\""));
 226     CFStringAppend(json, CFSTR("\""));
 227
 228     return [reinterpret_cast<const NSString *>(json) autorelease];
 229 }
 230
 231 - (void *) cy$symbol {
 232     return dlsym(RTLD_DEFAULT, [self UTF8String]);
 233 }
 234
 235 @end
 236
 237 @interface CYJSObject : NSDictionary {
 238     JSObjectRef object_;
 239     JSContextRef context_;
 240 }
 241
 242 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 243
 244 - (NSUInteger) count;
 245 - (id) objectForKey:(id)key;
 246 - (NSEnumerator *) keyEnumerator;
 247 - (void) setObject:(id)object forKey:(id)key;
 248 - (void) removeObjectForKey:(id)key;
 249
 250 @end
 251
 252 @interface CYJSArray : NSArray {
 253     JSObjectRef object_;
 254     JSContextRef context_;
 255 }
 256
 257 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 258
 259 - (NSUInteger) count;
 260 - (id) objectAtIndex:(NSUInteger)index;
 261
 262 @end
 263
 264 JSContextRef CYGetJSContext() {
 265     return Context_;
 266 }
 267
 268 #define CYCatch \
 269     @catch (id error) { \
 270         CYThrow(context, error, exception); \
 271         return NULL; \
 272     }
 273
 274 void CYThrow(JSContextRef context, JSValueRef value);
 275
 276 id CYCastNSObject(JSContextRef context, JSObjectRef object) {
 277     if (JSValueIsObjectOfClass(context, object, Instance_))
 278         return reinterpret_cast<id>(JSObjectGetPrivate(object));
 279     JSValueRef exception(NULL);
 280     bool array(JSValueIsInstanceOfConstructor(context, object, Array_, &exception));
 281     CYThrow(context, exception);
 282     if (array)
 283         return [[[CYJSArray alloc] initWithJSObject:object inContext:context] autorelease];
 284     return [[[CYJSObject alloc] initWithJSObject:object inContext:context] autorelease];
 285 }
 286
 287 JSStringRef CYCopyJSString(id value) {
 288     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>([value description]));
 289 }
 290
 291 JSStringRef CYCopyJSString(const char *value) {
 292     return JSStringCreateWithUTF8CString(value);
 293 }
 294
 295 JSStringRef CYCopyJSString(JSStringRef value) {
 296     return JSStringRetain(value);
 297 }
 298
 299 JSStringRef CYCopyJSString(JSContextRef context, JSValueRef value) {
 300     JSValueRef exception(NULL);
 301     JSStringRef string(JSValueToStringCopy(context, value, &exception));
 302     CYThrow(context, exception);
 303     return string;
 304 }
 305
 306 // XXX: this is not a safe handle
 307 class CYJSString {
 308   private:
 309     JSStringRef string_;
 310
 311   public:
 312     template <typename Arg0_>
 313     CYJSString(Arg0_ arg0) {
 314         string_ = CYCopyJSString(arg0);
 315     }
 316
 317     template <typename Arg0_, typename Arg1_>
 318     CYJSString(Arg0_ arg0, Arg1_ arg1) {
 319         string_ = CYCopyJSString(arg0, arg1);
 320     }
 321
 322     ~CYJSString() {
 323         JSStringRelease(string_);
 324     }
 325
 326     operator JSStringRef() const {
 327         return string_;
 328     }
 329 };
 330
 331 CFStringRef CYCopyCFString(JSStringRef value) {
 332     return JSStringCopyCFString(kCFAllocatorDefault, value);
 333 }
 334
 335 CFStringRef CYCopyCFString(JSContextRef context, JSValueRef value) {
 336     return CYCopyCFString(CYJSString(context, value));
 337 }
 338
 339 double CYCastDouble(JSContextRef context, JSValueRef value) {
 340     JSValueRef exception(NULL);
 341     double number(JSValueToNumber(context, value, &exception));
 342     CYThrow(context, exception);
 343     return number;
 344 }
 345
 346 CFNumberRef CYCopyCFNumber(JSContextRef context, JSValueRef value) {
 347     double number(CYCastDouble(context, value));
 348     return CFNumberCreate(kCFAllocatorDefault, kCFNumberDoubleType, &number);
 349 }
 350
 351 NSString *CYCastNSString(JSStringRef value) {
 352     return [reinterpret_cast<const NSString *>(CYCopyCFString(value)) autorelease];
 353 }
 354
 355 CFTypeRef CYCopyCFType(JSContextRef context, JSValueRef value) {
 356     switch (JSType type = JSValueGetType(context, value)) {
 357         case kJSTypeUndefined:
 358             return CFRetain([WebUndefined undefined]);
 359         case kJSTypeNull:
 360             return nil;
 361         case kJSTypeBoolean:
 362             return CFRetain(JSValueToBoolean(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 363         case kJSTypeNumber:
 364             return CYCopyCFNumber(context, value);
 365         case kJSTypeString:
 366             return CYCopyCFString(context, value);
 367         case kJSTypeObject:
 368             return CFRetain((CFTypeRef) CYCastNSObject(context, (JSObjectRef) value));
 369         default:
 370             @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"JSValueGetType() == 0x%x", type] userInfo:nil];
 371     }
 372 }
 373
 374 NSArray *CYCastNSArray(JSPropertyNameArrayRef names) {
 375     size_t size(JSPropertyNameArrayGetCount(names));
 376     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
 377     for (size_t index(0); index != size; ++index)
 378         [array addObject:CYCastNSString(JSPropertyNameArrayGetNameAtIndex(names, index))];
 379     return array;
 380 }
 381
 382 id CYCastNSObject(JSContextRef context, JSValueRef value) {
 383     const NSObject *object(reinterpret_cast<const NSObject *>(CYCopyCFType(context, value)));
 384     return object == nil ? nil : [object autorelease];
 385 }
 386
 387 void CYThrow(JSContextRef context, JSValueRef value) {
 388     if (value == NULL)
 389         return;
 390     @throw CYCastNSObject(context, value);
 391 }
 392
 393 JSValueRef CYCastJSValue(JSContextRef context, id value) {
 394     return value == nil ? JSValueMakeNull(context) : [value cy$JSValueInContext:context];
 395 }
 396
 397 void CYThrow(JSContextRef context, id error, JSValueRef *exception) {
 398     *exception = CYCastJSValue(context, error);
 399 }
 400
 401 @implementation CYJSObject
 402
 403 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
 404     if ((self = [super init]) != nil) {
 405         object_ = object;
 406         context_ = context;
 407     } return self;
 408 }
 409
 410 - (NSUInteger) count {
 411     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
 412     size_t size(JSPropertyNameArrayGetCount(names));
 413     JSPropertyNameArrayRelease(names);
 414     return size;
 415 }
 416
 417 - (id) objectForKey:(id)key {
 418     JSValueRef exception(NULL);
 419     JSValueRef value(JSObjectGetProperty(context_, object_, CYJSString(key), &exception));
 420     CYThrow(context_, exception);
 421     return CYCastNSObject(context_, value);
 422 }
 423
 424 - (NSEnumerator *) keyEnumerator {
 425     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
 426     NSEnumerator *enumerator([CYCastNSArray(names) objectEnumerator]);
 427     JSPropertyNameArrayRelease(names);
 428     return enumerator;
 429 }
 430
 431 - (void) setObject:(id)object forKey:(id)key {
 432     JSValueRef exception(NULL);
 433     JSObjectSetProperty(context_, object_, CYJSString(key), CYCastJSValue(context_, object), kJSPropertyAttributeNone, &exception);
 434     CYThrow(context_, exception);
 435 }
 436
 437 - (void) removeObjectForKey:(id)key {
 438     JSValueRef exception(NULL);
 439     // XXX: this returns a bool... throw exception, or ignore?
 440     JSObjectDeleteProperty(context_, object_, CYJSString(key), &exception);
 441     CYThrow(context_, exception);
 442 }
 443
 444 @end
 445
 446 @implementation CYJSArray
 447
 448 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
 449     if ((self = [super init]) != nil) {
 450         object_ = object;
 451         context_ = context;
 452     } return self;
 453 }
 454
 455 - (NSUInteger) count {
 456     JSValueRef exception(NULL);
 457     JSValueRef value(JSObjectGetProperty(context_, object_, length_, &exception));
 458     CYThrow(context_, exception);
 459     return CYCastDouble(context_, value);
 460 }
 461
 462 - (id) objectAtIndex:(NSUInteger)index {
 463     JSValueRef exception(NULL);
 464     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
 465     CYThrow(context_, exception);
 466     id object(CYCastNSObject(context_, value));
 467     return object == nil ? [NSNull null] : object;
 468 }
 469
 470 @end
 471
 472 CFStringRef CYCopyJSONString(JSContextRef context, JSValueRef value) {
 473     id object(CYCastNSObject(context, value));
 474     return reinterpret_cast<CFStringRef>([(object == nil ? @"null" : [object cy$toJSON]) retain]);
 475 }
 476
 477 static void OnData(CFSocketRef socket, CFSocketCallBackType type, CFDataRef address, const void *value, void *info) {
 478     switch (type) {
 479         case kCFSocketDataCallBack:
 480             CFDataRef data(reinterpret_cast<CFDataRef>(value));
 481             Client *client(reinterpret_cast<Client *>(info));
 482
 483             if (client->message_ == NULL)
 484                 client->message_ = CFHTTPMessageCreateEmpty(kCFAllocatorDefault, TRUE);
 485
 486             if (!CFHTTPMessageAppendBytes(client->message_, CFDataGetBytePtr(data), CFDataGetLength(data)))
 487                 CFLog(kCFLogLevelError, CFSTR("CFHTTPMessageAppendBytes()"));
 488             else if (CFHTTPMessageIsHeaderComplete(client->message_)) {
 489                 CFURLRef url(CFHTTPMessageCopyRequestURL(client->message_));
 490                 Boolean absolute;
 491                 CFStringRef path(CFURLCopyStrictPath(url, &absolute));
 492                 CFRelease(client->message_);
 493
 494                 CFStringRef code(CFURLCreateStringByReplacingPercentEscapes(kCFAllocatorDefault, path, CFSTR("")));
 495                 CFRelease(path);
 496
 497                 JSStringRef script(JSStringCreateWithCFString(code));
 498                 CFRelease(code);
 499
 500                 JSValueRef result(JSEvaluateScript(CYGetJSContext(), script, NULL, NULL, 0, NULL));
 501                 JSStringRelease(script);
 502
 503                 CFHTTPMessageRef response(CFHTTPMessageCreateResponse(kCFAllocatorDefault, 200, NULL, kCFHTTPVersion1_1));
 504                 CFHTTPMessageSetHeaderFieldValue(response, CFSTR("Content-Type"), CFSTR("application/json; charset=utf-8"));
 505
 506                 CFStringRef json(CYCopyJSONString(CYGetJSContext(), result));
 507                 CFDataRef body(CFStringCreateExternalRepresentation(kCFAllocatorDefault, json, kCFStringEncodingUTF8, NULL));
 508                 CFRelease(json);
 509
 510                 CFStringRef length(CFStringCreateWithFormat(kCFAllocatorDefault, NULL, CFSTR("%u"), CFDataGetLength(body)));
 511                 CFHTTPMessageSetHeaderFieldValue(response, CFSTR("Content-Length"), length);
 512                 CFRelease(length);
 513
 514                 CFHTTPMessageSetBody(response, body);
 515                 CFRelease(body);
 516
 517                 CFDataRef serialized(CFHTTPMessageCopySerializedMessage(response));
 518                 CFRelease(response);
 519
 520                 CFSocketSendData(socket, NULL, serialized, 0);
 521                 CFRelease(serialized);
 522
 523                 CFRelease(url);
 524             }
 525         break;
 526     }
 527 }
 528
 529 static void OnAccept(CFSocketRef socket, CFSocketCallBackType type, CFDataRef address, const void *value, void *info) {
 530     switch (type) {
 531         case kCFSocketAcceptCallBack:
 532             Client *client(new Client());
 533
 534             client->message_ = NULL;
 535
 536             CFSocketContext context;
 537             context.version = 0;
 538             context.info = client;
 539             context.retain = NULL;
 540             context.release = NULL;
 541             context.copyDescription = NULL;
 542
 543             client->socket_ = CFSocketCreateWithNative(kCFAllocatorDefault, *reinterpret_cast<const CFSocketNativeHandle *>(value), kCFSocketDataCallBack, &OnData, &context);
 544
 545             CFRunLoopAddSource(CFRunLoopGetCurrent(), CFSocketCreateRunLoopSource(kCFAllocatorDefault, client->socket_, 0), kCFRunLoopDefaultMode);
 546         break;
 547     }
 548 }
 549
 550 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { _pooled
 551     @try {
 552         NSString *name(CYCastNSString(property));
 553         NSLog(@"%@", name);
 554         return NULL;
 555     } CYCatch
 556 }
 557
 558 typedef id jocData;
 559
 560 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { _pooled
 561     @try {
 562         id data(reinterpret_cast<jocData>(JSObjectGetPrivate(object)));
 563         return CYMakeObject(context, [[data alloc] autorelease]);
 564     } CYCatch
 565 }
 566
 567 struct ptrData {
 568     apr_pool_t *pool_;
 569     void *value_;
 570     sig::Type type_;
 571
 572     void *operator new(size_t size) {
 573         apr_pool_t *pool;
 574         apr_pool_create(&pool, NULL);
 575         void *data(apr_palloc(pool, size));
 576         reinterpret_cast<ptrData *>(data)->pool_ = pool;
 577         return data;;
 578     }
 579
 580     ptrData(void *value) :
 581         value_(value)
 582     {
 583     }
 584 };
 585
 586 struct ffiData : ptrData {
 587     sig::Signature signature_;
 588     ffi_cif cif_;
 589
 590     ffiData(void (*value)(), const char *type) :
 591         ptrData(reinterpret_cast<void *>(value))
 592     {
 593         sig::Parse(pool_, &signature_, type);
 594         sig::sig_ffi_cif(pool_, &sig::ObjectiveC, &signature_, &cif_);
 595     }
 596 };
 597
 598 struct selData : ptrData {
 599     selData(SEL value) :
 600         ptrData(value)
 601     {
 602     }
 603 };
 604
 605 static void Pointer_finalize(JSObjectRef object) {
 606     ptrData *data(reinterpret_cast<ptrData *>(JSObjectGetPrivate(object)));
 607     apr_pool_destroy(data->pool_);
 608 }
 609
 610 static void Instance_finalize(JSObjectRef object) {
 611     id data(reinterpret_cast<jocData>(JSObjectGetPrivate(object)));
 612     [data release];
 613 }
 614
 615 JSObjectRef CYMakeFunction(JSContextRef context, void (*function)(), const char *type) {
 616     ffiData *data(new ffiData(function, type));
 617     return JSObjectMake(context, Functor_, data);
 618 }
 619
 620
 621 JSObjectRef CYMakeFunction(JSContextRef context, void *function, const char *type) {
 622     return CYMakeFunction(context, reinterpret_cast<void (*)()>(function), type);
 623 }
 624
 625 void CYSetProperty(JSContextRef context, JSObjectRef object, const char *name, JSValueRef value) {
 626     JSValueRef exception(NULL);
 627     JSObjectSetProperty(context, object, CYJSString(name), value, kJSPropertyAttributeNone, &exception);
 628     CYThrow(context, exception);
 629 }
 630
 631 char *CYPoolCString(apr_pool_t *pool, JSStringRef value) {
 632     size_t size(JSStringGetMaximumUTF8CStringSize(value));
 633     char *string(new(pool) char[size]);
 634     JSStringGetUTF8CString(value, string, size);
 635     JSStringRelease(value);
 636     return string;
 637 }
 638
 639 char *CYPoolCString(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
 640     return CYPoolCString(pool, CYJSString(context, value));
 641 }
 642
 643 // XXX: this macro is unhygenic
 644 #define CYCastCString(context, value) ({ \
 645     JSValueRef exception(NULL); \
 646     JSStringRef string(JSValueToStringCopy(context, value, &exception)); \
 647     CYThrow(context, exception); \
 648     size_t size(JSStringGetMaximumUTF8CStringSize(string)); \
 649     char *utf8(reinterpret_cast<char *>(alloca(size))); \
 650     JSStringGetUTF8CString(string, utf8, size); \
 651     JSStringRelease(string); \
 652     utf8; \
 653 })
 654
 655 SEL CYCastSEL(JSContextRef context, JSValueRef value) {
 656     if (JSValueIsNull(context, value))
 657         return NULL;
 658     else if (JSValueIsObjectOfClass(context, value, Selector_)) {
 659         selData *data(reinterpret_cast<selData *>(JSObjectGetPrivate((JSObjectRef) value)));
 660         return reinterpret_cast<SEL>(data->value_);
 661     } else
 662         return sel_registerName(CYCastCString(context, value));
 663 }
 664
 665 void *CYCastPointer(JSContextRef context, JSValueRef value) {
 666     switch (JSValueGetType(context, value)) {
 667         case kJSTypeNull:
 668             return NULL;
 669         case kJSTypeString:
 670             return dlsym(RTLD_DEFAULT, CYCastCString(context, value));
 671         case kJSTypeObject:
 672             if (JSValueIsObjectOfClass(context, value, Pointer_)) {
 673                 ptrData *data(reinterpret_cast<ptrData *>(JSObjectGetPrivate((JSObjectRef) value)));
 674                 return data->value_;
 675             }
 676         default:
 677             return reinterpret_cast<void *>(static_cast<uintptr_t>(CYCastDouble(context, value)));
 678     }
 679 }
 680
 681 void CYPoolFFI(apr_pool_t *pool, JSContextRef context, sig::Type *type, void *data, JSValueRef value) {
 682     switch (type->primitive) {
 683         case sig::boolean_P:
 684             *reinterpret_cast<bool *>(data) = JSValueToBoolean(context, value);
 685         break;
 686
 687 #define CYPoolFFI_(primitive, native) \
 688         case sig::primitive ## _P: \
 689             *reinterpret_cast<native *>(data) = CYCastDouble(context, value); \
 690         break;
 691
 692         CYPoolFFI_(uchar, unsigned char)
 693         CYPoolFFI_(char, char)
 694         CYPoolFFI_(ushort, unsigned short)
 695         CYPoolFFI_(short, short)
 696         CYPoolFFI_(ulong, unsigned long)
 697         CYPoolFFI_(long, long)
 698         CYPoolFFI_(uint, unsigned int)
 699         CYPoolFFI_(int, int)
 700         CYPoolFFI_(ulonglong, unsigned long long)
 701         CYPoolFFI_(longlong, long long)
 702         CYPoolFFI_(float, float)
 703         CYPoolFFI_(double, double)
 704
 705         case sig::object_P:
 706         case sig::typename_P:
 707             *reinterpret_cast<id *>(data) = CYCastNSObject(context, value);
 708         break;
 709
 710         case sig::selector_P:
 711             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
 712         break;
 713
 714         case sig::pointer_P:
 715             *reinterpret_cast<void **>(data) = CYCastPointer(context, value);
 716         break;
 717
 718         case sig::string_P:
 719             *reinterpret_cast<char **>(data) = CYPoolCString(pool, context, value);
 720         break;
 721
 722         case sig::struct_P:
 723             goto fail;
 724
 725         case sig::void_P:
 726         break;
 727
 728         default: fail:
 729             NSLog(@"CYPoolFFI(%c)\n", type->primitive);
 730             _assert(false);
 731     }
 732 }
 733
 734 JSValueRef CYFromFFI(JSContextRef context, sig::Type *type, void *data) {
 735     JSValueRef value;
 736
 737     switch (type->primitive) {
 738         case sig::boolean_P:
 739             value = JSValueMakeBoolean(context, *reinterpret_cast<bool *>(data));
 740         break;
 741
 742 #define CYFromFFI_(primitive, native) \
 743         case sig::primitive ## _P: \
 744             value = JSValueMakeNumber(context, *reinterpret_cast<native *>(data)); \
 745         break;
 746
 747         CYFromFFI_(uchar, unsigned char)
 748         CYFromFFI_(char, char)
 749         CYFromFFI_(ushort, unsigned short)
 750         CYFromFFI_(short, short)
 751         CYFromFFI_(ulong, unsigned long)
 752         CYFromFFI_(long, long)
 753         CYFromFFI_(uint, unsigned int)
 754         CYFromFFI_(int, int)
 755         CYFromFFI_(ulonglong, unsigned long long)
 756         CYFromFFI_(longlong, long long)
 757         CYFromFFI_(float, float)
 758         CYFromFFI_(double, double)
 759
 760         case sig::object_P:
 761         case sig::typename_P: {
 762             value = CYCastJSValue(context, *reinterpret_cast<id *>(data));
 763         } break;
 764
 765         case sig::selector_P: {
 766             if (SEL sel = *reinterpret_cast<SEL *>(data)) {
 767                 selData *data(new selData(sel));
 768                 value = JSObjectMake(context, Selector_, data);
 769             } else goto null;
 770         } break;
 771
 772         case sig::pointer_P: {
 773             if (void *pointer = *reinterpret_cast<void **>(data)) {
 774                 ptrData *data(new ptrData(pointer));
 775                 value = JSObjectMake(context, Pointer_, data);
 776             } else goto null;
 777         } break;
 778
 779         case sig::string_P: {
 780             if (char *utf8 = *reinterpret_cast<char **>(data))
 781                 value = JSValueMakeString(context, CYJSString(utf8));
 782             else goto null;
 783         } break;
 784
 785         case sig::struct_P:
 786             goto fail;
 787
 788         case sig::void_P:
 789             value = JSValueMakeUndefined(context);
 790         break;
 791
 792         null:
 793             value = JSValueMakeNull(context);
 794         break;
 795
 796         default: fail:
 797             NSLog(@"CYFromFFI(%c)\n", type->primitive);
 798             _assert(false);
 799     }
 800
 801     return value;
 802 }
 803
 804 static JSValueRef CYCallFunction(JSContextRef context, size_t count, const JSValueRef *arguments, JSValueRef *exception, sig::Signature *signature, ffi_cif *cif, void (*function)()) { _pooled
 805     @try {
 806         if (count != signature->count - 1)
 807             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to ffi function" userInfo:nil];
 808
 809         CYPool pool;
 810         void *values[count];
 811
 812         for (unsigned index(0); index != count; ++index) {
 813             sig::Element *element(&signature->elements[index + 1]);
 814             // XXX: alignment?
 815             values[index] = new(pool) uint8_t[cif->arg_types[index]->size];
 816             CYPoolFFI(pool, context, element->type, values[index], arguments[index]);
 817         }
 818
 819         uint8_t value[cif->rtype->size];
 820         ffi_call(cif, function, value, values);
 821
 822         return CYFromFFI(context, signature->elements[0].type, value);
 823     } CYCatch
 824 }
 825
 826 static JSValueRef Global_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { _pooled
 827     @try {
 828         NSString *name(CYCastNSString(property));
 829         if (Class _class = NSClassFromString(name))
 830             return CYMakeObject(context, _class);
 831         if (NSMutableArray *entry = [Bridge_ objectForKey:name])
 832             switch ([[entry objectAtIndex:0] intValue]) {
 833                 case 0:
 834                     return JSEvaluateScript(CYGetJSContext(), CYJSString([entry objectAtIndex:1]), NULL, NULL, 0, NULL);
 835                 case 1:
 836                     return CYMakeFunction(context, [name cy$symbol], [[entry objectAtIndex:1] UTF8String]);
 837                 case 2:
 838                     CYPool pool;
 839                     sig::Signature signature;
 840                     sig::Parse(pool, &signature, [[entry objectAtIndex:1] UTF8String]);
 841                     return CYFromFFI(context, signature.elements[0].type, [name cy$symbol]);
 842             }
 843         return NULL;
 844     } CYCatch
 845 }
 846
 847 bool stret(ffi_type *ffi_type) {
 848     return ffi_type->type == FFI_TYPE_STRUCT && (
 849         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
 850         struct_forward_array[ffi_type->size] != 0
 851     );
 852 }
 853
 854 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { _pooled
 855     const char *type;
 856
 857     @try {
 858         if (count < 2)
 859             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"too few arguments to objc_msgSend" userInfo:nil];
 860
 861         id self(CYCastNSObject(context, arguments[0]));
 862         if (self == nil)
 863             return JSValueMakeNull(context);
 864
 865         SEL _cmd(CYCastSEL(context, arguments[1]));
 866         NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
 867         if (method == nil)
 868             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:[NSString stringWithFormat:@"unrecognized selector %s sent to object %p", sel_getName(_cmd), self] userInfo:nil];
 869
 870         type = [[method _typeString] UTF8String];
 871     } CYCatch
 872
 873     CYPool pool;
 874
 875     sig::Signature signature;
 876     sig::Parse(pool, &signature, type);
 877
 878     ffi_cif cif;
 879     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
 880
 881     void (*function)() = stret(cif.rtype) ? reinterpret_cast<void (*)()>(&objc_msgSend_stret) : reinterpret_cast<void (*)()>(&objc_msgSend);
 882     return CYCallFunction(context, count, arguments, exception, &signature, &cif, function);
 883 }
 884
 885 static JSValueRef ffi_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
 886     ffiData *data(reinterpret_cast<ffiData *>(JSObjectGetPrivate(object)));
 887     return CYCallFunction(context, count, arguments, exception, &data->signature_, &data->cif_, reinterpret_cast<void (*)()>(data->value_));
 888 }
 889
 890 JSObjectRef ffi(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
 891     @try {
 892         if (count != 2)
 893             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to ffi constructor" userInfo:nil];
 894         void *function(CYCastPointer(context, arguments[0]));
 895         const char *type(CYCastCString(context, arguments[1]));
 896         return CYMakeFunction(context, function, type);
 897     } CYCatch
 898 }
 899
 900 JSValueRef Pointer_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
 901     ptrData *data(reinterpret_cast<ptrData *>(JSObjectGetPrivate(object)));
 902     return JSValueMakeNumber(context, reinterpret_cast<uintptr_t>(data->value_));
 903 }
 904
 905 static JSStaticValue Pointer_staticValues[2] = {
 906     {"value", &Pointer_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
 907     {NULL, NULL, NULL, 0}
 908 };
 909
 910 CYDriver::CYDriver(const std::string &filename) :
 911     state_(CYClear),
 912     data_(NULL),
 913     size_(0),
 914     filename_(filename),
 915     source_(NULL)
 916 {
 917     ScannerInit();
 918 }
 919
 920 CYDriver::~CYDriver() {
 921     ScannerDestroy();
 922 }
 923
 924 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
 925     CYDriver::Error error;
 926     error.location_ = location;
 927     error.message_ = message;
 928     driver.errors_.push_back(error);
 929 }
 930
 931 MSInitialize { _pooled
 932     apr_initialize();
 933
 934     NSCFBoolean_ = objc_getClass("NSCFBoolean");
 935
 936     pid_t pid(getpid());
 937
 938     struct sockaddr_in address;
 939     address.sin_len = sizeof(address);
 940     address.sin_family = AF_INET;
 941     address.sin_addr.s_addr = INADDR_ANY;
 942     address.sin_port = htons(10000 + pid);
 943
 944     CFDataRef data(CFDataCreate(kCFAllocatorDefault, reinterpret_cast<UInt8 *>(&address), sizeof(address)));
 945
 946     CFSocketSignature signature;
 947     signature.protocolFamily = AF_INET;
 948     signature.socketType = SOCK_STREAM;
 949     signature.protocol = IPPROTO_TCP;
 950     signature.address = data;
 951
 952     CFSocketRef socket(CFSocketCreateWithSocketSignature(kCFAllocatorDefault, &signature, kCFSocketAcceptCallBack, &OnAccept, NULL));
 953     CFRunLoopAddSource(CFRunLoopGetCurrent(), CFSocketCreateRunLoopSource(kCFAllocatorDefault, socket, 0), kCFRunLoopDefaultMode);
 954
 955     JSClassDefinition definition;
 956
 957     definition = kJSClassDefinitionEmpty;
 958     definition.className = "Pointer";
 959     definition.staticValues = Pointer_staticValues;
 960     definition.finalize = &Pointer_finalize;
 961     Pointer_ = JSClassCreate(&definition);
 962
 963     definition = kJSClassDefinitionEmpty;
 964     definition.className = "Functor";
 965     definition.parentClass = Pointer_;
 966     definition.callAsFunction = &ffi_callAsFunction;
 967     Functor_ = JSClassCreate(&definition);
 968
 969     definition = kJSClassDefinitionEmpty;
 970     definition.className = "Selector";
 971     definition.parentClass = Pointer_;
 972     Selector_ = JSClassCreate(&definition);
 973
 974     definition = kJSClassDefinitionEmpty;
 975     definition.className = "Instance_";
 976     definition.getProperty = &Instance_getProperty;
 977     definition.callAsConstructor = &Instance_callAsConstructor;
 978     definition.finalize = &Instance_finalize;
 979     Instance_ = JSClassCreate(&definition);
 980
 981     definition = kJSClassDefinitionEmpty;
 982     definition.getProperty = &Global_getProperty;
 983     JSClassRef Global(JSClassCreate(&definition));
 984
 985     JSContextRef context(JSGlobalContextCreate(Global));
 986     Context_ = context;
 987
 988     JSObjectRef global(JSContextGetGlobalObject(context));
 989
 990     CYSetProperty(context, global, "ffi", JSObjectMakeConstructor(context, Functor_, &ffi));
 991
 992     CYSetProperty(context, global, "objc_msgSend", JSObjectMakeFunctionWithCallback(context, CYJSString("objc_msgSend"), &$objc_msgSend));
 993
 994     Bridge_ = [[NSMutableDictionary dictionaryWithContentsOfFile:@"/usr/lib/libcycript.plist"] retain];
 995
 996     name_ = JSStringCreateWithUTF8CString("name");
 997     message_ = JSStringCreateWithUTF8CString("message");
 998     length_ = JSStringCreateWithUTF8CString("length");
 999
1000     JSValueRef exception(NULL);
1001     JSValueRef value(JSObjectGetProperty(CYGetJSContext(), global, CYJSString("Array"), &exception));
1002     CYThrow(context, exception);
1003     Array_ = JSValueToObject(CYGetJSContext(), value, &exception);
1004     CYThrow(context, exception);
1005 }