configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30
  31 AC_PROG_CXX
  32 AC_PROG_OBJCXX
  33 AM_PROG_AR
  34 AC_PROG_INSTALL
  35
  36 LT_INIT([disable-static])
  37
  38 AC_LANG([C++])
  39
  40 PKG_PROG_PKG_CONFIG([0.22])
  41
  42 AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
  43 AC_PATH_PROG([GIT], [git])
  44 AC_PATH_PROG([TIME], [time])
  45
  46 dnl CY_CHECK_PROGS_VERSION {{{
  47 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  48     AC_ARG_VAR(]$1[, ]$3[)
  49
  50     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  51     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  52         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  53         AS_VAR_IF(version, [], ,
  54             AS_VERSION_COMPARE($version, ]$5[, ,
  55                 ac_cv_path_]$1[=$ac_path_]$1[,
  56                 ac_cv_path_]$1[=$ac_path_]$1[))
  57     , AC_MSG_RESULT(no))
  58
  59     AS_IF([true], [
  60         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  61         AC_MSG_RESULT($]$1[)
  62     ], AS_IF([true], [
  63         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  64     ], [
  65         AC_SUBST(]$1[, [:])
  66         AC_MSG_RESULT([no])
  67     ]))
  68 ]) dnl }}}
  69
  70 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  71     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  72 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  73     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  74 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  75     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  76 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  77     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  78
  79 AC_MSG_CHECKING([bison for %code{}])
  80 echo '%code{}%%_:' >conftest.y
  81 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  82     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  83     AC_MSG_RESULT([yes])
  84 else
  85     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  86     AC_MSG_RESULT([no])
  87 fi
  88
  89 rm -f conftest.y
  90 AC_SUBST([CY_FILTERS])
  91
  92 dnl CY_TRY {{{
  93 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  94 AC_DEFUN([CY_FAILURE], [cy_good=0])
  95
  96 AC_DEFUN([CY_TRY], [
  97     cy_save=$]$1[
  98         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  99         ]$3[
 100     ]$1[=$cy_save
 101     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 102 ]) dnl }}}
 103
 104 AC_DEFUN([CY_TEST_FLAG_], [
 105     AC_LANG_PUSH(]$2[)
 106     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 107     CY_TRY(]$3[, $1, [
 108         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 109             [CY_SUCCESS], [CY_FAILURE])
 110     ], [
 111         AC_MSG_RESULT([yes])
 112         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 113     ], [AC_MSG_RESULT([no])])
 114     AC_LANG_POP(]$2[)
 115 ])
 116
 117 AC_DEFUN([CY_TEST_FLAG], [
 118     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 119     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 120     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 121 ])
 122
 123 AX_CFLAGS_WARN_ALL
 124 AX_CXXFLAGS_WARN_ALL
 125
 126 dnl XXX: this is used to support GNU Objective-C struct objc_method
 127 CY_TEST_FLAG([-Wno-deprecated-declarations])
 128
 129 CY_TEST_FLAG([-Wno-dangling-else])
 130 CY_TEST_FLAG([-Wno-overloaded-virtual])
 131 CY_TEST_FLAG([-Wno-parentheses])
 132 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 133
 134 dnl -arch * {{{
 135 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 136     AC_MSG_CHECKING([for -arch $cy_arch])
 137     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 138         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 139     ], [
 140         AC_MSG_RESULT([yes])
 141         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 142     ], [AC_MSG_RESULT([no])])
 143 done
 144 AC_SUBST([CY_ARCH])
 145 dnl }}}
 146
 147 AC_DEFUN([CY_LT_LIB], [
 148     cy_save=$LIBS
 149     LIBS=
 150     ]$2[
 151     ]$1[=$LIBS
 152     LIBS=$cy_save
 153     AC_SUBST(]$1[)
 154 ])
 155
 156 dnl --enable-javascript {{{
 157 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 158     AC_CHECK_FRAMEWORK([JavaScriptCore], [
 159         #include <JavaScriptCore/JSBase.h>
 160     ], [
 161         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 162     ], [
 163         AC_SUBST([CY_EXECUTE], [1])
 164     ], [
 165         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 166             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 167                 AC_SUBST([CY_EXECUTE], [1])
 168                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 169                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 170             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 171         done
 172     ])
 173 ])
 174
 175 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 176     CY_CHECK_JAVASCRIPTCORE])
 177
 178 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 179     [--enable-javascript@<:@=ENGINE@:>@],
 180     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 181 )], [
 182     AS_CASE([$enableval],
 183         [yes], [
 184             CY_CHECK_JAVASCRIPT],
 185         [no], [
 186             AC_SUBST([CY_EXECUTE], [0])],
 187         [JavaScriptCore], [
 188             CY_CHECK_JAVASCRIPTCORE],
 189         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 190 ], [CY_CHECK_JAVASCRIPT])
 191 dnl }}}
 192
 193 dnl APR_FIND_APR {{{
 194 APR_FIND_APR([], [], [1], [1])
 195 AS_CASE([$apr_found], [yes], [
 196     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 197     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 198     AC_SUBST([LTLIBAPR])
 199 ], [AC_MSG_ERROR([missing "libapr"])])
 200 dnl }}}
 201
 202 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 203     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 204         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 205         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 206     ], [AC_MSG_ERROR([missing "libffi"])])])
 207
 208 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 209
 210 AS_CASE([$CY_EXECUTE], [1], [
 211     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 212
 213     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 214         CY_CHECK_PKG_CONFIG_LIBFFI
 215     ], [
 216         AC_SEARCH_LIBS([ffi_call], [ffi])
 217         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 218     ]))
 219
 220     AC_LANG_PUSH([Objective C++])
 221
 222     AC_MSG_CHECKING([if we really have Objective C++])
 223     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 224         CY_OBJECTIVEC=1
 225         AC_MSG_RESULT([yes])
 226     ], [AC_MSG_RESULT([no])])
 227
 228     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 229         AC_CHECK_FRAMEWORK([CoreFoundation], [
 230             #include <CoreFoundation/CFBase.h>
 231         ], [CFAllocatorGetDefault();], [
 232             AC_SUBST([CY_OBJECTIVEC])
 233
 234             AC_CHECK_FRAMEWORK([Foundation], [
 235                 #include <Foundation/NSObject.h>
 236             ], [[[[NSObject alloc] init];]])
 237
 238             AC_CHECK_FRAMEWORK([WebKit], [
 239                 #include <WebKit/WebScriptObject.h>
 240             ], [[[[WebScriptObject alloc] init];]])
 241         ], [
 242             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 243             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 244
 245             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 246                 AC_SUBST([CY_OBJECTIVEC])
 247                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 248                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 249             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 250         ])
 251     ])
 252
 253     AC_LANG_POP([Objective C++])
 254 ])
 255
 256 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 257
 258 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 259 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 260
 261 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 262
 263 AC_LANG_PUSH([C])
 264 AM_ICONV
 265 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 266 AC_LANG_POP([C])
 267
 268 AC_SUBST([LTFLAGS])
 269 AC_SUBST([SO], [$acl_shlibext])
 270
 271 AS_IF([test "x$CY_EXECUTE" = x1], [
 272     AC_CHECK_HEADER([mach/mach.h], [
 273         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 274         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 275         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 276         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 277         AC_SUBST([CY_MACH], [1])])])
 278 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 279
 280 AC_CONFIG_FILES([Makefile])
 281 AC_OUTPUT