Cycript.l.in

   1 %{
   2 // XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf
   3
   4 #define YYLTYPE cy::location
   5 #include "Cycript.tab.hh"
   6 typedef cy::parser::token tk;
   7
   8 #define YY_EXTRA_TYPE CYDriver *
   9
  10 #define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
  11 #define C T yyextra->state_ = CYClear;
  12 #define R T yyextra->state_ = CYRestricted;
  13
  14 #define E(prefix) L C { \
  15     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng + sizeof(prefix)))); \
  16     memcpy(value, prefix, sizeof(prefix) - 1); \
  17     memcpy(value + sizeof(prefix) - 1, yytext, yyleng); \
  18     value[yyleng + sizeof(prefix) - 1] = '\0'; \
  19     yylval->literal_ = new(yyextra->pool_) CYRegEx(value); \
  20     return tk::RegularExpressionLiteral; \
  21 }
  22
  23 #define N \
  24     if (yyextra->state_ != CYNewLine) { \
  25         bool restricted(yyextra->state_ == CYRestricted); \
  26         if (restricted) { \
  27             yyextra->state_ = CYClear; \
  28             return tk::NewLine; \
  29         } else \
  30             yyextra->state_ = CYNewLine; \
  31     }
  32
  33 #define M { \
  34     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
  35         unsigned lines(0); \
  36         size_t left; \
  37         do { \
  38             ++lines; \
  39             left = yyleng - (nl - yytext) - 1; \
  40             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
  41         } while (nl != NULL); \
  42         yylloc->end.lines(lines); \
  43         yylloc->end.columns(left); \
  44         yylloc->step(); \
  45         N \
  46     } else L \
  47 }
  48
  49 #define L { \
  50     yylloc->step(); \
  51     yylloc->columns(yyleng); \
  52 }
  53
  54 int H(char c) {
  55     if (c >= '0' && c <= '9')
  56         return c - '0';
  57     if (c >= 'a' && c <= 'f')
  58         return c - 'a' + 10;
  59     if (c >= 'A' && c <= 'F')
  60         return c - 'A' + 10;
  61     return -1;
  62 }
  63
  64 #define YY_INPUT(data, value, size) { \
  65     if (yyextra->file_ != NULL) { \
  66         size_t copy(fread(data, 1, size, yyextra->file_)); \
  67         value = copy == 0 ? YY_NULL : copy; \
  68     } else if (yyextra->size_ == 0) \
  69         value = YY_NULL; \
  70     else { \
  71         size_t copy(std::min(size, yyextra->size_)); \
  72         memcpy(data, yyextra->data_, copy); \
  73         yyextra->data_ += copy; \
  74         yyextra->size_ -= copy; \
  75         value = copy; \
  76     } \
  77 }
  78
  79 %}
  80
  81 %option prefix="cy"
  82 %option bison-bridge
  83 %option bison-locations
  84 %option noyywrap
  85 %option yylineno
  86 %option nounput
  87 %option interactive
  88 %option reentrant
  89
  90 Exponent [eE][+-]?[0-9]+
  91 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
  92
  93 IdentifierStart [a-zA-Z$_]
  94 IdentifierPart  [a-zA-Z$_0-9]
  95
  96 NonTerminator [^\n]
  97 BackslashSequence \\{NonTerminator}
  98 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
  99 RegularExpressionChar [^\n\\/]|{BackslashSequence}
 100 RegularExpressionFlags {IdentifierPart}*
 101 RegularExpressionChars {RegularExpressionChar}*
 102 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
 103
 104 %s Div
 105 %s RegExp
 106
 107 %%
 108
 109 <RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} E("")
 110
 111 \/\/[^\n]* L
 112 \/\*(\n|[^\*]|\*[^/])*\*\/ M
 113
 114 @begin E4X
 115 <RegExp>\<!--(\n|[^-]|-[^-])*-->
 116 <RegExp>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]>
 117 <RegExp>\<?(\n|[^?]|\?[^>])*?>
 118
 119 "@"    L C return tk::At;
 120 "::"   L C return tk::ColonColon;
 121 "<>"   L C return tk::LeftRight;
 122 "</>"  L C return tk::LeftSlashRight;
 123 ".."   L C return tk::PeriodPeriod;
 124 "/>"   L C return tk::SlashRight;
 125 @end
 126
 127 "&"    L C return tk::Ampersand;
 128 "&&"   L C return tk::AmpersandAmpersand;
 129 "&="   L C return tk::AmpersandEqual;
 130 "^"    L C return tk::Carrot;
 131 "^="   L C return tk::CarrotEqual;
 132 "="    L C return tk::Equal;
 133 "=="   L C return tk::EqualEqual;
 134 "==="  L C return tk::EqualEqualEqual;
 135 "!"    L C return tk::Exclamation;
 136 "!="   L C return tk::ExclamationEqual;
 137 "!=="  L C return tk::ExclamationEqualEqual;
 138 "-"    L C return tk::Hyphen;
 139 "-="   L C return tk::HyphenEqual;
 140 "--"   L C return yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen;
 141 "->"   L C return tk::HyphenRight;
 142 "<"    L C return tk::Left;
 143 "<="   L C return tk::LeftEqual;
 144 "<<"   L C return tk::LeftLeft;
 145 "<<="  L C return tk::LeftLeftEqual;
 146 "%"    L C return tk::Percent;
 147 "%="   L C return tk::PercentEqual;
 148 "."    L C return tk::Period;
 149 "|"    L C return tk::Pipe;
 150 "|="   L C return tk::PipeEqual;
 151 "||"   L C return tk::PipePipe;
 152 "+"    L C return tk::Plus;
 153 "+="   L C return tk::PlusEqual;
 154 "++"   L C return yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus;
 155 ">"    L C return tk::Right;
 156 ">="   L C return tk::RightEqual;
 157 ">>"   L C return tk::RightRight;
 158 ">>="  L C return tk::RightRightEqual;
 159 ">>>"  L C return tk::RightRightRight;
 160 ">>>=" L C return tk::RightRightRightEqual;
 161 "*"    L C return tk::Star;
 162 "*="   L C return tk::StarEqual;
 163 "~"    L C return tk::Tilde;
 164
 165 <Div>"/"  L C return tk::Slash;
 166 <Div>"/=" L C return tk::SlashEqual;
 167
 168 ":"    L C return tk::Colon;
 169 ","    L C return tk::Comma;
 170 "?"    L C return tk::Question;
 171 ";"    L C return tk::SemiColon;
 172
 173 "("    L C return tk::OpenParen;
 174 ")"    L C return tk::CloseParen;
 175
 176 "{"    L C return tk::OpenBrace;
 177 "}"    L C return tk::CloseBrace;
 178
 179 "["    L C return tk::OpenBracket;
 180 "]"    L C return tk::CloseBracket;
 181
 182 @begin ObjectiveC
 183 "@class"       L C return tk::AtClass;
 184 "@end"         L C return tk::AtEnd;
 185 "@selector"    L C return tk::AtSelector;
 186 @end
 187
 188 "false"        L C yylval->false_ = new(yyextra->pool_) CYFalse(); return tk::False;
 189 "null"         L C yylval->null_ = new(yyextra->pool_) CYNull(); return tk::Null;
 190 "true"         L C yylval->true_ = new(yyextra->pool_) CYTrue(); return tk::True;
 191
 192 "break"        L R yylval->word_ = new(yyextra->pool_) CYWord("break"); return tk::Break;
 193 "case"         L C yylval->word_ = new(yyextra->pool_) CYWord("case"); return tk::Case;
 194 "catch"        L C yylval->word_ = new(yyextra->pool_) CYWord("catch"); return tk::Catch;
 195 "continue"     L R yylval->word_ = new(yyextra->pool_) CYWord("continue"); return tk::Continue;
 196 "default"      L C yylval->word_ = new(yyextra->pool_) CYWord("default"); return tk::Default;
 197 "delete"       L C yylval->word_ = new(yyextra->pool_) CYWord("delete"); return tk::Delete;
 198 "do"           L C yylval->word_ = new(yyextra->pool_) CYWord("do"); return tk::Do;
 199 "else"         L C yylval->word_ = new(yyextra->pool_) CYWord("else"); return tk::Else;
 200 "finally"      L C yylval->word_ = new(yyextra->pool_) CYWord("finally"); return tk::Finally;
 201 "for"          L C yylval->word_ = new(yyextra->pool_) CYWord("for"); return tk::For;
 202 "function"     L C yylval->word_ = new(yyextra->pool_) CYWord("function"); return tk::Function;
 203 "if"           L C yylval->word_ = new(yyextra->pool_) CYWord("if"); return tk::If;
 204 "in"           L C yylval->word_ = new(yyextra->pool_) CYWord("in"); return tk::In;
 205 "instanceof"   L C yylval->word_ = new(yyextra->pool_) CYWord("instanceof"); return tk::InstanceOf;
 206 "new"          L C yylval->word_ = new(yyextra->pool_) CYWord("new"); return tk::New;
 207 "return"       L R yylval->word_ = new(yyextra->pool_) CYWord("return"); return tk::Return;
 208 "switch"       L C yylval->word_ = new(yyextra->pool_) CYWord("switch"); return tk::Switch;
 209 "this"         L C yylval->this_ = new(yyextra->pool_) CYThis(); return tk::This;
 210 "throw"        L R yylval->word_ = new(yyextra->pool_) CYWord("throw"); return tk::Throw;
 211 "try"          L C yylval->word_ = new(yyextra->pool_) CYWord("try"); return tk::Try;
 212 "typeof"       L C yylval->word_ = new(yyextra->pool_) CYWord("typeof"); return tk::TypeOf;
 213 "var"          L C yylval->word_ = new(yyextra->pool_) CYWord("var"); return tk::Var;
 214 "void"         L C yylval->word_ = new(yyextra->pool_) CYWord("void"); return tk::Void;
 215 "while"        L C yylval->word_ = new(yyextra->pool_) CYWord("while"); return tk::While;
 216 "with"         L C yylval->word_ = new(yyextra->pool_) CYWord("with"); return tk::With;
 217
 218 "debugger"     L C yylval->word_ = new(yyextra->pool_) CYWord("debugger"); return tk::Debugger;
 219
 220 "const"        L C yylval->word_ = new(yyextra->pool_) CYWord("const"); return tk::Const;
 221
 222 "class"        L C yylval->word_ = new(yyextra->pool_) CYWord("class"); return tk::Class;
 223 "enum"         L C yylval->word_ = new(yyextra->pool_) CYWord("enum"); return tk::Enum;
 224 "export"       L C yylval->word_ = new(yyextra->pool_) CYWord("export"); return tk::Export;
 225 "extends"      L C yylval->word_ = new(yyextra->pool_) CYWord("extends"); return tk::Extends;
 226 "import"       L C yylval->word_ = new(yyextra->pool_) CYWord("import"); return tk::Import;
 227 "super"        L C yylval->word_ = new(yyextra->pool_) CYWord("super"); return tk::Super;
 228
 229 "implements"   L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("implements"); return tk::Implements;
 230 "interface"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("interface"); return tk::Interface;
 231 "package"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("package"); return tk::Package;
 232 "private"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("private"); return tk::Private;
 233 "protected"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("protected"); return tk::Protected;
 234 "public"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("public"); return tk::Public;
 235 "static"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("static"); return tk::Static;
 236
 237 "abstract"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("abstract"); return tk::Abstract;
 238 "boolean"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("boolean"); return tk::Boolean;
 239 "byte"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("byte"); return tk::Byte;
 240 "char"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("char"); return tk::Char;
 241 "double"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("double"); return tk::Double;
 242 "final"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("final"); return tk::Final;
 243 "float"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("float"); return tk::Float;
 244 "goto"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("goto"); return tk::Goto;
 245 "int"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("int"); return tk::Int;
 246 "long"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("long"); return tk::Long;
 247 "native"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("native"); return tk::Native;
 248 "short"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("short"); return tk::Short;
 249 "synchronized" L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("synchronized"); return tk::Synchronized;
 250 "throws"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("throws"); return tk::Throws;
 251 "transient"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("transient"); return tk::Transient;
 252 "volatile"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("volatile"); return tk::Volatile;
 253
 254 "let"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("let"); return tk::Let;
 255 "yield"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("yield"); return tk::Yield;
 256
 257 "each"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("each"); return tk::Each;
 258
 259 {IdentifierStart}{IdentifierPart}* L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); return tk::Identifier_;
 260
 261 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? L C yylval->number_ = new(yyextra->pool_) CYNumber(strtod(yytext, NULL)); return tk::NumericLiteral;
 262
 263 0[xX][0-9a-fA-F]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 16)); return tk::NumericLiteral;
 264
 265 0[bB][0-1]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 2)); return tk::NumericLiteral;
 266
 267 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 268     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng)));
 269     char *local(value);
 270
 271     for (int i(1); i != yyleng - 1; ++i) {
 272         char next(yytext[i]);
 273
 274         if (yytext[i] == '\\')
 275             switch (next = yytext[++i]) {
 276                 case '\n': continue;
 277                 case '\\': next = '\\'; break;
 278                 case '\'': next = '\''; break;
 279                 case '"': next = '"'; break;
 280                 case 'b': next = '\b'; break;
 281                 case 'f': next = '\f'; break;
 282                 case 'n': next = '\n'; break;
 283                 case 'r': next = '\r'; break;
 284                 case 't': next = '\t'; break;
 285                 case 'v': next = '\v'; break;
 286                 case '0': next = '\0'; break;
 287
 288                 case 'x':
 289                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 290                     i += 2;
 291                 break;
 292             }
 293
 294         *local++ = next;
 295     }
 296
 297     *local = '\0';
 298     yylval->string_ = new(yyextra->pool_) CYString(value, local - value);
 299     return tk::StringLiteral;
 300 }
 301
 302 \r?\n yylloc->end.lines(); yylloc->step(); N
 303
 304 [ \t] L
 305 <<EOF>> L yyterminate();
 306
 307 . L {
 308     CYDriver::Error error;
 309     error.location_ = *yylloc;
 310     error.message_ = "syntax error, unknown token";
 311     yyextra->errors_.push_back(error);
 312     yyterminate();
 313 }
 314
 315 %%
 316
 317 void CYDriver::ScannerInit() {
 318     cylex_init(&scanner_);
 319     cyset_extra(this, scanner_);
 320 }
 321
 322 void CYDriver::ScannerDestroy() {
 323     cylex_destroy(scanner_);
 324 }
 325
 326 void CYDriver::BeginCondition(Condition condition) {
 327     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 328
 329     switch (condition) {
 330         case RegExpCondition:
 331             BEGIN(RegExp);
 332             break;
 333         default:
 334             _assert(false);
 335     }
 336 }