configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30
  31 AC_PROG_CXX
  32 AC_PROG_OBJCXX
  33 AM_PROG_AR
  34 AC_PROG_INSTALL
  35
  36 LT_INIT([disable-static])
  37
  38 AC_LANG([C++])
  39
  40 PKG_PROG_PKG_CONFIG([0.22])
  41
  42 AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
  43 AC_PATH_PROG([GIT], [git])
  44 AC_PATH_PROG([TIME], [time])
  45
  46 dnl CY_CHECK_PROGS_VERSION {{{
  47 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  48     AC_ARG_VAR(]$1[, ]$3[)
  49
  50     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  51     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  52         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  53         AS_VAR_IF(version, [], ,
  54             AS_VERSION_COMPARE($version, ]$5[, ,
  55                 ac_cv_path_]$1[=$ac_path_]$1[,
  56                 ac_cv_path_]$1[=$ac_path_]$1[))
  57     , AC_MSG_RESULT(no))
  58
  59     AS_IF([true], [
  60         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  61         AC_MSG_RESULT($]$1[)
  62     ], AS_IF([true], [
  63         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  64     ], [
  65         AC_SUBST(]$1[, [:])
  66         AC_MSG_RESULT([no])
  67     ]))
  68 ]) dnl }}}
  69
  70 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  71     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  72 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  73     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  74 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  75     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  76 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  77     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  78
  79 AC_MSG_CHECKING([bison for %code{}])
  80 echo '%code{}%%_:' >conftest.y
  81 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  82     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  83     AC_MSG_RESULT([yes])
  84 else
  85     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  86     AC_MSG_RESULT([no])
  87 fi
  88
  89 rm -f conftest.y
  90 AC_SUBST([CY_FILTERS])
  91
  92 dnl CY_TRY {{{
  93 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  94 AC_DEFUN([CY_FAILURE], [cy_good=0])
  95
  96 AC_DEFUN([CY_TRY], [
  97     cy_save=$]$1[
  98         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  99         ]$3[
 100     ]$1[=$cy_save
 101     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 102 ]) dnl }}}
 103
 104 AC_DEFUN([CY_COMPILE_FLAG], [
 105     AC_LIB_APPENDTOVAR([CFLAGS], ]$1[)
 106     AC_LIB_APPENDTOVAR([CXXFLAGS], ]$1[)
 107     AC_LIB_APPENDTOVAR([OBJCXXFLAGS], ]$1[)
 108 ])
 109
 110 AC_DEFUN([CY_TEST_FLAG_], [
 111     AC_LANG_PUSH(]$2[)
 112     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 113     CY_TRY(]$3[, $1, [
 114         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 115             [CY_SUCCESS], [CY_FAILURE])
 116     ], [
 117         AC_MSG_RESULT([yes])
 118         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 119     ], [AC_MSG_RESULT([no])])
 120     AC_LANG_POP(]$2[)
 121 ])
 122
 123 AC_DEFUN([CY_TEST_FLAG], [
 124     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 125     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 126     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 127 ])
 128
 129 AX_CFLAGS_WARN_ALL
 130 AX_CXXFLAGS_WARN_ALL
 131
 132 CY_TEST_FLAG([-Wno-overloaded-virtual])
 133 CY_TEST_FLAG([-Wno-parentheses])
 134 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 135
 136 dnl -arch * {{{
 137 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 138     AC_MSG_CHECKING([for -arch $cy_arch])
 139     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 140         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 141     ], [
 142         AC_MSG_RESULT([yes])
 143         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 144     ], [AC_MSG_RESULT([no])])
 145 done
 146 AC_SUBST([CY_ARCH])
 147 dnl }}}
 148
 149 AC_DEFUN([CY_LT_LIB], [
 150     cy_save=$LIBS
 151     LIBS=
 152     ]$2[
 153     ]$1[=$LIBS
 154     LIBS=$cy_save
 155     AC_SUBST(]$1[)
 156 ])
 157
 158 dnl --with-frameworks {{{
 159 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
 160     [--with-frameworks=DIRS],
 161     [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
 162 )], [
 163     for cy_framework in $withval; do
 164         CY_COMPILE_FLAG([-F$cy_framework])
 165     done
 166 ]) dnl }}}
 167 dnl --enable-javascript {{{
 168 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 169     AC_CHECK_FRAMEWORK([JavaScriptCore], [
 170         #include <JavaScriptCore/JSBase.h>
 171     ], [
 172         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 173     ], [
 174         AC_SUBST([CY_EXECUTE], [1])
 175     ], [
 176         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 177             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 178                 AC_SUBST([CY_EXECUTE], [1])
 179                 CY_COMPILE_FLAG([`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 180                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 181             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 182         done
 183     ])
 184 ])
 185
 186 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 187     CY_CHECK_JAVASCRIPTCORE])
 188
 189 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 190     [--enable-javascript@<:@=ENGINE@:>@],
 191     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 192 )], [
 193     AS_CASE([$enableval],
 194         [yes], [
 195             CY_CHECK_JAVASCRIPT],
 196         [no], [
 197             AC_SUBST([CY_EXECUTE], [0])],
 198         [JavaScriptCore], [
 199             CY_CHECK_JAVASCRIPTCORE],
 200         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 201 ], [CY_CHECK_JAVASCRIPT])
 202 dnl }}}
 203
 204 dnl APR_FIND_APR {{{
 205 APR_FIND_APR([], [], [1], [1])
 206 AS_CASE([$apr_found], [yes], [
 207     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 208     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 209     AC_SUBST([LTLIBAPR])
 210 ], [AC_MSG_ERROR([missing "libapr"])])
 211 dnl }}}
 212
 213 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 214     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 215         CY_COMPILE_FLAG([`$PKG_CONFIG --cflags libffi`])
 216         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 217     ], [AC_MSG_ERROR([missing "libffi"])])])
 218
 219 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 220
 221 AS_CASE([$CY_EXECUTE], [1], [
 222     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 223
 224     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 225         CY_CHECK_PKG_CONFIG_LIBFFI
 226     ], [
 227         AC_SEARCH_LIBS([ffi_call], [ffi])
 228         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 229     ]))
 230
 231     AC_LANG_PUSH([Objective C++])
 232
 233     AC_MSG_CHECKING([if we really have Objective C++])
 234     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 235         CY_OBJECTIVEC=1
 236         AC_MSG_RESULT([yes])
 237     ], [AC_MSG_RESULT([no])])
 238
 239     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 240         AC_CHECK_FRAMEWORK([CoreFoundation], [
 241             #include <CoreFoundation/CFBase.h>
 242         ], [CFAllocatorGetDefault();], [
 243             AC_SUBST([CY_OBJECTIVEC])
 244
 245             AC_CHECK_FRAMEWORK([Foundation], [
 246                 #include <Foundation/NSObject.h>
 247             ], [[[[NSObject alloc] init];]])
 248
 249             AC_CHECK_FRAMEWORK([WebKit], [
 250                 #include <WebKit/WebScriptObject.h>
 251             ], [[[[WebScriptObject alloc] init];]])
 252         ], [
 253             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 254             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 255
 256             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 257                 AC_SUBST([CY_OBJECTIVEC])
 258                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 259                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 260             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 261         ])
 262     ])
 263
 264     AC_LANG_POP([Objective C++])
 265 ])
 266
 267 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 268
 269 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 270 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 271
 272 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 273
 274 AC_LANG_PUSH([C])
 275 AM_ICONV
 276 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 277 AC_LANG_POP([C])
 278
 279 AC_SUBST([LTFLAGS])
 280 AC_SUBST([SO], [$acl_shlibext])
 281
 282 AS_IF([test "x$CY_EXECUTE" = x1], [
 283     AC_CHECK_HEADER([mach/mach.h], [
 284         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 285         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 286         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 287         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 288         AC_SUBST([CY_MACH], [1])])])
 289 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 290
 291 AC_CONFIG_FILES([Makefile])
 292 AC_OUTPUT