Parser.ypp.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 %code top {
  23 #define YYSTACKEXPANDABLE 1
  24 }
  25
  26 %code requires {
  27 #include "Driver.hpp"
  28 #include "Parser.hpp"
  29 #include "Stack.hpp"
  30 #define CYNew new(driver.pool_)
  31
  32 @begin ObjectiveC
  33 #include "ObjectiveC/Syntax.hpp"
  34 @end
  35
  36 @begin E4X
  37 #include "E4X/Syntax.hpp"
  38 @end
  39
  40 #include "Highlight.hpp"
  41 }
  42
  43 %union { bool bool_; }
  44
  45 %union { CYMember *access_; }
  46 %union { CYArgument *argument_; }
  47 %union { CYAssignment *assignment_; }
  48 %union { CYBoolean *boolean_; }
  49 %union { CYClause *clause_; }
  50 %union { cy::Syntax::Catch *catch_; }
  51 %union { CYClassTail *classTail_; }
  52 %union { CYComprehension *comprehension_; }
  53 %union { CYDeclaration *declaration_; }
  54 %union { CYDeclarations *declarations_; }
  55 %union { CYElement *element_; }
  56 %union { CYExpression *expression_; }
  57 %union { CYFalse *false_; }
  58 %union { CYVariable *variable_; }
  59 %union { CYFinally *finally_; }
  60 %union { CYForInitializer *for_; }
  61 %union { CYForInInitializer *forin_; }
  62 %union { CYFunctionParameter *functionParameter_; }
  63 %union { CYIdentifier *identifier_; }
  64 %union { CYInfix *infix_; }
  65 %union { CYLiteral *literal_; }
  66 %union { CYMethod *method_; }
  67 %union { CYModule *module_; }
  68 %union { CYNull *null_; }
  69 %union { CYNumber *number_; }
  70 %union { CYParenthetical *parenthetical_; }
  71 %union { CYProperty *property_; }
  72 %union { CYPropertyName *propertyName_; }
  73 %union { CYRubyProc *rubyProc_; }
  74 %union { CYSpan *span_; }
  75 %union { CYStatement *statement_; }
  76 %union { CYString *string_; }
  77 %union { CYTarget *target_; }
  78 %union { CYThis *this_; }
  79 %union { CYTrue *true_; }
  80 %union { CYWord *word_; }
  81
  82 @begin C
  83 %union { CYTypeModifier *modifier_; }
  84 %union { CYTypeSpecifier *specifier_; }
  85 %union { CYTypedIdentifier *typedIdentifier_; }
  86 %union { CYTypedParameter *typedParameter_; }
  87 @end
  88
  89 @begin ObjectiveC
  90 %union { CYMessage *message_; }
  91 %union { CYMessageParameter *messageParameter_; }
  92 %union { CYImplementationField *implementationField_; }
  93 %union { CYProtocol *protocol_; }
  94 %union { CYSelectorPart *selector_; }
  95 @end
  96
  97 @begin E4X
  98 %union { CYAttribute *attribute_; }
  99 %union { CYPropertyIdentifier *propertyIdentifier_; }
 100 %union { CYSelector *selector_; }
 101 @end
 102
 103 %code provides {
 104
 105 struct YYSTYPE {
 106     cy::parser::semantic_type semantic_;
 107     hi::Value highlight_;
 108 };
 109
 110 int cylex(YYSTYPE *, CYLocation *, void *);
 111
 112 }
 113
 114 %code {
 115
 116 typedef cy::parser::token tk;
 117
 118 #undef yylex
 119 _finline int yylex(cy::parser::semantic_type *semantic, CYLocation *location, CYDriver &driver) {
 120     if (driver.mark_ == CYMarkIgnore);
 121     else if (driver.mark_ == CYMarkScript) {
 122         driver.mark_ = CYMarkIgnore;
 123         return cy::parser::token::MarkScript;
 124     } else if (driver.mark_ == CYMarkModule) {
 125         driver.mark_ = CYMarkIgnore;
 126         return cy::parser::token::MarkModule;
 127     }
 128
 129   lex:
 130     if (driver.newline_ == CYDriver::NewLineHere)
 131         driver.newline_ = CYDriver::NewLineLast;
 132     else if (driver.newline_ == CYDriver::NewLineLast)
 133         driver.newline_ = CYDriver::NewLineNone;
 134
 135     YYSTYPE data;
 136     int token(cylex(&data, location, driver.scanner_));
 137     *semantic = data.semantic_;
 138
 139     switch (token) {
 140         case tk::_in_:
 141             if (driver.in_.top())
 142                 token = tk::_in__;
 143         break;
 144
 145         case tk::_yield_:
 146             if (driver.yield_.top())
 147                 token = tk::_yield__;
 148         break;
 149
 150         case tk::HyphenHyphen:
 151             if (driver.newline_ == CYDriver::NewLineLast)
 152                 token = tk::HyphenHyphen_;
 153         break;
 154
 155         case tk::NewLine:
 156             driver.newline_ = CYDriver::NewLineHere;
 157             if (!driver.next_)
 158                 goto lex;
 159         break;
 160
 161         case tk::PlusPlus:
 162             if (driver.newline_ == CYDriver::NewLineLast)
 163                 token = tk::PlusPlus_;
 164         break;
 165     }
 166
 167     driver.next_ = false;
 168     return token;
 169 }
 170
 171 #define CYLEX() do if (yyla.empty()) { \
 172     YYCDEBUG << "Mapping a token: "; \
 173     yyla.type = yytranslate_(yylex(&yyla.value, &yyla.location, driver)); \
 174     YY_SYMBOL_PRINT("Next token is", yyla); \
 175 } while (false)
 176
 177 #define CYMAP(to, from) do { \
 178     CYLEX(); \
 179     if (yyla.type == yytranslate_(token::from)) \
 180         yyla.type = yytranslate_(token::to); \
 181 } while (false)
 182
 183 #define CYLIN(from) do { \
 184     CYLEX(); \
 185     if (yyla.type == yytranslate_(token::from) && driver.newline_ == CYDriver::NewLineLast) \
 186         yyla.type = yytranslate_(token::from ## _); \
 187 } while (false)
 188
 189 #define CYERR(location, message) do { \
 190     error(location, message); \
 191     YYABORT; \
 192 } while (false)
 193
 194 #define CYNOT(location) \
 195     CYERR(location, "unimplemented feature")
 196
 197 }
 198
 199 %name-prefix "cy"
 200
 201 %language "C++"
 202
 203 %initial-action {
 204     @$.begin.filename = @$.end.filename = &driver.filename_;
 205 };
 206
 207 %locations
 208 %defines
 209
 210 %define api.location.type { CYLocation }
 211
 212 //%glr-parser
 213 //%expect 1
 214
 215 %error-verbose
 216
 217 %param { CYDriver &driver }
 218
 219 /* Token Declarations {{{ */
 220 @begin E4X
 221 %token XMLCDATA
 222 %token XMLComment
 223 %token XMLPI
 224
 225 %token XMLAttributeValue
 226 %token XMLName
 227 %token XMLTagCharacters
 228 %token XMLText
 229 %token XMLWhitespace
 230 @end
 231
 232 @begin E4X
 233 %token LeftRight "<>"
 234 %token LeftSlashRight "</>"
 235
 236 %token SlashRight "/>"
 237 %token LeftSlash "</"
 238
 239 %token ColonColon "::"
 240 %token PeriodPeriod ".."
 241 @end
 242
 243 @begin E4X ObjectiveC
 244 %token At "@"
 245 %token Pound "#"
 246 @end
 247
 248 %token Ampersand "&"
 249 %token AmpersandAmpersand "&&"
 250 %token AmpersandEqual "&="
 251 %token Carrot "^"
 252 %token CarrotEqual "^="
 253 %token Equal "="
 254 %token EqualEqual "=="
 255 %token EqualEqualEqual "==="
 256 %token EqualRight "=>"
 257 %token EqualRight_ "\n=>"
 258 %token Exclamation "!"
 259 %token ExclamationEqual "!="
 260 %token ExclamationEqualEqual "!=="
 261 %token Hyphen "-"
 262 %token HyphenEqual "-="
 263 %token HyphenHyphen "--"
 264 %token HyphenHyphen_ "\n--"
 265 %token HyphenRight "->"
 266 %token Left "<"
 267 %token LeftEqual "<="
 268 %token LeftLeft "<<"
 269 %token LeftLeftEqual "<<="
 270 %token Percent "%"
 271 %token PercentEqual "%="
 272 %token Period "."
 273 %token PeriodPeriodPeriod "..."
 274 %token Pipe "|"
 275 %token PipeEqual "|="
 276 %token PipePipe "||"
 277 %token Plus "+"
 278 %token PlusEqual "+="
 279 %token PlusPlus "++"
 280 %token PlusPlus_ "\n++"
 281 %token Right ">"
 282 %token RightEqual ">="
 283 %token RightRight ">>"
 284 %token RightRightEqual ">>="
 285 %token RightRightRight ">>>"
 286 %token RightRightRightEqual ">>>="
 287 %token Slash "/"
 288 %token SlashEqual "/="
 289 %token Star "*"
 290 %token StarEqual "*="
 291 %token Tilde "~"
 292
 293 %token Colon ":"
 294 %token Comma ","
 295 %token Question "?"
 296 %token SemiColon ";"
 297 %token NewLine "\n"
 298
 299 %token Comment
 300
 301 %token OpenParen "("
 302 %token CloseParen ")"
 303
 304 %token OpenBrace "{"
 305 %token OpenBrace_ "\n{"
 306 %token OpenBrace__ ";{"
 307 %token CloseBrace "}"
 308
 309 %token OpenBracket "["
 310 %token CloseBracket "]"
 311
 312 %token At_error_ "@error"
 313
 314 @begin Java
 315 %token At_class_ "@class"
 316 @end
 317
 318 @begin C
 319 %token _typedef_ "typedef"
 320 %token _unsigned_ "unsigned"
 321 %token _signed_ "signed"
 322 %token _extern_ "extern"
 323 @end
 324
 325 @begin C
 326 %token At_encode_ "@encode"
 327 @end
 328
 329 @begin ObjectiveC
 330 %token At_implementation_ "@implementation"
 331 %token At_import_ "@import"
 332 %token At_end_ "@end"
 333 %token At_selector_ "@selector"
 334 %token At_null_ "@null"
 335 %token At_YES_ "@YES"
 336 %token At_NO_ "@NO"
 337 %token At_true_ "@true"
 338 %token At_false_ "@false"
 339 %token _YES_ "YES"
 340 %token _NO_ "NO"
 341 @end
 342
 343 %token _false_ "false"
 344 %token _null_ "null"
 345 %token _true_ "true"
 346
 347 %token _break_ "break"
 348 %token _case_ "case"
 349 %token _catch_ "catch"
 350 %token _class_ "class"
 351 %token _class__ ";class"
 352 %token _const_ "const"
 353 %token _continue_ "continue"
 354 %token _debugger_ "debugger"
 355 %token _default_ "default"
 356 %token _delete_ "delete"
 357 %token _do_ "do"
 358 %token _else_ "else"
 359 %token _enum_ "enum"
 360 %token _export_ "export"
 361 %token _extends_ "extends"
 362 %token _finally_ "finally"
 363 %token _for_ "for"
 364 %token _function_ "function"
 365 %token _function__ ";function"
 366 %token _if_ "if"
 367 %token _import_ "import"
 368 %token _in_ "in"
 369 %token _in__ "!in"
 370 %token _Infinity_ "Infinity"
 371 %token _instanceof_ "instanceof"
 372 %token _new_ "new"
 373 %token _return_ "return"
 374 %token _super_ "super"
 375 %token _switch_ "switch"
 376 %token _target_ "target"
 377 %token _this_ "this"
 378 %token _throw_ "throw"
 379 %token _try_ "try"
 380 %token _typeof_ "typeof"
 381 %token _var_ "var"
 382 %token _void_ "void"
 383 %token _while_ "while"
 384 %token _with_ "with"
 385
 386 %token _abstract_ "abstract"
 387 %token _await_ "await"
 388 %token _boolean_ "boolean"
 389 %token _byte_ "byte"
 390 %token _char_ "char"
 391 %token _constructor_ "constructor"
 392 %token _double_ "double"
 393 %token _eval_ "eval"
 394 %token _final_ "final"
 395 %token _float_ "float"
 396 %token _from_ "from"
 397 %token _get_ "get"
 398 %token _goto_ "goto"
 399 %token _implements_ "implements"
 400 %token _int_ "int"
 401 %token _interface_ "interface"
 402 %token _let_ "let"
 403 %token _long_ "long"
 404 %token _native_ "native"
 405 %token _package_ "package"
 406 %token _private_ "private"
 407 %token _protected_ "protected"
 408 %token _prototype_ "prototype"
 409 %token _public_ "public"
 410 %token _set_ "set"
 411 %token _short_ "short"
 412 %token _static_ "static"
 413 %token _synchronized_ "synchronized"
 414 %token _throws_ "throws"
 415 %token _transient_ "transient"
 416 %token _volatile_ "volatile"
 417 %token _yield_ "yield"
 418 %token _yield__ "!yield"
 419
 420 %token _undefined_ "undefined"
 421
 422 @begin ObjectiveC
 423 %token _bool_ "bool"
 424 %token _BOOL_ "BOOL"
 425 %token _id_ "id"
 426 %token _nil_ "nil"
 427 %token _NULL_ "NULL"
 428 %token _SEL_ "SEL"
 429 @end
 430
 431 %token _auto_ "auto"
 432 %token _each_ "each"
 433 %token _of_ "of"
 434
 435 @begin E4X
 436 %token _namespace_ "namespace"
 437 %token _xml_ "xml"
 438 @end
 439
 440 %token AutoComplete
 441 %token YieldStar
 442
 443 %token <identifier_> Identifier_
 444 %token <number_> NumericLiteral
 445 %token <string_> StringLiteral
 446 %token <literal_> RegularExpressionLiteral
 447
 448 %token <string_> NoSubstitutionTemplate
 449 %token <string_> TemplateHead
 450 %token <string_> TemplateMiddle
 451 %token <string_> TemplateTail
 452
 453 %type <target_> AccessExpression
 454 %type <expression_> AdditiveExpression
 455 %type <argument_> ArgumentList_
 456 %type <argument_> ArgumentList
 457 %type <argument_> ArgumentListOpt
 458 %type <argument_> Arguments
 459 %type <target_> ArrayComprehension
 460 %type <literal_> ArrayLiteral
 461 %type <expression_> ArrowFunction
 462 %type <functionParameter_> ArrowParameters
 463 %type <expression_> AssignmentExpression
 464 %type <expression_> AssignmentExpressionOpt
 465 %type <identifier_> BindingIdentifier
 466 %type <identifier_> BindingIdentifierOpt
 467 %type <declarations_> BindingList_
 468 %type <declarations_> BindingList
 469 %type <expression_> BitwiseANDExpression
 470 %type <statement_> Block
 471 %type <statement_> BlockStatement
 472 %type <boolean_> BooleanLiteral
 473 %type <declaration_> BindingElement
 474 %type <expression_> BitwiseORExpression
 475 %type <expression_> BitwiseXORExpression
 476 %type <statement_> BreakStatement
 477 %type <statement_> BreakableStatement
 478 %type <expression_> CallExpression_
 479 %type <target_> CallExpression
 480 %type <clause_> CaseBlock
 481 %type <clause_> CaseClause
 482 %type <clause_> CaseClausesOpt
 483 %type <catch_> Catch
 484 %type <identifier_> CatchParameter
 485 %type <statement_> ClassDeclaration
 486 %type <target_> ClassExpression
 487 %type <classTail_> ClassHeritage
 488 %type <classTail_> ClassHeritageOpt
 489 %type <classTail_> ClassTail
 490 %type <target_> Comprehension
 491 %type <comprehension_> ComprehensionFor
 492 %type <comprehension_> ComprehensionIf
 493 %type <comprehension_> ComprehensionTail
 494 %type <propertyName_> ComputedPropertyName
 495 %type <expression_> ConditionalExpression
 496 %type <statement_> ContinueStatement
 497 %type <statement_> ConciseBody
 498 %type <parenthetical_> CoverParenthesizedExpressionAndArrowParameterList
 499 %type <statement_> DebuggerStatement
 500 %type <statement_> Declaration__
 501 %type <statement_> Declaration_
 502 %type <statement_> Declaration
 503 %type <clause_> DefaultClause
 504 %type <element_> ElementList
 505 %type <element_> ElementListOpt
 506 %type <statement_> ElseStatementOpt
 507 %type <for_> EmptyStatement
 508 %type <expression_> EqualityExpression
 509 %type <expression_> Expression
 510 %type <expression_> ExpressionOpt
 511 %type <for_> ExpressionStatement_
 512 %type <statement_> ExpressionStatement
 513 %type <finally_> Finally
 514 %type <declaration_> ForBinding
 515 %type <forin_> ForDeclaration
 516 %type <forin_> ForInStatementInitializer
 517 %type <for_> ForStatementInitializer
 518 %type <declaration_> FormalParameter
 519 %type <functionParameter_> FormalParameterList_
 520 %type <functionParameter_> FormalParameterList
 521 %type <functionParameter_> FormalParameters
 522 %type <statement_> FunctionBody
 523 %type <statement_> FunctionDeclaration
 524 %type <target_> FunctionExpression
 525 %type <statement_> FunctionStatementList
 526 %type <statement_> GeneratorBody
 527 %type <statement_> GeneratorDeclaration
 528 %type <target_> GeneratorExpression
 529 %type <method_> GeneratorMethod
 530 %type <statement_> HoistableDeclaration
 531 %type <identifier_> Identifier
 532 %type <identifier_> IdentifierType
 533 %type <word_> IdentifierName
 534 %type <variable_> IdentifierReference
 535 %type <statement_> IfStatement
 536 %type <target_> IndirectExpression
 537 %type <expression_> Initializer
 538 %type <expression_> InitializerOpt
 539 %type <statement_> IterationStatement
 540 %type <identifier_> LabelIdentifier
 541 %type <statement_> LabelledItem
 542 %type <statement_> LabelledStatement
 543 %type <assignment_> LeftHandSideAssignment
 544 %type <target_> LeftHandSideExpression
 545 %type <bool_> LetOrConst
 546 %type <declaration_> LexicalBinding
 547 %type <for_> LexicalDeclaration_
 548 %type <statement_> LexicalDeclaration
 549 %type <literal_> Literal
 550 %type <propertyName_> LiteralPropertyName
 551 %type <expression_> LogicalANDExpression
 552 %type <expression_> LogicalORExpression
 553 %type <access_> MemberAccess
 554 %type <target_> MemberExpression
 555 %type <method_> MethodDefinition
 556 %type <module_> ModulePath
 557 %type <expression_> MultiplicativeExpression
 558 %type <target_> NewExpression
 559 %type <null_> NullLiteral
 560 %type <literal_> ObjectLiteral
 561 %type <expression_> PostfixExpression
 562 %type <target_> PrimaryExpression
 563 %type <propertyName_> PropertyName
 564 %type <property_> PropertyDefinition
 565 %type <property_> PropertyDefinitionList_
 566 %type <property_> PropertyDefinitionList
 567 %type <property_> PropertyDefinitionListOpt
 568 %type <declaration_> PropertySetParameterList
 569 %type <expression_> RelationalExpression
 570 %type <statement_> ReturnStatement
 571 %type <rubyProc_> RubyProcExpression
 572 %type <functionParameter_> RubyProcParameterList_
 573 %type <functionParameter_> RubyProcParameterList
 574 %type <functionParameter_> RubyProcParameters
 575 %type <functionParameter_> RubyProcParametersOpt
 576 %type <statement_> Script
 577 %type <statement_> ScriptBody
 578 %type <statement_> ScriptBodyOpt
 579 %type <expression_> ShiftExpression
 580 %type <declaration_> SingleNameBinding
 581 %type <statement_> Statement__
 582 %type <statement_> Statement_
 583 %type <statement_> Statement
 584 %type <statement_> StatementList
 585 %type <statement_> StatementListOpt
 586 %type <statement_> StatementListItem
 587 %type <functionParameter_> StrictFormalParameters
 588 %type <target_> SuperCall
 589 %type <target_> SuperProperty
 590 %type <statement_> SwitchStatement
 591 %type <target_> TemplateLiteral
 592 %type <span_> TemplateSpans
 593 %type <statement_> ThrowStatement
 594 %type <statement_> TryStatement
 595 %type <expression_> UnaryExpression_
 596 %type <expression_> UnaryExpression
 597 %type <declaration_> VariableDeclaration
 598 %type <declarations_> VariableDeclarationList_
 599 %type <declarations_> VariableDeclarationList
 600 %type <for_> VariableStatement_
 601 %type <statement_> VariableStatement
 602 %type <statement_> WithStatement
 603 %type <word_> Word
 604 @begin ObjectiveC
 605 %type <word_> WordOpt
 606 @end
 607 %type <expression_> YieldExpression
 608
 609 @begin C
 610 %type <specifier_> IntegerType
 611 %type <specifier_> IntegerTypeOpt
 612 %type <typedIdentifier_> PrefixedType
 613 %type <specifier_> PrimitiveType
 614 %type <typedIdentifier_> SuffixedType
 615 %type <typedIdentifier_> TypeSignifier
 616 %type <modifier_> TypeQualifierLeft
 617 %type <typedIdentifier_> TypeQualifierRight
 618 %type <typedIdentifier_> TypedIdentifier
 619 %type <typedParameter_> TypedParameterList_
 620 %type <typedParameter_> TypedParameterList
 621 %type <typedParameter_> TypedParameterListOpt
 622 @end
 623
 624 @begin ObjectiveC
 625 %type <expression_> AssignmentExpressionClassic
 626 %type <expression_> BoxableExpression
 627 %type <statement_> CategoryStatement
 628 %type <expression_> ClassSuperOpt
 629 %type <expression_> ConditionalExpressionClassic
 630 %type <implementationField_> ImplementationFieldListOpt
 631 %type <implementationField_> ImplementationFields
 632 %type <message_> ClassMessageDeclaration
 633 %type <message_> ClassMessageDeclarationListOpt
 634 %type <protocol_> ClassProtocolListOpt
 635 %type <protocol_> ClassProtocols
 636 %type <protocol_> ClassProtocolsOpt
 637 %type <statement_> ImplementationStatement
 638 %type <target_> MessageExpression
 639 %type <messageParameter_> MessageParameter
 640 %type <messageParameter_> MessageParameters
 641 %type <messageParameter_> MessageParameterList
 642 %type <messageParameter_> MessageParameterListOpt
 643 %type <bool_> MessageScope
 644 %type <argument_> SelectorCall_
 645 %type <argument_> SelectorCall
 646 %type <selector_> SelectorExpression_
 647 %type <selector_> SelectorExpression
 648 %type <selector_> SelectorExpressionOpt
 649 %type <argument_> SelectorList
 650 %type <word_> SelectorWordOpt
 651 %type <typedIdentifier_> TypeOpt
 652 %type <argument_> VariadicCall
 653 @end
 654
 655 @begin E4X
 656 %type <propertyIdentifier_> PropertyIdentifier_
 657 %type <selector_> PropertySelector_
 658 %type <selector_> PropertySelector
 659 %type <identifier_> QualifiedIdentifier_
 660 %type <identifier_> QualifiedIdentifier
 661 %type <identifier_> WildcardIdentifier
 662 %type <identifier_> XMLComment
 663 %type <identifier_> XMLCDATA
 664 %type <identifier_> XMLElement
 665 %type <identifier_> XMLElementContent
 666 %type <identifier_> XMLMarkup
 667 %type <identifier_> XMLPI
 668
 669 %type <attribute_> AttributeIdentifier
 670 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 671 %type <expression_> PropertyIdentifier
 672 %type <expression_> XMLListInitialiser
 673 %type <expression_> XMLInitialiser
 674 @end
 675 /* }}} */
 676 /* Token Priorities {{{ */
 677 %nonassoc ""
 678 %left "{"
 679
 680 %nonassoc "if"
 681 %nonassoc "else"
 682 /* }}} */
 683
 684 %start Program
 685 %token MarkModule
 686 %token MarkScript
 687
 688 %%
 689
 690 Program
 691     : MarkScript Script
 692     | MarkModule Module
 693     ;
 694
 695 /* Lexer State {{{ */
 696 LexPushInOn: { driver.in_.push(true); };
 697 LexPushInOff: { driver.in_.push(false); };
 698 LexPopIn: { driver.in_.pop(); };
 699
 700 LexPushReturnOn: { driver.return_.push(true); };
 701 LexPopReturn: { driver.return_.pop(); };
 702
 703 LexPushSuperOn: { driver.super_.push(true); };
 704 LexPushSuperOff: { driver.super_.push(false); };
 705 LexPopSuper: { driver.super_.pop(); };
 706
 707 LexPushYieldOn: { driver.yield_.push(true); };
 708 LexPushYieldOff: { driver.yield_.push(false); };
 709 LexPopYield: { driver.yield_.pop(); };
 710
 711 LexSetRegExp
 712     : { CYLEX(); if (yyla.type == yytranslate_(token::Slash)) { yyla.clear(); driver.SetRegEx(false); } else if (yyla.type == yytranslate_(token::SlashEqual)) { yyla.clear(); driver.SetRegEx(true); } }
 713     ;
 714
 715 LexNewLine
 716     : { if (!yyla.empty() && yyla.type_get() != yyeof_) CYERR(@$, "unexpected lookahead"); driver.next_ = true; }
 717     ;
 718
 719 LexNoStar
 720     : { CYMAP(YieldStar, Star); }
 721     ;
 722
 723 LexNoBrace
 724     : { CYMAP(OpenBrace__, OpenBrace); CYMAP(OpenBrace__, OpenBrace_); }
 725     ;
 726
 727 LexNoClass
 728     : { CYMAP(_class__, _class_); }
 729     ;
 730
 731 LexNoFunction
 732     : { CYMAP(_function__, _function_); }
 733     ;
 734
 735 LexSetStatement
 736     : LexNoBrace LexNoClass LexNoFunction
 737     ;
 738 /* }}} */
 739 /* Virtual Tokens {{{ */
 740 BRACE
 741     : "{"
 742     | "\n{"
 743     ;
 744
 745 Var_
 746     : "var"
 747     ;
 748 /* }}} */
 749
 750 /* 11.6 Names and Keywords {{{ */
 751 IdentifierName
 752     : Word { $$ = $1; }
 753     | "for" { $$ = CYNew CYWord("for"); }
 754     | "in" { $$ = CYNew CYWord("in"); }
 755     | "instanceof" { $$ = CYNew CYWord("instanceof"); }
 756     ;
 757
 758 NewLineOpt
 759     : "\n"
 760     |
 761     ;
 762
 763 Word
 764     : Identifier { $$ = $1; }
 765     | "auto" { $$ = CYNew CYWord("auto"); }
 766     | "break" { $$ = CYNew CYWord("break"); }
 767     | "case" { $$ = CYNew CYWord("case"); }
 768     | "catch" { $$ = CYNew CYWord("catch"); }
 769     | "class" { $$ = CYNew CYWord("class"); }
 770     | ";class" { $$ = CYNew CYWord("class"); }
 771     | "const" { $$ = CYNew CYWord("const"); }
 772     | "continue" { $$ = CYNew CYWord("continue"); }
 773     | "debugger" { $$ = CYNew CYWord("debugger"); }
 774     | "default" { $$ = CYNew CYWord("default"); }
 775     | "delete" LexSetRegExp { $$ = CYNew CYWord("delete"); }
 776     | "do" { $$ = CYNew CYWord("do"); }
 777     | "else" { $$ = CYNew CYWord("else"); }
 778     | "enum" { $$ = CYNew CYWord("enum"); }
 779     | "export" { $$ = CYNew CYWord("export"); }
 780     | "extends" { $$ = CYNew CYWord("extends"); }
 781     | "false" { $$ = CYNew CYWord("false"); }
 782     | "finally" { $$ = CYNew CYWord("finally"); }
 783     | "function" { $$ = CYNew CYWord("function"); }
 784     | "if" { $$ = CYNew CYWord("if"); }
 785     | "import" { $$ = CYNew CYWord("import"); }
 786     | "!in" { $$ = CYNew CYWord("in"); }
 787     | "new" LexSetRegExp { $$ = CYNew CYWord("new"); }
 788     | "null" { $$ = CYNew CYWord("null"); }
 789     | "return" { $$ = CYNew CYWord("return"); }
 790     | "super" { $$ = CYNew CYWord("super"); }
 791     | "switch" { $$ = CYNew CYWord("switch"); }
 792     | "this" { $$ = CYNew CYWord("this"); }
 793     | "throw" { $$ = CYNew CYWord("throw"); }
 794     | "true" { $$ = CYNew CYWord("true"); }
 795     | "try" { $$ = CYNew CYWord("try"); }
 796     | "typeof" LexSetRegExp { $$ = CYNew CYWord("typeof"); }
 797     | "var" { $$ = CYNew CYWord("var"); }
 798     | "void" LexSetRegExp { $$ = CYNew CYWord("void"); }
 799     | "while" { $$ = CYNew CYWord("while"); }
 800     | "with" { $$ = CYNew CYWord("with"); }
 801     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 802
 803     | Yield LexSetRegExp NewLineOpt { $$ = CYNew CYIdentifier("yield"); }
 804
 805     // XXX: should be Identifier
 806     | "let" { $$ = CYNew CYIdentifier("let"); }
 807     ;
 808
 809 @begin ObjectiveC
 810 WordOpt
 811     : Word { $$ = $1; }
 812     | { $$ = NULL; }
 813     ;
 814 @end
 815 /* }}} */
 816 /* 11.8.1 Null Literals {{{ */
 817 NullLiteral
 818     : "null" { $$ = CYNew CYNull(); }
 819     ;
 820 /* }}} */
 821 /* 11.8.2 Boolean Literals {{{ */
 822 BooleanLiteral
 823     : "true" { $$ = CYNew CYTrue(); }
 824     | "false" { $$ = CYNew CYFalse(); }
 825     ;
 826 /* }}} */
 827
 828 /* 11.9 Automatic Semicolon Insertion {{{ */
 829 StrictSemi
 830     : { driver.Warning(@$, "warning, automatic semi-colon insertion required"); }
 831     ;
 832
 833 TerminatorSoft
 834     : ";"
 835     | "\n" StrictSemi
 836     ;
 837
 838 Terminator
 839     : ";"
 840     | error { if (yyla.type_get() != yyeof_ && yyla.type != yytranslate_(token::CloseBrace) && driver.newline_ == CYDriver::NewLineNone) { CYERR(@1, "required semi-colon"); } else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 841     ;
 842
 843 TerminatorOpt
 844     : ";"
 845     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 846     ;
 847 /* }}} */
 848
 849 /* 12.1 Identifiers {{{ */
 850 IdentifierReference
 851     : Identifier { $$ = CYNew CYVariable($1); }
 852     | "yield" { $$ = CYNew CYVariable(CYNew CYIdentifier("yield")); }
 853     ;
 854
 855 BindingIdentifier
 856     : Identifier { $$ = $1; }
 857     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 858     ;
 859
 860 BindingIdentifierOpt
 861     : BindingIdentifier { $$ = $1; }
 862     | { $$ = NULL; }
 863     ;
 864
 865 LabelIdentifier
 866     : Identifier { $$ = $1; }
 867     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 868     ;
 869
 870 IdentifierType
 871     : Identifier_ { $$ = $1; }
 872     | "abstract" { $$ = CYNew CYIdentifier("abstract"); }
 873     | "await" { $$ = CYNew CYIdentifier("await"); }
 874     | "boolean" { $$ = CYNew CYIdentifier("boolean"); }
 875     | "byte" { $$ = CYNew CYIdentifier("byte"); }
 876     | "constructor" { $$ = CYNew CYIdentifier("constructor"); }
 877     | "double" { $$ = CYNew CYIdentifier("double"); }
 878     | "each" { $$ = CYNew CYIdentifier("each"); }
 879     | "eval" { $$ = CYNew CYIdentifier("eval"); }
 880     | "final" { $$ = CYNew CYIdentifier("final"); }
 881     | "float" { $$ = CYNew CYIdentifier("float"); }
 882     | "from" { $$ = CYNew CYIdentifier("from"); }
 883     | "get" { $$ = CYNew CYIdentifier("get"); }
 884     | "goto" { $$ = CYNew CYIdentifier("goto"); }
 885     | "implements" { $$ = CYNew CYIdentifier("implements"); }
 886     | "Infinity" { $$ = CYNew CYIdentifier("Infinity"); }
 887     | "interface" { $$ = CYNew CYIdentifier("interface"); }
 888     | "native" { $$ = CYNew CYIdentifier("native"); }
 889     | "of" { $$ = CYNew CYIdentifier("of"); }
 890     | "package" { $$ = CYNew CYIdentifier("package"); }
 891     | "private" { $$ = CYNew CYIdentifier("private"); }
 892     | "protected" { $$ = CYNew CYIdentifier("protected"); }
 893     | "prototype" { $$ = CYNew CYIdentifier("prototype"); }
 894     | "public" { $$ = CYNew CYIdentifier("public"); }
 895     | "set" { $$ = CYNew CYIdentifier("set"); }
 896     | "synchronized" { $$ = CYNew CYIdentifier("synchronized"); }
 897     | "target" { $$ = CYNew CYIdentifier("target"); }
 898     | "throws" { $$ = CYNew CYIdentifier("throws"); }
 899     | "transient" { $$ = CYNew CYIdentifier("transient"); }
 900     | "undefined" { $$ = CYNew CYIdentifier("undefined"); }
 901 @begin ObjectiveC
 902     | "bool" { $$ = CYNew CYIdentifier("bool"); }
 903     | "BOOL" { $$ = CYNew CYIdentifier("BOOL"); }
 904     | "id" { $$ = CYNew CYIdentifier("id"); }
 905     | "SEL" { $$ = CYNew CYIdentifier("SEL"); }
 906 @end
 907     ;
 908
 909 Identifier
 910     : IdentifierType
 911     | "char" { $$ = CYNew CYIdentifier("char"); }
 912     | "int" { $$ = CYNew CYIdentifier("int"); }
 913     | "long" { $$ = CYNew CYIdentifier("long"); }
 914     | "short" { $$ = CYNew CYIdentifier("short"); }
 915     | "static" { $$ = CYNew CYIdentifier("static"); }
 916     | "volatile" { $$ = CYNew CYIdentifier("volatile"); }
 917 @begin C
 918     | "extern" { $$ = CYNew CYIdentifier("extern"); }
 919     | "signed" { $$ = CYNew CYIdentifier("signed"); }
 920     | "typedef" { $$ = CYNew CYIdentifier("typedef"); }
 921     | "unsigned" { $$ = CYNew CYIdentifier("unsigned"); }
 922 @end
 923 @begin ObjectiveC
 924     | "nil" { $$ = CYNew CYIdentifier("nil"); }
 925     | "NO" { $$ = CYNew CYIdentifier("NO"); }
 926     | "NULL" { $$ = CYNew CYIdentifier("NULL"); }
 927     | "YES" { $$ = CYNew CYIdentifier("YES"); }
 928 @end
 929     ;
 930 /* }}} */
 931 /* 12.2 Primary Expression {{{ */
 932 PrimaryExpression
 933     : "this" { $$ = CYNew CYThis(); }
 934     | IdentifierReference { $$ = $1; }
 935     | Literal { $$ = $1; }
 936     | ArrayLiteral { $$ = $1; }
 937     | ObjectLiteral { $$ = $1; }
 938     | FunctionExpression { $$ = $1; }
 939     | ClassExpression { $$ = $1; }
 940     | GeneratorExpression { $$ = $1; }
 941     | RegularExpressionLiteral { $$ = $1; }
 942     | TemplateLiteral { $$ = $1; }
 943     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) CYERR(@1, "invalid parenthetical"); $$ = $1; }
 944     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 945     ;
 946
 947 CoverParenthesizedExpressionAndArrowParameterList
 948     : "(" LexPushInOff Expression ")" LexPopIn { $$ = CYNew CYParenthetical($3); }
 949     | "(" LexPushInOff LexSetRegExp ")" LexPopIn { $$ = NULL; }
 950     | "(" LexPushInOff LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 951     | "(" LexPushInOff Expression "," LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 952     ;
 953 /* }}} */
 954 /* 12.2.4 Literals {{{ */
 955 Literal
 956     : NullLiteral { $$ = $1; }
 957     | BooleanLiteral { $$ = $1; }
 958     | NumericLiteral { $$ = $1; }
 959     | StringLiteral { $$ = $1; }
 960     ;
 961 /* }}} */
 962 /* 12.2.5 Array Initializer {{{ */
 963 ArrayLiteral
 964     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 965     ;
 966
 967 ElementList
 968     : AssignmentExpressionOpt "," ElementListOpt { $$ = CYNew CYElementValue($1, $3); }
 969     | LexSetRegExp "..." AssignmentExpression { $$ = CYNew CYElementSpread($3); }
 970     | AssignmentExpression { $$ = CYNew CYElementValue($1, NULL); }
 971     ;
 972
 973 ElementListOpt
 974     : ElementList { $$ = $1; }
 975     | LexSetRegExp { $$ = NULL; }
 976     ;
 977 /* }}} */
 978 /* 12.2.6 Object Initializer {{{ */
 979 ObjectLiteral
 980     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 981     ;
 982
 983 PropertyDefinitionList_
 984     : "," PropertyDefinitionListOpt { $$ = $2; }
 985     | { $$ = NULL; }
 986     ;
 987
 988 PropertyDefinitionList
 989     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 990     ;
 991
 992 PropertyDefinitionListOpt
 993     : LexSetRegExp PropertyDefinitionList { $$ = $2; }
 994     | LexSetRegExp { $$ = NULL; }
 995     ;
 996
 997 PropertyDefinition
 998     : IdentifierReference { $$ = CYNew CYPropertyValue($1->name_, $1); }
 999     | CoverInitializedName { CYNOT(@$); }
1000     | PropertyName ":" AssignmentExpression { $$ = CYNew CYPropertyValue($1, $3); }
1001     | MethodDefinition { $$ = $1; }
1002     ;
1003
1004 PropertyName
1005     : LiteralPropertyName { $$ = $1; }
1006     | ComputedPropertyName { $$ = $1; }
1007     ;
1008
1009 LiteralPropertyName
1010     : IdentifierName { $$ = $1; }
1011     | StringLiteral { $$ = $1; }
1012     | NumericLiteral { $$ = $1; }
1013     ;
1014
1015 ComputedPropertyName
1016     : "[" AssignmentExpression "]" { $$ = CYNew CYComputed($2); }
1017     ;
1018
1019 CoverInitializedName
1020     : IdentifierReference Initializer
1021     ;
1022
1023 Initializer
1024     : "=" AssignmentExpression { $$ = $2; }
1025     ;
1026
1027 InitializerOpt
1028     : Initializer { $$ = $1; }
1029     | { $$ = NULL; }
1030     ;
1031 /* }}} */
1032 /* 12.2.9 Template Literals {{{ */
1033 TemplateLiteral
1034     : NoSubstitutionTemplate { $$ = CYNew CYTemplate($1, NULL); }
1035     | TemplateHead TemplateSpans { $$ = CYNew CYTemplate($1, $2); }
1036     ;
1037
1038 TemplateSpans
1039     : Expression TemplateMiddle TemplateSpans { $$ = CYNew CYSpan($1, $2, $3); }
1040     | Expression TemplateTail { $$ = CYNew CYSpan($1, $2, NULL); }
1041     ;
1042 /* }}} */
1043
1044 /* 12.3 Left-Hand-Side Expressions {{{ */
1045 MemberAccess
1046     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
1047     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
1048     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
1049     | TemplateLiteral { CYNOT(@$); }
1050     ;
1051
1052 MemberExpression
1053     : LexSetRegExp PrimaryExpression { $$ = $2; }
1054     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1055     | SuperProperty { $$ = $1; }
1056     | MetaProperty { CYNOT(@$); }
1057     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
1058     ;
1059
1060 SuperProperty
1061     : LexSetRegExp "super" { if (!driver.super_.top()) CYERR(@2, "invalid super"); } "[" Expression "]" { $$ = CYNew CYSuperAccess($5); }
1062     | LexSetRegExp "super" { if (!driver.super_.top()) CYERR(@2, "invalid super"); } "." IdentifierName { $$ = CYNew CYSuperAccess(CYNew CYString($5)); }
1063     ;
1064
1065 MetaProperty
1066     : NewTarget
1067     ;
1068
1069 NewTarget
1070     : LexSetRegExp "new" LexSetRegExp "." "target"
1071     ;
1072
1073 NewExpression
1074     : MemberExpression { $$ = $1; }
1075     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
1076     ;
1077
1078 CallExpression_
1079     : MemberExpression { $$ = $1; }
1080     | CallExpression { $$ = $1; }
1081     ;
1082
1083 CallExpression
1084     : CallExpression_ Arguments { if (!$1->Eval()) $$ = CYNew CYCall($1, $2); else $$ = CYNew CYEval($2); }
1085     | SuperCall { $$ = $1; }
1086     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1087     ;
1088
1089 SuperCall
1090     : LexSetRegExp "super" { if (!driver.super_.top()) CYERR(@2, "invalid super"); } Arguments { $$ = CYNew CYSuperCall($4); }
1091     ;
1092
1093 Arguments
1094     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
1095     ;
1096
1097 ArgumentList_
1098     : "," ArgumentList { $$ = $2; }
1099     | { $$ = NULL; }
1100     ;
1101
1102 ArgumentList
1103     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
1104     | LexSetRegExp "..." AssignmentExpression { CYNOT(@$); }
1105     ;
1106
1107 ArgumentListOpt
1108     : ArgumentList { $$ = $1; }
1109     | LexSetRegExp { $$ = NULL; }
1110     ;
1111
1112 AccessExpression
1113     : NewExpression { $$ = $1; }
1114     | CallExpression { $$ = $1; }
1115     ;
1116
1117 LeftHandSideExpression
1118     : AccessExpression { $$ = $1; }
1119     | LexSetRegExp IndirectExpression { $$ = $2; }
1120     ;
1121 /* }}} */
1122 /* 12.4 Postfix Expressions {{{ */
1123 PostfixExpression
1124     : AccessExpression { $$ = $1; }
1125     | AccessExpression "++" { $$ = CYNew CYPostIncrement($1); }
1126     | AccessExpression "--" { $$ = CYNew CYPostDecrement($1); }
1127     ;
1128 /* }}} */
1129 /* 12.5 Unary Operators {{{ */
1130 UnaryExpression_
1131     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
1132     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
1133     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
1134     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1135     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1136     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1137     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1138     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
1139     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
1140     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
1141     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
1142     ;
1143
1144 UnaryExpression
1145     : %prec "" PostfixExpression LexOpenBrace { $$ = $1; }
1146     | LexSetRegExp UnaryExpression_ { $$ = $2; }
1147     ;
1148 /* }}} */
1149 /* 12.6 Multiplicative Operators {{{ */
1150 MultiplicativeExpression
1151     : UnaryExpression { $$ = $1; }
1152     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
1153     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
1154     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
1155     ;
1156 /* }}} */
1157 /* 12.7 Additive Operators {{{ */
1158 AdditiveExpression
1159     : MultiplicativeExpression { $$ = $1; }
1160     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
1161     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
1162     ;
1163 /* }}} */
1164 /* 12.8 Bitwise Shift Operators {{{ */
1165 ShiftExpression
1166     : AdditiveExpression { $$ = $1; }
1167     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
1168     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
1169     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
1170     ;
1171 /* }}} */
1172 /* 12.9 Relational Operators {{{ */
1173 RelationalExpression
1174     : ShiftExpression { $$ = $1; }
1175     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
1176     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
1177     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
1178     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
1179     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
1180     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
1181     ;
1182 /* }}} */
1183 /* 12.10 Equality Operators {{{ */
1184 EqualityExpression
1185     : RelationalExpression { $$ = $1; }
1186     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1187     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1188     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1189     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1190     ;
1191 /* }}} */
1192 /* 12.11 Binary Bitwise Operators {{{ */
1193 BitwiseANDExpression
1194     : EqualityExpression { $$ = $1; }
1195     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1196     ;
1197
1198 BitwiseXORExpression
1199     : BitwiseANDExpression { $$ = $1; }
1200     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1201     ;
1202
1203 BitwiseORExpression
1204     : BitwiseXORExpression { $$ = $1; }
1205     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1206     ;
1207 /* }}} */
1208 /* 12.12 Binary Logical Operators {{{ */
1209 LogicalANDExpression
1210     : BitwiseORExpression { $$ = $1; }
1211     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1212     ;
1213
1214 LogicalORExpression
1215     : LogicalANDExpression { $$ = $1; }
1216     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1217     ;
1218 /* }}} */
1219 /* 12.13 Conditional Operator ( ? : ) {{{ */
1220 @begin ObjectiveC
1221 ConditionalExpressionClassic
1222     : LogicalORExpression { $$ = $1; }
1223     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpressionClassic { $$ = CYNew CYCondition($1, $4, $7); }
1224     ;
1225 @end
1226
1227 ConditionalExpression
1228     : LogicalORExpression { $$ = $1; }
1229     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1230     ;
1231 /* }}} */
1232 /* 12.14 Assignment Operators {{{ */
1233 LeftHandSideAssignment
1234     : LeftHandSideExpression "=" { $$ = CYNew CYAssign($1, NULL); }
1235     | LeftHandSideExpression "*=" { $$ = CYNew CYMultiplyAssign($1, NULL); }
1236     | LeftHandSideExpression "/=" { $$ = CYNew CYDivideAssign($1, NULL); }
1237     | LeftHandSideExpression "%=" { $$ = CYNew CYModulusAssign($1, NULL); }
1238     | LeftHandSideExpression "+=" { $$ = CYNew CYAddAssign($1, NULL); }
1239     | LeftHandSideExpression "-=" { $$ = CYNew CYSubtractAssign($1, NULL); }
1240     | LeftHandSideExpression "<<=" { $$ = CYNew CYShiftLeftAssign($1, NULL); }
1241     | LeftHandSideExpression ">>=" { $$ = CYNew CYShiftRightSignedAssign($1, NULL); }
1242     | LeftHandSideExpression ">>>=" { $$ = CYNew CYShiftRightUnsignedAssign($1, NULL); }
1243     | LeftHandSideExpression "&=" { $$ = CYNew CYBitwiseAndAssign($1, NULL); }
1244     | LeftHandSideExpression "^=" { $$ = CYNew CYBitwiseXOrAssign($1, NULL); }
1245     | LeftHandSideExpression "|=" { $$ = CYNew CYBitwiseOrAssign($1, NULL); }
1246     ;
1247
1248 @begin ObjectiveC
1249 AssignmentExpressionClassic
1250     : ConditionalExpressionClassic { $$ = $1; }
1251     | LeftHandSideAssignment AssignmentExpressionClassic { $1->SetRight($2); $$ = $1; }
1252     ;
1253 @end
1254
1255 AssignmentExpression
1256     : ConditionalExpression { $$ = $1; }
1257     | LexSetRegExp YieldExpression { $$ = $2; }
1258     | ArrowFunction { $$ = $1; }
1259     | LeftHandSideAssignment AssignmentExpression { $1->SetRight($2); $$ = $1; }
1260     ;
1261
1262 AssignmentExpressionOpt
1263     : AssignmentExpression { $$ = $1; }
1264     | LexSetRegExp { $$ = NULL; }
1265     ;
1266 /* }}} */
1267 /* 12.15 Comma Operator ( , ) {{{ */
1268 Expression
1269     : AssignmentExpression { $$ = $1; }
1270     | Expression "," AssignmentExpression { $$ = CYNew CYCompound($1, $3); }
1271     ;
1272
1273 ExpressionOpt
1274     : Expression { $$ = $1; }
1275     | LexSetRegExp { $$ = NULL; }
1276     ;
1277 /* }}} */
1278
1279 /* 13 Statements and Declarations {{{ */
1280 Statement__
1281     : BlockStatement { $$ = $1; }
1282     | VariableStatement { $$ = $1; }
1283     | EmptyStatement { $$ = $1; }
1284     | IfStatement { $$ = $1; }
1285     | BreakableStatement { $$ = $1; }
1286     | ContinueStatement { $$ = $1; }
1287     | BreakStatement { $$ = $1; }
1288     | ReturnStatement { $$ = $1; }
1289     | WithStatement { $$ = $1; }
1290     | LabelledStatement { $$ = $1; }
1291     | ThrowStatement { $$ = $1; }
1292     | TryStatement { $$ = $1; }
1293     | DebuggerStatement { $$ = $1; }
1294     ;
1295
1296 Statement_
1297     : LexSetRegExp Statement__ { $$ = $2; }
1298     | ExpressionStatement { $$ = $1; }
1299     ;
1300
1301 Statement
1302     : LexSetStatement Statement_ { $$ = $2; }
1303     ;
1304
1305 Declaration__
1306     : HoistableDeclaration { $$ = $1; }
1307     | ClassDeclaration { $$ = $1; }
1308     | LexicalDeclaration { $$ = $1; }
1309     ;
1310
1311 Declaration_
1312     : LexSetRegExp Declaration__ { $$ = $2; }
1313     ;
1314
1315 Declaration
1316     : LexSetStatement Declaration_ { $$ = $2; }
1317     ;
1318
1319 HoistableDeclaration
1320     : FunctionDeclaration { $$ = $1; }
1321     | GeneratorDeclaration { $$ = $1; }
1322     ;
1323
1324 BreakableStatement
1325     : IterationStatement { $$ = $1; }
1326     | SwitchStatement { $$ = $1; }
1327     ;
1328 /* }}} */
1329 /* 13.2 Block {{{ */
1330 BlockStatement
1331     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1332     ;
1333
1334 Block
1335     : BRACE StatementListOpt "}" { $$ = $2; }
1336     ;
1337
1338 StatementList
1339     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1340     ;
1341
1342 StatementListOpt
1343     : StatementList { $$ = $1; }
1344     | LexSetStatement LexSetRegExp { $$ = NULL; }
1345     ;
1346
1347 StatementListItem
1348     : Statement { $$ = $1; }
1349     | Declaration { $$ = $1; }
1350     ;
1351 /* }}} */
1352 /* 13.3 Let and Const Declarations {{{ */
1353 LexicalDeclaration_
1354     : LetOrConst BindingList { $$ = CYNew CYLet($1, $2); }
1355     ;
1356
1357 LexicalDeclaration
1358     : LexicalDeclaration_ Terminator { $$ = $1; }
1359     ;
1360
1361 LetOrConst
1362     : "let" { $$ = false; }
1363     | "const" { $$ = true; }
1364     ;
1365
1366 BindingList_
1367     : "," BindingList { $$ = $2; }
1368     | { $$ = NULL; }
1369     ;
1370
1371 BindingList
1372     : LexicalBinding BindingList_ { $$ = CYNew CYDeclarations($1, $2); }
1373     ;
1374
1375 LexicalBinding
1376     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1377     | BindingPattern Initializer { CYNOT(@1); }
1378     ;
1379 /* }}} */
1380 /* 13.3.2 Variable Statement {{{ */
1381 VariableStatement_
1382     : Var_ VariableDeclarationList { $$ = CYNew CYVar($2); }
1383     ;
1384
1385 VariableStatement
1386     : VariableStatement_ Terminator { $$ = $1; }
1387     ;
1388
1389 VariableDeclarationList_
1390     : "," VariableDeclarationList { $$ = $2; }
1391     | { $$ = NULL; }
1392     ;
1393
1394 VariableDeclarationList
1395     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1396     ;
1397
1398 VariableDeclaration
1399     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1400     | BindingPattern Initializer { CYNOT(@1); }
1401     ;
1402 /* }}} */
1403 /* 13.3.3 Destructuring Binding Patterns {{{ */
1404 BindingPattern
1405     : ObjectBindingPattern
1406     | ArrayBindingPattern
1407     ;
1408
1409 ObjectBindingPattern
1410     : BRACE BindingPropertyListOpt "}"
1411     ;
1412
1413 ArrayBindingPattern
1414     : "[" { CYNOT(@$); }
1415     ;
1416
1417 BindingPropertyList_
1418     : "," BindingPropertyListOpt
1419     |
1420     ;
1421
1422 BindingPropertyList
1423     : BindingProperty BindingPropertyList_
1424     ;
1425
1426 BindingPropertyListOpt
1427     : BindingPropertyList
1428     |
1429     ;
1430
1431 BindingProperty
1432     : SingleNameBinding
1433     | PropertyName ":" BindingElement
1434     ;
1435
1436 BindingElement
1437     : SingleNameBinding { $$ = $1; }
1438     | BindingPattern InitializerOpt { CYNOT(@$); }
1439     ;
1440
1441 SingleNameBinding
1442     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1443     ;
1444
1445 BindingRestElement
1446     : "..." BindingIdentifier
1447     ;
1448 /* }}} */
1449 /* 13.4 Empty Statement {{{ */
1450 EmptyStatement
1451     : ";" { $$ = CYNew CYEmpty(); }
1452     ;
1453 /* }}} */
1454 /* 13.5 Expression Statement {{{ */
1455 ExpressionStatement_
1456     : Expression { $$ = CYNew CYExpress($1); }
1457
1458 ExpressionStatement
1459     : ExpressionStatement_ Terminator { $$ = $1; }
1460     ;
1461 /* }}} */
1462 /* 13.6 The if Statement {{{ */
1463 ElseStatementOpt
1464     : "else" Statement { $$ = $2; }
1465     | %prec "if" { $$ = NULL; }
1466     ;
1467
1468 IfStatement
1469     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1470     ;
1471 /* }}} */
1472 /* 13.7 Iteration Statements {{{ */
1473 IterationStatement
1474     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1475     | "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1476     | "for" "(" LexPushInOn ForStatementInitializer LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $6, $8, $10); }
1477     | "for" "(" LexPushInOn LexSetRegExp Var_ BindingIdentifier Initializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForInitialized(CYNew CYDeclaration($6, $7), $10, $12); }
1478     | "for" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1479     | "for" "(" LexPushInOn ForInStatementInitializer "of" LexPopIn AssignmentExpression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1480     ;
1481
1482 ForStatementInitializer
1483     : LexSetRegExp EmptyStatement { $$ = $2; }
1484     | ExpressionStatement_ ";" { $$ = $1; }
1485     | LexSetRegExp VariableStatement_ ";" { $$ = $2; }
1486     | LexSetRegExp LexicalDeclaration_ ";" { $$ = $2; }
1487     ;
1488
1489 ForInStatementInitializer
1490     : AccessExpression { $$ = $1; }
1491     | LexSetRegExp IndirectExpression { $$ = $2; }
1492     | LexSetRegExp Var_ ForBinding { $$ = CYNew CYForVariable($3); }
1493     | LexSetRegExp ForDeclaration { $$ = $2; }
1494     ;
1495
1496 ForDeclaration
1497     : LetOrConst ForBinding { $$ = CYNew CYForLexical($1, $2); }
1498     ;
1499
1500 ForBinding
1501     : BindingIdentifier { $$ = CYNew CYDeclaration($1, NULL); }
1502     | BindingPattern { CYNOT(@1); }
1503     ;
1504 /* }}} */
1505 /* 13.8 The continue Statement {{{ */
1506 Continue
1507     : "continue" LexNewLine
1508     ;
1509
1510 ContinueStatement
1511     : Continue TerminatorSoft { $$ = CYNew CYContinue(NULL); }
1512     | Continue Identifier Terminator { $$ = CYNew CYContinue($2); }
1513     ;
1514 /* }}} */
1515 /* 13.9 The break Statement {{{ */
1516 Break
1517     : "break" LexNewLine
1518     ;
1519
1520 BreakStatement
1521     : Break TerminatorSoft { $$ = CYNew CYBreak(NULL); }
1522     | Break Identifier Terminator { $$ = CYNew CYBreak($2); }
1523     ;
1524 /* }}} */
1525 /* 13.10 The return Statement {{{ */
1526 Return
1527     : "return" { if (!driver.return_.top()) CYERR(@1, "invalid return"); } LexNewLine
1528     ;
1529
1530 ReturnStatement
1531     : Return LexSetRegExp TerminatorSoft { $$ = CYNew CYReturn(NULL); }
1532     | Return Expression Terminator { $$ = CYNew CYReturn($2); }
1533     ;
1534 /* }}} */
1535 /* 13.11 The with Statement {{{ */
1536 WithStatement
1537     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1538     ;
1539 /* }}} */
1540 /* 13.12 The switch Statement {{{ */
1541 SwitchStatement
1542     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1543     ;
1544
1545 CaseBlock
1546     : BRACE CaseClausesOpt "}" { $$ = $2; }
1547     ;
1548
1549 CaseClause
1550     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1551     ;
1552
1553 CaseClausesOpt
1554     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1555     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1556     | { $$ = NULL; }
1557     ;
1558
1559 // XXX: the standard makes certain you can only have one of these
1560 DefaultClause
1561     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1562     ;
1563 /* }}} */
1564 /* 13.13 Labelled Statements {{{ */
1565 LabelledStatement
1566     : LabelIdentifier ":" LabelledItem { $$ = CYNew CYLabel($1, $3); }
1567     ;
1568
1569 LabelledItem
1570     : Statement { $$ = $1; }
1571     | LexSetStatement LexSetRegExp FunctionDeclaration { $$ = $3; }
1572     ;
1573 /* }}} */
1574 /* 13.14 The throw Statement {{{ */
1575 Throw
1576     : "throw" LexNewLine
1577     ;
1578
1579 ThrowStatement
1580     : Throw LexSetRegExp TerminatorSoft { CYERR(@1, "throw without exception"); }
1581     | Throw Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1582     ;
1583 /* }}} */
1584 /* 13.15 The try Statement {{{ */
1585 TryStatement
1586     : "try" Block Catch { $$ = CYNew cy::Syntax::Try($2, $3, NULL); }
1587     | "try" Block Finally { $$ = CYNew cy::Syntax::Try($2, NULL, $3); }
1588     | "try" Block Catch Finally { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1589     ;
1590
1591 Catch
1592     : "catch" "(" CatchParameter ")" Block { $$ = CYNew cy::Syntax::Catch($3, $5); }
1593     ;
1594
1595 Finally
1596     : "finally" Block { $$ = CYNew CYFinally($2); }
1597     ;
1598
1599 CatchParameter
1600     : BindingIdentifier { $$ = $1; }
1601     | BindingPattern { CYNOT(@$); }
1602     ;
1603 /* }}} */
1604 /* 13.16 The debugger Statement {{{ */
1605 DebuggerStatement
1606     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1607     ;
1608 /* }}} */
1609
1610 /* 14.1 Function Definitions {{{ */
1611 FunctionDeclaration
1612     : ";function" BindingIdentifier "(" FormalParameters ")" BRACE LexPushSuperOff FunctionBody "}" LexPopSuper { $$ = CYNew CYFunctionStatement($2, $4, $8); }
1613     ;
1614
1615 FunctionExpression
1616     : "function" BindingIdentifierOpt "(" LexPushInOff FormalParameters ")" LexPopIn BRACE LexPushSuperOff LexPushInOff FunctionBody "}" LexPopIn LexPopSuper { $$ = CYNew CYFunctionExpression($2, $5, $11); }
1617     ;
1618
1619 StrictFormalParameters
1620     : FormalParameters { $$ = $1; }
1621     ;
1622
1623 FormalParameters
1624     : { $$ = NULL; }
1625     | FormalParameterList
1626     ;
1627
1628 FormalParameterList_
1629     : "," FormalParameterList { $$ = $2; }
1630     | { $$ = NULL; }
1631     ;
1632
1633 FormalParameterList
1634     : FunctionRestParameter { CYNOT(@$); }
1635     | FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1636     ;
1637
1638 FunctionRestParameter
1639     : BindingRestElement
1640     ;
1641
1642 FormalParameter
1643     : BindingElement { $$ = $1; }
1644     ;
1645
1646 FunctionBody
1647     : LexPushYieldOff FunctionStatementList LexPopYield { $$ = $2; }
1648     ;
1649
1650 FunctionStatementList
1651     : LexPushReturnOn StatementListOpt LexPopReturn { $$ = $2; }
1652     ;
1653 /* }}} */
1654 /* 14.2 Arrow Function Definitions {{{ */
1655 LexEqualRight
1656     : { CYLIN(EqualRight); }
1657     ;
1658
1659 ArrowFunction
1660     : LexSetRegExp ArrowParameters LexEqualRight "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $6); }
1661     ;
1662
1663 ArrowParameters
1664     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1665     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) $$ = NULL; else { $$ = $1->expression_->Parameter(); if ($$ == NULL) CYERR(@1, "invalid parameter list"); } }
1666     ;
1667
1668 ConciseBody
1669     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1670     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1671     ;
1672 /* }}} */
1673 /* 14.3 Method Definitions {{{ */
1674 MethodDefinition
1675     : PropertyName "(" StrictFormalParameters ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyMethod($1, $3, $6); }
1676     | GeneratorMethod { $$ = $1; }
1677     | "get" PropertyName "(" ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyGetter($2, $6); }
1678     | "set" PropertyName "(" PropertySetParameterList ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertySetter($2, CYNew CYFunctionParameter($4), $7); }
1679     ;
1680
1681 PropertySetParameterList
1682     : FormalParameter { $$ = $1; }
1683     ;
1684 /* }}} */
1685 /* 14.4 Generator Function Definitions {{{ */
1686 GeneratorMethod
1687     : "*" PropertyName "(" StrictFormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorMethod($2, $4, $7); */ }
1688     ;
1689
1690 GeneratorDeclaration
1691     : ";function" "*" BindingIdentifier "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorStatement($3, $5, $8); */ }
1692     ;
1693
1694 GeneratorExpression
1695     : "function" "*" BindingIdentifierOpt "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorExpression($3, $5, $8); */ }
1696     ;
1697
1698 GeneratorBody
1699     : LexPushYieldOn FunctionStatementList LexPopYield { $$ = $2; }
1700     ;
1701
1702 Yield
1703     : "!yield" LexNewLine LexNoStar
1704     ;
1705
1706 YieldExpression
1707     : Yield LexSetRegExp NewLineOpt { CYNOT(@$); /* $$ = CYNew CYYieldValue(NULL); */ }
1708     | Yield AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldValue($2); */ }
1709     | Yield LexSetRegExp YieldStar AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldGenerator($4); */ }
1710     ;
1711 /* }}} */
1712 /* 14.5 Class Definitions {{{ */
1713 ClassDeclaration
1714     : ";class" BindingIdentifier ClassTail { $$ = CYNew CYClassStatement($2, $3); }
1715     ;
1716
1717 ClassExpression
1718     : "class" BindingIdentifierOpt ClassTail { $$ = CYNew CYClassExpression($2, $3); }
1719     ;
1720
1721 ClassTail
1722     : ClassHeritageOpt { driver.class_.push($1); } BRACE LexPushSuperOn ClassBodyOpt "}" LexPopSuper { driver.class_.pop(); $$ = $1; }
1723     ;
1724
1725 ClassHeritage
1726     : "extends" LeftHandSideExpression { $$ = CYNew CYClassTail($2); }
1727     ;
1728
1729 ClassHeritageOpt
1730     : ClassHeritage { $$ = $1; }
1731     | { $$ = CYNew CYClassTail(NULL); }
1732     ;
1733
1734 ClassBody
1735     : ClassElementList
1736     ;
1737
1738 ClassBodyOpt
1739     : ClassBody
1740     |
1741     ;
1742
1743 ClassElementList
1744     : ClassElementListOpt ClassElement
1745     ;
1746
1747 ClassElementListOpt
1748     : ClassElementList
1749     |
1750     ;
1751
1752 ClassElement
1753     : MethodDefinition { if (CYFunctionExpression *constructor = $1->Constructor()) driver.class_.top()->constructor_ = constructor; else driver.class_.top()->instance_->*$1; }
1754     | "static" MethodDefinition { driver.class_.top()->static_->*$2; }
1755     | ";"
1756     ;
1757 /* }}} */
1758
1759 /* 15.1 Scripts {{{ */
1760 Script
1761     : ScriptBodyOpt { driver.script_ = CYNew CYScript($1); }
1762     ;
1763
1764 ScriptBody
1765     : StatementList { $$ = $1; }
1766     ;
1767
1768 ScriptBodyOpt
1769     : ScriptBody { $$ = $1; }
1770     | LexSetStatement LexSetRegExp { $$ = NULL; }
1771     ;
1772 /* }}} */
1773 /* 15.2 Modules {{{ */
1774 Module
1775     : ModuleBodyOpt
1776     ;
1777
1778 ModuleBody
1779     : ModuleItemList
1780     ;
1781
1782 ModuleBodyOpt
1783     : ModuleBody
1784     |
1785     ;
1786
1787 ModuleItemList
1788     : ModuleItemListOpt ModuleItem
1789     ;
1790
1791 ModuleItemListOpt
1792     : ModuleItemList
1793     |
1794     ;
1795
1796 ModuleItem
1797     : LexSetStatement LexSetRegExp ImportDeclaration
1798     | LexSetStatement LexSetRegExp ExportDeclaration
1799     | StatementListItem
1800     ;
1801 /* }}} */
1802 /* 15.2.2 Imports {{{ */
1803 ImportDeclaration
1804     : "import" ImportClause FromClause Terminator
1805     | "import" ModuleSpecifier Terminator
1806     ;
1807
1808 ImportClause
1809     : ImportedDefaultBinding
1810     | NameSpaceImport
1811     | NamedImports
1812     | ImportedDefaultBinding "," NameSpaceImport
1813     | ImportedDefaultBinding "," NamedImports
1814     ;
1815
1816 ImportedDefaultBinding
1817     : ImportedBinding
1818     ;
1819
1820 NameSpaceImport
1821     : "*" "as" ImportedBinding
1822     ;
1823
1824 NamedImports
1825     : BRACE ImportsListOpt "}"
1826     ;
1827
1828 FromClause
1829     : "from" ModuleSpecifier
1830     ;
1831
1832 ImportsList_
1833     : "," ImportsListOpt
1834     |
1835     ;
1836
1837 ImportsList
1838     : ImportSpecifier ImportsList_
1839     ;
1840
1841 ImportsListOpt
1842     : ImportsList
1843     |
1844     ;
1845
1846 ImportSpecifier
1847     : ImportedBinding
1848     | IdentifierName "as" ImportedBinding
1849     ;
1850
1851 ModuleSpecifier
1852     : StringLiteral
1853     ;
1854
1855 ImportedBinding
1856     : BindingIdentifier
1857     ;
1858 /* }}} */
1859 /* 15.2.3 Exports {{{ */
1860 ExportDeclaration_
1861     : "*" FromClause Terminator
1862     | ExportClause FromClause Terminator
1863     | ExportClause Terminator
1864     | VariableStatement
1865     | "default" LexSetStatement LexSetRegExp HoistableDeclaration
1866     | "default" LexSetStatement LexSetRegExp ClassDeclaration
1867     | "default" LexSetStatement AssignmentExpression Terminator
1868     ;
1869
1870 ExportDeclaration
1871     : "export" LexSetStatement LexSetRegExp ExportDeclaration_
1872     | "export" Declaration
1873     ;
1874
1875 ExportClause
1876     : ";{" ExportsListOpt "}"
1877     ;
1878
1879 ExportsList_
1880     : "," ExportsListOpt
1881     |
1882     ;
1883
1884 ExportsList
1885     : ExportSpecifier ExportsList_
1886     ;
1887
1888 ExportsListOpt
1889     : ExportsList
1890     |
1891     ;
1892
1893 ExportSpecifier
1894     : IdentifierName
1895     | IdentifierName "as" IdentifierName
1896     ;
1897 /* }}} */
1898
1899 @begin C
1900 /* Cycript (C): Type Encoding {{{ */
1901 TypeSignifier
1902     : IdentifierType { $$ = CYNew CYTypedIdentifier(@1, $1); }
1903     | "(" LexPushInOff "*" TypeQualifierRight ")" LexPopIn { $$ = $4; }
1904     ;
1905
1906 SuffixedType
1907     : SuffixedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1908     | "(" LexPushInOff "^" TypeQualifierRight ")" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $4; $$->modifier_ = CYNew CYTypeBlockWith($9, $$->modifier_); }
1909     | TypeSignifier "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; $$->modifier_ = CYNew CYTypeFunctionWith($4, $$->modifier_); }
1910     | "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypedIdentifier(@1); $$->modifier_ = CYNew CYTypeFunctionWith($3, $$->modifier_); }
1911     | TypeSignifier { $$ = $1; }
1912     | { $$ = CYNew CYTypedIdentifier(@$); }
1913     ;
1914
1915 PrefixedType
1916     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1917     ;
1918
1919 TypeQualifierLeft
1920     : { $$ = NULL; }
1921     | "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1922     | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); }
1923     ;
1924
1925 TypeQualifierRight
1926     : PrefixedType { $$ = $1; }
1927     | SuffixedType { $$ = $1; }
1928     | "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1929     | "volatile" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeVolatile($$->modifier_); }
1930     ;
1931
1932 IntegerType
1933     : "int" { $$ = CYNew CYTypeVariable("int"); }
1934     | "unsigned" IntegerTypeOpt { $$ = CYNew CYTypeUnsigned($2); }
1935     | "signed" IntegerTypeOpt { $$ = CYNew CYTypeSigned($2); }
1936     | "long" IntegerTypeOpt { $$ = CYNew CYTypeLong($2); }
1937     | "short" IntegerTypeOpt { $$ = CYNew CYTypeShort($2); }
1938     ;
1939
1940 IntegerTypeOpt
1941     : IntegerType { $$ = $1; }
1942     | { $$ = CYNew CYTypeVariable("int"); }
1943     ;
1944
1945 PrimitiveType
1946     : IdentifierType { $$ = CYNew CYTypeVariable($1); }
1947     | IntegerType { $$ = $1; }
1948     | "void" { $$ = CYNew CYTypeVoid(); }
1949     | "char" { $$ = CYNew CYTypeVariable("char"); }
1950     | "signed" "char" { $$ = CYNew CYTypeSigned(CYNew CYTypeVariable("char")); }
1951     | "unsigned" "char" { $$ = CYNew CYTypeUnsigned(CYNew CYTypeVariable("char")); }
1952     ;
1953
1954 TypedIdentifier
1955     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->specifier_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1956     ;
1957
1958 PrimaryExpression
1959     : "@encode" "(" TypedIdentifier ")" { $$ = CYNew CYEncodedType($3); }
1960     ;
1961 /* }}} */
1962 @end
1963
1964 @begin ObjectiveC
1965 /* Cycript (Objective-C): @class Declaration {{{ */
1966 ClassSuperOpt
1967     /* XXX: why the hell did I choose MemberExpression? */
1968     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1969     | { $$ = NULL; }
1970     ;
1971
1972 ImplementationFieldListOpt
1973     : LexSetRegExp TypedIdentifier ";" ImplementationFieldListOpt { $$ = CYNew CYImplementationField($2, $4); }
1974     | LexSetRegExp { $$ = NULL; }
1975     ;
1976
1977 ImplementationFields
1978     : BRACE ImplementationFieldListOpt "}" { $$ = $2; }
1979     ;
1980
1981 MessageScope
1982     : "+" { $$ = false; }
1983     | "-" { $$ = true; }
1984     ;
1985
1986 TypeOpt
1987     : "(" LexSetRegExp TypedIdentifier ")" { if ($3->identifier_ != NULL) CYERR($3->location_, "unexpected identifier"); $$ = $3; }
1988     | { $$ = CYNew CYTypedIdentifier(CYNew CYTypeVariable("id")); }
1989     ;
1990
1991 MessageParameter
1992     : Word ":" TypeOpt Identifier { $3->identifier_ = $4; $$ = CYNew CYMessageParameter($1, $3); }
1993     ;
1994
1995 MessageParameterList
1996     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1997     ;
1998
1999 MessageParameterListOpt
2000     : MessageParameterList { $$ = $1; }
2001     | { $$ = NULL; }
2002     ;
2003
2004 MessageParameters
2005     : MessageParameterList { $$ = $1; }
2006     | Word { $$ = CYNew CYMessageParameter($1, NULL); }
2007     ;
2008
2009 ClassMessageDeclaration
2010     : MessageScope TypeOpt MessageParameters BRACE LexPushSuperOn FunctionBody "}" LexPopSuper { $$ = CYNew CYMessage($1, $2, $3, $6); }
2011     ;
2012
2013 ClassMessageDeclarationListOpt
2014     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
2015     | { $$ = NULL; }
2016     ;
2017
2018 // XXX: this should be AssignmentExpressionNoRight
2019 ClassProtocols
2020     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
2021     ;
2022
2023 ClassProtocolsOpt
2024     : "," ClassProtocols { $$ = $2; }
2025     | { $$ = NULL; }
2026     ;
2027
2028 ClassProtocolListOpt
2029     : "<" ClassProtocols ">" { $$ = $2; }
2030     | { $$ = NULL; }
2031     ;
2032
2033 ImplementationStatement
2034     : "@implementation" Identifier ClassSuperOpt ClassProtocolListOpt ImplementationFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYImplementation($2, $3, $4, $5, $6); }
2035     ;
2036
2037 CategoryName
2038     : "(" WordOpt ")"
2039     ;
2040
2041 CategoryStatement
2042     : "@implementation" Identifier CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
2043     ;
2044
2045 Statement__
2046     : ImplementationStatement { $$ = $1; }
2047     | CategoryStatement { $$ = $1; }
2048     ;
2049 /* }}} */
2050 /* Cycript (Objective-C): Send Message {{{ */
2051 VariadicCall
2052     : "," AssignmentExpressionClassic VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
2053     | { $$ = NULL; }
2054     ;
2055
2056 SelectorWordOpt
2057     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
2058     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
2059     ;
2060
2061 SelectorCall_
2062     : SelectorCall { $$ = $1; }
2063     | VariadicCall { $$ = $1; }
2064     ;
2065
2066 SelectorCall
2067     : SelectorWordOpt ":" AssignmentExpressionClassic SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYWord(""), $3, $4); }
2068     ;
2069
2070 SelectorList
2071     : SelectorCall { $$ = $1; }
2072     | Word { $$ = CYNew CYArgument($1, NULL); }
2073     ;
2074
2075 MessageExpression
2076     : "[" LexPushInOff AssignmentExpressionClassic { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
2077     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
2078     ;
2079
2080 SelectorExpression_
2081     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
2082     ;
2083
2084 SelectorExpression
2085     : SelectorExpression_ { $$ = $1; }
2086     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
2087     ;
2088
2089 SelectorExpressionOpt
2090     : SelectorExpression_ { $$ = $1; }
2091     | { $$ = NULL; }
2092     ;
2093
2094 PrimaryExpression
2095     : MessageExpression { $$ = $1; }
2096     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
2097     ;
2098 /* }}} */
2099 @end
2100
2101 /* Cycript: @import Directive {{{ */
2102 ModulePath
2103     : ModulePath "." Word { $$ = CYNew CYModule($3, $1); }
2104     | Word { $$ = CYNew CYModule($1); }
2105     ;
2106
2107 Declaration__
2108     : "@import" ModulePath { $$ = CYNew CYImport($2); }
2109     ;
2110 /* }}} */
2111
2112 @begin ObjectiveC
2113 /* Cycript (Objective-C): Boxed Expressions {{{ */
2114 BoxableExpression
2115     : NullLiteral { $$ = $1; }
2116     | BooleanLiteral { $$ = $1; }
2117     | NumericLiteral { $$ = $1; }
2118     | StringLiteral { $$ = $1; }
2119     | ArrayLiteral { $$ = $1; }
2120     | ObjectLiteral { $$ = $1; }
2121     | CoverParenthesizedExpressionAndArrowParameterList { $$ = $1; }
2122     | "YES" { $$ = CYNew CYTrue(); }
2123     | "NO" { $$ = CYNew CYFalse(); }
2124     ;
2125
2126 PrimaryExpression
2127     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
2128     | "@YES" { $$ = CYNew CYBox(CYNew CYTrue()); }
2129     | "@NO" { $$ = CYNew CYBox(CYNew CYFalse()); }
2130     | "@true" { $$ = CYNew CYBox(CYNew CYTrue()); }
2131     | "@false" { $$ = CYNew CYBox(CYNew CYFalse()); }
2132     | "@null" { $$ = CYNew CYBox(CYNew CYNull()); }
2133     ;
2134 /* }}} */
2135 /* Cycript (Objective-C): Block Expressions {{{ */
2136 PrimaryExpression
2137     : "^" TypedIdentifier { if ($2->identifier_ != NULL) CYERR($2->location_, "unexpected identifier"); } BRACE LexPushInOff FunctionBody "}" LexPopIn { if (CYTypeFunctionWith *function = $2->Function()) $$ = CYNew CYObjCBlock($2, function->parameters_, $6); else CYERR($2->location_, "expected parameters"); }
2138     ;
2139 /* }}} */
2140 /* Cycript (Objective-C): Instance Literals {{{ */
2141 PrimaryExpression
2142     : "#" NumericLiteral { $$ = CYNew CYInstanceLiteral($2); }
2143     ;
2144 /* }}} */
2145 @end
2146
2147 @begin C
2148 /* Cycript (C): Pointer Indirection/Addressing {{{ */
2149 UnaryExpression_
2150     : IndirectExpression { $$ = $1; }
2151     ;
2152
2153 IndirectExpression
2154     : "*" UnaryExpression { $$ = CYNew CYIndirect($2); }
2155     ;
2156
2157 UnaryExpression_
2158     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
2159     ;
2160
2161 MemberAccess
2162     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
2163     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
2164     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
2165     ;
2166 /* }}} */
2167 /* Cycript (C): auto Compatibility {{{ */
2168 Var_
2169     : "auto"
2170     ;
2171 /* }}} */
2172 /* Cycript (C): Lambda Expressions {{{ */
2173 TypedParameterList_
2174     : "," TypedParameterList { $$ = $2; }
2175     | { $$ = NULL; }
2176     ;
2177
2178 TypedParameterList
2179     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
2180     ;
2181
2182 TypedParameterListOpt
2183     : TypedParameterList { $$ = $1; }
2184     | { $$ = NULL; }
2185     ;
2186
2187 PrimaryExpression
2188     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
2189     ;
2190 /* }}} */
2191 /* Cycript (C): Type Definitions {{{ */
2192 Statement__
2193     : "typedef" TypedIdentifier { if ($2->identifier_ == NULL) CYERR($2->location_, "expected identifier"); } Terminator { $$ = CYNew CYTypeDefinition($2); }
2194     ;
2195 /* }}} */
2196 /* Cycript (C): extern "C" {{{ */
2197 Statement__
2198     : "extern" StringLiteral { if (strcmp($2->Value(), "C") != 0) CYERR(@2, "unknown extern binding"); } TypedIdentifier { if ($4->identifier_ == NULL) CYERR($4->location_, "expected identifier"); } Terminator { $$ = CYNew CYExternal($2, $4); }
2199     ;
2200 /* }}} */
2201
2202 @end
2203
2204 @begin E4X
2205 /* Lexer State {{{ */
2206 LexPushRegExp
2207     : { driver.PushCondition(CYDriver::RegExpCondition); }
2208     ;
2209
2210 LexPushXMLContent
2211     : { driver.PushCondition(CYDriver::XMLContentCondition); }
2212     ;
2213
2214 LexPushXMLTag
2215     : { driver.PushCondition(CYDriver::XMLTagCondition); }
2216     ;
2217
2218 LexPop
2219     : { driver.PopCondition(); }
2220     ;
2221
2222 LexSetXMLContent
2223     : { driver.SetCondition(CYDriver::XMLContentCondition); }
2224     ;
2225
2226 LexSetXMLTag
2227     : { driver.SetCondition(CYDriver::XMLTagCondition); }
2228     ;
2229 /* }}} */
2230 /* Virtual Tokens {{{ */
2231 XMLWhitespaceOpt
2232     : XMLWhitespace
2233     |
2234     ;
2235 /* }}} */
2236
2237 /* 8.1 Context Keywords {{{ */
2238 Identifier
2239     : "namespace" { $$ = CYNew CYIdentifier("namespace"); }
2240     | "xml" { $$ = CYNew CYIdentifier("xml"); }
2241     ;
2242 /* }}} */
2243 /* 8.3 XML Initializer Input Elements {{{ */
2244 XMLMarkup
2245     : XMLComment { $$ = $1; }
2246     | XMLCDATA { $$ = $1; }
2247     | XMLPI { $$ = $1; }
2248     ;
2249 /* }}} */
2250
2251 /* 11.1 Primary Expressions {{{ */
2252 PrimaryExpression
2253     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
2254     | XMLInitialiser { $$ = $1; }
2255     | XMLListInitialiser { $$ = $1; }
2256     ;
2257
2258 PropertyIdentifier
2259     : AttributeIdentifier { $$ = $1; }
2260     | QualifiedIdentifier { $$ = $1; }
2261     | WildcardIdentifier { $$ = $1; }
2262     ;
2263 /* }}} */
2264 /* 11.1.1 Attribute Identifiers {{{ */
2265 AttributeIdentifier
2266     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
2267     ;
2268
2269 PropertySelector_
2270     : PropertySelector { $$ = $1; }
2271     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
2272     ;
2273
2274 PropertySelector
2275     : Identifier { $$ = CYNew CYSelector($1); }
2276     | WildcardIdentifier { $$ = $1; }
2277     ;
2278 /* }}} */
2279 /* 11.1.2 Qualified Identifiers {{{ */
2280 QualifiedIdentifier_
2281     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
2282     | QualifiedIdentifier { $$ = $1; }
2283     ;
2284
2285 QualifiedIdentifier
2286     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
2287     ;
2288 /* }}} */
2289 /* 11.1.3 Wildcard Identifiers {{{ */
2290 WildcardIdentifier
2291     : "*" { $$ = CYNew CYWildcard(); }
2292     ;
2293 /* }}} */
2294 /* 11.1.4 XML Initializer {{{ */
2295 XMLInitialiser
2296     : XMLMarkup { $$ = $1; }
2297     | XMLElement { $$ = $1; }
2298     ;
2299
2300 XMLElement
2301     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
2302     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
2303     ;
2304
2305 XMLTagContent
2306     : LexPushXMLTag XMLTagName XMLAttributes
2307     ;
2308
2309 XMLExpression
2310     : BRACE LexPushRegExp Expression LexPop "}"
2311     ;
2312
2313 XMLTagName
2314     : XMLExpression
2315     | XMLName
2316     ;
2317
2318 XMLAttributes_
2319     : XMLAttributes_ XMLAttribute
2320     |
2321     ;
2322
2323 XMLAttributes
2324     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
2325     | XMLAttributes_ XMLWhitespaceOpt
2326     ;
2327
2328 XMLAttributeValue_
2329     : XMLExpression
2330     | XMLAttributeValue
2331     ;
2332
2333 XMLAttribute
2334     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
2335     ;
2336
2337 XMLElementContent
2338     : XMLExpression XMLElementContentOpt
2339     | XMLMarkup XMLElementContentOpt
2340     | XMLText XMLElementContentOpt
2341     | XMLElement XMLElementContentOpt
2342     ;
2343
2344 XMLElementContentOpt
2345     : XMLElementContent
2346     |
2347     ;
2348 /* }}} */
2349 /* 11.1.5 XMLList Initializer {{{ */
2350 XMLListInitialiser
2351     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
2352     ;
2353 /* }}} */
2354
2355 /* 11.2 Left-Hand-Side Expressions {{{ */
2356 PropertyIdentifier_
2357     : Identifier { $$ = $1; }
2358     | PropertyIdentifier { $$ = $1; }
2359     ;
2360
2361 MemberAccess
2362     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
2363     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
2364     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
2365     ;
2366 /* }}} */
2367 /* 12.1 The default xml namespace Statement {{{ */
2368 /* XXX: DefaultXMLNamespaceStatement
2369     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
2370     ;
2371
2372 Statement__
2373     : DefaultXMLNamespaceStatement { $$ = $1; }
2374     ; */
2375 /* }}} */
2376 @end
2377
2378 /* JavaScript FTL: Array Comprehensions {{{ */
2379 Comprehension
2380     : AssignmentExpression ComprehensionFor ComprehensionTail { $$ = CYNew CYArrayComprehension($1, $2->Modify($3)); }
2381     ;
2382
2383 ComprehensionFor
2384     : "for" "each" "(" LexPushInOn ForBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
2385     ;
2386 /* }}} */
2387 /* JavaScript FTL: for each {{{ */
2388 IterationStatement
2389     : "for" "each" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
2390     ;
2391 /* }}} */
2392
2393 /* JavaScript FTW: Array Comprehensions {{{ */
2394 PrimaryExpression
2395     : ArrayComprehension
2396     ;
2397
2398 ArrayComprehension
2399     : "[" LexPushInOff Comprehension "]" LexPopIn { $$ = $3; }
2400     ;
2401
2402 Comprehension
2403     : LexSetRegExp ComprehensionFor ComprehensionTail AssignmentExpression { $$ = CYNew CYArrayComprehension($4, $2->Modify($3)); }
2404     ;
2405
2406 ComprehensionTail
2407     : { $$ = NULL; }
2408     | ComprehensionFor ComprehensionTail { $$ = $1->Modify($2); }
2409     | ComprehensionIf ComprehensionTail { $$ = $1->Modify($2); }
2410     ;
2411
2412 ComprehensionFor
2413     : "for" "(" LexPushInOn ForBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
2414     | "for" "(" LexPushInOn ForBinding "of" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($4, $7); }
2415     ;
2416
2417 ComprehensionIf
2418     : "if" "(" AssignmentExpression ")" { $$ = CYNew CYIfComprehension($3); }
2419     ;
2420 /* }}} */
2421 /* JavaScript FTW: Coalesce Operator {{{ */
2422 ConditionalExpression
2423     : LogicalORExpression "?" LexPushInOff LexSetRegExp ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $1, $7); }
2424     ;
2425 /* }}} */
2426 /* JavaScript FTW: Named Arguments {{{ */
2427 ArgumentList
2428     : LexSetRegExp Word ":" AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument($2, $4, $5); }
2429     ;
2430 /* }}} */
2431 /* JavaScript FTW: Ruby Blocks {{{ */
2432 RubyProcParameterList_
2433     : "," RubyProcParameterList { $$ = $2; }
2434     | { $$ = NULL; }
2435     ;
2436
2437 RubyProcParameterList
2438     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
2439     | { $$ = NULL; }
2440     ;
2441
2442 RubyProcParameters
2443     : LexSetRegExp "|" RubyProcParameterList "|" { $$ = $3; }
2444     | LexSetRegExp "||" { $$ = NULL; }
2445     ;
2446
2447 RubyProcParametersOpt
2448     : RubyProcParameters { $$ = $1; }
2449     | LexSetRegExp { $$ = NULL; }
2450     ;
2451
2452 LexOpenBrace
2453     : { CYLIN(OpenBrace); }
2454     ;
2455
2456 RubyProcExpression
2457     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
2458     ;
2459
2460 PrimaryExpression
2461     : BRACE LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
2462     ;
2463
2464 PostfixExpression
2465     : PostfixExpression LexOpenBrace RubyProcExpression { $$ = CYNew CYRubyBlock($1, $3); }
2466     ;
2467 /* }}} */
2468
2469 %%
2470
2471 bool CYDriver::Parse(CYMark mark) {
2472     mark_ = mark;
2473     CYLocal<CYPool> local(&pool_);
2474     cy::parser parser(*this);
2475 #ifdef YYDEBUG
2476     parser.set_debug_level(debug_);
2477 #endif
2478     return parser.parse() != 0;
2479 }
2480
2481 void CYDriver::Warning(const cy::parser::location_type &location, const char *message) {
2482     if (!strict_)
2483         return;
2484
2485     CYDriver::Error error;
2486     error.warning_ = true;
2487     error.location_ = location;
2488     error.message_ = message;
2489     errors_.push_back(error);
2490 }
2491
2492 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
2493     CYDriver::Error error;
2494     error.warning_ = false;
2495     error.location_ = location;
2496     error.message_ = message;
2497     driver.errors_.push_back(error);
2498 }