Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 typedef struct {
  43     bool newline_;
  44
  45     union {
  46         bool bool_;
  47
  48         CYDriver::Condition condition_;
  49
  50         CYArgument *argument_;
  51         CYAssignment *assignment_;
  52         CYBoolean *boolean_;
  53         CYClause *clause_;
  54         cy::Syntax::Catch *catch_;
  55         CYComment *comment_;
  56         CYComprehension *comprehension_;
  57         CYCompound *compound_;
  58         CYDeclaration *declaration_;
  59         CYDeclarations *declarations_;
  60         CYElement *element_;
  61         CYExpression *expression_;
  62         CYFalse *false_;
  63         CYFinally *finally_;
  64         CYForInitialiser *for_;
  65         CYForInInitialiser *forin_;
  66         CYFunctionParameter *functionParameter_;
  67         CYIdentifier *identifier_;
  68         CYInfix *infix_;
  69         CYLiteral *literal_;
  70         CYMember *member_;
  71         CYNull *null_;
  72         CYNumber *number_;
  73         CYProgram *program_;
  74         CYProperty *property_;
  75         CYPropertyName *propertyName_;
  76         CYRubyProc *rubyProc_;
  77         CYStatement *statement_;
  78         CYString *string_;
  79         CYThis *this_;
  80         CYTrue *true_;
  81         CYWord *word_;
  82
  83 @begin ObjectiveC
  84         CYClassName *className_;
  85         CYField *field_;
  86         CYMessage *message_;
  87         CYMessageParameter *messageParameter_;
  88         CYProtocol *protocol_;
  89         CYSelectorPart *selector_;
  90 @end
  91
  92 @begin E4X
  93         CYAttribute *attribute_;
  94         CYPropertyIdentifier *propertyIdentifier_;
  95         CYSelector *selector_;
  96 @end
  97     };
  98 } YYSTYPE;
  99
 100 #define YYSTYPE YYSTYPE
 101 @if Bison24 }
 102
 103 @if Bison24 %code provides {
 104 int cylex(YYSTYPE *, cy::location *, void *);
 105 @if Bison24 }
 106
 107 @if Bison23 %}
 108
 109 %name-prefix="cy"
 110
 111 @if Bison23 %skeleton "lalr1.cc"
 112 @if Bison24 %language "C++"
 113
 114 %initial-action {
 115     @$.begin.filename = @$.end.filename = &driver.filename_;
 116 };
 117
 118 %locations
 119 %defines
 120
 121 //%glr-parser
 122 //%expect 1
 123
 124 %error-verbose
 125
 126 %parse-param { CYDriver &driver }
 127 %lex-param { void *cyscanner }
 128
 129 @begin E4X
 130 %token XMLCDATA
 131 %token XMLComment
 132 %token XMLPI
 133
 134 %token XMLAttributeValue
 135 %token XMLName
 136 %token XMLTagCharacters
 137 %token XMLText
 138 %token XMLWhitespace
 139 @end
 140
 141 @begin E4X
 142 %token LeftRight "<>"
 143 %token LeftSlashRight "</>"
 144
 145 %token SlashRight "/>"
 146 %token LeftSlash "</"
 147
 148 %token ColonColon "::"
 149 %token PeriodPeriod ".."
 150 @end
 151
 152 @begin E4X ObjectiveC
 153 %token At "@"
 154 @end
 155
 156 %token Ampersand "&"
 157 %token AmpersandAmpersand "&&"
 158 %token AmpersandEqual "&="
 159 %token Carrot "^"
 160 %token CarrotEqual "^="
 161 %token Equal "="
 162 %token EqualEqual "=="
 163 %token EqualEqualEqual "==="
 164 %token EqualRight "=>"
 165 %token Exclamation "!"
 166 %token ExclamationEqual "!="
 167 %token ExclamationEqualEqual "!=="
 168 %token Hyphen "-"
 169 %token HyphenEqual "-="
 170 %token HyphenHyphen "--"
 171 %token HyphenHyphen_ "\n--"
 172 %token HyphenRight "->"
 173 %token Left "<"
 174 %token LeftEqual "<="
 175 %token LeftLeft "<<"
 176 %token LeftLeftEqual "<<="
 177 %token Percent "%"
 178 %token PercentEqual "%="
 179 %token Period "."
 180 %token PeriodPeriodPeriod "..."
 181 %token Pipe "|"
 182 %token PipeEqual "|="
 183 %token PipePipe "||"
 184 %token Plus "+"
 185 %token PlusEqual "+="
 186 %token PlusPlus "++"
 187 %token PlusPlus_ "\n++"
 188 %token Right ">"
 189 %token RightEqual ">="
 190 %token RightRight ">>"
 191 %token RightRightEqual ">>="
 192 %token RightRightRight ">>>"
 193 %token RightRightRightEqual ">>>="
 194 %token Slash "/"
 195 %token SlashEqual "/="
 196 %token Star "*"
 197 %token StarEqual "*="
 198 %token Tilde "~"
 199
 200 %token Colon ":"
 201 %token Comma ","
 202 %token Question "?"
 203 %token SemiColon ";"
 204 %token NewLine "\n"
 205
 206 %token <comment_> Comment
 207
 208 %token OpenParen "("
 209 %token CloseParen ")"
 210
 211 %token OpenBrace "{"
 212 %token OpenBrace_ "\n{"
 213 %token OpenBrace__ ";{"
 214 %token CloseBrace "}"
 215
 216 %token OpenBracket "["
 217 %token CloseBracket "]"
 218
 219 @begin Java
 220 %token AtClass "@class"
 221 @end
 222
 223 @begin ObjectiveC
 224 %token AtImplementation "@implementation"
 225 %token AtImplementation_ ";@implementation"
 226 %token AtImport "@import"
 227 %token AtEnd "@end"
 228 %token AtSelector "@selector"
 229 @end
 230
 231 %token <false_> False "false"
 232 %token <null_> Null "null"
 233 %token <true_> True "true"
 234
 235 // ES3/ES5/WIE/JSC Reserved
 236 %token <word_> Break "break"
 237 %token <word_> Case "case"
 238 %token <word_> Catch "catch"
 239 %token <word_> Continue "continue"
 240 %token <word_> Default "default"
 241 %token <word_> Delete "delete"
 242 %token <word_> Do "do"
 243 %token <word_> Else "else"
 244 %token <word_> Finally "finally"
 245 %token <word_> For "for"
 246 %token <word_> Function "function"
 247 %token <word_> Function_ ";function"
 248 %token <word_> If "if"
 249 %token <word_> In "in"
 250 %token <word_> In_ "!in"
 251 %token <word_> InstanceOf "instanceof"
 252 %token <word_> New "new"
 253 %token <word_> Return "return"
 254 %token <word_> Switch "switch"
 255 %token <this_> This "this"
 256 %token <word_> Throw "throw"
 257 %token <word_> Try "try"
 258 %token <word_> TypeOf "typeof"
 259 %token <word_> Var "var"
 260 %token <word_> Void "void"
 261 %token <word_> While "while"
 262 %token <word_> With "with"
 263
 264 // ES3/IE6 Future, ES5/JSC Reserved
 265 %token <word_> Debugger "debugger"
 266
 267 // ES3/ES5/IE6 Future, JSC Reserved
 268 %token <word_> Const "const"
 269
 270 // ES3/ES5/IE6/JSC Future
 271 %token <word_> Class "class"
 272 %token <word_> Enum "enum"
 273 %token <word_> Export "export"
 274 %token <word_> Extends "extends"
 275 %token <word_> Import "import"
 276 %token <word_> Super "super"
 277
 278 // ES3 Future, ES5 Strict Future
 279 %token <identifier_> Implements "implements"
 280 %token <identifier_> Interface "interface"
 281 %token <identifier_> Package "package"
 282 %token <identifier_> Private "private"
 283 %token <identifier_> Protected "protected"
 284 %token <identifier_> Public "public"
 285 %token <identifier_> Static "static"
 286
 287 // ES3 Future
 288 %token <identifier_> Abstract "abstract"
 289 %token <identifier_> Boolean "boolean"
 290 %token <identifier_> Byte "byte"
 291 %token <identifier_> Char "char"
 292 %token <identifier_> Double "double"
 293 %token <identifier_> Final "final"
 294 %token <identifier_> Float "float"
 295 %token <identifier_> Goto "goto"
 296 %token <identifier_> Int "int"
 297 %token <identifier_> Long "long"
 298 %token <identifier_> Native "native"
 299 %token <identifier_> Short "short"
 300 %token <identifier_> Synchronized "synchronized"
 301 %token <identifier_> Throws "throws"
 302 %token <identifier_> Transient "transient"
 303 %token <identifier_> Volatile "volatile"
 304
 305 // ES5 Strict
 306 %token <identifier_> Let "let"
 307 %token <identifier_> Yield "yield"
 308
 309 // Woah?!
 310 %token <identifier_> Each "each"
 311 %token <identifier_> Of "of"
 312
 313 @begin E4X
 314 // E4X Conditional
 315 %token <identifier_> Namespace "namespace"
 316 %token <identifier_> XML "xml"
 317 @end
 318
 319 %token AutoComplete
 320
 321 %token <identifier_> Identifier_
 322 %token <number_> NumericLiteral
 323 %token <string_> StringLiteral
 324 %token <literal_> RegularExpressionLiteral
 325
 326 %type <expression_> AdditiveExpression
 327 %type <argument_> ArgumentList_
 328 %type <argument_> ArgumentList
 329 %type <argument_> ArgumentListOpt
 330 %type <argument_> Arguments
 331 %type <literal_> ArrayLiteral
 332 %type <expression_> ArrowFunction
 333 %type <functionParameter_> ArrowParameters
 334 %type <expression_> AssignmentExpression
 335 %type <identifier_> BindingIdentifier
 336 %type <expression_> BitwiseANDExpression
 337 %type <statement_> Block_
 338 %type <statement_> Block
 339 %type <boolean_> BooleanLiteral
 340 %type <declaration_> BindingElement
 341 %type <expression_> BitwiseORExpression
 342 %type <expression_> BitwiseXORExpression
 343 %type <statement_> BreakStatement
 344 %type <statement_> BreakableStatement
 345 %type <expression_> CallExpression_
 346 %type <expression_> CallExpression
 347 %type <clause_> CaseBlock
 348 %type <clause_> CaseClause
 349 %type <clause_> CaseClausesOpt
 350 %type <catch_> CatchOpt
 351 %type <comprehension_> ComprehensionList
 352 %type <comprehension_> ComprehensionListOpt
 353 %type <expression_> ConditionalExpression
 354 %type <statement_> ContinueStatement
 355 %type <statement_> ConciseBody
 356 %type <statement_> DebuggerStatement
 357 %type <statement_> Declaration__
 358 %type <statement_> Declaration_
 359 %type <statement_> Declaration
 360 %type <clause_> DefaultClause
 361 %type <expression_> Element
 362 %type <expression_> ElementOpt
 363 %type <element_> ElementList
 364 %type <element_> ElementListOpt
 365 %type <statement_> ElseStatementOpt
 366 %type <statement_> EmptyStatement
 367 %type <expression_> EqualityExpression
 368 %type <compound_> Expression_
 369 %type <compound_> Expression
 370 %type <expression_> ExpressionOpt
 371 %type <statement_> ExpressionStatement
 372 %type <finally_> FinallyOpt
 373 %type <comprehension_> ForComprehension
 374 %type <for_> ForStatementInitialiser
 375 %type <forin_> ForInStatementInitialiser
 376 %type <declaration_> FormalParameter
 377 %type <functionParameter_> FormalParameterList_
 378 %type <functionParameter_> FormalParameterList
 379 %type <functionParameter_> FormalParameterListOpt
 380 %type <statement_> FunctionBody
 381 %type <statement_> FunctionDeclaration
 382 %type <expression_> FunctionExpression
 383 %type <identifier_> Identifier
 384 %type <identifier_> IdentifierOpt
 385 %type <word_> IdentifierName
 386 %type <comprehension_> IfComprehension
 387 %type <statement_> IfStatement
 388 %type <expression_> Initialiser
 389 %type <expression_> InitialiserOpt
 390 %type <statement_> IterationStatement
 391 %type <statement_> LabelledStatement
 392 %type <expression_> LeftHandSideExpression
 393 %type <statement_> LetStatement
 394 %type <statement_> LexicalDeclaration
 395 %type <literal_> Literal
 396 %type <literal_> LiteralNoRE
 397 %type <expression_> LogicalANDExpression
 398 %type <expression_> LogicalORExpression
 399 %type <member_> MemberAccess
 400 %type <expression_> MemberExpression_
 401 %type <expression_> MemberExpression
 402 %type <expression_> MultiplicativeExpression
 403 %type <expression_> NewExpression
 404 %type <null_> NullLiteral
 405 %type <literal_> ObjectLiteral
 406 %type <compound_> Parenthetical
 407 %type <compound_> ParentheticalOpt
 408 %type <expression_> PostfixExpression
 409 %type <expression_> PrimaryExpression
 410 %type <statement_> Program
 411 %type <statement_> ProgramBody
 412 %type <statement_> ProgramBodyOpt
 413 %type <propertyName_> PropertyName_
 414 %type <propertyName_> PropertyName
 415 %type <property_> PropertyDefinition
 416 %type <property_> PropertyDefinitionList_
 417 %type <property_> PropertyDefinitionList
 418 %type <property_> PropertyDefinitionListOpt
 419 %type <expression_> RelationalExpression
 420 %type <statement_> ReturnStatement
 421 %type <rubyProc_> RubyProcExpression
 422 %type <functionParameter_> RubyProcParameterList_
 423 %type <functionParameter_> RubyProcParameterList
 424 %type <functionParameter_> RubyProcParameters
 425 %type <functionParameter_> RubyProcParametersOpt
 426 %type <expression_> ShiftExpression
 427 %type <declaration_> SingleNameBinding
 428 %type <statement_> Statement__
 429 %type <statement_> Statement_
 430 %type <statement_> Statement
 431 %type <statement_> StatementList
 432 %type <statement_> StatementListOpt
 433 %type <statement_> StatementListItem
 434 %type <statement_> SwitchStatement
 435 %type <statement_> ThrowStatement
 436 %type <statement_> TryStatement
 437 %type <expression_> UnaryExpression_
 438 %type <expression_> UnaryExpression
 439 %type <declaration_> VariableDeclaration
 440 %type <declarations_> VariableDeclarationList_
 441 %type <declarations_> VariableDeclarationList
 442 %type <statement_> VariableStatement
 443 %type <statement_> WithStatement
 444 %type <word_> Word
 445 %type <word_> WordOpt
 446
 447 @begin ObjectiveC
 448 %type <statement_> CategoryStatement
 449 %type <expression_> ClassExpression
 450 %type <statement_> ClassStatement
 451 %type <expression_> ClassSuperOpt
 452 %type <field_> ClassFieldList
 453 %type <message_> ClassMessageDeclaration
 454 %type <message_> ClassMessageDeclarationListOpt
 455 %type <className_> ClassName
 456 %type <className_> ClassNameOpt
 457 %type <protocol_> ClassProtocolListOpt
 458 %type <protocol_> ClassProtocols
 459 %type <protocol_> ClassProtocolsOpt
 460 %type <expression_> MessageExpression
 461 %type <messageParameter_> MessageParameter
 462 %type <messageParameter_> MessageParameters
 463 %type <messageParameter_> MessageParameterList
 464 %type <messageParameter_> MessageParameterListOpt
 465 %type <bool_> MessageScope
 466 %type <argument_> SelectorCall_
 467 %type <argument_> SelectorCall
 468 %type <selector_> SelectorExpression_
 469 %type <selector_> SelectorExpression
 470 %type <selector_> SelectorExpressionOpt
 471 %type <argument_> SelectorList
 472 %type <word_> SelectorWordOpt
 473 %type <expression_> TypeOpt
 474 %type <argument_> VariadicCall
 475 @end
 476
 477 @begin E4X
 478 %type <propertyIdentifier_> PropertyIdentifier_
 479 %type <selector_> PropertySelector_
 480 %type <selector_> PropertySelector
 481 %type <identifier_> QualifiedIdentifier_
 482 %type <identifier_> QualifiedIdentifier
 483 %type <identifier_> WildcardIdentifier
 484 %type <identifier_> XMLComment
 485 %type <identifier_> XMLCDATA
 486 %type <identifier_> XMLElement
 487 %type <identifier_> XMLElementContent
 488 %type <identifier_> XMLMarkup
 489 %type <identifier_> XMLPI
 490
 491 %type <attribute_> AttributeIdentifier
 492 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 493 %type <expression_> PropertyIdentifier
 494 %type <expression_> XMLListInitialiser
 495 %type <expression_> XMLInitialiser
 496 @end
 497
 498 %nonassoc ""
 499 %left "++" "--"
 500
 501 %nonassoc "if"
 502 %nonassoc "else"
 503
 504 %start Program
 505
 506 %%
 507
 508 /* Lexer State {{{ */
 509 LexPushInOn
 510     : { driver.in_.push(true); }
 511     ;
 512
 513 LexPushInOff
 514     : { driver.in_.push(false); }
 515     ;
 516
 517 LexPopIn
 518     : { driver.in_.pop(); }
 519     ;
 520
 521 LexSetRegExp
 522     : { driver.SetCondition(CYDriver::RegExpCondition); }
 523     ;
 524
 525 LexNoBrace
 526     : { if (yychar == yyempty_) driver.nobrace_ = true; else if (yychar == token::OpenBrace || yychar == token::OpenBrace_) yychar = token::OpenBrace__; }
 527     ;
 528
 529 LexNoFunction
 530     : { if (yychar == token::Function) yychar = token::Function_; }
 531     ;
 532
 533 LexSetStatement
 534     : LexNoBrace LexNoFunction
 535     ;
 536 /* }}} */
 537
 538 BRACE
 539     : "{"
 540     | "\n{"
 541     ;
 542
 543 StrictSemi
 544     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 545     ;
 546
 547 Terminator
 548     : ";"
 549     | error { if (yychar != yyeof_ && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 550     ;
 551
 552 TerminatorOpt
 553     : ";"
 554     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 555     ;
 556
 557 /*CommaOpt
 558     : ","
 559     |
 560     ;*/
 561
 562 NewLineOpt
 563     : "\n"
 564     |
 565     ;
 566
 567 IdentifierName
 568     : Word { $$ = $1; }
 569     ;
 570
 571 Word
 572     : Identifier { $$ = $1; }
 573     | "break" NewLineOpt { $$ = $1; }
 574     | "case" { $$ = $1; }
 575     | "catch" { $$ = $1; }
 576     | "class" { $$ = $1; }
 577     | "const" { $$ = $1; }
 578     | "continue" NewLineOpt { $$ = $1; }
 579     | "debugger" { $$ = $1; }
 580     | "default" { $$ = $1; }
 581     | "delete" { $$ = $1; }
 582     | "do" { $$ = $1; }
 583     | "else" { $$ = $1; }
 584     | "enum" { $$ = $1; }
 585     | "export" { $$ = $1; }
 586     | "extends" { $$ = $1; }
 587     | "false" { $$ = $1; }
 588     | "finally" { $$ = $1; }
 589     /* XXX: | "for" { $$ = $1; } */
 590     | "function" { $$ = $1; }
 591     | "if" { $$ = $1; }
 592     | "import" { $$ = $1; }
 593     /* XXX: | "in" { $$ = $1; } */
 594     | "!in" { $$ = $1; }
 595     /* XXX: | "instanceof" { $$ = $1; } */
 596
 597     // XXX: as it currently is not an Identifier
 598     | "let" { $$ = $1; }
 599
 600     | "new" { $$ = $1; }
 601     | "null" { $$ = $1; }
 602     | "return" NewLineOpt { $$ = $1; }
 603     | "super" { $$ = $1; }
 604     | "switch" { $$ = $1; }
 605     | "this" { $$ = $1; }
 606     | "throw" NewLineOpt { $$ = $1; }
 607     | "true" { $$ = $1; }
 608     | "try" { $$ = $1; }
 609     | "typeof" { $$ = $1; }
 610     | "var" { $$ = $1; }
 611     | "void" { $$ = $1; }
 612     | "while" { $$ = $1; }
 613     | "with" { $$ = $1; }
 614     ;
 615
 616 WordOpt
 617     : Word { $$ = $1; }
 618     | { $$ = NULL; }
 619     ;
 620
 621 @begin ObjectiveC
 622 PrimaryExpression
 623     : "@" LiteralNoRE { $$ = CYNew CYBox($2); }
 624     | "@" ArrayLiteral { $$ = CYNew CYBox($2); }
 625     | "@" ObjectLiteral { $$ = CYNew CYBox($2); }
 626     | "@" Parenthetical { $$ = CYNew CYBox($2); }
 627     ;
 628 @end
 629
 630 Identifier
 631     : Identifier_ { $$ = $1; }
 632
 633     | "implements" { $$ = $1; }
 634     | "interface" { $$ = $1; }
 635     | "package" { $$ = $1; }
 636     | "private" { $$ = $1; }
 637     | "protected" { $$ = $1; }
 638     | "public" { $$ = $1; }
 639     | "static" { $$ = $1; }
 640
 641     | "abstract" { $$ = $1; }
 642     | "boolean" { $$ = $1; }
 643     | "byte" { $$ = $1; }
 644     | "char" { $$ = $1; }
 645     | "double" { $$ = $1; }
 646     | "final" { $$ = $1; }
 647     | "float" { $$ = $1; }
 648     | "goto" { $$ = $1; }
 649     | "int" { $$ = $1; }
 650     | "long" { $$ = $1; }
 651     | "native" { $$ = $1; }
 652     | "short" { $$ = $1; }
 653     | "synchronized" { $$ = $1; }
 654     | "throws" { $$ = $1; }
 655     | "transient" { $$ = $1; }
 656     | "volatile" { $$ = $1; }
 657
 658     // XXX: currently I only have this as Word
 659     // | "let" { $$ = $1; }
 660
 661     | "yield" { $$ = $1; }
 662
 663     | "each" { $$ = $1; }
 664     | "of" { $$ = $1; }
 665     ;
 666
 667 IdentifierOpt
 668     : Identifier { $$ = $1; }
 669     | { $$ = NULL; }
 670     ;
 671
 672 LiteralNoRE
 673     : NullLiteral { $$ = $1; }
 674     | BooleanLiteral { $$ = $1; }
 675     | NumericLiteral { $$ = $1; }
 676     | StringLiteral { $$ = $1; }
 677     ;
 678
 679 Literal
 680     : LiteralNoRE { $$ = $1; }
 681     | RegularExpressionLiteral { $$ = $1; }
 682     ;
 683
 684 NullLiteral
 685     : "null" { $$ = $1; }
 686     ;
 687
 688 BooleanLiteral
 689     : "true" { $$ = $1; }
 690     | "false" { $$ = $1; }
 691     ;
 692
 693 /* 11.1 Primary Expressions {{{ */
 694 Parenthetical
 695     : "(" LexPushInOff Expression LexPopIn ")" { $$ = $3; }
 696     ;
 697
 698 ParentheticalOpt
 699     : Parenthetical { $$ = $1; }
 700     | { $$ = NULL; }
 701     ;
 702
 703 PrimaryExpression
 704     : "this" { $$ = $1; }
 705     | Identifier { $$ = CYNew CYVariable($1); }
 706     | Literal { $$ = $1; }
 707     | ArrayLiteral { $$ = $1; }
 708     | ObjectLiteral { $$ = $1; }
 709     | FunctionExpression { $$ = $1; }
 710     | Parenthetical { $$ = $1; }
 711     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 712     ;
 713 /* }}} */
 714 /* 11.1.4.1 Array Initialiser {{{ */
 715 ArrayLiteral
 716     : "[" LexPushInOff ElementListOpt LexPopIn "]" { $$ = CYNew CYArray($3); }
 717     ;
 718
 719 Element
 720     : AssignmentExpression { $$ = $1; }
 721     ;
 722
 723 ElementOpt
 724     : Element { $$ = $1; }
 725     | LexSetRegExp { $$ = NULL; }
 726     ;
 727
 728 ElementList
 729     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 730     | Element { $$ = CYNew CYElement($1, NULL); }
 731     ;
 732
 733 ElementListOpt
 734     : ElementList { $$ = $1; }
 735     | LexSetRegExp { $$ = NULL; }
 736     ;
 737 /* }}} */
 738 /* 11.1.5 Object Initialiser {{{ */
 739 ObjectLiteral
 740     : BRACE LexPushInOff PropertyDefinitionListOpt LexPopIn "}" { $$ = CYNew CYObject($3); }
 741     ;
 742
 743 PropertyDefinitionList_
 744     : "," PropertyDefinitionList { $$ = $2; }
 745     | "," { $$ = NULL; }
 746     | { $$ = NULL; }
 747     ;
 748
 749 PropertyDefinitionList
 750     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 751     ;
 752
 753 PropertyDefinitionListOpt
 754     : PropertyDefinitionList { $$ = $1; }
 755     | { $$ = NULL; }
 756     ;
 757
 758 PropertyDefinition
 759     //: IdentifierName { $$ = CYNew CYProperty($1, CYNew CYVariable($1)); }
 760     : PropertyName ":" AssignmentExpression { $$ = CYNew CYProperty($1, $3); }
 761     //| MethodDefinition
 762     ;
 763
 764 PropertyName_
 765     : IdentifierName { $$ = $1; }
 766     | StringLiteral { $$ = $1; }
 767     | NumericLiteral { $$ = $1; }
 768     ;
 769
 770 PropertyName
 771     : LexSetRegExp PropertyName_ { $$ = $2; }
 772     ;
 773 /* }}} */
 774
 775 /* 11.2 Left-Hand-Side Expressions {{{ */
 776 MemberAccess
 777     : "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYDirectMember(NULL, $3); }
 778     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 779     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 780     ;
 781
 782 MemberExpression_
 783     : MemberExpression { $$ = $1; }
 784     //| "super" { $$ = $1; }
 785     ;
 786
 787 MemberExpression
 788     : LexSetRegExp PrimaryExpression { $$ = $2; }
 789     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 790     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 791     ;
 792
 793 NewExpression
 794     : MemberExpression { $$ = $1; }
 795     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 796     ;
 797
 798 CallExpression_
 799     : MemberExpression_
 800     | CallExpression
 801     ;
 802
 803 CallExpression
 804     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 805     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 806     ;
 807
 808 Arguments
 809     : "(" LexPushInOff ArgumentListOpt LexPopIn ")" { $$ = $3; }
 810     ;
 811
 812 ArgumentList_
 813     : "," ArgumentList { $$ = $2; }
 814     | { $$ = NULL; }
 815     ;
 816
 817 ArgumentList
 818     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 819     ;
 820
 821 ArgumentListOpt
 822     : ArgumentList { $$ = $1; }
 823     | LexSetRegExp { $$ = NULL; }
 824     ;
 825
 826 LeftHandSideExpression
 827     : NewExpression { $$ = $1; }
 828     | CallExpression { $$ = $1; }
 829     ;
 830 /* }}} */
 831 /* 11.3 Postfix Expressions {{{ */
 832 PostfixExpression
 833     : %prec "" LeftHandSideExpression { $$ = $1; }
 834     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 835     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 836     ;
 837 /* }}} */
 838 /* 11.4 Unary Operators {{{ */
 839 UnaryExpression_
 840     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 841     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 842     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 843     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 844     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 845     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 846     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 847     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 848     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 849     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 850     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 851     ;
 852
 853 UnaryExpression
 854     : PostfixExpression { $$ = $1; }
 855     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 856     ;
 857 /* }}} */
 858 /* 11.5 Multiplicative Operators {{{ */
 859 MultiplicativeExpression
 860     : UnaryExpression { $$ = $1; }
 861     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 862     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 863     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 864     ;
 865 /* }}} */
 866 /* 11.6 Additive Operators {{{ */
 867 AdditiveExpression
 868     : MultiplicativeExpression { $$ = $1; }
 869     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 870     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 871     ;
 872 /* }}} */
 873 /* 11.7 Bitwise Shift Operators {{{ */
 874 ShiftExpression
 875     : AdditiveExpression { $$ = $1; }
 876     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 877     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 878     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 879     ;
 880 /* }}} */
 881 /* 11.8 Relational Operators {{{ */
 882 RelationalExpression
 883     : ShiftExpression { $$ = $1; }
 884     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 885     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 886     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 887     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 888     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 889     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 890     ;
 891 /* }}} */
 892 /* 11.9 Equality Operators {{{ */
 893 EqualityExpression
 894     : RelationalExpression { $$ = $1; }
 895     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 896     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 897     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 898     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 899     ;
 900 /* }}} */
 901 /* 11.10 Binary Bitwise Operators {{{ */
 902 BitwiseANDExpression
 903     : EqualityExpression { $$ = $1; }
 904     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 905     ;
 906
 907 BitwiseXORExpression
 908     : BitwiseANDExpression { $$ = $1; }
 909     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 910     ;
 911
 912 BitwiseORExpression
 913     : BitwiseXORExpression { $$ = $1; }
 914     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 915     ;
 916 /* }}} */
 917 /* 11.11 Binary Logical Operators {{{ */
 918 LogicalANDExpression
 919     : BitwiseORExpression { $$ = $1; }
 920     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 921     ;
 922
 923 LogicalORExpression
 924     : LogicalANDExpression { $$ = $1; }
 925     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
 926     ;
 927 /* }}} */
 928 /* 11.12 Conditional Operator ( ? : ) {{{ */
 929 ConditionalExpression
 930     : LogicalORExpression { $$ = $1; }
 931     | LogicalORExpression "?" LexPushInOff AssignmentExpression LexPopIn ":" AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
 932     ;
 933 /* }}} */
 934 /* 11.13 Assignment Operators {{{ */
 935 AssignmentExpression
 936     : ConditionalExpression { $$ = $1; }
 937     | ArrowFunction { $$ = $1; }
 938     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
 939     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
 940     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
 941     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
 942     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
 943     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
 944     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
 945     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
 946     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
 947     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
 948     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
 949     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
 950     ;
 951 /* }}} */
 952 /* 11.14 Comma Operator {{{ */
 953 Expression_
 954     : "," Expression { $$ = $2; }
 955     | { $$ = CYNew CYCompound(); }
 956     ;
 957
 958 Expression
 959     : AssignmentExpression Expression_ { $2->AddPrev($1); $$ = $2; }
 960     ;
 961
 962 ExpressionOpt
 963     : Expression { $$ = $1; }
 964     | LexSetRegExp { $$ = NULL; }
 965     ;
 966 /* }}} */
 967
 968 /* 12 Statements {{{ */
 969 Statement__
 970     : Block { $$ = $1; }
 971     | VariableStatement { $$ = $1; }
 972     | EmptyStatement { $$ = $1; }
 973     | IfStatement { $$ = $1; }
 974     | BreakableStatement { $$ = $1; }
 975     | ContinueStatement { $$ = $1; }
 976     | BreakStatement { $$ = $1; }
 977     | ReturnStatement { $$ = $1; }
 978     | WithStatement { $$ = $1; }
 979     | LabelledStatement { $$ = $1; }
 980     | ThrowStatement { $$ = $1; }
 981     | TryStatement { $$ = $1; }
 982     | DebuggerStatement { $$ = $1; }
 983     ;
 984
 985 Statement_
 986     : LexSetRegExp Statement__ { $$ = $2; }
 987     | ExpressionStatement { $$ = $1; }
 988     ;
 989
 990 Statement
 991     : LexSetStatement Statement_ { $$ = $2; }
 992     ;
 993
 994 Declaration__
 995     : FunctionDeclaration { $$ = $1; }
 996     | LexicalDeclaration { $$ = $1; }
 997     ;
 998
 999 Declaration_
1000     : LexSetRegExp Declaration__ { $$ = $2; }
1001     ;
1002
1003 Declaration
1004     : LexSetStatement Declaration_ { $$ = $2; }
1005     ;
1006
1007 BreakableStatement
1008     : IterationStatement { $$ = $1; }
1009     | SwitchStatement { $$ = $1; }
1010     ;
1011 /* }}} */
1012 /* 12.1 Block {{{ */
1013 Block_
1014     : BRACE StatementListOpt "}" { $$ = $2; }
1015     ;
1016
1017 Block
1018     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1019     ;
1020
1021 StatementList
1022     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1023     ;
1024
1025 StatementListOpt
1026     : StatementList { $$ = $1; }
1027     | LexSetRegExp { $$ = NULL; }
1028     ;
1029
1030 StatementListItem
1031     : Statement { $$ = $1; }
1032     | Declaration { $$ = $1; }
1033     ;
1034 /* }}} */
1035 /* 12.2 Declarations {{{ */
1036 BindingIdentifier
1037     : Identifier { $$ = $1; }
1038     ;
1039
1040 // XXX: BindingPattern
1041 /* }}} */
1042 /* 12.2.1 Let and Const Declarations {{{ */
1043 LexicalDeclaration
1044     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1045     ;
1046
1047 LetOrConst
1048     : "let"
1049     | "const"
1050     ;
1051 /* }}} */
1052 /* 12.2.2 Variable Statement {{{ */
1053 VariableStatement
1054     : "var" VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1055     ;
1056
1057 VariableDeclarationList_
1058     : "," VariableDeclarationList { $$ = $2; }
1059     | { $$ = NULL; }
1060     ;
1061
1062 VariableDeclarationList
1063     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1064     ;
1065
1066 VariableDeclaration
1067     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1068     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1069     ;
1070
1071 Initialiser
1072     : "=" AssignmentExpression { $$ = $2; }
1073     ;
1074
1075 InitialiserOpt
1076     : Initialiser { $$ = $1; }
1077     | { $$ = NULL; }
1078     ;
1079 /* }}} */
1080 /* 12.2.4 Destructuring Binding Patterns {{{ */
1081 // XXX: *
1082
1083 BindingElement
1084     : SingleNameBinding { $$ = $1; }
1085     ;
1086
1087 SingleNameBinding
1088     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1089     ;
1090 /* }}} */
1091 /* 12.3 Empty Statement {{{ */
1092 EmptyStatement
1093     : ";" { $$ = CYNew CYEmpty(); }
1094     ;
1095 /* }}} */
1096 /* 12.4 Expression Statement {{{ */
1097 ExpressionStatement
1098     : Expression Terminator { $$ = CYNew CYExpress($1); }
1099     ;
1100 /* }}} */
1101 /* 12.5 The if Statement {{{ */
1102 ElseStatementOpt
1103     : "else" Statement { $$ = $2; }
1104     | %prec "if" { $$ = NULL; }
1105     ;
1106
1107 IfStatement
1108     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1109     ;
1110 /* }}} */
1111
1112 /* 12.6.1 The do-while Statement {{{ */
1113 IterationStatement
1114     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1115     ;
1116 /* }}} */
1117 /* 12.6.2 The while Statement {{{ */
1118 IterationStatement
1119     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1120     ;
1121 /* }}} */
1122 /* 12.6.3 The for Statement {{{ */
1123 IterationStatement
1124     : "for" "(" LexPushInOn ForStatementInitialiser LexPopIn ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1125     ;
1126
1127 ForStatementInitialiser
1128     : ExpressionOpt { $$ = $1; }
1129     | LexSetRegExp "var" VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1130     ;
1131 /* }}} */
1132 /* 12.6.4 The for-in and for-of Statements {{{ */
1133 IterationStatement
1134     : "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1135     | "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "of" Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1136     ;
1137
1138 ForInStatementInitialiser
1139     : LeftHandSideExpression { $$ = $1; }
1140     | LexSetRegExp "var" VariableDeclaration { $$ = $3; }
1141     ;
1142 /* }}} */
1143
1144 /* 12.7 The continue Statement {{{ */
1145 ContinueStatement
1146     : "continue" "\n" StrictSemi { $$ = CYNew CYContinue(NULL); }
1147     | "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1148     ;
1149 /* }}} */
1150 /* 12.8 The break Statement {{{ */
1151 BreakStatement
1152     : "break" "\n" StrictSemi { $$ = CYNew CYBreak(NULL); }
1153     | "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1154     ;
1155 /* }}} */
1156 /* 12.9 The return Statement {{{ */
1157 ReturnStatement
1158     : "return" "\n" StrictSemi { $$ = CYNew CYReturn(NULL); }
1159     | "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1160     ;
1161 /* }}} */
1162 /* 12.10 The with Statement {{{ */
1163 WithStatement
1164     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1165     ;
1166 /* }}} */
1167
1168 /* 12.11 The switch Statement {{{ */
1169 SwitchStatement
1170     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1171     ;
1172
1173 CaseBlock
1174     : BRACE CaseClausesOpt "}" { $$ = $2; }
1175     ;
1176
1177 CaseClause
1178     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1179     ;
1180
1181 CaseClausesOpt
1182     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1183     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1184     | { $$ = NULL; }
1185     ;
1186
1187 DefaultClause
1188     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1189     ;
1190 /* }}} */
1191 /* 12.12 Labelled Statements {{{ */
1192 LabelledStatement
1193     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1194     ;
1195 /* }}} */
1196 /* 12.13 The throw Statement {{{ */
1197 ThrowStatement
1198     : "throw" "\n" StrictSemi { YYABORT; }
1199     | "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1200     ;
1201 /* }}} */
1202 /* 12.14 The try Statement {{{ */
1203 TryStatement
1204     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1205     ;
1206
1207 CatchOpt
1208     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1209     | { $$ = NULL; }
1210     ;
1211
1212 FinallyOpt
1213     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1214     | { $$ = NULL; }
1215     ;
1216 /* }}} */
1217 /* 12.14 The debugger Statement {{{ */
1218 DebuggerStatement
1219     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1220     ;
1221 /* }}} */
1222
1223 /* 13.1 Function Definitions {{{ */
1224 FunctionDeclaration
1225     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1226     ;
1227
1228 FunctionExpression
1229     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt LexPopIn ")" BRACE LexPushInOff FunctionBody LexPopIn "}" { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1230     ;
1231
1232 FormalParameterList_
1233     : "," FormalParameterList { $$ = $2; }
1234     | { $$ = NULL; }
1235     ;
1236
1237 FormalParameterList
1238     // XXX: : FunctionRestParameter { $$ = $1; }
1239     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1240     ;
1241
1242 FormalParameterListOpt
1243     : FormalParameterList
1244     | { $$ = NULL; }
1245     ;
1246
1247 /* XXX: FunctionRestParameter
1248     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1249     ;*/
1250
1251 FormalParameter
1252     : BindingElement { $$ = $1; }
1253     ;
1254
1255 FunctionBody
1256     : StatementListOpt { $$ = $1; }
1257     ;
1258 /* }}} */
1259 /* 13.2 Arrow Function Definitions {{{ */
1260 ArrowFunction
1261     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFunctionExpression(NULL, $2, $5); }
1262     ;
1263
1264 ArrowParameters
1265     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1266     //| ParentheticalOpt { $$ = $1; }
1267     ;
1268
1269 ConciseBody
1270     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1271     | ";{" LexPushInOff FunctionBody LexPopIn "}" { $$ = $3; }
1272     ;
1273 /* }}} */
1274 /* 14 Program {{{ */
1275 Program
1276     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1277     ;
1278
1279 ProgramBody
1280     : StatementList { $$ = $1; }
1281     ;
1282
1283 ProgramBodyOpt
1284     : ProgramBody { $$ = $1; }
1285     | { $$ = NULL; }
1286     ;
1287 /* }}} */
1288
1289 @begin ObjectiveC
1290 /* Cycript (Objective-C): @class Declaration {{{ */
1291 ClassSuperOpt
1292     /* XXX: why the hell did I choose MemberExpression? */
1293     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1294     | { $$ = NULL; }
1295     ;
1296
1297 ClassField
1298     : Expression Identifier ";"
1299     ;
1300
1301 ClassFieldList
1302     : BRACE ClassFieldListOpt "}" { $$ = NULL; }
1303     ;
1304
1305 ClassFieldListOpt
1306     : ClassFieldListOpt ClassField
1307     |
1308     ;
1309
1310 MessageScope
1311     : "+" { $$ = false; }
1312     | "-" { $$ = true; }
1313     ;
1314
1315 TypeOpt
1316     : "(" Expression ")" { $$ = $2; }
1317     | "(" LexSetRegExp "void" ")" { $$ = NULL; }
1318     | { $$ = NULL; }
1319     ;
1320
1321 MessageParameter
1322     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1323     ;
1324
1325 MessageParameterList
1326     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1327     ;
1328
1329 MessageParameterListOpt
1330     : MessageParameterList { $$ = $1; }
1331     | { $$ = NULL; }
1332     ;
1333
1334 MessageParameters
1335     : MessageParameterList { $$ = $1; }
1336     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1337     ;
1338
1339 ClassMessageDeclaration
1340     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1341     ;
1342
1343 ClassMessageDeclarationListOpt
1344     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1345     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1346     | { $$ = NULL; }
1347     ;
1348
1349 ClassName
1350     : Identifier { $$ = $1; }
1351     | "(" AssignmentExpression ")" { $$ = $2; }
1352     ;
1353
1354 ClassNameOpt
1355     : ClassName { $$ = $1; }
1356     | { $$ = NULL; }
1357     ;
1358
1359 // XXX: this should be AssignmentExpressionNoRight
1360 ClassProtocols
1361     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1362     ;
1363
1364 ClassProtocolsOpt
1365     : "," ClassProtocols { $$ = $2; }
1366     | { $$ = NULL; }
1367     ;
1368
1369 ClassProtocolListOpt
1370     : "<" ClassProtocols ">" { $$ = $2; }
1371     | { $$ = NULL; }
1372     ;
1373
1374 ClassExpression
1375     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt LexPopIn "@end" { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1376     ;
1377
1378 ClassStatement
1379     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1380     ;
1381
1382 CategoryName
1383     : "(" WordOpt ")"
1384     ;
1385
1386 CategoryStatement
1387     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1388     ;
1389
1390 PrimaryExpression
1391     : ClassExpression { $$ = $1; }
1392     ;
1393
1394 Statement__
1395     : ClassStatement { $$ = $1; }
1396     | CategoryStatement { $$ = $1; }
1397     ;
1398 /* }}} */
1399 /* Cycript (Objective-C): Send Message {{{ */
1400 VariadicCall
1401     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1402     | { $$ = NULL; }
1403     ;
1404
1405 SelectorWordOpt
1406     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1407     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1408     ;
1409
1410 SelectorCall_
1411     : SelectorCall { $$ = $1; }
1412     | VariadicCall { $$ = $1; }
1413     ;
1414
1415 SelectorCall
1416     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1417     ;
1418
1419 SelectorList
1420     : SelectorCall { $$ = $1; }
1421     | Word { $$ = CYNew CYArgument($1, NULL); }
1422     ;
1423
1424 MessageExpression
1425     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList LexPopIn "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1426     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList LexPopIn "]" { $$ = CYNew CYSendSuper($6); }
1427     ;
1428
1429 SelectorExpression_
1430     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1431     ;
1432
1433 SelectorExpression
1434     : SelectorExpression_ { $$ = $1; }
1435     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1436     ;
1437
1438 SelectorExpressionOpt
1439     : SelectorExpression_ { $$ = $1; }
1440     | { $$ = NULL; }
1441     ;
1442
1443 PrimaryExpression
1444     : MessageExpression { $$ = $1; }
1445     | "@selector" "(" LexPushInOff SelectorExpression LexPopIn ")" { $$ = CYNew CYSelector($4); }
1446     ;
1447 /* }}} */
1448 /* Cycript (Objective-C): @import Directive {{{ */
1449 PathName
1450     : "/" PathName
1451     | "." PathName
1452     | Word PathName
1453     |
1454     ;
1455
1456 ImportPath
1457     : "<" PathName ">"
1458     | StringLiteral
1459     ;
1460
1461 StatementListItem
1462     : "@import" ImportPath { $$ = CYNew CYImport(); }
1463     ;
1464 /* }}} */
1465 @end
1466
1467 @begin C
1468 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1469 LeftHandSideExpression
1470     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1471     ;
1472
1473 UnaryExpression_
1474     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1475     ;
1476
1477 MemberAccess
1478     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1479     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1480     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1481     ;
1482 /* }}} */
1483 @end
1484
1485 /* YUI: Documentation Comments {{{ */
1486 Statement__
1487     : Comment { $$ = $1; }
1488     ;
1489 /* }}} */
1490
1491 @begin E4X
1492 /* Lexer State {{{ */
1493 LexPushRegExp
1494     : { driver.PushCondition(CYDriver::RegExpCondition); }
1495     ;
1496
1497 LexPushXMLContent
1498     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1499     ;
1500
1501 LexPushXMLTag
1502     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1503     ;
1504
1505 LexPop
1506     : { driver.PopCondition(); }
1507     ;
1508
1509 LexSetXMLContent
1510     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1511     ;
1512
1513 LexSetXMLTag
1514     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1515     ;
1516 /* }}} */
1517
1518 XMLWhitespaceOpt
1519     : XMLWhitespace
1520     |
1521     ;
1522
1523 /* 8.1 Context Keywords {{{ */
1524 Identifier
1525     : "namespace" { $$ = $1; }
1526     | "xml" { $$ = $1; }
1527     ;
1528 /* }}} */
1529 /* 8.3 XML Initialiser Input Elements {{{ */
1530 XMLMarkup
1531     : XMLComment { $$ = $1; }
1532     | XMLCDATA { $$ = $1; }
1533     | XMLPI { $$ = $1; }
1534     ;
1535 /* }}} */
1536 /* 11.1 Primary Expressions {{{ */
1537 PrimaryExpression
1538     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1539     | XMLInitialiser { $$ = $1; }
1540     | XMLListInitialiser { $$ = $1; }
1541     ;
1542
1543 PropertyIdentifier
1544     : AttributeIdentifier { $$ = $1; }
1545     | QualifiedIdentifier { $$ = $1; }
1546     | WildcardIdentifier { $$ = $1; }
1547     ;
1548 /* }}} */
1549 /* 11.1.1 Attribute Identifiers {{{ */
1550 AttributeIdentifier
1551     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1552     ;
1553
1554 PropertySelector_
1555     : PropertySelector { $$ = $1; }
1556     | "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYSelector($3); }
1557     ;
1558
1559 PropertySelector
1560     : Identifier { $$ = CYNew CYSelector($1); }
1561     | WildcardIdentifier { $$ = $1; }
1562     ;
1563 /* }}} */
1564 /* 11.1.2 Qualified Identifiers {{{ */
1565 QualifiedIdentifier_
1566     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1567     | QualifiedIdentifier { $$ = $1; }
1568     ;
1569
1570 QualifiedIdentifier
1571     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1572     ;
1573 /* }}} */
1574 /* 11.1.3 Wildcard Identifiers {{{ */
1575 WildcardIdentifier
1576     : "*" { $$ = CYNew CYWildcard(); }
1577     ;
1578 /* }}} */
1579 /* 11.1.4 XML Initialiser {{{ */
1580 XMLInitialiser
1581     : XMLMarkup { $$ = $1; }
1582     | XMLElement { $$ = $1; }
1583     ;
1584
1585 XMLElement
1586     : "<" LexPushInOff XMLTagContent LexPop LexPopIn "/>"
1587     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop LexPopIn ">"
1588     ;
1589
1590 XMLTagContent
1591     : LexPushXMLTag XMLTagName XMLAttributes
1592     ;
1593
1594 XMLExpression
1595     : BRACE LexPushRegExp Expression LexPop "}"
1596     ;
1597
1598 XMLTagName
1599     : XMLExpression
1600     | XMLName
1601     ;
1602
1603 XMLAttributes_
1604     : XMLAttributes_ XMLAttribute
1605     |
1606     ;
1607
1608 XMLAttributes
1609     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1610     | XMLAttributes_ XMLWhitespaceOpt
1611     ;
1612
1613 XMLAttributeValue_
1614     : XMLExpression
1615     | XMLAttributeValue
1616     ;
1617
1618 XMLAttribute
1619     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1620     ;
1621
1622 XMLElementContent
1623     : XMLExpression XMLElementContentOpt
1624     | XMLMarkup XMLElementContentOpt
1625     | XMLText XMLElementContentOpt
1626     | XMLElement XMLElementContentOpt
1627     ;
1628
1629 XMLElementContentOpt
1630     : XMLElementContent
1631     |
1632     ;
1633 /* }}} */
1634 /* 11.1.5 XMLList Initialiser {{{ */
1635 XMLListInitialiser
1636     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop LexPopIn "</>" { $$ = CYNew CYXMLList($4); }
1637     ;
1638 /* }}} */
1639 /* 11.2 Left-Hand-Side Expressions {{{ */
1640 PropertyIdentifier_
1641     : Identifier { $$ = $1; }
1642     | PropertyIdentifier { $$ = $1; }
1643     ;
1644
1645 MemberAccess
1646     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1647     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1648     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1649     ;
1650 /* }}} */
1651 /* 12.1 The default xml namespace Statement {{{ */
1652 /* XXX: DefaultXMLNamespaceStatement
1653     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1654     ;
1655
1656 Statement__
1657     : DefaultXMLNamespaceStatement { $$ = $1; }
1658     ; */
1659 /* }}} */
1660 @end
1661
1662 /* JavaScript 1.7: Array Comprehensions {{{ */
1663 IfComprehension
1664     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1665     ;
1666
1667 ForComprehension
1668     : "for" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
1669     | "for" "each" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
1670     ;
1671
1672 ComprehensionList
1673     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1674     ;
1675
1676 ComprehensionListOpt
1677     : ComprehensionList { $$ = $1; }
1678     | IfComprehension { $$ = $1; }
1679     | { $$ = NULL; }
1680     ;
1681
1682 PrimaryExpression
1683     : "[" LexPushInOff AssignmentExpression ComprehensionList LexPopIn "]" { $$ = CYNew CYArrayComprehension($3, $4); }
1684     ;
1685 /* }}} */
1686 /* JavaScript 1.7: for each {{{ */
1687 IterationStatement
1688     : "for" "each" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
1689     ;
1690 /* }}} */
1691 /* JavaScript 1.7: let Statements {{{ */
1692 LetStatement
1693     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1694     ;
1695
1696 Statement__
1697     : LetStatement
1698     ;
1699 /* }}} */
1700
1701 /* JavaScript FTW: Ruby Blocks {{{ */
1702 RubyProcParameterList_
1703     : "," RubyProcParameterList { $$ = $2; }
1704     | { $$ = NULL; }
1705     ;
1706
1707 RubyProcParameterList
1708     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1709     | { $$ = NULL; }
1710     ;
1711
1712 RubyProcParameters
1713     : "|" RubyProcParameterList "|" { $$ = $2; }
1714     | "||" { $$ = NULL; }
1715     ;
1716
1717 RubyProcParametersOpt
1718     : RubyProcParameters
1719     | { $$ = NULL; }
1720     ;
1721
1722 RubyProcExpression
1723     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1724     ;
1725
1726 PrimaryExpression
1727     : "{" LexPushInOff RubyProcParameters StatementListOpt LexPopIn "}" { $$ = CYNew CYRubyProc($3, $4); }
1728     ;
1729
1730 CallExpression
1731     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1732     ;
1733 /* }}} */
1734
1735 %%