Cycript.l.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2012  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 /* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */
  23
  24 %{
  25 #define YYLTYPE cy::location
  26 #include "Cycript.tab.hh"
  27 typedef cy::parser::token tk;
  28
  29 #define YY_EXTRA_TYPE CYDriver *
  30
  31 #define F(value) do { \
  32     int token(value); \
  33     yyextra->nobrace_ = false; \
  34     return token; \
  35 } while (false)
  36
  37 #define A new($pool)
  38 #define Y apr_pstrmemdup($pool, yytext, yyleng)
  39
  40 #define I(type, Type, value) do { \
  41     yylval->type ## _ = A CY ## Type; \
  42     F(value); \
  43 } while (false)
  44
  45 #define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
  46 #define C T yyextra->state_ = CYClear;
  47 #define R T yyextra->state_ = CYRestricted;
  48
  49 #define N \
  50     if (yyextra->state_ != CYNewLine) { \
  51         if (yyextra->state_ != CYRestricted) \
  52             yyextra->state_ = CYNewLine; \
  53         else { \
  54             yyextra->state_ = CYClear; \
  55             F(tk::NewLine); \
  56         } \
  57     }
  58
  59 #define V(more) { \
  60     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
  61         unsigned lines(0); \
  62         size_t left; \
  63         do { \
  64             ++lines; \
  65             left = yyleng - (nl - yytext) - 1; \
  66             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
  67         } while (nl != NULL); \
  68         yylloc->end.lines(lines); \
  69         yylloc->end.columns(left); \
  70         yylloc->step(); \
  71         more \
  72     } else L \
  73 }
  74
  75 #define L { \
  76     yylloc->step(); \
  77     yylloc->columns(yyleng); \
  78 }
  79
  80 int H(char c) {
  81     if (c >= '0' && c <= '9')
  82         return c - '0';
  83     if (c >= 'a' && c <= 'f')
  84         return c - 'a' + 10;
  85     if (c >= 'A' && c <= 'F')
  86         return c - 'A' + 10;
  87     return -1;
  88 }
  89
  90 #define YY_INPUT(data, value, size) { \
  91     if (yyextra->file_ != NULL) { \
  92         size_t copy(fread(data, 1, size, yyextra->file_)); \
  93         value = copy == 0 ? YY_NULL : copy; \
  94     } else if (yyextra->size_ == 0) \
  95         value = YY_NULL; \
  96     else { \
  97         size_t copy(size); \
  98         copy = (std::min(copy, yyextra->size_)); \
  99         memcpy(data, yyextra->data_, copy); \
 100         yyextra->data_ += copy; \
 101         yyextra->size_ -= copy; \
 102         value = copy; \
 103     } \
 104 }
 105
 106 %}
 107
 108 %option prefix="cy"
 109 %option bison-bridge
 110 %option bison-locations
 111 %option noyywrap
 112 %option yylineno
 113 %option nounput
 114 %option interactive
 115 %option reentrant
 116 %option stack
 117
 118 Exponent [eE][+-]?[0-9]+
 119 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
 120
 121 IdentifierStart [a-zA-Z$_]
 122 IdentifierPart  [a-zA-Z$_0-9]
 123
 124 NonTerminator [^\n]
 125 BackslashSequence \\{NonTerminator}
 126 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
 127 RegularExpressionChar [^\n\\/]|{BackslashSequence}
 128 RegularExpressionFlags {IdentifierPart}*
 129 RegularExpressionChars {RegularExpressionChar}*
 130 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
 131
 132 @begin E4X
 133 XMLNameStart [a-zA-Z_:]
 134 XMLNamePart [a-zA-Z0-9.-_:]
 135 XMLName {XMLNameStart}{XMLNamePart}*
 136 @end
 137
 138 %s Div
 139 %s RegExp
 140
 141 @begin E4X
 142 %x XMLContent
 143 %x XMLTag
 144 @end
 145
 146 %%
 147
 148 <RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} L C I(literal, RegEx(Y), tk::RegularExpressionLiteral);
 149
 150 \/\/[^\n]* L
 151
 152         /* http://ostermiller.org/findcomment.html */
 153         /* XXX: unify these two rules using !? */
 154 \/\*!([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V() C I(comment, Comment(Y), tk::Comment);
 155 \/\*([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V(N)
 156
 157 @begin E4X
 158 <RegExp>"<>"      L F(tk::LeftRight);
 159 <XMLContent>"</>" L F(tk::LeftSlashRight);
 160
 161 <RegExp,XMLContent>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]> V() F(tk::XMLCDATA);
 162 <RegExp,XMLContent>\<!--(\n|[^-]|-[^-])*--> V() F(tk::XMLComment);
 163 <RegExp,XMLContent>\<?(\n|[^?]|\?[^>])*?> V() F(tk::XMLPI);
 164
 165 <XMLTag>"="  L F(tk::Equal);
 166 <XMLTag>">"  L F(tk::Right);
 167 <XMLTag>"/>" L F(tk::SlashRight);
 168 <XMLTag>"{"  L F(tk::OpenBrace);
 169
 170 <XMLTag>\"(\n|[^"])*\"|'(\n|[^'])*' V() F(tk::XMLAttributeValue);
 171 <XMLTag>{XMLName} L F(tk::XMLName);
 172 <XMLTag>[ \t\r\n] V() F(tk::XMLWhitespace);
 173
 174 <XMLContent>"{"  L F(tk::OpenBrace);
 175 <XMLContent>"<"  L F(tk::Left);
 176 <XMLContent>"</" L F(tk::LeftSlash);
 177 @end
 178
 179 "..."  L C F(tk::PeriodPeriodPeriod);
 180
 181 @begin E4X
 182 "::"   L C F(tk::ColonColon);
 183 ".."   L C F(tk::PeriodPeriod);
 184 @end
 185
 186 @begin E4X ObjectiveC
 187 "@"    L C F(tk::At);
 188 @end
 189
 190 "&"    L C F(tk::Ampersand);
 191 "&&"   L C F(tk::AmpersandAmpersand);
 192 "&="   L C F(tk::AmpersandEqual);
 193 "^"    L C F(tk::Carrot);
 194 "^="   L C F(tk::CarrotEqual);
 195 "="    L C F(tk::Equal);
 196 "=="   L C F(tk::EqualEqual);
 197 "==="  L C F(tk::EqualEqualEqual);
 198 "=>"   L C F(tk::EqualRight);
 199 "!"    L C F(tk::Exclamation);
 200 "!="   L C F(tk::ExclamationEqual);
 201 "!=="  L C F(tk::ExclamationEqualEqual);
 202 "-"    L C F(tk::Hyphen);
 203 "-="   L C F(tk::HyphenEqual);
 204 "--"   L C F(yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen);
 205 "->"   L C F(tk::HyphenRight);
 206 "<"    L C F(tk::Left);
 207 "<="   L C F(tk::LeftEqual);
 208 "<<"   L C F(tk::LeftLeft);
 209 "<<="  L C F(tk::LeftLeftEqual);
 210 "%"    L C F(tk::Percent);
 211 "%="   L C F(tk::PercentEqual);
 212 "."    L C F(tk::Period);
 213 "|"    L C F(tk::Pipe);
 214 "|="   L C F(tk::PipeEqual);
 215 "||"   L C F(tk::PipePipe);
 216 "+"    L C F(tk::Plus);
 217 "+="   L C F(tk::PlusEqual);
 218 "++"   L C F(yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus);
 219 ">"    L C F(tk::Right);
 220 ">="   L C F(tk::RightEqual);
 221 ">>"   L C F(tk::RightRight);
 222 ">>="  L C F(tk::RightRightEqual);
 223 ">>>"  L C F(tk::RightRightRight);
 224 ">>>=" L C F(tk::RightRightRightEqual);
 225 "*"    L C F(tk::Star);
 226 "*="   L C F(tk::StarEqual);
 227 "~"    L C F(tk::Tilde);
 228
 229 <Div>"/"  L C F(tk::Slash);
 230 <Div>"/=" L C F(tk::SlashEqual);
 231
 232 ":"    L C F(tk::Colon);
 233 ","    L C F(tk::Comma);
 234 "?"    L C F(tk::Question);
 235 ";"    L C F(tk::SemiColon);
 236
 237 "("    L C F(tk::OpenParen);
 238 ")"    L C F(tk::CloseParen);
 239
 240 "{"    L C F(yyextra->nobrace_ ? tk::OpenBrace__ : yylval->newline_ ? tk::OpenBrace_ : tk::OpenBrace);
 241 "}"    L C F(tk::CloseBrace);
 242
 243 "["    L C F(tk::OpenBracket);
 244 "]"    L C F(tk::CloseBracket);
 245
 246 @begin Java
 247 "@class"          L C F(tk::AtClass);
 248 @end
 249
 250 @begin ObjectiveC
 251 "@end"            L C F(tk::AtEnd);
 252 "@implementation" L C F(tk::AtImplementation);
 253 "@import"         L C F(tk::AtImport);
 254 "@selector"       L C F(tk::AtSelector);
 255 @end
 256
 257 "false"        L C I(false, False(), tk::False);
 258 "null"         L C I(null, Null(), tk::Null);
 259 "true"         L C I(true, True(), tk::True);
 260
 261 "auto"         L C I(word, Word("auto"), tk::Auto);
 262 "break"        L R I(word, Word("break"), tk::Break);
 263 "case"         L C I(word, Word("case"), tk::Case);
 264 "catch"        L C I(word, Word("catch"), tk::Catch);
 265 "continue"     L R I(word, Word("continue"), tk::Continue);
 266 "default"      L C I(word, Word("default"), tk::Default);
 267 "delete"       L C I(word, Word("delete"), tk::Delete);
 268 "do"           L C I(word, Word("do"), tk::Do);
 269 "else"         L C I(word, Word("else"), tk::Else);
 270 "finally"      L C I(word, Word("finally"), tk::Finally);
 271 "for"          L C I(word, Word("for"), tk::For);
 272 "function"     L C I(word, Word("function"), tk::Function);
 273 "if"           L C I(word, Word("if"), tk::If);
 274 "in"           L C I(word, Word("in"), yyextra->in_.top() ? tk::In_ : tk::In);
 275 "instanceof"   L C I(word, Word("instanceof"), tk::InstanceOf);
 276 "new"          L C I(word, Word("new"), tk::New);
 277 "return"       L R I(word, Word("return"), tk::Return);
 278 "switch"       L C I(word, Word("switch"), tk::Switch);
 279 "this"         L C I(this, This(), tk::This);
 280 "throw"        L R I(word, Word("throw"), tk::Throw);
 281 "try"          L C I(word, Word("try"), tk::Try);
 282 "typeof"       L C I(word, Word("typeof"), tk::TypeOf);
 283 "var"          L C I(word, Word("var"), tk::Var);
 284 "void"         L C I(word, Word("void"), tk::Void);
 285 "while"        L C I(word, Word("while"), tk::While);
 286 "with"         L C I(word, Word("with"), tk::With);
 287
 288 "debugger"     L C I(word, Word("debugger"), tk::Debugger);
 289
 290 "const"        L C I(word, Word("const"), tk::Const);
 291
 292 "class"        L C I(word, Word("class"), tk::Class);
 293 "enum"         L C I(word, Word("enum"), tk::Enum);
 294 "export"       L C I(word, Word("export"), tk::Export);
 295 "extends"      L C I(word, Word("extends"), tk::Extends);
 296 "import"       L C I(word, Word("import"), tk::Import);
 297 "super"        L C I(word, Word("super"), tk::Super);
 298
 299 "implements"   L C I(identifier, Identifier("implements"), tk::Implements);
 300 "interface"    L C I(identifier, Identifier("interface"), tk::Interface);
 301 "package"      L C I(identifier, Identifier("package"), tk::Package);
 302 "private"      L C I(identifier, Identifier("private"), tk::Private);
 303 "protected"    L C I(identifier, Identifier("protected"), tk::Protected);
 304 "public"       L C I(identifier, Identifier("public"), tk::Public);
 305 "static"       L C I(identifier, Identifier("static"), tk::Static);
 306
 307 "abstract"     L C I(identifier, Identifier("abstract"), tk::Abstract);
 308 "boolean"      L C I(identifier, Identifier("boolean"), tk::Boolean);
 309 "byte"         L C I(identifier, Identifier("byte"), tk::Byte);
 310 "char"         L C I(identifier, Identifier("char"), tk::Char);
 311 "double"       L C I(identifier, Identifier("double"), tk::Double);
 312 "final"        L C I(identifier, Identifier("final"), tk::Final);
 313 "float"        L C I(identifier, Identifier("float"), tk::Float);
 314 "goto"         L C I(identifier, Identifier("goto"), tk::Goto);
 315 "int"          L C I(identifier, Identifier("int"), tk::Int);
 316 "long"         L C I(identifier, Identifier("long"), tk::Long);
 317 "native"       L C I(identifier, Identifier("native"), tk::Native);
 318 "short"        L C I(identifier, Identifier("short"), tk::Short);
 319 "synchronized" L C I(identifier, Identifier("synchronized"), tk::Synchronized);
 320 "throws"       L C I(identifier, Identifier("throws"), tk::Throws);
 321 "transient"    L C I(identifier, Identifier("transient"), tk::Transient);
 322 "volatile"     L C I(identifier, Identifier("volatile"), tk::Volatile);
 323
 324 "let"          L C I(identifier, Identifier("let"), tk::Let);
 325 "yield"        L C I(identifier, Identifier("yield"), tk::Yield);
 326
 327 "each"         L C I(identifier, Identifier("each"), tk::Each);
 328 "of"           L C I(identifier, Identifier("of"), tk::Of);
 329
 330 @begin E4X
 331 "namespace"    L C I(identifier, Identifier("namespace"), tk::Namespace);
 332 "xml"          L C I(identifier, Identifier("xml"), tk::XML);
 333 @end
 334
 335 {IdentifierStart}{IdentifierPart}* L C I(identifier, Identifier(Y), tk::Identifier_);
 336
 337 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? L C I(number, Number(strtod(yytext, NULL)), tk::NumericLiteral);
 338
 339 0[xX][0-9a-fA-F]+ L C I(number, Number(strtoull(yytext + 2, NULL, 16)), tk::NumericLiteral);
 340 0[0-7]+ L C I(number, Number(strtoull(yytext + 1, NULL, 8)), tk::NumericLiteral);
 341 0[bB][0-1]+ L C I(number, Number(strtoull(yytext + 2, NULL, 2)), tk::NumericLiteral);
 342
 343 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 344     char *value(A char[yyleng]);
 345     char *local(value);
 346
 347     for (yy_size_t i(1), e(yyleng - 1); i != e; ++i) {
 348         char next(yytext[i]);
 349
 350         if (yytext[i] == '\\')
 351             switch (next = yytext[++i]) {
 352                 case '\n': continue;
 353                 case '\\': next = '\\'; break;
 354                 case '\'': next = '\''; break;
 355                 case '"': next = '"'; break;
 356                 case 'b': next = '\b'; break;
 357                 case 'f': next = '\f'; break;
 358                 case 'n': next = '\n'; break;
 359                 case 'r': next = '\r'; break;
 360                 case 't': next = '\t'; break;
 361                 case 'v': next = '\v'; break;
 362                 case '0': next = '\0'; break;
 363
 364                 case 'x':
 365                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 366                     i += 2;
 367                 break;
 368             }
 369
 370         *local++ = next;
 371     }
 372
 373     *local = '\0';
 374     I(string, String(value, local - value), tk::StringLiteral);
 375 }
 376
 377 \r?\n|\r|\xe2\x80[\xa8\xa9] yylloc->end.lines(); yylloc->step(); N
 378
 379 [ \t] L
 380
 381 <<EOF>> if (yyextra->auto_) { yyextra->auto_ = false; F(tk::AutoComplete); } L yyterminate();
 382
 383 . L {
 384     CYDriver::Error error;
 385     error.location_ = *yylloc;
 386     error.message_ = "syntax error, unknown token";
 387     yyextra->errors_.push_back(error);
 388     yyterminate();
 389 }
 390
 391 %%
 392
 393 void CYDriver::ScannerInit() {
 394     cylex_init(&scanner_);
 395     cyset_extra(this, scanner_);
 396 }
 397
 398 void CYDriver::ScannerDestroy() {
 399     cylex_destroy(scanner_);
 400 }
 401
 402 CYDriver::Condition CYDriver::GetCondition() {
 403     switch (yy_top_state(scanner_)) {
 404         case RegExp:
 405             return RegExpCondition;
 406 @begin E4X
 407         case XMLContent:
 408             return XMLContentCondition;
 409         case XMLTag:
 410             return XMLTagCondition;
 411 @end
 412         default:
 413             _assert(false);
 414     }
 415 }
 416
 417 void CYDriver::SetCondition(Condition condition) {
 418     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 419
 420     switch (condition) {
 421         case RegExpCondition:
 422             BEGIN(RegExp);
 423             break;
 424 @begin E4X
 425         case XMLContentCondition:
 426             BEGIN(XMLContent);
 427             break;
 428         case XMLTagCondition:
 429             BEGIN(XMLTag);
 430             break;
 431 @end
 432         default:
 433             _assert(false);
 434     }
 435 }
 436
 437 void CYDriver::PushCondition(Condition condition) {
 438     switch (condition) {
 439         case RegExpCondition:
 440             yy_push_state(RegExp, scanner_);
 441             break;
 442 @begin E4X
 443         case XMLContentCondition:
 444             yy_push_state(XMLContent, scanner_);
 445             break;
 446         case XMLTagCondition:
 447             yy_push_state(XMLTag, scanner_);
 448             break;
 449 @end
 450         default:
 451             _assert(false);
 452     }
 453 }
 454
 455 void CYDriver::PopCondition() {
 456     yy_pop_state(scanner_);
 457 }