Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 typedef struct {
  43     bool newline_;
  44
  45     union {
  46         bool bool_;
  47
  48         CYDriver::Condition condition_;
  49
  50         CYArgument *argument_;
  51         CYAssignment *assignment_;
  52         CYBoolean *boolean_;
  53         CYClause *clause_;
  54         cy::Syntax::Catch *catch_;
  55         CYComment *comment_;
  56         CYComprehension *comprehension_;
  57         CYCompound *compound_;
  58         CYDeclaration *declaration_;
  59         CYDeclarations *declarations_;
  60         CYElement *element_;
  61         CYExpression *expression_;
  62         CYFalse *false_;
  63         CYFinally *finally_;
  64         CYForInitialiser *for_;
  65         CYForInInitialiser *forin_;
  66         CYFunctionParameter *functionParameter_;
  67         CYIdentifier *identifier_;
  68         CYInfix *infix_;
  69         CYLiteral *literal_;
  70         CYMember *member_;
  71         CYNull *null_;
  72         CYNumber *number_;
  73         CYProgram *program_;
  74         CYProperty *property_;
  75         CYPropertyName *propertyName_;
  76         CYRubyProc *rubyProc_;
  77         CYStatement *statement_;
  78         CYString *string_;
  79         CYThis *this_;
  80         CYTrue *true_;
  81         CYWord *word_;
  82
  83 @begin ObjectiveC
  84         CYClassName *className_;
  85         CYField *field_;
  86         CYMessage *message_;
  87         CYMessageParameter *messageParameter_;
  88         CYProtocol *protocol_;
  89         CYSelectorPart *selector_;
  90 @end
  91
  92 @begin E4X
  93         CYAttribute *attribute_;
  94         CYPropertyIdentifier *propertyIdentifier_;
  95         CYSelector *selector_;
  96 @end
  97     };
  98 } YYSTYPE;
  99
 100 #define YYSTYPE YYSTYPE
 101 @if Bison24 }
 102
 103 @if Bison24 %code provides {
 104 int cylex(YYSTYPE *, cy::location *, void *);
 105 @if Bison24 }
 106
 107 @if Bison23 %}
 108
 109 %name-prefix="cy"
 110
 111 @if Bison23 %skeleton "lalr1.cc"
 112 @if Bison24 %language "C++"
 113
 114 %initial-action {
 115     @$.begin.filename = @$.end.filename = &driver.filename_;
 116 };
 117
 118 %locations
 119 %defines
 120
 121 //%glr-parser
 122 //%expect 1
 123
 124 %error-verbose
 125
 126 %parse-param { CYDriver &driver }
 127 %lex-param { void *cyscanner }
 128
 129 @begin E4X
 130 %token XMLCDATA
 131 %token XMLComment
 132 %token XMLPI
 133
 134 %token XMLAttributeValue
 135 %token XMLName
 136 %token XMLTagCharacters
 137 %token XMLText
 138 %token XMLWhitespace
 139 @end
 140
 141 @begin E4X
 142 %token LeftRight "<>"
 143 %token LeftSlashRight "</>"
 144
 145 %token SlashRight "/>"
 146 %token LeftSlash "</"
 147
 148 %token ColonColon "::"
 149 %token PeriodPeriod ".."
 150 @end
 151
 152 @begin E4X ObjectiveC
 153 %token At "@"
 154 @end
 155
 156 %token Ampersand "&"
 157 %token AmpersandAmpersand "&&"
 158 %token AmpersandEqual "&="
 159 %token Carrot "^"
 160 %token CarrotEqual "^="
 161 %token Equal "="
 162 %token EqualEqual "=="
 163 %token EqualEqualEqual "==="
 164 %token Exclamation "!"
 165 %token ExclamationEqual "!="
 166 %token ExclamationEqualEqual "!=="
 167 %token Hyphen "-"
 168 %token HyphenEqual "-="
 169 %token HyphenHyphen "--"
 170 %token HyphenHyphen_ "\n--"
 171 %token HyphenRight "->"
 172 %token Left "<"
 173 %token LeftEqual "<="
 174 %token LeftLeft "<<"
 175 %token LeftLeftEqual "<<="
 176 %token Percent "%"
 177 %token PercentEqual "%="
 178 %token Period "."
 179 %token Pipe "|"
 180 %token PipeEqual "|="
 181 %token PipePipe "||"
 182 %token Plus "+"
 183 %token PlusEqual "+="
 184 %token PlusPlus "++"
 185 %token PlusPlus_ "\n++"
 186 %token Right ">"
 187 %token RightEqual ">="
 188 %token RightRight ">>"
 189 %token RightRightEqual ">>="
 190 %token RightRightRight ">>>"
 191 %token RightRightRightEqual ">>>="
 192 %token Slash "/"
 193 %token SlashEqual "/="
 194 %token Star "*"
 195 %token StarEqual "*="
 196 %token Tilde "~"
 197
 198 %token Colon ":"
 199 %token Comma ","
 200 %token Question "?"
 201 %token SemiColon ";"
 202 %token NewLine "\n"
 203
 204 %token <comment_> Comment
 205
 206 %token OpenParen "("
 207 %token CloseParen ")"
 208
 209 %token OpenBrace "{"
 210 %token OpenBrace_ "\n{"
 211 %token CloseBrace "}"
 212
 213 %token OpenBracket "["
 214 %token CloseBracket "]"
 215
 216 @begin Java
 217 %token AtClass "@class"
 218 @end
 219
 220 @begin ObjectiveC
 221 %token AtImplementation "@implementation"
 222 %token AtImport "@import"
 223 %token AtEnd "@end"
 224 %token AtSelector "@selector"
 225 @end
 226
 227 %token <false_> False "false"
 228 %token <null_> Null "null"
 229 %token <true_> True "true"
 230
 231 // ES3/ES5/WIE/JSC Reserved
 232 %token <word_> Break "break"
 233 %token <word_> Case "case"
 234 %token <word_> Catch "catch"
 235 %token <word_> Continue "continue"
 236 %token <word_> Default "default"
 237 %token <word_> Delete "delete"
 238 %token <word_> Do "do"
 239 %token <word_> Else "else"
 240 %token <word_> Finally "finally"
 241 %token <word_> For "for"
 242 %token <word_> Function "function"
 243 %token <word_> If "if"
 244 %token <word_> In "in"
 245 %token <word_> InstanceOf "instanceof"
 246 %token <word_> New "new"
 247 %token <word_> Return "return"
 248 %token <word_> Switch "switch"
 249 %token <this_> This "this"
 250 %token <word_> Throw "throw"
 251 %token <word_> Try "try"
 252 %token <word_> TypeOf "typeof"
 253 %token <word_> Var "var"
 254 %token <word_> Void "void"
 255 %token <word_> While "while"
 256 %token <word_> With "with"
 257
 258 // ES3/IE6 Future, ES5/JSC Reserved
 259 %token <word_> Debugger "debugger"
 260
 261 // ES3/ES5/IE6 Future, JSC Reserved
 262 %token <word_> Const "const"
 263
 264 // ES3/ES5/IE6/JSC Future
 265 %token <word_> Class "class"
 266 %token <word_> Enum "enum"
 267 %token <word_> Export "export"
 268 %token <word_> Extends "extends"
 269 %token <word_> Import "import"
 270 %token <word_> Super "super"
 271
 272 // ES3 Future, ES5 Strict Future
 273 %token <identifier_> Implements "implements"
 274 %token <identifier_> Interface "interface"
 275 %token <identifier_> Package "package"
 276 %token <identifier_> Private "private"
 277 %token <identifier_> Protected "protected"
 278 %token <identifier_> Public "public"
 279 %token <identifier_> Static "static"
 280
 281 // ES3 Future
 282 %token <identifier_> Abstract "abstract"
 283 %token <identifier_> Boolean "boolean"
 284 %token <identifier_> Byte "byte"
 285 %token <identifier_> Char "char"
 286 %token <identifier_> Double "double"
 287 %token <identifier_> Final "final"
 288 %token <identifier_> Float "float"
 289 %token <identifier_> Goto "goto"
 290 %token <identifier_> Int "int"
 291 %token <identifier_> Long "long"
 292 %token <identifier_> Native "native"
 293 %token <identifier_> Short "short"
 294 %token <identifier_> Synchronized "synchronized"
 295 %token <identifier_> Throws "throws"
 296 %token <identifier_> Transient "transient"
 297 %token <identifier_> Volatile "volatile"
 298
 299 // ES5 Strict
 300 %token <identifier_> Let "let"
 301 %token <identifier_> Yield "yield"
 302
 303 // Woah?!
 304 %token <identifier_> Each "each"
 305
 306 @begin E4X
 307 // E4X Conditional
 308 %token <identifier_> Namespace "namespace"
 309 %token <identifier_> XML "xml"
 310 @end
 311
 312 %token AutoComplete
 313
 314 %token <identifier_> Identifier_
 315 %token <number_> NumericLiteral
 316 %token <string_> StringLiteral
 317 %token <literal_> RegularExpressionLiteral
 318
 319 %type <expression_> AdditiveExpression
 320 %type <expression_> AdditiveExpressionNoBF
 321 %type <argument_> ArgumentList
 322 %type <argument_> ArgumentList_
 323 %type <argument_> ArgumentListOpt
 324 %type <argument_> Arguments
 325 %type <literal_> ArrayLiteral
 326 %type <expression_> AssigneeExpression
 327 %type <expression_> AssigneeExpressionNoBF
 328 %type <expression_> AssignmentExpression
 329 %type <assignment_> AssignmentExpression_
 330 %type <expression_> AssignmentExpressionNoBF
 331 %type <expression_> AssignmentExpressionNoIn
 332 %type <expression_> BitwiseANDExpression
 333 %type <expression_> BitwiseANDExpressionNoBF
 334 %type <expression_> BitwiseANDExpressionNoIn
 335 %type <statement_> Block
 336 %type <statement_> Block_
 337 %type <boolean_> BooleanLiteral
 338 %type <expression_> BitwiseORExpression
 339 %type <expression_> BitwiseORExpressionNoBF
 340 %type <expression_> BitwiseORExpressionNoIn
 341 %type <expression_> BitwiseXORExpression
 342 %type <expression_> BitwiseXORExpressionNoBF
 343 %type <expression_> BitwiseXORExpressionNoIn
 344 %type <statement_> BreakStatement
 345 %type <expression_> CallExpression
 346 %type <expression_> CallExpressionNoBF
 347 %type <clause_> CaseBlock
 348 %type <clause_> CaseClause
 349 %type <clause_> CaseClausesOpt
 350 %type <catch_> CatchOpt
 351 %type <comprehension_> ComprehensionList
 352 %type <comprehension_> ComprehensionListOpt
 353 %type <expression_> ConditionalExpression
 354 %type <expression_> ConditionalExpressionNoBF
 355 %type <expression_> ConditionalExpressionNoIn
 356 %type <statement_> ContinueStatement
 357 %type <clause_> DefaultClause
 358 %type <statement_> DoWhileStatement
 359 %type <expression_> Element
 360 %type <expression_> ElementOpt
 361 %type <element_> ElementList
 362 %type <element_> ElementListOpt
 363 %type <statement_> ElseStatementOpt
 364 %type <statement_> EmptyStatement
 365 %type <expression_> EqualityExpression
 366 %type <expression_> EqualityExpressionNoBF
 367 %type <expression_> EqualityExpressionNoIn
 368 %type <expression_> Expression
 369 %type <expression_> ExpressionOpt
 370 %type <compound_> Expression_
 371 %type <expression_> ExpressionNoBF
 372 %type <expression_> ExpressionNoIn
 373 %type <compound_> ExpressionNoIn_
 374 %type <expression_> ExpressionNoInOpt
 375 %type <statement_> ExpressionStatement
 376 %type <finally_> FinallyOpt
 377 %type <comprehension_> ForComprehension
 378 %type <statement_> ForStatement
 379 %type <for_> ForStatementInitialiser
 380 %type <statement_> ForInStatement
 381 %type <forin_> ForInStatementInitialiser
 382 %type <functionParameter_> FormalParameterList
 383 %type <functionParameter_> FormalParameterList_
 384 %type <statement_> FunctionBody
 385 %type <statement_> FunctionDeclaration
 386 %type <expression_> FunctionExpression
 387 %type <identifier_> Identifier
 388 %type <identifier_> IdentifierOpt
 389 %type <comprehension_> IfComprehension
 390 %type <statement_> IfStatement
 391 %type <expression_> Initialiser
 392 %type <expression_> InitialiserOpt
 393 %type <expression_> InitialiserNoIn
 394 %type <expression_> InitialiserNoInOpt
 395 %type <statement_> IterationStatement
 396 %type <statement_> LabelledStatement
 397 %type <expression_> LeftHandSideExpression
 398 %type <expression_> LeftHandSideExpressionNoBF
 399 //%type <statement_> LetStatement
 400 %type <literal_> Literal
 401 %type <literal_> LiteralNoRE
 402 %type <literal_> LiteralRE
 403 %type <expression_> LogicalANDExpression
 404 %type <expression_> LogicalANDExpressionNoBF
 405 %type <expression_> LogicalANDExpressionNoIn
 406 %type <expression_> LogicalORExpression
 407 %type <expression_> LogicalORExpressionNoBF
 408 %type <expression_> LogicalORExpressionNoIn
 409 %type <member_> MemberAccess
 410 %type <expression_> MemberExpression
 411 %type <expression_> MemberExpression_
 412 %type <expression_> MemberExpressionNoBF
 413 %type <expression_> MultiplicativeExpression
 414 %type <expression_> MultiplicativeExpressionNoBF
 415 %type <expression_> NewExpression
 416 %type <expression_> NewExpression_
 417 %type <expression_> NewExpressionNoBF
 418 %type <null_> NullLiteral
 419 %type <literal_> ObjectLiteral
 420 %type <expression_> PostfixExpression
 421 %type <expression_> PostfixExpressionNoBF
 422 %type <expression_> PrimaryExpression
 423 %type <expression_> PrimaryExpressionNo
 424 %type <expression_> PrimaryExpressionNoBF
 425 %type <expression_> PrimaryExpressionNoRE
 426 %type <expression_> PrimaryExpressionBF
 427 %type <statement_> Program
 428 %type <propertyName_> PropertyName
 429 %type <propertyName_> PropertyName_
 430 %type <property_> PropertyNameAndValueList
 431 %type <property_> PropertyNameAndValueList_
 432 %type <property_> PropertyNameAndValueListOpt
 433 %type <expression_> RelationalExpression
 434 %type <infix_> RelationalExpression_
 435 %type <expression_> RelationalExpressionNoBF
 436 %type <expression_> RelationalExpressionNoIn
 437 %type <infix_> RelationalExpressionNoIn_
 438 %type <statement_> ReturnStatement
 439 %type <rubyProc_> RubyProcExpression
 440 %type <rubyProc_> RubyProcExpressionNoOA
 441 %type <functionParameter_> RubyProcParameterList
 442 %type <functionParameter_> RubyProcParameterList_
 443 %type <functionParameter_> RubyProcParameters
 444 %type <functionParameter_> RubyProcParametersOpt
 445 %type <expression_> ShiftExpression
 446 %type <expression_> ShiftExpressionNoBF
 447 %type <statement_> SourceElement
 448 %type <statement_> SourceElement_
 449 %type <statement_> SourceElements
 450 %type <statement_> Statement
 451 %type <statement_> Statement_
 452 %type <statement_> StatementList
 453 %type <statement_> StatementListOpt
 454 %type <statement_> SwitchStatement
 455 %type <statement_> ThrowStatement
 456 %type <statement_> TryStatement
 457 %type <expression_> UnaryExpression
 458 %type <expression_> UnaryExpression_
 459 %type <expression_> UnaryExpressionNoBF
 460 %type <declaration_> VariableDeclaration
 461 %type <declaration_> VariableDeclarationNoIn
 462 %type <declarations_> VariableDeclarationList
 463 %type <declarations_> VariableDeclarationList_
 464 %type <declarations_> VariableDeclarationListNoIn
 465 %type <declarations_> VariableDeclarationListNoIn_
 466 %type <statement_> VariableStatement
 467 %type <statement_> WhileStatement
 468 %type <statement_> WithStatement
 469
 470 @begin C
 471 %type <expression_> AssigneeExpressionNoRE
 472 %type <expression_> CallExpressionNoRE
 473 %type <expression_> LeftHandSideExpressionNoRE
 474 %type <expression_> MemberExpressionNoRE
 475 %type <expression_> NewExpressionNoRE
 476 %type <expression_> PostfixExpressionNoRE
 477 %type <expression_> UnaryAssigneeExpression
 478 %type <expression_> UnaryExpressionNoRE
 479 @end
 480
 481 @begin ObjectiveC
 482 %type <statement_> CategoryStatement
 483 %type <expression_> ClassExpression
 484 %type <statement_> ClassStatement
 485 %type <expression_> ClassSuperOpt
 486 %type <field_> ClassFieldList
 487 %type <message_> ClassMessageDeclaration
 488 %type <message_> ClassMessageDeclarationListOpt
 489 %type <className_> ClassName
 490 %type <className_> ClassNameOpt
 491 %type <protocol_> ClassProtocolListOpt
 492 %type <protocol_> ClassProtocols
 493 %type <protocol_> ClassProtocolsOpt
 494 %type <expression_> MessageExpression
 495 %type <messageParameter_> MessageParameter
 496 %type <messageParameter_> MessageParameters
 497 %type <messageParameter_> MessageParameterList
 498 %type <messageParameter_> MessageParameterListOpt
 499 %type <bool_> MessageScope
 500 %type <argument_> SelectorCall
 501 %type <argument_> SelectorCall_
 502 %type <selector_> SelectorExpression
 503 %type <selector_> SelectorExpression_
 504 %type <selector_> SelectorExpressionOpt
 505 %type <argument_> SelectorList
 506 %type <word_> SelectorWordOpt
 507 %type <expression_> TypeOpt
 508 %type <argument_> VariadicCall
 509 %type <word_> Word
 510 %type <word_> WordOpt
 511 @end
 512
 513 @begin E4X
 514 %type <propertyIdentifier_> PropertyIdentifier_
 515 %type <selector_> PropertySelector
 516 %type <selector_> PropertySelector_
 517 %type <identifier_> QualifiedIdentifier
 518 %type <identifier_> QualifiedIdentifier_
 519 %type <identifier_> WildcardIdentifier
 520 %type <identifier_> XMLComment
 521 %type <identifier_> XMLCDATA
 522 %type <identifier_> XMLElement
 523 %type <identifier_> XMLElementContent
 524 %type <identifier_> XMLMarkup
 525 %type <identifier_> XMLPI
 526
 527 %type <attribute_> AttributeIdentifier
 528 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 529 %type <expression_> PropertyIdentifier
 530 %type <expression_> XMLListInitialiser
 531 %type <expression_> XMLInitialiser
 532 @end
 533
 534 %nonassoc Identifier_ "abstract" "boolean" "break" "byte" "case" "catch" "char" "class" "const" "continue" "debugger" "default" "delete" "do" "double" "each" "enum" "export" "extends" "false" "final" "finally" "float" /*"for"*/ "function" "goto" "implements" "import" /*"in"*/ /*"instanceof"*/ "int" "interface" "let" "long" "namespace" "native" "new" "null" "package" "private" "protected" "public" "return" "short" "super" "static" "switch" "synchronized" "this" "throw" "throws" "transient" "true" "try" "typeof" "var" "void" "volatile" "while" "with" "xml" "yield"
 535
 536 %nonassoc "if"
 537 %nonassoc "else"
 538
 539 %nonassoc "++" "--"
 540 %nonassoc "(" "["
 541
 542 %left "*" "/" "%"
 543 %left "+" "-"
 544 %left "<<" ">>" ">>>"
 545 %left "<" ">" "<=" ">=" "instanceof" "in"
 546 %left "==" "!=" "===" "!=="
 547 %left "&"
 548 %left "^"
 549 %left "|"
 550 %left "&&"
 551 %left "||"
 552
 553 %right "=" "*=" "/=" "%=" "+=" "-=" "<<=" ">>=" ">>>=" "&=" "^=" "|="
 554
 555 %start Program
 556
 557 %%
 558
 559 /* Lexer State {{{ */
 560 LexSetRegExp
 561     : { driver.SetCondition(CYDriver::RegExpCondition); }
 562     ;
 563 /* }}} */
 564
 565 Brace
 566     : "{"
 567     | "\n{"
 568     ;
 569
 570 StrictSemi
 571     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 572     ;
 573
 574 Terminator_
 575     : ";"
 576     | "\n" StrictSemi
 577     ;
 578
 579 TerminatorOpt
 580     : Terminator_
 581     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 582     ;
 583
 584 Terminator
 585     : Terminator_
 586     | error { if (yychar != 0 && yychar != cy::parser::token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 587     ;
 588
 589 /*CommaOpt
 590     : ","
 591     |
 592     ;*/
 593
 594 @begin ObjectiveC
 595 NewLineOpt
 596     : "\n"
 597     |
 598     ;
 599
 600 WordOpt
 601     : Word { $$ = $1; }
 602     | { $$ = NULL; }
 603     ;
 604
 605 Word
 606     : Identifier { $$ = $1; }
 607     | "break" NewLineOpt { $$ = $1; }
 608     | "case" { $$ = $1; }
 609     | "catch" { $$ = $1; }
 610     | "class" { $$ = $1; }
 611     | "const" { $$ = $1; }
 612     | "continue" NewLineOpt { $$ = $1; }
 613     | "debugger" { $$ = $1; }
 614     | "default" { $$ = $1; }
 615     | "delete" { $$ = $1; }
 616     | "do" { $$ = $1; }
 617     | "else" { $$ = $1; }
 618     | "enum" { $$ = $1; }
 619     | "export" { $$ = $1; }
 620     | "extends" { $$ = $1; }
 621     | "false" { $$ = $1; }
 622     | "finally" { $$ = $1; }
 623     /* XXX: | "for" { $$ = $1; } */
 624     | "function" { $$ = $1; }
 625     | "if" { $$ = $1; }
 626     | "import" { $$ = $1; }
 627     /* XXX: | "in" { $$ = $1; } */
 628     /* XXX: | "instanceof" { $$ = $1; } */
 629     | "new" { $$ = $1; }
 630     | "null" { $$ = $1; }
 631     | "return" NewLineOpt { $$ = $1; }
 632     | "super" { $$ = $1; }
 633     | "switch" { $$ = $1; }
 634     | "this" { $$ = $1; }
 635     | "throw" NewLineOpt { $$ = $1; }
 636     | "true" { $$ = $1; }
 637     | "try" { $$ = $1; }
 638     | "typeof" { $$ = $1; }
 639     | "var" { $$ = $1; }
 640     | "void" { $$ = $1; }
 641     | "while" { $$ = $1; }
 642     | "with" { $$ = $1; }
 643     ;
 644 @end
 645
 646 Identifier
 647     : Identifier_ { $$ = $1; }
 648
 649     | "implements" { $$ = $1; }
 650     | "interface" { $$ = $1; }
 651     | "package" { $$ = $1; }
 652     | "private" { $$ = $1; }
 653     | "protected" { $$ = $1; }
 654     | "public" { $$ = $1; }
 655     | "static" { $$ = $1; }
 656
 657     | "abstract" { $$ = $1; }
 658     | "boolean" { $$ = $1; }
 659     | "byte" { $$ = $1; }
 660     | "char" { $$ = $1; }
 661     | "double" { $$ = $1; }
 662     | "final" { $$ = $1; }
 663     | "float" { $$ = $1; }
 664     | "goto" { $$ = $1; }
 665     | "int" { $$ = $1; }
 666     | "long" { $$ = $1; }
 667     | "native" { $$ = $1; }
 668     | "short" { $$ = $1; }
 669     | "synchronized" { $$ = $1; }
 670     | "throws" { $$ = $1; }
 671     | "transient" { $$ = $1; }
 672     | "volatile" { $$ = $1; }
 673
 674     | "let" { $$ = $1; }
 675     | "yield" { $$ = $1; }
 676
 677     | "each" { $$ = $1; }
 678     ;
 679
 680 IdentifierOpt
 681     : Identifier { $$ = $1; }
 682     | { $$ = NULL; }
 683     ;
 684
 685 LiteralNoRE
 686     : NullLiteral { $$ = $1; }
 687     | BooleanLiteral { $$ = $1; }
 688     | NumericLiteral { $$ = $1; }
 689     | StringLiteral { $$ = $1; }
 690     | "@" StringLiteral { $$ = $2; }
 691     ;
 692
 693 LiteralRE
 694     : RegularExpressionLiteral { $$ = $1; }
 695     ;
 696
 697 Literal
 698     : LiteralNoRE { $$ = $1; }
 699     | LiteralRE { $$ = $1; }
 700     ;
 701
 702 NullLiteral
 703     : "null" { $$ = $1; }
 704     ;
 705
 706 BooleanLiteral
 707     : "true" { $$ = $1; }
 708     | "false" { $$ = $1; }
 709     ;
 710
 711 /* 11.1 Primary Expressions {{{ */
 712 PrimaryExpression
 713     : LexSetRegExp PrimaryExpressionNoRE { $$ = $2; }
 714     ;
 715
 716 PrimaryExpressionNoBF
 717     : PrimaryExpressionNo { $$ = $1; }
 718     ;
 719
 720 PrimaryExpressionNoRE
 721     : PrimaryExpressionBF { $$ = $1; }
 722     | PrimaryExpressionNo { $$ = $1; }
 723     ;
 724
 725 PrimaryExpressionNo
 726     : "this" { $$ = $1; }
 727     | Identifier { $$ = CYNew CYVariable($1); }
 728     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 729     | Literal { $$ = $1; }
 730     | ArrayLiteral { $$ = $1; }
 731     | "(" Expression ")" { $$ = $2; }
 732     ;
 733
 734 PrimaryExpressionBF
 735     : ObjectLiteral { $$ = $1; }
 736     ;
 737 /* }}} */
 738 /* 11.1.4 Array Initialiser {{{ */
 739 ArrayLiteral
 740     : "[" ElementListOpt "]" { $$ = CYNew CYArray($2); }
 741     ;
 742
 743 Element
 744     : AssignmentExpression { $$ = $1; }
 745     ;
 746
 747 ElementOpt
 748     : Element { $$ = $1; }
 749     | LexSetRegExp { $$ = NULL; }
 750     ;
 751
 752 ElementListOpt
 753     : ElementList { $$ = $1; }
 754     | LexSetRegExp { $$ = NULL; }
 755     ;
 756
 757 ElementList
 758     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 759     | Element { $$ = CYNew CYElement($1, NULL); }
 760     ;
 761 /* }}} */
 762 /* 11.1.5 Object Initialiser {{{ */
 763 ObjectLiteral
 764     : Brace PropertyNameAndValueListOpt "}" { $$ = CYNew CYObject($2); }
 765     ;
 766
 767 PropertyNameAndValueList_
 768     : "," PropertyNameAndValueList { $$ = $2; }
 769     | { $$ = NULL; }
 770     ;
 771
 772 PropertyNameAndValueListOpt
 773     : PropertyNameAndValueList { $$ = $1; }
 774     | { $$ = NULL; }
 775     ;
 776
 777 PropertyNameAndValueList
 778     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = CYNew CYProperty($1, $3, $4); }
 779     ;
 780
 781 PropertyName_
 782     : Identifier { $$ = $1; }
 783     | StringLiteral { $$ = $1; }
 784     | NumericLiteral { $$ = $1; }
 785     ;
 786
 787 PropertyName
 788     : LexSetRegExp PropertyName_ { $$ = $2; }
 789     ;
 790 /* }}} */
 791
 792 /* 11.2 Left-Hand-Side Expressions {{{ */
 793 MemberExpression_
 794     : "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($2, $3); }
 795     ;
 796
 797 MemberAccess
 798     : "[" Expression "]" { $$ = CYNew CYDirectMember(NULL, $2); }
 799     | "." Identifier { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 800     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 801     ;
 802
 803 MemberExpression
 804     : PrimaryExpression { $$ = $1; }
 805     | LexSetRegExp FunctionExpression { $$ = $2; }
 806     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 807     | LexSetRegExp MemberExpression_ { $$ = $2; }
 808     ;
 809
 810 MemberExpressionNoBF
 811     : PrimaryExpressionNoBF { $$ = $1; }
 812     | MemberExpressionNoBF { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 813     | MemberExpression_ { $$ = $1; }
 814     ;
 815
 816 @begin C
 817 MemberExpressionNoRE
 818     : PrimaryExpressionNoRE { $$ = $1; }
 819     | FunctionExpression { $$ = $1; }
 820     | MemberExpressionNoRE { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 821     | MemberExpression_ { $$ = $1; }
 822     ;
 823 @end
 824
 825 NewExpression_
 826     : "new" NewExpression { $$ = CYNew cy::Syntax::New($2, NULL); }
 827     ;
 828
 829 NewExpression
 830     : MemberExpression { $$ = $1; }
 831     | LexSetRegExp NewExpression_ { $$ = $2; }
 832     ;
 833
 834 NewExpressionNoBF
 835     : MemberExpressionNoBF { $$ = $1; }
 836     | NewExpression_ { $$ = $1; }
 837     ;
 838
 839 @begin C
 840 NewExpressionNoRE
 841     : MemberExpressionNoRE { $$ = $1; }
 842     | NewExpression_ { $$ = $1; }
 843     ;
 844 @end
 845
 846 CallExpression
 847     : MemberExpression Arguments { $$ = CYNew CYCall($1, $2); }
 848     | CallExpression Arguments { $$ = CYNew CYCall($1, $2); }
 849     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 850     ;
 851
 852 CallExpressionNoBF
 853     : MemberExpressionNoBF Arguments { $$ = CYNew CYCall($1, $2); }
 854     | CallExpressionNoBF Arguments { $$ = CYNew CYCall($1, $2); }
 855     | CallExpressionNoBF { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 856     ;
 857
 858 @begin C
 859 CallExpressionNoRE
 860     : MemberExpressionNoRE Arguments { $$ = CYNew CYCall($1, $2); }
 861     | CallExpressionNoRE Arguments { $$ = CYNew CYCall($1, $2); }
 862     | CallExpressionNoRE { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 863     ;
 864 @end
 865
 866 ArgumentList_
 867     : "," ArgumentList { $$ = $2; }
 868     | { $$ = NULL; }
 869     ;
 870
 871 ArgumentListOpt
 872     : ArgumentList { $$ = $1; }
 873     | LexSetRegExp { $$ = NULL; }
 874     ;
 875
 876 ArgumentList
 877     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 878     ;
 879
 880 Arguments
 881     : "(" ArgumentListOpt ")" { $$ = $2; }
 882     ;
 883
 884 LeftHandSideExpression
 885     : NewExpression { $$ = $1; }
 886     | CallExpression { $$ = $1; }
 887     ;
 888
 889 LeftHandSideExpressionNoBF
 890     : NewExpressionNoBF { $$ = $1; }
 891     | CallExpressionNoBF { $$ = $1; }
 892     ;
 893
 894 @begin C
 895 LeftHandSideExpressionNoRE
 896     : NewExpressionNoRE { $$ = $1; }
 897     | CallExpressionNoRE { $$ = $1; }
 898     ;
 899 @end
 900 /* }}} */
 901 /* 11.3 Postfix Expressions {{{ */
 902 PostfixExpression
 903     : AssigneeExpression { $$ = $1; }
 904     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 905     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 906     ;
 907
 908 PostfixExpressionNoBF
 909     : AssigneeExpressionNoBF { $$ = $1; }
 910     | LeftHandSideExpressionNoBF "++" { $$ = CYNew CYPostIncrement($1); }
 911     | LeftHandSideExpressionNoBF "--" { $$ = CYNew CYPostDecrement($1); }
 912     ;
 913
 914 @begin C
 915 PostfixExpressionNoRE
 916     : AssigneeExpressionNoRE { $$ = $1; }
 917     | LeftHandSideExpressionNoRE "++" { $$ = CYNew CYPostIncrement($1); }
 918     | LeftHandSideExpressionNoRE "--" { $$ = CYNew CYPostDecrement($1); }
 919     ;
 920 @end
 921 /* }}} */
 922 /* 11.4 Unary Operators {{{ */
 923 UnaryExpression_
 924     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 925     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 926     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 927     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 928     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 929     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 930     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 931     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 932     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 933     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 934     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 935     ;
 936
 937 UnaryExpression
 938     : PostfixExpression { $$ = $1; }
 939     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 940     ;
 941
 942 UnaryExpressionNoBF
 943     : PostfixExpressionNoBF { $$ = $1; }
 944     | UnaryExpression_ { $$ = $1; }
 945     ;
 946
 947 @begin C
 948 UnaryExpressionNoRE
 949     : PostfixExpressionNoRE { $$ = $1; }
 950     | UnaryExpression_ { $$ = $1; }
 951     ;
 952 @end
 953 /* }}} */
 954 /* 11.5 Multiplicative Operators {{{ */
 955 MultiplicativeExpression
 956     : UnaryExpression { $$ = $1; }
 957     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 958     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 959     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 960     ;
 961
 962 MultiplicativeExpressionNoBF
 963     : UnaryExpressionNoBF { $$ = $1; }
 964     | MultiplicativeExpressionNoBF "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 965     | MultiplicativeExpressionNoBF "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 966     | MultiplicativeExpressionNoBF "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 967     ;
 968 /* }}} */
 969 /* 11.6 Additive Operators {{{ */
 970 AdditiveExpression
 971     : MultiplicativeExpression { $$ = $1; }
 972     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 973     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 974     ;
 975
 976 AdditiveExpressionNoBF
 977     : MultiplicativeExpressionNoBF { $$ = $1; }
 978     | AdditiveExpressionNoBF "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 979     | AdditiveExpressionNoBF "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 980     ;
 981 /* }}} */
 982 /* 11.7 Bitwise Shift Operators {{{ */
 983 ShiftExpression
 984     : AdditiveExpression { $$ = $1; }
 985     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 986     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 987     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 988     ;
 989
 990 ShiftExpressionNoBF
 991     : AdditiveExpressionNoBF { $$ = $1; }
 992     | ShiftExpressionNoBF "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 993     | ShiftExpressionNoBF ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 994     | ShiftExpressionNoBF ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 995     ;
 996 /* }}} */
 997 /* 11.8 Relational Operators {{{ */
 998 RelationalExpressionNoIn_
 999     : "<" ShiftExpression { $$ = CYNew CYLess(NULL, $2); }
1000     | ">" ShiftExpression { $$ = CYNew CYGreater(NULL, $2); }
1001     | "<=" ShiftExpression { $$ = CYNew CYLessOrEqual(NULL, $2); }
1002     | ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual(NULL, $2); }
1003     | "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf(NULL, $2); }
1004     ;
1005
1006 RelationalExpression_
1007     : RelationalExpressionNoIn_ { $$ = $1; }
1008     | "in" ShiftExpression { $$ = CYNew CYIn(NULL, $2); }
1009     ;
1010
1011 RelationalExpression
1012     : ShiftExpression { $$ = $1; }
1013     | RelationalExpression RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
1014     ;
1015
1016 RelationalExpressionNoIn
1017     : ShiftExpression { $$ = $1; }
1018     | RelationalExpressionNoIn RelationalExpressionNoIn_ { $2->SetLeft($1); $$ = $2; }
1019     ;
1020
1021 RelationalExpressionNoBF
1022     : ShiftExpressionNoBF { $$ = $1; }
1023     | RelationalExpressionNoBF RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
1024     ;
1025 /* }}} */
1026 /* 11.9 Equality Operators {{{ */
1027 EqualityExpression
1028     : RelationalExpression { $$ = $1; }
1029     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1030     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1031     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1032     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1033     ;
1034
1035 EqualityExpressionNoIn
1036     : RelationalExpressionNoIn { $$ = $1; }
1037     | EqualityExpressionNoIn "==" RelationalExpressionNoIn { $$ = CYNew CYEqual($1, $3); }
1038     | EqualityExpressionNoIn "!=" RelationalExpressionNoIn { $$ = CYNew CYNotEqual($1, $3); }
1039     | EqualityExpressionNoIn "===" RelationalExpressionNoIn { $$ = CYNew CYIdentical($1, $3); }
1040     | EqualityExpressionNoIn "!==" RelationalExpressionNoIn { $$ = CYNew CYNotIdentical($1, $3); }
1041     ;
1042
1043 EqualityExpressionNoBF
1044     : RelationalExpressionNoBF { $$ = $1; }
1045     | EqualityExpressionNoBF "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1046     | EqualityExpressionNoBF "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1047     | EqualityExpressionNoBF "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1048     | EqualityExpressionNoBF "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1049     ;
1050 /* }}} */
1051 /* 11.10 Binary Bitwise Operators {{{ */
1052 BitwiseANDExpression
1053     : EqualityExpression { $$ = $1; }
1054     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1055     ;
1056
1057 BitwiseANDExpressionNoIn
1058     : EqualityExpressionNoIn { $$ = $1; }
1059     | BitwiseANDExpressionNoIn "&" EqualityExpressionNoIn { $$ = CYNew CYBitwiseAnd($1, $3); }
1060     ;
1061
1062 BitwiseANDExpressionNoBF
1063     : EqualityExpressionNoBF { $$ = $1; }
1064     | BitwiseANDExpressionNoBF "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1065     ;
1066
1067 BitwiseXORExpression
1068     : BitwiseANDExpression { $$ = $1; }
1069     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1070     ;
1071
1072 BitwiseXORExpressionNoIn
1073     : BitwiseANDExpressionNoIn { $$ = $1; }
1074     | BitwiseXORExpressionNoIn "^" BitwiseANDExpressionNoIn { $$ = CYNew CYBitwiseXOr($1, $3); }
1075     ;
1076
1077 BitwiseXORExpressionNoBF
1078     : BitwiseANDExpressionNoBF { $$ = $1; }
1079     | BitwiseXORExpressionNoBF "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1080     ;
1081
1082 BitwiseORExpression
1083     : BitwiseXORExpression { $$ = $1; }
1084     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1085     ;
1086
1087 BitwiseORExpressionNoIn
1088     : BitwiseXORExpressionNoIn { $$ = $1; }
1089     | BitwiseORExpressionNoIn "|" BitwiseXORExpressionNoIn { $$ = CYNew CYBitwiseOr($1, $3); }
1090     ;
1091
1092 BitwiseORExpressionNoBF
1093     : BitwiseXORExpressionNoBF { $$ = $1; }
1094     | BitwiseORExpressionNoBF "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1095     ;
1096 /* }}} */
1097 /* 11.11 Binary Logical Operators {{{ */
1098 LogicalANDExpression
1099     : BitwiseORExpression { $$ = $1; }
1100     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1101     ;
1102
1103 LogicalANDExpressionNoIn
1104     : BitwiseORExpressionNoIn { $$ = $1; }
1105     | LogicalANDExpressionNoIn "&&" BitwiseORExpressionNoIn { $$ = CYNew CYLogicalAnd($1, $3); }
1106     ;
1107
1108 LogicalANDExpressionNoBF
1109     : BitwiseORExpressionNoBF { $$ = $1; }
1110     | LogicalANDExpressionNoBF "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1111     ;
1112
1113 LogicalORExpression
1114     : LogicalANDExpression { $$ = $1; }
1115     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1116     ;
1117
1118 LogicalORExpressionNoIn
1119     : LogicalANDExpressionNoIn { $$ = $1; }
1120     | LogicalORExpressionNoIn "||" LogicalANDExpressionNoIn { $$ = CYNew CYLogicalOr($1, $3); }
1121     ;
1122
1123 LogicalORExpressionNoBF
1124     : LogicalANDExpressionNoBF { $$ = $1; }
1125     | LogicalORExpressionNoBF "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1126     ;
1127 /* }}} */
1128 /* 11.12 Conditional Operator ( ? : ) {{{ */
1129 ConditionalExpression
1130     : LogicalORExpression { $$ = $1; }
1131     | LogicalORExpression "?" AssignmentExpression ":" AssignmentExpression { $$ = CYNew CYCondition($1, $3, $5); }
1132     ;
1133
1134 ConditionalExpressionNoIn
1135     : LogicalORExpressionNoIn { $$ = $1; }
1136     | LogicalORExpressionNoIn "?" AssignmentExpression ":" AssignmentExpressionNoIn { $$ = CYNew CYCondition($1, $3, $5); }
1137     ;
1138
1139 ConditionalExpressionNoBF
1140     : LogicalORExpressionNoBF { $$ = $1; }
1141     | LogicalORExpressionNoBF "?" AssignmentExpression ":" AssignmentExpression { $$ = CYNew CYCondition($1, $3, $5); }
1142     ;
1143 /* }}} */
1144 /* 11.13 Assignment Operators {{{ */
1145 AssignmentExpression_
1146     : "=" AssignmentExpression { $$ = CYNew CYAssign(NULL, $2); }
1147     | "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign(NULL, $2); }
1148     | "/=" AssignmentExpression { $$ = CYNew CYDivideAssign(NULL, $2); }
1149     | "%=" AssignmentExpression { $$ = CYNew CYModulusAssign(NULL, $2); }
1150     | "+=" AssignmentExpression { $$ = CYNew CYAddAssign(NULL, $2); }
1151     | "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign(NULL, $2); }
1152     | "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign(NULL, $2); }
1153     | ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign(NULL, $2); }
1154     | ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign(NULL, $2); }
1155     | "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign(NULL, $2); }
1156     | "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign(NULL, $2); }
1157     | "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign(NULL, $2); }
1158     ;
1159
1160 AssigneeExpression
1161     : LeftHandSideExpression { $$ = $1; }
1162 @begin C
1163     | LexSetRegExp UnaryAssigneeExpression { $$ = $2; }
1164 @end
1165     ;
1166
1167 AssigneeExpressionNoBF
1168     : LeftHandSideExpressionNoBF { $$ = $1; }
1169 @begin C
1170     | UnaryAssigneeExpression { $$ = $1; }
1171 @end
1172     ;
1173
1174 @begin C
1175 AssigneeExpressionNoRE
1176     : LeftHandSideExpressionNoRE { $$ = $1; }
1177     | UnaryAssigneeExpression { $$ = $1; }
1178     ;
1179 @end
1180
1181 AssignmentExpression
1182     : ConditionalExpression { $$ = $1; }
1183     | AssigneeExpression AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1184     ;
1185
1186 AssignmentExpressionNoIn
1187     : ConditionalExpressionNoIn { $$ = $1; }
1188     | AssigneeExpression "=" AssignmentExpressionNoIn { $$ = CYNew CYAssign($1, $3); }
1189     | AssigneeExpression "*=" AssignmentExpressionNoIn { $$ = CYNew CYMultiplyAssign($1, $3); }
1190     | AssigneeExpression "/=" AssignmentExpressionNoIn { $$ = CYNew CYDivideAssign($1, $3); }
1191     | AssigneeExpression "%=" AssignmentExpressionNoIn { $$ = CYNew CYModulusAssign($1, $3); }
1192     | AssigneeExpression "+=" AssignmentExpressionNoIn { $$ = CYNew CYAddAssign($1, $3); }
1193     | AssigneeExpression "-=" AssignmentExpressionNoIn { $$ = CYNew CYSubtractAssign($1, $3); }
1194     | AssigneeExpression "<<=" AssignmentExpressionNoIn { $$ = CYNew CYShiftLeftAssign($1, $3); }
1195     | AssigneeExpression ">>=" AssignmentExpressionNoIn { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1196     | AssigneeExpression ">>>=" AssignmentExpressionNoIn { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1197     | AssigneeExpression "&=" AssignmentExpressionNoIn { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1198     | AssigneeExpression "^=" AssignmentExpressionNoIn { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1199     | AssigneeExpression "|=" AssignmentExpressionNoIn { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1200     ;
1201
1202 AssignmentExpressionNoBF
1203     : ConditionalExpressionNoBF { $$ = $1; }
1204     | AssigneeExpressionNoBF AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1205     ;
1206 /* }}} */
1207 /* 11.14 Comma Operator {{{ */
1208 Expression_
1209     : "," Expression { $$ = CYNew CYCompound($2); }
1210     | { $$ = NULL; }
1211     ;
1212
1213 ExpressionNoIn_
1214     : "," ExpressionNoIn { $$ = CYNew CYCompound($2); }
1215     | { $$ = NULL; }
1216     ;
1217
1218 ExpressionOpt
1219     : Expression { $$ = $1; }
1220     | LexSetRegExp { $$ = NULL; }
1221     ;
1222
1223 ExpressionNoInOpt
1224     : ExpressionNoIn { $$ = $1; }
1225     | LexSetRegExp { $$ = NULL; }
1226     ;
1227
1228 Expression
1229     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1230     ;
1231
1232 ExpressionNoIn
1233     : AssignmentExpressionNoIn ExpressionNoIn_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1234     ;
1235
1236 ExpressionNoBF
1237     : AssignmentExpressionNoBF Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1238     ;
1239 /* }}} */
1240
1241 /* 12 Statements {{{ */
1242 Statement_
1243     : Block { $$ = $1; }
1244     | VariableStatement { $$ = $1; }
1245     | EmptyStatement { $$ = $1; }
1246     | ExpressionStatement { $$ = $1; }
1247     | IfStatement { $$ = $1; }
1248     | IterationStatement { $$ = $1; }
1249     | ContinueStatement { $$ = $1; }
1250     | BreakStatement { $$ = $1; }
1251     | ReturnStatement { $$ = $1; }
1252     | WithStatement { $$ = $1; }
1253     | LabelledStatement { $$ = $1; }
1254     | SwitchStatement { $$ = $1; }
1255     | ThrowStatement { $$ = $1; }
1256     | TryStatement { $$ = $1; }
1257     ;
1258
1259 Statement
1260     : LexSetRegExp Statement_ { $$ = $2; }
1261     ;
1262 /* }}} */
1263 /* 12.1 Block {{{ */
1264 Block_
1265     : Brace StatementListOpt "}" { $$ = $2; }
1266     ;
1267
1268 Block
1269     : Block_ { $$ = CYNew CYBlock($1); }
1270     ;
1271
1272 StatementList
1273     : Statement StatementListOpt { $1->SetNext($2); $$ = $1; }
1274     ;
1275
1276 StatementListOpt
1277     : StatementList { $$ = $1; }
1278     | LexSetRegExp { $$ = NULL; }
1279     ;
1280 /* }}} */
1281 /* 12.2 Variable Statement {{{ */
1282 VariableStatement
1283     : "var" VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1284     ;
1285
1286 VariableDeclarationList_
1287     : "," VariableDeclarationList { $$ = $2; }
1288     | { $$ = NULL; }
1289     ;
1290
1291 VariableDeclarationListNoIn_
1292     : "," VariableDeclarationListNoIn { $$ = $2; }
1293     | { $$ = NULL; }
1294     ;
1295
1296 VariableDeclarationList
1297     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1298     ;
1299
1300 VariableDeclarationListNoIn
1301     : VariableDeclarationNoIn VariableDeclarationListNoIn_ { $$ = CYNew CYDeclarations($1, $2); }
1302     ;
1303
1304 VariableDeclaration
1305     : Identifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1306     ;
1307
1308 VariableDeclarationNoIn
1309     : Identifier InitialiserNoInOpt { $$ = CYNew CYDeclaration($1, $2); }
1310     ;
1311
1312 InitialiserOpt
1313     : Initialiser { $$ = $1; }
1314     | { $$ = NULL; }
1315     ;
1316
1317 InitialiserNoInOpt
1318     : InitialiserNoIn { $$ = $1; }
1319     | { $$ = NULL; }
1320     ;
1321
1322 Initialiser
1323     : "=" AssignmentExpression { $$ = $2; }
1324     ;
1325
1326 InitialiserNoIn
1327     : "=" AssignmentExpressionNoIn { $$ = $2; }
1328     ;
1329 /* }}} */
1330 /* 12.3 Empty Statement {{{ */
1331 EmptyStatement
1332     : ";" { $$ = CYNew CYEmpty(); }
1333     ;
1334 /* }}} */
1335 /* 12.4 Expression Statement {{{ */
1336 ExpressionStatement
1337     : ExpressionNoBF Terminator { $$ = CYNew CYExpress($1); }
1338     ;
1339 /* }}} */
1340 /* 12.5 The if Statement {{{ */
1341 ElseStatementOpt
1342     : "else" Statement { $$ = $2; }
1343     | %prec "if" { $$ = NULL; }
1344     ;
1345
1346 IfStatement
1347     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1348     ;
1349 /* }}} */
1350
1351 /* 12.6 Iteration Statements {{{ */
1352 IterationStatement
1353     : DoWhileStatement { $$ = $1; }
1354     | WhileStatement { $$ = $1; }
1355     | ForStatement { $$ = $1; }
1356     | ForInStatement { $$ = $1; }
1357     ;
1358 /* }}} */
1359 /* 12.6.1 The do-while Statement {{{ */
1360 DoWhileStatement
1361     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1362     ;
1363 /* }}} */
1364 /* 12.6.2 The while Statement {{{ */
1365 WhileStatement
1366     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1367     ;
1368 /* }}} */
1369 /* 12.6.3 The for Statement {{{ */
1370 ForStatement
1371     : "for" "(" ForStatementInitialiser ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($3, $5, $7, $9); }
1372     ;
1373
1374 ForStatementInitialiser
1375     : ExpressionNoInOpt { $$ = $1; }
1376     | LexSetRegExp "var" VariableDeclarationListNoIn { $$ = $3; }
1377     ;
1378 /* }}} */
1379 /* 12.6.4 The for-in Statement {{{ */
1380 ForInStatement
1381     : "for" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = CYNew CYForIn($3, $5, $7); }
1382     ;
1383
1384 ForInStatementInitialiser
1385     : LeftHandSideExpression { $$ = $1; }
1386     | LexSetRegExp "var" VariableDeclarationNoIn { $$ = $3; }
1387     ;
1388 /* }}} */
1389
1390 /* 12.7 The continue Statement {{{ */
1391 ContinueStatement
1392     : "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1393     ;
1394 /* }}} */
1395 /* 12.8 The break Statement {{{ */
1396 BreakStatement
1397     : "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1398     ;
1399 /* }}} */
1400 /* 12.9 The return Statement {{{ */
1401 ReturnStatement
1402     : "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1403     ;
1404 /* }}} */
1405 /* 12.10 The with Statement {{{ */
1406 WithStatement
1407     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1408     ;
1409 /* }}} */
1410
1411 /* 12.11 The switch Statement {{{ */
1412 SwitchStatement
1413     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1414     ;
1415
1416 CaseBlock
1417     : Brace CaseClausesOpt "}" { $$ = $2; }
1418     ;
1419
1420 CaseClausesOpt
1421     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1422     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1423     | { $$ = NULL; }
1424     ;
1425
1426 CaseClause
1427     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1428     ;
1429
1430 DefaultClause
1431     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1432     ;
1433 /* }}} */
1434 /* 12.12 Labelled Statements {{{ */
1435 LabelledStatement
1436     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1437     ;
1438 /* }}} */
1439 /* 12.13 The throw Statement {{{ */
1440 ThrowStatement
1441     : "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1442     ;
1443 /* }}} */
1444 /* 12.14 The try Statement {{{ */
1445 TryStatement
1446     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1447     ;
1448
1449 CatchOpt
1450     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1451     | { $$ = NULL; }
1452     ;
1453
1454 FinallyOpt
1455     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1456     | { $$ = NULL; }
1457     ;
1458 /* }}} */
1459
1460 /* 13 Function Definition {{{ */
1461 FunctionDeclaration
1462     : "function" Identifier "(" FormalParameterList ")" Brace FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1463     ;
1464
1465 FunctionExpression
1466     : "function" IdentifierOpt "(" FormalParameterList ")" Brace FunctionBody "}" { $$ = CYNew CYFunctionExpression($2, $4, $7); }
1467     ;
1468
1469 FormalParameterList_
1470     : "," FormalParameterList { $$ = $2; }
1471     | { $$ = NULL; }
1472     ;
1473
1474 FormalParameterList
1475     : Identifier FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1476     | { $$ = NULL; }
1477     ;
1478
1479 FunctionBody
1480     : SourceElements { $$ = $1; }
1481     ;
1482 /* }}} */
1483 /* 14 Program {{{ */
1484 Program
1485     : SourceElements { driver.program_ = CYNew CYProgram($1); }
1486     ;
1487
1488 SourceElements
1489     : SourceElement SourceElements { $1->SetNext($2); $$ = $1; }
1490     | LexSetRegExp { $$ = NULL; }
1491     ;
1492
1493 SourceElement_
1494     : Statement_ { $$ = $1; }
1495     | FunctionDeclaration { $$ = $1; }
1496     ;
1497
1498 SourceElement
1499     : LexSetRegExp SourceElement_ { $$ = $2; }
1500     ;
1501 /* }}} */
1502
1503 @begin ObjectiveC
1504 /* Cycript (Objective-C): @class Declaration {{{ */
1505 ClassSuperOpt
1506     /* XXX: why the hell did I choose MemberExpressionNoBF? */
1507     : ":" LexSetRegExp MemberExpressionNoBF { $$ = $3; }
1508     | { $$ = NULL; }
1509     ;
1510
1511 ClassField
1512     : Expression Identifier ";"
1513     ;
1514
1515 ClassFieldListOpt
1516     : ClassFieldListOpt ClassField
1517     |
1518     ;
1519
1520 ClassFieldList
1521     : Brace ClassFieldListOpt "}" { $$ = NULL; }
1522     ;
1523
1524 MessageScope
1525     : "+" { $$ = false; }
1526     | "-" { $$ = true; }
1527     ;
1528
1529 TypeOpt
1530     : "(" Expression ")" { $$ = $2; }
1531     | "(" LexSetRegExp "void" ")" { $$ = NULL; }
1532     | { $$ = NULL; }
1533     ;
1534
1535 MessageParameter
1536     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1537     ;
1538
1539 MessageParameterListOpt
1540     : MessageParameterList { $$ = $1; }
1541     | { $$ = NULL; }
1542     ;
1543
1544 MessageParameterList
1545     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1546     ;
1547
1548 MessageParameters
1549     : MessageParameterList { $$ = $1; }
1550     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1551     ;
1552
1553 ClassMessageDeclaration
1554     : MessageScope TypeOpt MessageParameters Brace FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1555     ;
1556
1557 ClassMessageDeclarationListOpt
1558     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1559     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1560     | { $$ = NULL; }
1561     ;
1562
1563 ClassName
1564     : Identifier { $$ = $1; }
1565     | "(" AssignmentExpression ")" { $$ = $2; }
1566     ;
1567
1568 ClassNameOpt
1569     : ClassName { $$ = $1; }
1570     | { $$ = NULL; }
1571     ;
1572
1573 // XXX: this should be AssignmentExpressionNoRight
1574 ClassProtocols
1575     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1576     ;
1577
1578 ClassProtocolsOpt
1579     : "," ClassProtocols { $$ = $2; }
1580     | { $$ = NULL; }
1581     ;
1582
1583 ClassProtocolListOpt
1584     : "<" ClassProtocols ">" { $$ = $2; }
1585     | { $$ = NULL; }
1586     ;
1587
1588 ClassExpression
1589     : "@implementation" ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassExpression($2, $3, $4, $5, $6); }
1590     ;
1591
1592 ClassStatement
1593     : "@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1594     ;
1595
1596 CategoryName
1597     : "(" Word ")"
1598     ;
1599
1600 CategoryStatement
1601     : "@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1602     ;
1603
1604 PrimaryExpressionBF
1605     : ClassExpression { $$ = $1; }
1606     ;
1607
1608 Statement_
1609     : ClassStatement { $$ = $1; }
1610     | CategoryStatement { $$ = $1; }
1611     ;
1612 /* }}} */
1613 /* Cycript (Objective-C): Send Message {{{ */
1614 VariadicCall
1615     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1616     | { $$ = NULL; }
1617     ;
1618
1619 SelectorCall_
1620     : SelectorCall { $$ = $1; }
1621     | VariadicCall { $$ = $1; }
1622     ;
1623
1624 SelectorWordOpt
1625     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1626     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1627     ;
1628
1629 SelectorCall
1630     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1631     ;
1632
1633 SelectorList
1634     : SelectorCall { $$ = $1; }
1635     | Word { $$ = CYNew CYArgument($1, NULL); }
1636     ;
1637
1638 MessageExpression
1639     : "[" AssignmentExpression { driver.contexts_.push_back($2); } SelectorList "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($2, $4); }
1640     | "[" LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" { $$ = CYNew CYSendSuper($5); }
1641     ;
1642
1643 SelectorExpressionOpt
1644     : SelectorExpression_ { $$ = $1; }
1645     | { $$ = NULL; }
1646     ;
1647
1648 SelectorExpression_
1649     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1650     ;
1651
1652 SelectorExpression
1653     : SelectorExpression_ { $$ = $1; }
1654     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1655     ;
1656
1657 PrimaryExpressionNo
1658     : MessageExpression { $$ = $1; }
1659     | "@selector" "(" SelectorExpression ")" { $$ = CYNew CYSelector($3); }
1660     ;
1661 /* }}} */
1662 /* Cycript (Objective-C): @import Directive {{{ */
1663 PathName
1664     : "/" PathName
1665     | "." PathName
1666     | Word PathName
1667     |
1668     ;
1669
1670 ImportPath
1671     : "<" PathName ">"
1672     | StringLiteral
1673     ;
1674
1675 SourceElement_
1676     : "@import" ImportPath { $$ = CYNew CYImport(); }
1677     ;
1678 /* }}} */
1679 @end
1680
1681 @begin C
1682 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1683 UnaryAssigneeExpression
1684     : "*" UnaryExpressionNoRE { $$ = CYNew CYIndirect($2); }
1685     ;
1686
1687 UnaryExpression_
1688     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1689     ;
1690
1691 MemberAccess
1692     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1693     | "->" Identifier { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1694     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1695     ;
1696 /* }}} */
1697 @end
1698
1699 /* YUI: Documentation Comments {{{ */
1700 Statement_
1701     : Comment { $$ = $1; }
1702     ;
1703 /* }}} */
1704
1705 @begin E4X
1706 /* Lexer State {{{ */
1707 LexPushRegExp
1708     : { driver.PushCondition(CYDriver::RegExpCondition); }
1709     ;
1710
1711 LexPushXMLContent
1712     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1713     ;
1714
1715 LexPushXMLTag
1716     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1717     ;
1718
1719 LexPop
1720     : { driver.PopCondition(); }
1721     ;
1722
1723 LexSetXMLContent
1724     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1725     ;
1726
1727 LexSetXMLTag
1728     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1729     ;
1730 /* }}} */
1731
1732 XMLWhitespaceOpt
1733     : XMLWhitespace
1734     |
1735     ;
1736
1737 /* 8.1 Context Keywords {{{ */
1738 Identifier
1739     : "namespace" { $$ = $1; }
1740     | "xml" { $$ = $1; }
1741     ;
1742 /* }}} */
1743 /* 8.3 XML Initialiser Input Elements {{{ */
1744 XMLMarkup
1745     : XMLComment { $$ = $1; }
1746     | XMLCDATA { $$ = $1; }
1747     | XMLPI { $$ = $1; }
1748     ;
1749 /* }}} */
1750 /* 11.1 Primary Expressions {{{ */
1751 PrimaryExpressionNo
1752     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1753     | XMLInitialiser { $$ = $1; }
1754     | XMLListInitialiser { $$ = $1; }
1755     ;
1756
1757 PropertyIdentifier
1758     : AttributeIdentifier { $$ = $1; }
1759     | QualifiedIdentifier { $$ = $1; }
1760     | WildcardIdentifier { $$ = $1; }
1761     ;
1762 /* }}} */
1763 /* 11.1.1 Attribute Identifiers {{{ */
1764 AttributeIdentifier
1765     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1766     ;
1767
1768 PropertySelector_
1769     : PropertySelector { $$ = $1; }
1770     | "[" Expression "]" { $$ = CYNew CYSelector($2); }
1771     ;
1772
1773 PropertySelector
1774     : Identifier { $$ = CYNew CYSelector($1); }
1775     | WildcardIdentifier { $$ = $1; }
1776     ;
1777 /* }}} */
1778 /* 11.1.2 Qualified Identifiers {{{ */
1779 QualifiedIdentifier_
1780     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1781     | QualifiedIdentifier { $$ = $1; }
1782     ;
1783
1784 QualifiedIdentifier
1785     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1786     ;
1787 /* }}} */
1788 /* 11.1.3 Wildcard Identifiers {{{ */
1789 WildcardIdentifier
1790     : "*" { $$ = CYNew CYWildcard(); }
1791     ;
1792 /* }}} */
1793 /* 11.1.4 XML Initialiser {{{ */
1794 XMLInitialiser
1795     : XMLMarkup { $$ = $1; }
1796     | XMLElement { $$ = $1; }
1797     ;
1798
1799 XMLElement
1800     : "<" XMLTagContent "/>" LexPop
1801     | "<" XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt ">" LexPop
1802     ;
1803
1804 XMLTagContent
1805     : LexPushXMLTag XMLTagName XMLAttributes
1806     ;
1807
1808 XMLExpression
1809     : Brace LexPushRegExp Expression "}" LexPop
1810     ;
1811
1812 XMLTagName
1813     : XMLExpression
1814     | XMLName
1815     ;
1816
1817 XMLAttributes_
1818     : XMLAttributes_ XMLAttribute
1819     |
1820     ;
1821
1822 XMLAttributes
1823     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1824     | XMLAttributes_ XMLWhitespaceOpt
1825     ;
1826
1827 XMLAttributeValue_
1828     : XMLExpression
1829     | XMLAttributeValue
1830     ;
1831
1832 XMLAttribute
1833     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1834     ;
1835
1836 XMLElementContent
1837     : XMLExpression XMLElementContentOpt
1838     | XMLMarkup XMLElementContentOpt
1839     | XMLText XMLElementContentOpt
1840     | XMLElement XMLElementContentOpt
1841     ;
1842
1843 XMLElementContentOpt
1844     : XMLElementContent
1845     |
1846     ;
1847 /* }}} */
1848 /* 11.1.5 XMLList Initialiser {{{ */
1849 XMLListInitialiser
1850     : "<>" LexPushXMLContent XMLElementContent "</>" LexPop { $$ = CYNew CYXMLList($3); }
1851     ;
1852 /* }}} */
1853 /* 11.2 Left-Hand-Side Expressions {{{ */
1854 PropertyIdentifier_
1855     : Identifier { $$ = $1; }
1856     | PropertyIdentifier { $$ = $1; }
1857     ;
1858
1859 MemberAccess
1860     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1861     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1862     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1863     ;
1864 /* }}} */
1865 /* 12.1 The default xml namespace Statement {{{ */
1866 /* XXX: DefaultXMLNamespaceStatement
1867     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1868     ;
1869
1870 Statement_
1871     : DefaultXMLNamespaceStatement { $$ = $1; }
1872     ; */
1873 /* }}} */
1874 @end
1875
1876 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1877 PropertyNameAndValueList_
1878     : "," { $$ = NULL; }
1879     ;
1880 /* }}} */
1881
1882 /* JavaScript 1.7: Array Comprehensions {{{ */
1883 IfComprehension
1884     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1885     ;
1886
1887 ForComprehension
1888     : "for" "(" Identifier "in" Expression ")" { $$ = CYNew CYForInComprehension($3, $5); }
1889     | "for" "each" "(" Identifier "in" Expression ")" { $$ = CYNew CYForEachInComprehension($4, $6); }
1890     ;
1891
1892 ComprehensionListOpt
1893     : ComprehensionList { $$ = $1; }
1894     | IfComprehension { $$ = $1; }
1895     | { $$ = NULL; }
1896     ;
1897
1898 ComprehensionList
1899     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1900     ;
1901
1902 PrimaryExpressionNo
1903     : "[" AssignmentExpression ComprehensionList "]" { $$ = CYNew CYArrayComprehension($2, $3); }
1904     ;
1905 /* }}} */
1906 /* JavaScript 1.7: for each {{{ */
1907 ForInStatement
1908     : "for" "each" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = CYNew CYForEachIn($4, $6, $8); }
1909     ;
1910 /* }}} */
1911 /* JavaScript 1.7: let Statements {{{ *//*
1912 LetStatement
1913     : "let" "(" VariableDeclarationList ")" Block_ { $$ = CYNew CYLet($3, $5); }
1914     ;
1915
1916 Statement_
1917     : LetStatement
1918     ;
1919 *//* }}} */
1920
1921 /* JavaScript FTW: Function Statements {{{ */
1922 Statement
1923     : LexSetRegExp FunctionDeclaration { driver.Warning(yylloc, "warning, FunctionDeclaration is a SourceElement, not a Statement"); } { $$ = $2; }
1924     ;
1925 /* }}} */
1926 /* JavaScript FTW: Optional Arguments {{{ */
1927 FormalParameterList
1928     : Identifier "=" AssignmentExpression FormalParameterList_ { $$ = CYNew CYOptionalFunctionParameter($1, $3, $4); }
1929     ;
1930 /* }}} */
1931 /* JavaScript FTW: Ruby Blocks {{{ */
1932 RubyProcParameterList_
1933     : "," RubyProcParameterList { $$ = $2; }
1934     | { $$ = NULL; }
1935     ;
1936
1937 RubyProcParameterList
1938     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1939     | { $$ = NULL; }
1940     ;
1941
1942 RubyProcParameters
1943     : "|" RubyProcParameterList "|" { $$ = $2; }
1944     | "||" { $$ = NULL; }
1945     ;
1946
1947 RubyProcParametersOpt
1948     : RubyProcParameters
1949     | { $$ = NULL; }
1950     ;
1951
1952 RubyProcExpression
1953     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1954     ;
1955
1956 RubyProcExpressionNoOA
1957     : "{" RubyProcParameters StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1958     ;
1959
1960 PrimaryExpressionNo
1961     : RubyProcExpressionNoOA { $$ = $1; }
1962     ;
1963
1964 LeftHandSideExpression
1965     : LeftHandSideExpression RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1966     ;
1967
1968 LeftHandSideExpressionNoBF
1969     : LeftHandSideExpressionNoBF RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1970     ;
1971
1972 @begin C
1973 LeftHandSideExpressionNoRE
1974     : LeftHandSideExpressionNoRE RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1975     ;
1976 @end
1977 /* }}} */
1978
1979 %%