Cycript.y

   1 /* Cycript - Remove Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 %code top {
  41 #include "Cycript.tab.hh"
  42 #define scanner driver.scanner_
  43 #define YYSTACKEXPANDABLE 1
  44 }
  45
  46 %code requires {
  47 #include "Parser.hpp"
  48
  49 typedef struct {
  50     bool newline_;
  51
  52     union {
  53         bool bool_;
  54
  55         CYArgument *argument_;
  56         CYAssignment *assignment_;
  57         CYBoolean *boolean_;
  58         CYClause *clause_;
  59         CYCatch *catch_;
  60         CYClassName *className_;
  61         CYCompound *compound_;
  62         CYDeclaration *declaration_;
  63         CYDeclarations *declarations_;
  64         CYElement *element_;
  65         CYExpression *expression_;
  66         CYFalse *false_;
  67         CYField *field_;
  68         CYForInitialiser *for_;
  69         CYForInInitialiser *forin_;
  70         CYFunctionParameter *functionParameter_;
  71         CYIdentifier *identifier_;
  72         CYInfix *infix_;
  73         CYLiteral *literal_;
  74         CYMember *member_;
  75         CYMessage *message_;
  76         CYMessageParameter *messageParameter_;
  77         CYNull *null_;
  78         CYNumber *number_;
  79         CYProperty *property_;
  80         CYPropertyName *propertyName_;
  81         CYSelectorPart *selector_;
  82         CYSource *source_;
  83         CYStatement *statement_;
  84         CYString *string_;
  85         CYThis *this_;
  86         CYTrue *true_;
  87         CYWord *word_;
  88     };
  89 } YYSTYPE;
  90
  91 }
  92
  93 %code provides {
  94 int cylex(YYSTYPE *lvalp, cy::location *llocp, void *scanner);
  95 }
  96
  97 %name-prefix "cy"
  98
  99 %language "C++"
 100 %locations
 101
 102 %initial-action {
 103     @$.begin.filename = @$.end.filename = &driver.filename_;
 104 };
 105
 106 %defines
 107
 108 %debug
 109 %error-verbose
 110
 111 %parse-param { CYDriver &driver }
 112 %lex-param { void *scanner }
 113
 114 %token Ampersand "&"
 115 %token AmpersandAmpersand "&&"
 116 %token AmpersandEqual "&="
 117 %token Carrot "^"
 118 %token CarrotEqual "^="
 119 %token Equal "="
 120 %token EqualEqual "=="
 121 %token EqualEqualEqual "==="
 122 %token Exclamation "!"
 123 %token ExclamationEqual "!="
 124 %token ExclamationEqualEqual "!=="
 125 %token Hyphen "-"
 126 %token HyphenEqual "-="
 127 %token HyphenHyphen "--"
 128 %token HyphenHyphen_ "\n--"
 129 %token HyphenRight "->"
 130 %token Left "<"
 131 %token LeftEqual "<="
 132 %token LeftLeft "<<"
 133 %token LeftLeftEqual "<<="
 134 %token Percent "%"
 135 %token PercentEqual "%="
 136 %token Period "."
 137 %token Pipe "|"
 138 %token PipeEqual "|="
 139 %token PipePipe "||"
 140 %token Plus "+"
 141 %token PlusEqual "+="
 142 %token PlusPlus "++"
 143 %token PlusPlus_ "\n++"
 144 %token Right ">"
 145 %token RightEqual ">="
 146 %token RightRight ">>"
 147 %token RightRightEqual ">>="
 148 %token RightRightRight ">>>"
 149 %token RightRightRightEqual ">>>="
 150 %token Slash "/"
 151 %token SlashEqual "/="
 152 %token Star "*"
 153 %token StarEqual "*="
 154 %token Tilde "~"
 155
 156 %token Colon ":"
 157 %token Comma ","
 158 %token Question "?"
 159 %token SemiColon ";"
 160 %token NewLine "\n"
 161
 162 %token OpenParen "("
 163 %token CloseParen ")"
 164
 165 %token OpenBrace "{"
 166 %token CloseBrace "}"
 167
 168 %token OpenBracket "["
 169 %token CloseBracket "]"
 170
 171 %token AtClass "@class"
 172 %token AtSelector "@selector"
 173 %token AtEnd "@end"
 174
 175 %token <word_> Break "break"
 176 %token <word_> Case "case"
 177 %token <word_> Catch "catch"
 178 %token <word_> Continue "continue"
 179 %token <word_> Default "default"
 180 %token <word_> Delete "delete"
 181 %token <word_> Do "do"
 182 %token <word_> Else "else"
 183 %token <false_> False "false"
 184 %token <word_> Finally "finally"
 185 %token <word_> For "for"
 186 %token <word_> Function "function"
 187 %token <word_> If "if"
 188 %token <word_> In "in"
 189 %token <word_> InstanceOf "instanceof"
 190 %token <word_> New "new"
 191 %token <null_> Null "null"
 192 %token <word_> Return "return"
 193 %token <word_> Switch "switch"
 194 %token <this_> This "this"
 195 %token <word_> Throw "throw"
 196 %token <true_> True "true"
 197 %token <word_> Try "try"
 198 %token <word_> TypeOf "typeof"
 199 %token <word_> Var "var"
 200 %token <word_> Void "void"
 201 %token <word_> While "while"
 202 %token <word_> With "with"
 203
 204 %token <word_> Abstract "abstract"
 205 %token <word_> Boolean "boolean"
 206 %token <word_> Byte "byte"
 207 %token <word_> Char "char"
 208 %token <word_> Class "class"
 209 %token <word_> Const "const"
 210 %token <word_> Debugger "debugger"
 211 %token <word_> Double "double"
 212 %token <word_> Enum "enum"
 213 %token <word_> Export "export"
 214 %token <word_> Extends "extends"
 215 %token <word_> Final "final"
 216 %token <word_> Float "float"
 217 %token <word_> Goto "goto"
 218 %token <word_> Implements "implements"
 219 %token <word_> Import "import"
 220 %token <word_> Int "int"
 221 %token <word_> Interface "interface"
 222 %token <word_> Long "long"
 223 %token <word_> Native "native"
 224 %token <word_> Package "package"
 225 %token <word_> Private "private"
 226 %token <word_> Protected "protected"
 227 %token <word_> Public "public"
 228 %token <word_> Short "short"
 229 %token <word_> Static "static"
 230 %token <word_> Super "super"
 231 %token <word_> Synchronized "synchronized"
 232 %token <word_> Throws "throws"
 233 %token <word_> Transient "transient"
 234 %token <word_> Volatile "volatile"
 235
 236 %token <identifier_> Identifier
 237 %token <number_> NumericLiteral
 238 %token <string_> StringLiteral
 239
 240 %type <expression_> AdditiveExpression
 241 %type <expression_> AdditiveExpressionNoBF
 242 %type <argument_> ArgumentList
 243 %type <argument_> ArgumentList_
 244 %type <argument_> ArgumentListOpt
 245 %type <argument_> Arguments
 246 %type <literal_> ArrayLiteral
 247 %type <expression_> AssigneeExpression
 248 %type <expression_> AssigneeExpression_
 249 %type <expression_> AssigneeExpressionNoBF
 250 %type <expression_> AssignmentExpression
 251 %type <assignment_> AssignmentExpression_
 252 %type <expression_> AssignmentExpressionNoBF
 253 %type <expression_> AssignmentExpressionNoIn
 254 %type <expression_> BitwiseANDExpression
 255 %type <expression_> BitwiseANDExpressionNoBF
 256 %type <expression_> BitwiseANDExpressionNoIn
 257 %type <statement_> Block
 258 %type <boolean_> BooleanLiteral
 259 %type <expression_> BitwiseORExpression
 260 %type <expression_> BitwiseORExpressionNoBF
 261 %type <expression_> BitwiseORExpressionNoIn
 262 %type <expression_> BitwiseXORExpression
 263 %type <expression_> BitwiseXORExpressionNoBF
 264 %type <expression_> BitwiseXORExpressionNoIn
 265 %type <statement_> BreakStatement
 266 %type <expression_> CallExpression
 267 %type <expression_> CallExpressionNoBF
 268 %type <clause_> CaseBlock
 269 %type <clause_> CaseClause
 270 %type <clause_> CaseClausesOpt
 271 %type <catch_> CatchOpt
 272 %type <statement_> CategoryStatement
 273 %type <expression_> ClassExpression
 274 %type <message_> ClassMessageDeclaration
 275 %type <message_> ClassMessageDeclarationListOpt
 276 %type <className_> ClassName
 277 %type <className_> ClassNameOpt
 278 %type <expression_> ClassSuperOpt
 279 %type <field_> ClassFieldList
 280 %type <expression_> ConditionalExpression
 281 %type <expression_> ConditionalExpressionNoBF
 282 %type <expression_> ConditionalExpressionNoIn
 283 %type <statement_> ContinueStatement
 284 %type <clause_> DefaultClause
 285 %type <statement_> DoWhileStatement
 286 %type <expression_> Element
 287 %type <expression_> ElementOpt
 288 %type <element_> ElementList
 289 %type <element_> ElementListOpt
 290 %type <statement_> ElseStatementOpt
 291 %type <statement_> EmptyStatement
 292 %type <expression_> EqualityExpression
 293 %type <expression_> EqualityExpressionNoBF
 294 %type <expression_> EqualityExpressionNoIn
 295 %type <expression_> Expression
 296 %type <expression_> ExpressionOpt
 297 %type <compound_> Expression_
 298 %type <expression_> ExpressionNoBF
 299 %type <expression_> ExpressionNoIn
 300 %type <compound_> ExpressionNoIn_
 301 %type <expression_> ExpressionNoInOpt
 302 %type <statement_> ExpressionStatement
 303 %type <statement_> FinallyOpt
 304 %type <statement_> ForStatement
 305 %type <for_> ForStatementInitialiser
 306 %type <statement_> ForInStatement
 307 %type <forin_> ForInStatementInitialiser
 308 %type <functionParameter_> FormalParameterList
 309 %type <functionParameter_> FormalParameterList_
 310 %type <source_> FunctionBody
 311 %type <source_> FunctionDeclaration
 312 %type <expression_> FunctionExpression
 313 %type <identifier_> IdentifierOpt
 314 %type <statement_> IfStatement
 315 %type <expression_> Initialiser
 316 %type <expression_> InitialiserOpt
 317 %type <expression_> InitialiserNoIn
 318 %type <expression_> InitialiserNoInOpt
 319 %type <statement_> IterationStatement
 320 %type <statement_> LabelledStatement
 321 %type <expression_> LeftHandSideExpression
 322 %type <expression_> LeftHandSideExpressionNoBF
 323 %type <literal_> Literal
 324 %type <expression_> LogicalANDExpression
 325 %type <expression_> LogicalANDExpressionNoBF
 326 %type <expression_> LogicalANDExpressionNoIn
 327 %type <expression_> LogicalORExpression
 328 %type <expression_> LogicalORExpressionNoBF
 329 %type <expression_> LogicalORExpressionNoIn
 330 %type <member_> MemberAccess
 331 %type <expression_> MemberExpression
 332 %type <expression_> MemberExpression_
 333 %type <expression_> MemberExpressionNoBF
 334 %type <messageParameter_> MessageParameter
 335 %type <messageParameter_> MessageParameters
 336 %type <messageParameter_> MessageParameterList
 337 %type <messageParameter_> MessageParameterListOpt
 338 %type <bool_> MessageScope
 339 %type <expression_> MultiplicativeExpression
 340 %type <expression_> MultiplicativeExpressionNoBF
 341 %type <expression_> NewExpression
 342 %type <expression_> NewExpression_
 343 %type <expression_> NewExpressionNoBF
 344 %type <null_> NullLiteral
 345 %type <literal_> ObjectLiteral
 346 %type <expression_> PostfixExpression
 347 %type <expression_> PostfixExpressionNoBF
 348 %type <expression_> PrimaryExpression
 349 %type <expression_> PrimaryExpression_
 350 %type <expression_> PrimaryExpressionNoBF
 351 %type <source_> Program
 352 %type <propertyName_> PropertyName
 353 %type <property_> PropertyNameAndValueList
 354 %type <property_> PropertyNameAndValueList_
 355 %type <property_> PropertyNameAndValueListOpt
 356 %type <expression_> RelationalExpression
 357 %type <infix_> RelationalExpression_
 358 %type <expression_> RelationalExpressionNoBF
 359 %type <expression_> RelationalExpressionNoIn
 360 %type <infix_> RelationalExpressionNoIn_
 361 %type <statement_> ReturnStatement
 362 %type <selector_> SelectorExpression
 363 %type <selector_> SelectorExpression_
 364 %type <selector_> SelectorExpressionOpt
 365 %type <expression_> ShiftExpression
 366 %type <expression_> ShiftExpressionNoBF
 367 %type <source_> SourceElement
 368 %type <source_> SourceElements
 369 %type <statement_> Statement
 370 %type <statement_> StatementList
 371 %type <statement_> StatementListOpt
 372 %type <statement_> SwitchStatement
 373 %type <statement_> ThrowStatement
 374 %type <statement_> TryStatement
 375 %type <expression_> TypeOpt
 376 %type <expression_> UnaryExpression
 377 %type <expression_> UnaryExpression_
 378 %type <expression_> UnaryExpressionNoBF
 379 %type <declaration_> VariableDeclaration
 380 %type <declaration_> VariableDeclarationNoIn
 381 %type <declarations_> VariableDeclarationList
 382 %type <declarations_> VariableDeclarationList_
 383 %type <declarations_> VariableDeclarationListNoIn
 384 %type <declarations_> VariableDeclarationListNoIn_
 385 %type <statement_> VariableStatement
 386 %type <statement_> WhileStatement
 387 %type <statement_> WithStatement
 388 %type <word_> Word
 389 %type <word_> WordOpt
 390
 391 %type <expression_> MessageExpression
 392 %type <argument_> SelectorCall
 393 %type <argument_> SelectorCall_
 394 %type <argument_> SelectorList
 395 %type <argument_> VariadicCall
 396
 397 %left "*" "/" "%"
 398 %left "+" "-"
 399 %left "<<" ">>" ">>>"
 400 %left "<" ">" "<=" ">=" "instanceof" "in"
 401 %left "==" "!=" "===" "!=="
 402 %left "&"
 403 %left "^"
 404 %left "|"
 405 %left "&&"
 406 %left "||"
 407
 408 %right "=" "*=" "/=" "%=" "+=" "-=" "<<=" ">>=" ">>>=" "&=" "^=" "|="
 409
 410 %nonassoc "if"
 411 %nonassoc "else"
 412
 413 %start Program
 414
 415 %%
 416
 417 TerminatorOpt
 418     : ";"
 419     | "\n"
 420     | error { yyerrok; driver.errors_.pop_back(); }
 421     ;
 422
 423 Terminator
 424     : ";"
 425     | "\n"
 426     | error { if (yychar != 0 && yychar != cy::parser::token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } }
 427     ;
 428
 429 CommaOpt
 430     : ","
 431     |
 432     ;
 433
 434 NewLineOpt
 435     : "\n"
 436     |
 437     ;
 438
 439 WordOpt
 440     : Word { $$ = $1; }
 441     | { $$ = NULL; }
 442     ;
 443
 444 Word
 445     : Identifier { $$ = $1; }
 446     | "abstract" { $$ = $1; }
 447     | "boolean" { $$ = $1; }
 448     | "break" NewLineOpt { $$ = $1; }
 449     | "byte" { $$ = $1; }
 450     | "case" { $$ = $1; }
 451     | "catch" { $$ = $1; }
 452     | "char" { $$ = $1; }
 453     | "class" { $$ = $1; }
 454     | "const" { $$ = $1; }
 455     | "continue" NewLineOpt { $$ = $1; }
 456     | "debugger" { $$ = $1; }
 457     | "default" { $$ = $1; }
 458     | "delete" { $$ = $1; }
 459     | "do" { $$ = $1; }
 460     | "double" { $$ = $1; }
 461     | "else" { $$ = $1; }
 462     | "enum" { $$ = $1; }
 463     | "export" { $$ = $1; }
 464     | "extends" { $$ = $1; }
 465     | "false" { $$ = $1; }
 466     | "final" { $$ = $1; }
 467     | "finally" { $$ = $1; }
 468     | "float" { $$ = $1; }
 469     | "for" { $$ = $1; }
 470     | "function" { $$ = $1; }
 471     | "goto" { $$ = $1; }
 472     | "if" { $$ = $1; }
 473     | "implements" { $$ = $1; }
 474     | "import" { $$ = $1; }
 475     /* XXX: | "in" { $$ = $1; } */
 476     /* XXX: | "instanceof" { $$ = $1; } */
 477     | "int" { $$ = $1; }
 478     | "interface" { $$ = $1; }
 479     | "long" { $$ = $1; }
 480     | "native" { $$ = $1; }
 481     | "new" { $$ = $1; }
 482     | "null" { $$ = $1; }
 483     | "package" { $$ = $1; }
 484     | "private" { $$ = $1; }
 485     | "protected" { $$ = $1; }
 486     | "public" { $$ = $1; }
 487     | "return" NewLineOpt { $$ = $1; }
 488     | "short" { $$ = $1; }
 489     | "static" { $$ = $1; }
 490     | "super" { $$ = $1; }
 491     | "switch" { $$ = $1; }
 492     | "synchronized" { $$ = $1; }
 493     | "this" { $$ = $1; }
 494     | "throw" NewLineOpt { $$ = $1; }
 495     | "throws" { $$ = $1; }
 496     | "transient" { $$ = $1; }
 497     | "true" { $$ = $1; }
 498     | "try" { $$ = $1; }
 499     | "typeof" { $$ = $1; }
 500     | "var" { $$ = $1; }
 501     | "void" { $$ = $1; }
 502     | "volatile" { $$ = $1; }
 503     | "while" { $$ = $1; }
 504     | "with" { $$ = $1; }
 505     ;
 506
 507 IdentifierOpt
 508     : Identifier { $$ = $1; }
 509     | { $$ = NULL; }
 510     ;
 511
 512 Literal
 513     : NullLiteral { $$ = $1; }
 514     | BooleanLiteral { $$ = $1; }
 515     | NumericLiteral { $$ = $1; }
 516     | StringLiteral { $$ = $1; }
 517     ;
 518
 519 NullLiteral
 520     : "null" { $$ = $1; }
 521     ;
 522
 523 BooleanLiteral
 524     : "true" { $$ = $1; }
 525     | "false" { $$ = $1; }
 526     ;
 527
 528 /* 11.1 Primary Expressions {{{ */
 529 PrimaryExpression_
 530     : "this" { $$ = $1; }
 531     | Identifier { $$ = new(driver.pool_) CYVariable($1); }
 532     | Literal { $$ = $1; }
 533     | ArrayLiteral { $$ = $1; }
 534     | "(" Expression ")" { $$ = $2; }
 535     ;
 536
 537 PrimaryExpression
 538     : ObjectLiteral { $$ = $1; }
 539     | PrimaryExpression_ { $$ = $1; }
 540     ;
 541
 542 PrimaryExpressionNoBF
 543     : PrimaryExpression_ { $$ = $1; }
 544     ;
 545 /* }}} */
 546 /* 11.1.4 Array Initialiser {{{ */
 547 ArrayLiteral
 548     : "[" ElementListOpt "]" { $$ = new(driver.pool_) CYArray($2); }
 549     ;
 550
 551 Element
 552     : AssignmentExpression { $$ = $1; }
 553     ;
 554
 555 ElementOpt
 556     : Element { $$ = $1; }
 557     | { $$ = NULL; }
 558     ;
 559
 560 ElementListOpt
 561     : ElementList { $$ = $1; }
 562     | { $$ = NULL; }
 563     ;
 564
 565 ElementList
 566     : ElementOpt "," ElementListOpt { $$ = new(driver.pool_) CYElement($1, $3); }
 567     | Element { $$ = new(driver.pool_) CYElement($1, NULL); }
 568     ;
 569 /* }}} */
 570 /* 11.1.5 Object Initialiser {{{ */
 571 ObjectLiteral
 572     : "{" PropertyNameAndValueListOpt "}" { $$ = new(driver.pool_) CYObject($2); }
 573     ;
 574
 575 PropertyNameAndValueList_
 576     : "," PropertyNameAndValueList { $$ = $2; }
 577     | CommaOpt { $$ = NULL; }
 578     ;
 579
 580 PropertyNameAndValueListOpt
 581     : PropertyNameAndValueList { $$ = $1; }
 582     | { $$ = NULL; }
 583     ;
 584
 585 PropertyNameAndValueList
 586     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = new(driver.pool_) CYProperty($1, $3, $4); }
 587     ;
 588
 589 PropertyName
 590     : Identifier { $$ = $1; }
 591     | StringLiteral { $$ = $1; }
 592     | NumericLiteral { $$ = $1; }
 593     ;
 594 /* }}} */
 595
 596 MemberExpression_
 597     : "new" MemberExpression Arguments { $$ = new(driver.pool_) CYNew($2, $3); }
 598     ;
 599
 600 MemberAccess
 601     : "[" Expression "]" { $$ = new(driver.pool_) CYDirectMember(NULL, $2); }
 602     | "." Identifier { $$ = new(driver.pool_) CYDirectMember(NULL, new(driver.pool_) CYString($2)); }
 603     ;
 604
 605 MemberExpression
 606     : PrimaryExpression { $$ = $1; }
 607     | FunctionExpression { $$ = $1; }
 608     | MemberExpression MemberAccess { $2->SetLeft($1); $$ = $2; }
 609     | MemberExpression_ { $$ = $1; }
 610     ;
 611
 612 MemberExpressionNoBF
 613     : PrimaryExpressionNoBF { $$ = $1; }
 614     | MemberExpressionNoBF MemberAccess { $2->SetLeft($1); $$ = $2; }
 615     | MemberExpression_ { $$ = $1; }
 616     ;
 617
 618 NewExpression_
 619     : "new" NewExpression { $$ = new(driver.pool_) CYNew($2, NULL); }
 620     ;
 621
 622 NewExpression
 623     : MemberExpression { $$ = $1; }
 624     | NewExpression_ { $$ = $1; }
 625     ;
 626
 627 NewExpressionNoBF
 628     : MemberExpressionNoBF { $$ = $1; }
 629     | NewExpression_ { $$ = $1; }
 630     ;
 631
 632 CallExpression
 633     : MemberExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 634     | CallExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 635     | CallExpression MemberAccess { $2->SetLeft($1); $$ = $2; }
 636     ;
 637
 638 CallExpressionNoBF
 639     : MemberExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 640     | CallExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 641     | CallExpressionNoBF MemberAccess { $2->SetLeft($1); $$ = $2; }
 642     ;
 643
 644 ArgumentList_
 645     : "," ArgumentList { $$ = $2; }
 646     | { $$ = NULL; }
 647     ;
 648
 649 ArgumentListOpt
 650     : ArgumentList { $$ = $1; }
 651     | { $$ = NULL; }
 652     ;
 653
 654 ArgumentList
 655     : AssignmentExpression ArgumentList_ { $$ = new(driver.pool_) CYArgument(NULL, $1, $2); }
 656     ;
 657
 658 Arguments
 659     : "(" ArgumentListOpt ")" { $$ = $2; }
 660     ;
 661
 662 LeftHandSideExpression
 663     : NewExpression { $$ = $1; }
 664     | CallExpression { $$ = $1; }
 665     ;
 666
 667 LeftHandSideExpressionNoBF
 668     : NewExpressionNoBF { $$ = $1; }
 669     | CallExpressionNoBF { $$ = $1; }
 670     ;
 671
 672 PostfixExpression
 673     : AssigneeExpression { $$ = $1; }
 674     | LeftHandSideExpression "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 675     | LeftHandSideExpression "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 676     ;
 677
 678 PostfixExpressionNoBF
 679     : AssigneeExpressionNoBF { $$ = $1; }
 680     | LeftHandSideExpressionNoBF "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 681     | LeftHandSideExpressionNoBF "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 682     ;
 683
 684 UnaryExpression_
 685     : "delete" UnaryExpression { $$ = new(driver.pool_) CYDelete($2); }
 686     | "void" UnaryExpression { $$ = new(driver.pool_) CYVoid($2); }
 687     | "typeof" UnaryExpression { $$ = new(driver.pool_) CYTypeOf($2); }
 688     | "++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 689     | "\n++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 690     | "--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 691     | "\n--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 692     | "+" UnaryExpression { $$ = $2; }
 693     | "-" UnaryExpression { $$ = new(driver.pool_) CYNegate($2); }
 694     | "~" UnaryExpression { $$ = new(driver.pool_) CYBitwiseNot($2); }
 695     | "!" UnaryExpression { $$ = new(driver.pool_) CYLogicalNot($2); }
 696     ;
 697
 698 UnaryExpression
 699     : PostfixExpression { $$ = $1; }
 700     | UnaryExpression_ { $$ = $1; }
 701     ;
 702
 703 UnaryExpressionNoBF
 704     : PostfixExpressionNoBF { $$ = $1; }
 705     | UnaryExpression_ { $$ = $1; }
 706     ;
 707
 708 MultiplicativeExpression
 709     : UnaryExpression { $$ = $1; }
 710     | MultiplicativeExpression "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 711     | MultiplicativeExpression "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 712     | MultiplicativeExpression "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 713     ;
 714
 715 MultiplicativeExpressionNoBF
 716     : UnaryExpressionNoBF { $$ = $1; }
 717     | MultiplicativeExpressionNoBF "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 718     | MultiplicativeExpressionNoBF "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 719     | MultiplicativeExpressionNoBF "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 720     ;
 721
 722 AdditiveExpression
 723     : MultiplicativeExpression { $$ = $1; }
 724     | AdditiveExpression "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 725     | AdditiveExpression "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 726     ;
 727
 728 AdditiveExpressionNoBF
 729     : MultiplicativeExpressionNoBF { $$ = $1; }
 730     | AdditiveExpressionNoBF "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 731     | AdditiveExpressionNoBF "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 732     ;
 733
 734 ShiftExpression
 735     : AdditiveExpression { $$ = $1; }
 736     | ShiftExpression "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 737     | ShiftExpression ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 738     | ShiftExpression ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 739     ;
 740
 741 ShiftExpressionNoBF
 742     : AdditiveExpressionNoBF { $$ = $1; }
 743     | ShiftExpressionNoBF "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 744     | ShiftExpressionNoBF ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 745     | ShiftExpressionNoBF ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 746     ;
 747
 748 RelationalExpressionNoIn_
 749     : "<" ShiftExpression { $$ = new(driver.pool_) CYLess(NULL, $2); }
 750     | ">" ShiftExpression { $$ = new(driver.pool_) CYGreater(NULL, $2); }
 751     | "<=" ShiftExpression { $$ = new(driver.pool_) CYLessOrEqual(NULL, $2); }
 752     | ">=" ShiftExpression { $$ = new(driver.pool_) CYGreaterOrEqual(NULL, $2); }
 753     | "instanceof" ShiftExpression { $$ = new(driver.pool_) CYInstanceOf(NULL, $2); }
 754     ;
 755
 756 RelationalExpression_
 757     : RelationalExpressionNoIn_ { $$ = $1; }
 758     | "in" ShiftExpression { $$ = new(driver.pool_) CYIn(NULL, $2); }
 759     ;
 760
 761 RelationalExpression
 762     : ShiftExpression { $$ = $1; }
 763     | RelationalExpression RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
 764     ;
 765
 766 RelationalExpressionNoIn
 767     : ShiftExpression { $$ = $1; }
 768     | RelationalExpressionNoIn RelationalExpressionNoIn_ { $2->SetLeft($1); $$ = $2; }
 769     ;
 770
 771 RelationalExpressionNoBF
 772     : ShiftExpressionNoBF { $$ = $1; }
 773     | RelationalExpressionNoBF RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
 774     ;
 775
 776 EqualityExpression
 777     : RelationalExpression { $$ = $1; }
 778     | EqualityExpression "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 779     | EqualityExpression "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 780     | EqualityExpression "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 781     | EqualityExpression "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 782     ;
 783
 784 EqualityExpressionNoIn
 785     : RelationalExpressionNoIn { $$ = $1; }
 786     | EqualityExpressionNoIn "==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYEqual($1, $3); }
 787     | EqualityExpressionNoIn "!=" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 788     | EqualityExpressionNoIn "===" RelationalExpressionNoIn { $$ = new(driver.pool_) CYIdentical($1, $3); }
 789     | EqualityExpressionNoIn "!==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 790     ;
 791
 792 EqualityExpressionNoBF
 793     : RelationalExpressionNoBF { $$ = $1; }
 794     | EqualityExpressionNoBF "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 795     | EqualityExpressionNoBF "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 796     | EqualityExpressionNoBF "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 797     | EqualityExpressionNoBF "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 798     ;
 799
 800 BitwiseANDExpression
 801     : EqualityExpression { $$ = $1; }
 802     | BitwiseANDExpression "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 803     ;
 804
 805 BitwiseANDExpressionNoIn
 806     : EqualityExpressionNoIn { $$ = $1; }
 807     | BitwiseANDExpressionNoIn "&" EqualityExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 808     ;
 809
 810 BitwiseANDExpressionNoBF
 811     : EqualityExpressionNoBF { $$ = $1; }
 812     | BitwiseANDExpressionNoBF "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 813     ;
 814
 815 BitwiseXORExpression
 816     : BitwiseANDExpression { $$ = $1; }
 817     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 818     ;
 819
 820 BitwiseXORExpressionNoIn
 821     : BitwiseANDExpressionNoIn { $$ = $1; }
 822     | BitwiseXORExpressionNoIn "^" BitwiseANDExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 823     ;
 824
 825 BitwiseXORExpressionNoBF
 826     : BitwiseANDExpressionNoBF { $$ = $1; }
 827     | BitwiseXORExpressionNoBF "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 828     ;
 829
 830 BitwiseORExpression
 831     : BitwiseXORExpression { $$ = $1; }
 832     | BitwiseORExpression "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 833     ;
 834
 835 BitwiseORExpressionNoIn
 836     : BitwiseXORExpressionNoIn { $$ = $1; }
 837     | BitwiseORExpressionNoIn "|" BitwiseXORExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 838     ;
 839
 840 BitwiseORExpressionNoBF
 841     : BitwiseXORExpressionNoBF { $$ = $1; }
 842     | BitwiseORExpressionNoBF "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 843     ;
 844
 845 LogicalANDExpression
 846     : BitwiseORExpression { $$ = $1; }
 847     | LogicalANDExpression "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 848     ;
 849
 850 LogicalANDExpressionNoIn
 851     : BitwiseORExpressionNoIn { $$ = $1; }
 852     | LogicalANDExpressionNoIn "&&" BitwiseORExpressionNoIn { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 853     ;
 854
 855 LogicalANDExpressionNoBF
 856     : BitwiseORExpressionNoBF { $$ = $1; }
 857     | LogicalANDExpressionNoBF "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 858     ;
 859
 860 LogicalORExpression
 861     : LogicalANDExpression { $$ = $1; }
 862     | LogicalORExpression "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 863     ;
 864
 865 LogicalORExpressionNoIn
 866     : LogicalANDExpressionNoIn { $$ = $1; }
 867     | LogicalORExpressionNoIn "||" LogicalANDExpressionNoIn { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 868     ;
 869
 870 LogicalORExpressionNoBF
 871     : LogicalANDExpressionNoBF { $$ = $1; }
 872     | LogicalORExpressionNoBF "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 873     ;
 874
 875 ConditionalExpression
 876     : LogicalORExpression { $$ = $1; }
 877     | LogicalORExpression "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 878     ;
 879
 880 ConditionalExpressionNoIn
 881     : LogicalORExpressionNoIn { $$ = $1; }
 882     | LogicalORExpressionNoIn "?" AssignmentExpression ":" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 883     ;
 884
 885 ConditionalExpressionNoBF
 886     : LogicalORExpressionNoBF { $$ = $1; }
 887     | LogicalORExpressionNoBF "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 888     ;
 889
 890 AssignmentExpression_
 891     : "=" AssignmentExpression { $$ = new(driver.pool_) CYAssign(NULL, $2); }
 892     | "*=" AssignmentExpression { $$ = new(driver.pool_) CYMultiplyAssign(NULL, $2); }
 893     | "/=" AssignmentExpression { $$ = new(driver.pool_) CYDivideAssign(NULL, $2); }
 894     | "%=" AssignmentExpression { $$ = new(driver.pool_) CYModulusAssign(NULL, $2); }
 895     | "+=" AssignmentExpression { $$ = new(driver.pool_) CYAddAssign(NULL, $2); }
 896     | "-=" AssignmentExpression { $$ = new(driver.pool_) CYSubtractAssign(NULL, $2); }
 897     | "<<=" AssignmentExpression { $$ = new(driver.pool_) CYShiftLeftAssign(NULL, $2); }
 898     | ">>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightSignedAssign(NULL, $2); }
 899     | ">>>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightUnsignedAssign(NULL, $2); }
 900     | "&=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseAndAssign(NULL, $2); }
 901     | "^=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseXOrAssign(NULL, $2); }
 902     | "|=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseOrAssign(NULL, $2); }
 903     ;
 904
 905 AssigneeExpression
 906     : LeftHandSideExpression { $$ = $1; }
 907     | AssigneeExpression_ { $$ = $1; }
 908     ;
 909
 910 AssigneeExpressionNoBF
 911     : LeftHandSideExpressionNoBF { $$ = $1; }
 912     | AssigneeExpression_ { $$ = $1; }
 913     ;
 914
 915 AssignmentExpression
 916     : ConditionalExpression { $$ = $1; }
 917     | AssigneeExpression AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
 918     ;
 919
 920 AssignmentExpressionNoIn
 921     : ConditionalExpressionNoIn { $$ = $1; }
 922     | AssigneeExpression "=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAssign($1, $3); }
 923     | AssigneeExpression "*=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYMultiplyAssign($1, $3); }
 924     | AssigneeExpression "/=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYDivideAssign($1, $3); }
 925     | AssigneeExpression "%=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYModulusAssign($1, $3); }
 926     | AssigneeExpression "+=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAddAssign($1, $3); }
 927     | AssigneeExpression "-=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYSubtractAssign($1, $3); }
 928     | AssigneeExpression "<<=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftLeftAssign($1, $3); }
 929     | AssigneeExpression ">>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightSignedAssign($1, $3); }
 930     | AssigneeExpression ">>>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightUnsignedAssign($1, $3); }
 931     | AssigneeExpression "&=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAndAssign($1, $3); }
 932     | AssigneeExpression "^=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOrAssign($1, $3); }
 933     | AssigneeExpression "|=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOrAssign($1, $3); }
 934     ;
 935
 936 AssignmentExpressionNoBF
 937     : ConditionalExpressionNoBF { $$ = $1; }
 938     | AssigneeExpressionNoBF AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
 939     ;
 940
 941 Expression_
 942     : "," Expression { $$ = new(driver.pool_) CYCompound($2); }
 943     | { $$ = NULL; }
 944     ;
 945
 946 ExpressionNoIn_
 947     : "," ExpressionNoIn { $$ = new(driver.pool_) CYCompound($2); }
 948     | { $$ = NULL; }
 949     ;
 950
 951 ExpressionOpt
 952     : Expression { $$ = $1; }
 953     | { $$ = NULL; }
 954     ;
 955
 956 ExpressionNoInOpt
 957     : ExpressionNoIn { $$ = $1; }
 958     | { $$ = NULL; }
 959     ;
 960
 961 Expression
 962     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 963     ;
 964
 965 ExpressionNoIn
 966     : AssignmentExpressionNoIn ExpressionNoIn_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 967     ;
 968
 969 ExpressionNoBF
 970     : AssignmentExpressionNoBF Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 971     ;
 972
 973 Statement
 974     : Block { $$ = $1; }
 975     | VariableStatement { $$ = $1; }
 976     | EmptyStatement { $$ = $1; }
 977     | ExpressionStatement { $$ = $1; }
 978     | IfStatement { $$ = $1; }
 979     | IterationStatement { $$ = $1; }
 980     | ContinueStatement { $$ = $1; }
 981     | BreakStatement { $$ = $1; }
 982     | ReturnStatement { $$ = $1; }
 983     | WithStatement { $$ = $1; }
 984     | LabelledStatement { $$ = $1; }
 985     | SwitchStatement { $$ = $1; }
 986     | ThrowStatement { $$ = $1; }
 987     | TryStatement { $$ = $1; }
 988     ;
 989
 990 Block
 991     : "{" StatementListOpt "}" { if ($2) $$ = new(driver.pool_) CYBlock($2); else $$ = new(driver.pool_) CYEmpty(); }
 992     ;
 993
 994 StatementList
 995     : Statement StatementListOpt { $1->SetNext($2); $$ = $1; }
 996     ;
 997
 998 StatementListOpt
 999     : StatementList { $$ = $1; }
1000     | { $$ = NULL; }
1001     ;
1002
1003 VariableStatement
1004     : "var" VariableDeclarationList Terminator { $$ = $2; }
1005     ;
1006
1007 VariableDeclarationList_
1008     : "," VariableDeclarationList { $$ = $2; }
1009     | { $$ = NULL; }
1010     ;
1011
1012 VariableDeclarationListNoIn_
1013     : "," VariableDeclarationListNoIn { $$ = $2; }
1014     | { $$ = NULL; }
1015     ;
1016
1017 VariableDeclarationList
1018     : VariableDeclaration VariableDeclarationList_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
1019     ;
1020
1021 VariableDeclarationListNoIn
1022     : VariableDeclarationNoIn VariableDeclarationListNoIn_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
1023     ;
1024
1025 VariableDeclaration
1026     : Identifier InitialiserOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
1027     ;
1028
1029 VariableDeclarationNoIn
1030     : Identifier InitialiserNoInOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
1031     ;
1032
1033 InitialiserOpt
1034     : Initialiser { $$ = $1; }
1035     | { $$ = NULL; }
1036     ;
1037
1038 InitialiserNoInOpt
1039     : InitialiserNoIn { $$ = $1; }
1040     | { $$ = NULL; }
1041     ;
1042
1043 Initialiser
1044     : "=" AssignmentExpression { $$ = $2; }
1045     ;
1046
1047 InitialiserNoIn
1048     : "=" AssignmentExpressionNoIn { $$ = $2; }
1049     ;
1050
1051 EmptyStatement
1052     : ";" { $$ = new(driver.pool_) CYEmpty(); }
1053     ;
1054
1055 ExpressionStatement
1056     : ExpressionNoBF Terminator { $$ = new(driver.pool_) CYExpress($1); }
1057     ;
1058
1059 ElseStatementOpt
1060     : "else" Statement { $$ = $2; }
1061     | %prec "if" { $$ = NULL; }
1062     ;
1063
1064 IfStatement
1065     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = new(driver.pool_) CYIf($3, $5, $6); }
1066     ;
1067
1068 IterationStatement
1069     : DoWhileStatement { $$ = $1; }
1070     | WhileStatement { $$ = $1; }
1071     | ForStatement { $$ = $1; }
1072     | ForInStatement { $$ = $1; }
1073     ;
1074
1075 DoWhileStatement
1076     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = new(driver.pool_) CYDoWhile($5, $2); }
1077     ;
1078
1079 WhileStatement
1080     : "while" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWhile($3, $5); }
1081     ;
1082
1083 ForStatement
1084     : "for" "(" ForStatementInitialiser ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = new(driver.pool_) CYFor($3, $5, $7, $9); }
1085     ;
1086
1087 ForStatementInitialiser
1088     : ExpressionNoInOpt { $$ = $1; }
1089     | "var" VariableDeclarationListNoIn { $$ = $2; }
1090     ;
1091
1092 ForInStatement
1093     : "for" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = new(driver.pool_) CYForIn($3, $5, $7); }
1094     ;
1095
1096 ForInStatementInitialiser
1097     : LeftHandSideExpression { $$ = $1; }
1098     | "var" VariableDeclarationNoIn { $$ = $2; }
1099     ;
1100
1101 ContinueStatement
1102     : "continue" IdentifierOpt Terminator { $$ = new(driver.pool_) CYContinue($2); }
1103     ;
1104
1105 BreakStatement
1106     : "break" IdentifierOpt Terminator { $$ = new(driver.pool_) CYBreak($2); }
1107     ;
1108
1109 ReturnStatement
1110     : "return" ExpressionOpt Terminator { $$ = new(driver.pool_) CYReturn($2); }
1111     ;
1112
1113 WithStatement
1114     : "with" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWith($3, $5); }
1115     ;
1116
1117 SwitchStatement
1118     : "switch" "(" Expression ")" CaseBlock { $$ = new(driver.pool_) CYSwitch($3, $5); }
1119     ;
1120
1121 CaseBlock
1122     : "{" CaseClausesOpt "}" { $$ = $2; }
1123     ;
1124
1125 CaseClausesOpt
1126     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1127     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1128     | { $$ = NULL; }
1129     ;
1130
1131 CaseClause
1132     : "case" Expression ":" StatementListOpt { $$ = new(driver.pool_) CYClause($2, $4); }
1133     ;
1134
1135 DefaultClause
1136     : "default" ":" StatementListOpt { $$ = new(driver.pool_) CYClause(NULL, $3); }
1137     ;
1138
1139 LabelledStatement
1140     : Identifier ":" Statement { $3->AddLabel($1); $$ = $3; }
1141     ;
1142
1143 ThrowStatement
1144     : "throw" Expression Terminator { $$ = new(driver.pool_) CYThrow($2); }
1145     ;
1146
1147 TryStatement
1148     : "try" Block CatchOpt FinallyOpt { $$ = new(driver.pool_) CYTry($2, $3, $4); }
1149     ;
1150
1151 CatchOpt
1152     : "catch" "(" Identifier ")" Block { $$ = new(driver.pool_) CYCatch($3, $5); }
1153     | { $$ = NULL; }
1154     ;
1155
1156 FinallyOpt
1157     : "finally" Block { $$ = $2; }
1158     | { $$ = NULL; }
1159     ;
1160
1161 FunctionDeclaration
1162     : "function" Identifier "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYFunction($2, $4, $7); }
1163     ;
1164
1165 FunctionExpression
1166     : "function" IdentifierOpt "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYLambda($2, $4, $7); }
1167     ;
1168
1169 FormalParameterList_
1170     : "," FormalParameterList { $$ = $2; }
1171     | { $$ = NULL; }
1172     ;
1173
1174 FormalParameterList
1175     : Identifier FormalParameterList_ { $$ = new(driver.pool_) CYFunctionParameter($1, $2); }
1176     | { $$ = NULL; }
1177     ;
1178
1179 FunctionBody
1180     : SourceElements { $$ = $1; }
1181     ;
1182
1183 Program
1184     : SourceElements { driver.source_ = $1; }
1185     ;
1186
1187 SourceElements
1188     : SourceElement SourceElements { $1->SetNext($2); $$ = $1; }
1189     | { $$ = NULL; }
1190     ;
1191
1192 SourceElement
1193     : Statement { $$ = $1; }
1194     | FunctionDeclaration { $$ = $1; }
1195     ;
1196
1197 /* Objective-C Extensions {{{ */
1198 ClassSuperOpt
1199     : ":" MemberExpressionNoBF { $$ = $2; }
1200     | { $$ = NULL; }
1201     ;
1202
1203 ClassFieldList
1204     : "{" "}" { $$ = NULL; }
1205     ;
1206
1207 MessageScope
1208     : "+" { $$ = false; }
1209     | "-" { $$ = true; }
1210     ;
1211
1212 TypeOpt
1213     : "(" Expression ")" { $$ = $2; }
1214     | { $$ = NULL; }
1215     ;
1216
1217 MessageParameter
1218     : Word ":" TypeOpt Identifier { $$ = new CYMessageParameter($1, $3, $4); }
1219     ;
1220
1221 MessageParameterListOpt
1222     : MessageParameterList { $$ = $1; }
1223     | { $$ = NULL; }
1224     ;
1225
1226 MessageParameterList
1227     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1228     ;
1229
1230 MessageParameters
1231     : MessageParameterList { $$ = $1; }
1232     | Word { $$ = new CYMessageParameter($1, NULL, NULL); }
1233     ;
1234
1235 ClassMessageDeclaration
1236     : MessageScope TypeOpt MessageParameters "{" FunctionBody "}" { $$ = new CYMessage($1, $2, $3, $5); }
1237     ;
1238
1239 ClassMessageDeclarationListOpt
1240     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1241     | { $$ = NULL; }
1242     ;
1243
1244 ClassName
1245     : Identifier { $$ = $1; }
1246     | "(" AssignmentExpression ")" { $$ = $2; }
1247     ;
1248
1249 ClassNameOpt
1250     : ClassName { $$ = $1; }
1251     | { $$ = NULL; }
1252     ;
1253
1254 ClassExpression
1255     : "@class" ClassNameOpt ClassSuperOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = new CYClass($2, $3, $4, $5); }
1256     ;
1257
1258 CategoryStatement
1259     : "@class" ClassName ClassMessageDeclarationListOpt "@end" { $$ = new CYCategory($2, $3); }
1260     ;
1261
1262 PrimaryExpression_
1263     : ClassExpression { $$ = $1; }
1264     ;
1265
1266 Statement
1267     : CategoryStatement
1268     ;
1269
1270 VariadicCall
1271     : "," AssignmentExpression VariadicCall { $$ = new(driver.pool_) CYArgument(NULL, $2, $3); }
1272     | { $$ = NULL; }
1273     ;
1274
1275 SelectorCall_
1276     : SelectorCall { $$ = $1; }
1277     | VariadicCall { $$ = $1; }
1278     ;
1279
1280 SelectorCall
1281     : WordOpt ":" AssignmentExpression SelectorCall_ { $$ = new(driver.pool_) CYArgument($1 ?: new(driver.pool_) CYBlank(), $3, $4); }
1282     ;
1283
1284 SelectorList
1285     : SelectorCall { $$ = $1; }
1286     | Word { $$ = new(driver.pool_) CYArgument($1, NULL); }
1287     ;
1288
1289 MessageExpression
1290     : "[" AssignmentExpression SelectorList "]" { $$ = new(driver.pool_) CYSend($2, $3); }
1291     ;
1292
1293 SelectorExpressionOpt
1294     : SelectorExpression_ { $$ = $1; }
1295     | { $$ = NULL; }
1296     ;
1297
1298 SelectorExpression_
1299     : WordOpt ":" SelectorExpressionOpt { $$ = new(driver.pool_) CYSelectorPart($1, true, $3); }
1300     ;
1301
1302 SelectorExpression
1303     : SelectorExpression_ { $$ = $1; }
1304     | Word { $$ = new(driver.pool_) CYSelectorPart($1, false, NULL); }
1305     ;
1306
1307 PrimaryExpression_
1308     : MessageExpression { $$ = $1; }
1309     | "@selector" "(" SelectorExpression ")" { $$ = new CYSelector($3); }
1310     ;
1311 /* }}} */
1312
1313 AssigneeExpression_
1314     : "*" UnaryExpression { $$ = new(driver.pool_) CYIndirect($2); }
1315     ;
1316
1317 UnaryExpression_
1318     : "&" UnaryExpression { $$ = new(driver.pool_) CYAddressOf($2); }
1319     ;
1320
1321 MemberAccess
1322     : "->" Identifier { $$ = new(driver.pool_) CYIndirectMember(NULL, new(driver.pool_) CYString($2)); }
1323     ;
1324
1325 /*
1326
1327 IfComprehension
1328     : "if" "(" Expression ")"
1329     ;
1330
1331 ForComprehension
1332     : "for" "(" ForInStatementInitialiser "in" Expression ")"
1333     ;
1334
1335 ComprehensionListOpt
1336     : ComprehensionList
1337     | IfComprehension
1338     |
1339     ;
1340
1341 ComprehensionList
1342     : ForComprehension ComprehensionListOpt
1343     ;
1344
1345 PrimaryExpression_
1346     : "[" AssignmentExpression ComprehensionList "]"
1347     ;
1348
1349 */
1350
1351 %%