Parser.ypp.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 %code top {
  23 #define YYSTACKEXPANDABLE 1
  24 }
  25
  26 %code requires {
  27 #include "Driver.hpp"
  28 #include "Parser.hpp"
  29 #include "Stack.hpp"
  30 #define CYNew new(driver.pool_)
  31
  32 @begin ObjectiveC
  33 #include "ObjectiveC/Syntax.hpp"
  34 @end
  35
  36 @begin E4X
  37 #include "E4X/Syntax.hpp"
  38 @end
  39
  40 #include "Highlight.hpp"
  41 }
  42
  43 %union { bool bool_; }
  44
  45 %union { CYMember *access_; }
  46 %union { CYArgument *argument_; }
  47 %union { CYAssignment *assignment_; }
  48 %union { CYBoolean *boolean_; }
  49 %union { CYClause *clause_; }
  50 %union { cy::Syntax::Catch *catch_; }
  51 %union { CYClassTail *classTail_; }
  52 %union { CYComprehension *comprehension_; }
  53 %union { CYDeclaration *declaration_; }
  54 %union { CYDeclarations *declarations_; }
  55 %union { CYElement *element_; }
  56 %union { CYExpression *expression_; }
  57 %union { CYFalse *false_; }
  58 %union { CYVariable *variable_; }
  59 %union { CYFinally *finally_; }
  60 %union { CYForInitializer *for_; }
  61 %union { CYForInInitializer *forin_; }
  62 %union { CYFunctionParameter *functionParameter_; }
  63 %union { CYIdentifier *identifier_; }
  64 %union { CYInfix *infix_; }
  65 %union { CYLiteral *literal_; }
  66 %union { CYMethod *method_; }
  67 %union { CYModule *module_; }
  68 %union { CYNull *null_; }
  69 %union { CYNumber *number_; }
  70 %union { CYParenthetical *parenthetical_; }
  71 %union { CYProperty *property_; }
  72 %union { CYPropertyName *propertyName_; }
  73 %union { CYRubyProc *rubyProc_; }
  74 %union { CYSpan *span_; }
  75 %union { CYStatement *statement_; }
  76 %union { CYString *string_; }
  77 %union { CYTarget *target_; }
  78 %union { CYThis *this_; }
  79 %union { CYTrue *true_; }
  80 %union { CYWord *word_; }
  81
  82 @begin C
  83 %union { CYTypeModifier *modifier_; }
  84 %union { CYTypeSpecifier *specifier_; }
  85 %union { CYTypedIdentifier *typedIdentifier_; }
  86 %union { CYTypedParameter *typedParameter_; }
  87 @end
  88
  89 @begin ObjectiveC
  90 %union { CYMessage *message_; }
  91 %union { CYMessageParameter *messageParameter_; }
  92 %union { CYImplementationField *implementationField_; }
  93 %union { CYProtocol *protocol_; }
  94 %union { CYSelectorPart *selector_; }
  95 @end
  96
  97 @begin E4X
  98 %union { CYAttribute *attribute_; }
  99 %union { CYPropertyIdentifier *propertyIdentifier_; }
 100 %union { CYSelector *selector_; }
 101 @end
 102
 103 %code provides {
 104
 105 struct YYSTYPE {
 106     cy::parser::semantic_type semantic_;
 107     hi::Value highlight_;
 108 };
 109
 110 int cylex(YYSTYPE *, CYLocation *, void *);
 111
 112 }
 113
 114 %code {
 115
 116 #undef yylex
 117 _finline int yylex(cy::parser::semantic_type *semantic, CYLocation *location, CYDriver &driver) {
 118     if (driver.mark_ == CYMarkIgnore);
 119     else if (driver.mark_ == CYMarkScript) {
 120         driver.mark_ = CYMarkIgnore;
 121         return cy::parser::token::MarkScript;
 122     } else if (driver.mark_ == CYMarkModule) {
 123         driver.mark_ = CYMarkIgnore;
 124         return cy::parser::token::MarkModule;
 125     }
 126
 127     YYSTYPE data;
 128     int token(cylex(&data, location, driver.scanner_));
 129     *semantic = data.semantic_;
 130     return token;
 131 }
 132
 133 #define CYLEX() do if (yyla.empty()) { \
 134     YYCDEBUG << "Mapping a token: "; \
 135     yyla.type = yytranslate_(yylex(&yyla.value, &yyla.location, driver)); \
 136     YY_SYMBOL_PRINT("Next token is", yyla); \
 137 } while (false)
 138
 139 #define CYMAP(to, from) do { \
 140     CYLEX(); \
 141     if (yyla.type == yytranslate_(token::from)) \
 142         yyla.type = yytranslate_(token::to); \
 143 } while (false)
 144
 145 #define CYERR(location, message) do { \
 146     error(location, message); \
 147     YYABORT; \
 148 } while (false)
 149
 150 #define CYNOT(location) \
 151     CYERR(location, "unimplemented feature")
 152
 153 }
 154
 155 %name-prefix "cy"
 156
 157 %language "C++"
 158
 159 %initial-action {
 160     @$.begin.filename = @$.end.filename = &driver.filename_;
 161 };
 162
 163 %locations
 164 %defines
 165
 166 %define api.location.type { CYLocation }
 167
 168 //%glr-parser
 169 //%expect 1
 170
 171 %error-verbose
 172
 173 %param { CYDriver &driver }
 174
 175 /* Token Declarations {{{ */
 176 @begin E4X
 177 %token XMLCDATA
 178 %token XMLComment
 179 %token XMLPI
 180
 181 %token XMLAttributeValue
 182 %token XMLName
 183 %token XMLTagCharacters
 184 %token XMLText
 185 %token XMLWhitespace
 186 @end
 187
 188 @begin E4X
 189 %token LeftRight "<>"
 190 %token LeftSlashRight "</>"
 191
 192 %token SlashRight "/>"
 193 %token LeftSlash "</"
 194
 195 %token ColonColon "::"
 196 %token PeriodPeriod ".."
 197 @end
 198
 199 @begin E4X ObjectiveC
 200 %token At "@"
 201 %token Pound "#"
 202 @end
 203
 204 %token Ampersand "&"
 205 %token AmpersandAmpersand "&&"
 206 %token AmpersandEqual "&="
 207 %token Carrot "^"
 208 %token CarrotEqual "^="
 209 %token Equal "="
 210 %token EqualEqual "=="
 211 %token EqualEqualEqual "==="
 212 %token EqualRight "=>"
 213 %token EqualRight_ "\n=>"
 214 %token Exclamation "!"
 215 %token ExclamationEqual "!="
 216 %token ExclamationEqualEqual "!=="
 217 %token Hyphen "-"
 218 %token HyphenEqual "-="
 219 %token HyphenHyphen "--"
 220 %token HyphenHyphen_ "\n--"
 221 %token HyphenRight "->"
 222 %token Left "<"
 223 %token LeftEqual "<="
 224 %token LeftLeft "<<"
 225 %token LeftLeftEqual "<<="
 226 %token Percent "%"
 227 %token PercentEqual "%="
 228 %token Period "."
 229 %token PeriodPeriodPeriod "..."
 230 %token Pipe "|"
 231 %token PipeEqual "|="
 232 %token PipePipe "||"
 233 %token Plus "+"
 234 %token PlusEqual "+="
 235 %token PlusPlus "++"
 236 %token PlusPlus_ "\n++"
 237 %token Right ">"
 238 %token RightEqual ">="
 239 %token RightRight ">>"
 240 %token RightRightEqual ">>="
 241 %token RightRightRight ">>>"
 242 %token RightRightRightEqual ">>>="
 243 %token Slash "/"
 244 %token SlashEqual "/="
 245 %token Star "*"
 246 %token StarEqual "*="
 247 %token Tilde "~"
 248
 249 %token Colon ":"
 250 %token Comma ","
 251 %token Question "?"
 252 %token SemiColon ";"
 253 %token NewLine "\n"
 254
 255 %token Comment
 256
 257 %token OpenParen "("
 258 %token CloseParen ")"
 259
 260 %token OpenBrace "{"
 261 %token OpenBrace_ "\n{"
 262 %token OpenBrace__ ";{"
 263 %token CloseBrace "}"
 264
 265 %token OpenBracket "["
 266 %token CloseBracket "]"
 267
 268 %token At_error_ "@error"
 269
 270 @begin Java
 271 %token At_class_ "@class"
 272 @end
 273
 274 @begin C
 275 %token _typedef_ "typedef"
 276 %token _unsigned_ "unsigned"
 277 %token _signed_ "signed"
 278 %token _extern_ "extern"
 279 @end
 280
 281 @begin C
 282 %token At_encode_ "@encode"
 283 @end
 284
 285 @begin ObjectiveC
 286 %token At_implementation_ "@implementation"
 287 %token At_import_ "@import"
 288 %token At_end_ "@end"
 289 %token At_selector_ "@selector"
 290 %token At_null_ "@null"
 291 %token At_YES_ "@YES"
 292 %token At_NO_ "@NO"
 293 %token At_true_ "@true"
 294 %token At_false_ "@false"
 295 %token _YES_ "YES"
 296 %token _NO_ "NO"
 297 @end
 298
 299 %token _false_ "false"
 300 %token _null_ "null"
 301 %token _true_ "true"
 302
 303 %token _break_ "break"
 304 %token _case_ "case"
 305 %token _catch_ "catch"
 306 %token _class_ "class"
 307 %token _class__ ";class"
 308 %token _const_ "const"
 309 %token _continue_ "continue"
 310 %token _debugger_ "debugger"
 311 %token _default_ "default"
 312 %token _delete_ "delete"
 313 %token _do_ "do"
 314 %token _else_ "else"
 315 %token _enum_ "enum"
 316 %token _export_ "export"
 317 %token _extends_ "extends"
 318 %token _finally_ "finally"
 319 %token _for_ "for"
 320 %token _function_ "function"
 321 %token _function__ ";function"
 322 %token _if_ "if"
 323 %token _import_ "import"
 324 %token _in_ "in"
 325 %token _in__ "!in"
 326 %token _Infinity_ "Infinity"
 327 %token _instanceof_ "instanceof"
 328 %token _new_ "new"
 329 %token _return_ "return"
 330 %token _return__ "!return"
 331 %token _super_ "super"
 332 %token _switch_ "switch"
 333 %token _target_ "target"
 334 %token _this_ "this"
 335 %token _throw_ "throw"
 336 %token _try_ "try"
 337 %token _typeof_ "typeof"
 338 %token _var_ "var"
 339 %token _void_ "void"
 340 %token _while_ "while"
 341 %token _with_ "with"
 342
 343 %token _abstract_ "abstract"
 344 %token _await_ "await"
 345 %token _boolean_ "boolean"
 346 %token _byte_ "byte"
 347 %token _char_ "char"
 348 %token _constructor_ "constructor"
 349 %token _double_ "double"
 350 %token _eval_ "eval"
 351 %token _final_ "final"
 352 %token _float_ "float"
 353 %token _from_ "from"
 354 %token _get_ "get"
 355 %token _goto_ "goto"
 356 %token _implements_ "implements"
 357 %token _int_ "int"
 358 %token _interface_ "interface"
 359 %token _let_ "let"
 360 %token _long_ "long"
 361 %token _native_ "native"
 362 %token _package_ "package"
 363 %token _private_ "private"
 364 %token _protected_ "protected"
 365 %token _prototype_ "prototype"
 366 %token _public_ "public"
 367 %token _set_ "set"
 368 %token _short_ "short"
 369 %token _static_ "static"
 370 %token _synchronized_ "synchronized"
 371 %token _throws_ "throws"
 372 %token _transient_ "transient"
 373 %token _volatile_ "volatile"
 374 %token _yield_ "yield"
 375 %token _yield__ "!yield"
 376
 377 %token _undefined_ "undefined"
 378
 379 @begin ObjectiveC
 380 %token _bool_ "bool"
 381 %token _BOOL_ "BOOL"
 382 %token _id_ "id"
 383 %token _nil_ "nil"
 384 %token _NULL_ "NULL"
 385 %token _SEL_ "SEL"
 386 @end
 387
 388 %token _auto_ "auto"
 389 %token _each_ "each"
 390 %token _of_ "of"
 391
 392 @begin E4X
 393 %token _namespace_ "namespace"
 394 %token _xml_ "xml"
 395 @end
 396
 397 %token AutoComplete
 398 %token YieldStar
 399
 400 %token <identifier_> Identifier_
 401 %token <number_> NumericLiteral
 402 %token <string_> StringLiteral
 403 %token <literal_> RegularExpressionLiteral
 404
 405 %token <string_> NoSubstitutionTemplate
 406 %token <string_> TemplateHead
 407 %token <string_> TemplateMiddle
 408 %token <string_> TemplateTail
 409
 410 %type <expression_> AdditiveExpression
 411 %type <argument_> ArgumentList_
 412 %type <argument_> ArgumentList
 413 %type <argument_> ArgumentListOpt
 414 %type <argument_> Arguments
 415 %type <target_> ArrayComprehension
 416 %type <literal_> ArrayLiteral
 417 %type <expression_> ArrowFunction
 418 %type <functionParameter_> ArrowParameters
 419 %type <expression_> AssignmentExpression
 420 %type <expression_> AssignmentExpressionOpt
 421 %type <identifier_> BindingIdentifier
 422 %type <identifier_> BindingIdentifierOpt
 423 %type <declarations_> BindingList_
 424 %type <declarations_> BindingList
 425 %type <expression_> BitwiseANDExpression
 426 %type <statement_> Block
 427 %type <statement_> BlockStatement
 428 %type <boolean_> BooleanLiteral
 429 %type <declaration_> BindingElement
 430 %type <expression_> BitwiseORExpression
 431 %type <expression_> BitwiseXORExpression
 432 %type <statement_> BreakStatement
 433 %type <statement_> BreakableStatement
 434 %type <expression_> CallExpression_
 435 %type <target_> CallExpression
 436 %type <clause_> CaseBlock
 437 %type <clause_> CaseClause
 438 %type <clause_> CaseClausesOpt
 439 %type <catch_> Catch
 440 %type <identifier_> CatchParameter
 441 %type <statement_> ClassDeclaration
 442 %type <target_> ClassExpression
 443 %type <classTail_> ClassHeritage
 444 %type <classTail_> ClassHeritageOpt
 445 %type <classTail_> ClassTail
 446 %type <target_> Comprehension
 447 %type <comprehension_> ComprehensionFor
 448 %type <comprehension_> ComprehensionIf
 449 %type <comprehension_> ComprehensionTail
 450 %type <propertyName_> ComputedPropertyName
 451 %type <expression_> ConditionalExpression
 452 %type <statement_> ContinueStatement
 453 %type <statement_> ConciseBody
 454 %type <parenthetical_> CoverParenthesizedExpressionAndArrowParameterList
 455 %type <statement_> DebuggerStatement
 456 %type <statement_> Declaration__
 457 %type <statement_> Declaration_
 458 %type <statement_> Declaration
 459 %type <clause_> DefaultClause
 460 %type <element_> ElementList
 461 %type <element_> ElementListOpt
 462 %type <statement_> ElseStatementOpt
 463 %type <for_> EmptyStatement
 464 %type <expression_> EqualityExpression
 465 %type <expression_> Expression
 466 %type <expression_> ExpressionOpt
 467 %type <for_> ExpressionStatement_
 468 %type <statement_> ExpressionStatement
 469 %type <finally_> Finally
 470 %type <declaration_> ForBinding
 471 %type <forin_> ForDeclaration
 472 %type <forin_> ForInStatementInitializer
 473 %type <for_> ForStatementInitializer
 474 %type <declaration_> FormalParameter
 475 %type <functionParameter_> FormalParameterList_
 476 %type <functionParameter_> FormalParameterList
 477 %type <functionParameter_> FormalParameters
 478 %type <statement_> FunctionBody
 479 %type <statement_> FunctionDeclaration
 480 %type <target_> FunctionExpression
 481 %type <statement_> FunctionStatementList
 482 %type <statement_> GeneratorBody
 483 %type <statement_> GeneratorDeclaration
 484 %type <target_> GeneratorExpression
 485 %type <method_> GeneratorMethod
 486 %type <statement_> HoistableDeclaration
 487 %type <identifier_> Identifier
 488 %type <identifier_> IdentifierType
 489 %type <word_> IdentifierName
 490 %type <variable_> IdentifierReference
 491 %type <statement_> IfStatement
 492 %type <expression_> Initializer
 493 %type <expression_> InitializerOpt
 494 %type <statement_> IterationStatement
 495 %type <identifier_> LabelIdentifier
 496 %type <statement_> LabelledItem
 497 %type <statement_> LabelledStatement
 498 %type <assignment_> LeftHandSideAssignment
 499 %type <target_> LeftHandSideExpression
 500 %type <bool_> LetOrConst
 501 %type <declaration_> LexicalBinding
 502 %type <for_> LexicalDeclaration_
 503 %type <statement_> LexicalDeclaration
 504 %type <literal_> Literal
 505 %type <propertyName_> LiteralPropertyName
 506 %type <expression_> LogicalANDExpression
 507 %type <expression_> LogicalORExpression
 508 %type <access_> MemberAccess
 509 %type <target_> MemberExpression
 510 %type <method_> MethodDefinition
 511 %type <module_> ModulePath
 512 %type <expression_> MultiplicativeExpression
 513 %type <target_> NewExpression
 514 %type <null_> NullLiteral
 515 %type <literal_> ObjectLiteral
 516 %type <expression_> PostfixExpression
 517 %type <target_> PrimaryExpression
 518 %type <propertyName_> PropertyName
 519 %type <property_> PropertyDefinition
 520 %type <property_> PropertyDefinitionList_
 521 %type <property_> PropertyDefinitionList
 522 %type <property_> PropertyDefinitionListOpt
 523 %type <declaration_> PropertySetParameterList
 524 %type <expression_> RelationalExpression
 525 %type <statement_> ReturnStatement
 526 %type <rubyProc_> RubyProcExpression
 527 %type <functionParameter_> RubyProcParameterList_
 528 %type <functionParameter_> RubyProcParameterList
 529 %type <functionParameter_> RubyProcParameters
 530 %type <functionParameter_> RubyProcParametersOpt
 531 %type <statement_> Script
 532 %type <statement_> ScriptBody
 533 %type <statement_> ScriptBodyOpt
 534 %type <expression_> ShiftExpression
 535 %type <declaration_> SingleNameBinding
 536 %type <statement_> Statement__
 537 %type <statement_> Statement_
 538 %type <statement_> Statement
 539 %type <statement_> StatementList
 540 %type <statement_> StatementListOpt
 541 %type <statement_> StatementListItem
 542 %type <functionParameter_> StrictFormalParameters
 543 %type <target_> SuperCall
 544 %type <target_> SuperProperty
 545 %type <statement_> SwitchStatement
 546 %type <target_> TemplateLiteral
 547 %type <span_> TemplateSpans
 548 %type <statement_> ThrowStatement
 549 %type <statement_> TryStatement
 550 %type <expression_> UnaryExpression_
 551 %type <expression_> UnaryExpression
 552 %type <declaration_> VariableDeclaration
 553 %type <declarations_> VariableDeclarationList_
 554 %type <declarations_> VariableDeclarationList
 555 %type <for_> VariableStatement_
 556 %type <statement_> VariableStatement
 557 %type <statement_> WithStatement
 558 %type <word_> Word
 559 @begin ObjectiveC
 560 %type <word_> WordOpt
 561 @end
 562 %type <expression_> YieldExpression
 563
 564 @begin C
 565 %type <specifier_> IntegerType
 566 %type <specifier_> IntegerTypeOpt
 567 %type <typedIdentifier_> PrefixedType
 568 %type <specifier_> PrimitiveType
 569 %type <typedIdentifier_> SuffixedType
 570 %type <typedIdentifier_> TypeSignifier
 571 %type <modifier_> TypeQualifierLeft
 572 %type <typedIdentifier_> TypeQualifierRight
 573 %type <typedIdentifier_> TypedIdentifier
 574 %type <typedParameter_> TypedParameterList_
 575 %type <typedParameter_> TypedParameterList
 576 %type <typedParameter_> TypedParameterListOpt
 577 @end
 578
 579 @begin ObjectiveC
 580 %type <expression_> AssignmentExpressionClassic
 581 %type <expression_> BoxableExpression
 582 %type <statement_> CategoryStatement
 583 %type <expression_> ClassSuperOpt
 584 %type <expression_> ConditionalExpressionClassic
 585 %type <implementationField_> ImplementationFieldListOpt
 586 %type <implementationField_> ImplementationFields
 587 %type <message_> ClassMessageDeclaration
 588 %type <message_> ClassMessageDeclarationListOpt
 589 %type <protocol_> ClassProtocolListOpt
 590 %type <protocol_> ClassProtocols
 591 %type <protocol_> ClassProtocolsOpt
 592 %type <statement_> ImplementationStatement
 593 %type <target_> MessageExpression
 594 %type <messageParameter_> MessageParameter
 595 %type <messageParameter_> MessageParameters
 596 %type <messageParameter_> MessageParameterList
 597 %type <messageParameter_> MessageParameterListOpt
 598 %type <bool_> MessageScope
 599 %type <argument_> SelectorCall_
 600 %type <argument_> SelectorCall
 601 %type <selector_> SelectorExpression_
 602 %type <selector_> SelectorExpression
 603 %type <selector_> SelectorExpressionOpt
 604 %type <argument_> SelectorList
 605 %type <word_> SelectorWordOpt
 606 %type <typedIdentifier_> TypeOpt
 607 %type <argument_> VariadicCall
 608 @end
 609
 610 @begin E4X
 611 %type <propertyIdentifier_> PropertyIdentifier_
 612 %type <selector_> PropertySelector_
 613 %type <selector_> PropertySelector
 614 %type <identifier_> QualifiedIdentifier_
 615 %type <identifier_> QualifiedIdentifier
 616 %type <identifier_> WildcardIdentifier
 617 %type <identifier_> XMLComment
 618 %type <identifier_> XMLCDATA
 619 %type <identifier_> XMLElement
 620 %type <identifier_> XMLElementContent
 621 %type <identifier_> XMLMarkup
 622 %type <identifier_> XMLPI
 623
 624 %type <attribute_> AttributeIdentifier
 625 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 626 %type <expression_> PropertyIdentifier
 627 %type <expression_> XMLListInitialiser
 628 %type <expression_> XMLInitialiser
 629 @end
 630 /* }}} */
 631 /* Token Priorities {{{ */
 632 %nonassoc ""
 633 %left "++" "--" "{"
 634
 635 %nonassoc "if"
 636 %nonassoc "else"
 637 /* }}} */
 638
 639 %start Program
 640 %token MarkModule
 641 %token MarkScript
 642
 643 %%
 644
 645 Program
 646     : MarkScript Script
 647     | MarkModule Module
 648     ;
 649
 650 /* Lexer State {{{ */
 651 LexPushInOn: { driver.in_.push(true); };
 652 LexPushInOff: { driver.in_.push(false); };
 653 LexPopIn: { driver.in_.pop(); };
 654
 655 LexPushReturnOn: { driver.return_.push(true); };
 656 LexPopReturn: { driver.return_.pop(); };
 657
 658 LexPushSuperOn: { driver.super_.push(true); };
 659 LexPushSuperOff: { driver.super_.push(false); };
 660 LexPopSuper: { driver.super_.pop(); };
 661
 662 LexPushYieldOn: { driver.yield_.push(true); };
 663 LexPushYieldOff: { driver.yield_.push(false); };
 664 LexPopYield: { driver.yield_.pop(); };
 665
 666 LexSetRegExp
 667     : { CYLEX(); if (yyla.type == yytranslate_(token::Slash)) { yyla.clear(); driver.SetRegEx(false); } else if (yyla.type == yytranslate_(token::SlashEqual)) { yyla.clear(); driver.SetRegEx(true); } }
 668     ;
 669
 670 LexNewLine
 671     : { if (!yyla.empty() && yyla.type_get() != yyeof_) CYERR(@$, "unexpected lookahead"); driver.next_ = true; }
 672     ;
 673
 674 LexNoStar
 675     : { CYMAP(YieldStar, Star); }
 676     ;
 677
 678 LexNoBrace
 679     : { CYMAP(OpenBrace__, OpenBrace); CYMAP(OpenBrace__, OpenBrace_); }
 680     ;
 681
 682 LexNoClass
 683     : { CYMAP(_class__, _class_); }
 684     ;
 685
 686 LexNoFunction
 687     : { CYMAP(_function__, _function_); }
 688     ;
 689
 690 LexSetStatement
 691     : LexNoBrace LexNoClass LexNoFunction
 692     ;
 693 /* }}} */
 694 /* Virtual Tokens {{{ */
 695 BRACE
 696     : "{"
 697     | "\n{"
 698     ;
 699
 700 Var_
 701     : "var"
 702     ;
 703 /* }}} */
 704
 705 /* 11.6 Names and Keywords {{{ */
 706 IdentifierName
 707     : Word { $$ = $1; }
 708     | "for" { $$ = CYNew CYWord("for"); }
 709     | "in" { $$ = CYNew CYWord("in"); }
 710     | "instanceof" { $$ = CYNew CYWord("instanceof"); }
 711     ;
 712
 713 NewLineOpt
 714     : "\n"
 715     |
 716     ;
 717
 718 Word
 719     : Identifier { $$ = $1; }
 720     | "auto" { $$ = CYNew CYWord("auto"); }
 721     | "break" { $$ = CYNew CYWord("break"); }
 722     | "case" { $$ = CYNew CYWord("case"); }
 723     | "catch" { $$ = CYNew CYWord("catch"); }
 724     | "class" { $$ = CYNew CYWord("class"); }
 725     | ";class" { $$ = CYNew CYWord("class"); }
 726     | "const" { $$ = CYNew CYWord("const"); }
 727     | "continue" { $$ = CYNew CYWord("continue"); }
 728     | "debugger" { $$ = CYNew CYWord("debugger"); }
 729     | "default" { $$ = CYNew CYWord("default"); }
 730     | "delete" LexSetRegExp { $$ = CYNew CYWord("delete"); }
 731     | "do" { $$ = CYNew CYWord("do"); }
 732     | "else" { $$ = CYNew CYWord("else"); }
 733     | "enum" { $$ = CYNew CYWord("enum"); }
 734     | "export" { $$ = CYNew CYWord("export"); }
 735     | "extends" { $$ = CYNew CYWord("extends"); }
 736     | "false" { $$ = CYNew CYWord("false"); }
 737     | "finally" { $$ = CYNew CYWord("finally"); }
 738     | "function" { $$ = CYNew CYWord("function"); }
 739     | "if" { $$ = CYNew CYWord("if"); }
 740     | "import" { $$ = CYNew CYWord("import"); }
 741     | "!in" { $$ = CYNew CYWord("in"); }
 742     | "new" LexSetRegExp { $$ = CYNew CYWord("new"); }
 743     | "null" { $$ = CYNew CYWord("null"); }
 744     | "return" { $$ = CYNew CYWord("return"); }
 745     | "!return" { $$ = CYNew CYWord("return"); }
 746     | "super" { $$ = CYNew CYWord("super"); }
 747     | "switch" { $$ = CYNew CYWord("switch"); }
 748     | "this" { $$ = CYNew CYWord("this"); }
 749     | "throw" { $$ = CYNew CYWord("throw"); }
 750     | "true" { $$ = CYNew CYWord("true"); }
 751     | "try" { $$ = CYNew CYWord("try"); }
 752     | "typeof" LexSetRegExp { $$ = CYNew CYWord("typeof"); }
 753     | "var" { $$ = CYNew CYWord("var"); }
 754     | "void" LexSetRegExp { $$ = CYNew CYWord("void"); }
 755     | "while" { $$ = CYNew CYWord("while"); }
 756     | "with" { $$ = CYNew CYWord("with"); }
 757     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 758
 759     | Yield LexSetRegExp NewLineOpt { $$ = CYNew CYIdentifier("yield"); }
 760
 761     // XXX: should be Identifier
 762     | "let" { $$ = CYNew CYIdentifier("let"); }
 763     ;
 764
 765 @begin ObjectiveC
 766 WordOpt
 767     : Word { $$ = $1; }
 768     | { $$ = NULL; }
 769     ;
 770 @end
 771 /* }}} */
 772 /* 11.8.1 Null Literals {{{ */
 773 NullLiteral
 774     : "null" { $$ = CYNew CYNull(); }
 775     ;
 776 /* }}} */
 777 /* 11.8.2 Boolean Literals {{{ */
 778 BooleanLiteral
 779     : "true" { $$ = CYNew CYTrue(); }
 780     | "false" { $$ = CYNew CYFalse(); }
 781     ;
 782 /* }}} */
 783
 784 /* 11.9 Automatic Semicolon Insertion {{{ */
 785 StrictSemi
 786     : { driver.Warning(@$, "warning, automatic semi-colon insertion required"); }
 787     ;
 788
 789 TerminatorSoft
 790     : ";"
 791     | "\n" StrictSemi
 792     ;
 793
 794 Terminator
 795     : ";"
 796     | error { if (yyla.type_get() != yyeof_ && yyla.type != yytranslate_(token::CloseBrace) && !driver.newline_) { CYERR(@1, "required semi-colon"); } else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 797     ;
 798
 799 TerminatorOpt
 800     : ";"
 801     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 802     ;
 803 /* }}} */
 804
 805 /* 12.1 Identifiers {{{ */
 806 IdentifierReference
 807     : Identifier { $$ = CYNew CYVariable($1); }
 808     | "yield" { $$ = CYNew CYVariable(CYNew CYIdentifier("yield")); }
 809     ;
 810
 811 BindingIdentifier
 812     : Identifier { $$ = $1; }
 813     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 814     ;
 815
 816 BindingIdentifierOpt
 817     : BindingIdentifier { $$ = $1; }
 818     | { $$ = NULL; }
 819     ;
 820
 821 LabelIdentifier
 822     : Identifier { $$ = $1; }
 823     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 824     ;
 825
 826 IdentifierType
 827     : Identifier_ { $$ = $1; }
 828     | "abstract" { $$ = CYNew CYIdentifier("abstract"); }
 829     | "await" { $$ = CYNew CYIdentifier("await"); }
 830     | "boolean" { $$ = CYNew CYIdentifier("boolean"); }
 831     | "byte" { $$ = CYNew CYIdentifier("byte"); }
 832     | "constructor" { $$ = CYNew CYIdentifier("constructor"); }
 833     | "double" { $$ = CYNew CYIdentifier("double"); }
 834     | "each" { $$ = CYNew CYIdentifier("each"); }
 835     | "eval" { $$ = CYNew CYIdentifier("eval"); }
 836     | "final" { $$ = CYNew CYIdentifier("final"); }
 837     | "float" { $$ = CYNew CYIdentifier("float"); }
 838     | "from" { $$ = CYNew CYIdentifier("from"); }
 839     | "get" { $$ = CYNew CYIdentifier("get"); }
 840     | "goto" { $$ = CYNew CYIdentifier("goto"); }
 841     | "implements" { $$ = CYNew CYIdentifier("implements"); }
 842     | "Infinity" { $$ = CYNew CYIdentifier("Infinity"); }
 843     | "interface" { $$ = CYNew CYIdentifier("interface"); }
 844     | "native" { $$ = CYNew CYIdentifier("native"); }
 845     | "of" { $$ = CYNew CYIdentifier("of"); }
 846     | "package" { $$ = CYNew CYIdentifier("package"); }
 847     | "private" { $$ = CYNew CYIdentifier("private"); }
 848     | "protected" { $$ = CYNew CYIdentifier("protected"); }
 849     | "prototype" { $$ = CYNew CYIdentifier("prototype"); }
 850     | "public" { $$ = CYNew CYIdentifier("public"); }
 851     | "set" { $$ = CYNew CYIdentifier("set"); }
 852     | "synchronized" { $$ = CYNew CYIdentifier("synchronized"); }
 853     | "target" { $$ = CYNew CYIdentifier("target"); }
 854     | "throws" { $$ = CYNew CYIdentifier("throws"); }
 855     | "transient" { $$ = CYNew CYIdentifier("transient"); }
 856     | "undefined" { $$ = CYNew CYIdentifier("undefined"); }
 857 @begin ObjectiveC
 858     | "bool" { $$ = CYNew CYIdentifier("bool"); }
 859     | "BOOL" { $$ = CYNew CYIdentifier("BOOL"); }
 860     | "id" { $$ = CYNew CYIdentifier("id"); }
 861     | "SEL" { $$ = CYNew CYIdentifier("SEL"); }
 862 @end
 863     ;
 864
 865 Identifier
 866     : IdentifierType
 867     | "char" { $$ = CYNew CYIdentifier("char"); }
 868     | "int" { $$ = CYNew CYIdentifier("int"); }
 869     | "long" { $$ = CYNew CYIdentifier("long"); }
 870     | "short" { $$ = CYNew CYIdentifier("short"); }
 871     | "static" { $$ = CYNew CYIdentifier("static"); }
 872     | "volatile" { $$ = CYNew CYIdentifier("volatile"); }
 873 @begin C
 874     | "extern" { $$ = CYNew CYIdentifier("extern"); }
 875     | "signed" { $$ = CYNew CYIdentifier("signed"); }
 876     | "typedef" { $$ = CYNew CYIdentifier("typedef"); }
 877     | "unsigned" { $$ = CYNew CYIdentifier("unsigned"); }
 878 @end
 879 @begin ObjectiveC
 880     | "nil" { $$ = CYNew CYIdentifier("nil"); }
 881     | "NO" { $$ = CYNew CYIdentifier("NO"); }
 882     | "NULL" { $$ = CYNew CYIdentifier("NULL"); }
 883     | "YES" { $$ = CYNew CYIdentifier("YES"); }
 884 @end
 885     ;
 886 /* }}} */
 887 /* 12.2 Primary Expression {{{ */
 888 PrimaryExpression
 889     : "this" { $$ = CYNew CYThis(); }
 890     | IdentifierReference { $$ = $1; }
 891     | Literal { $$ = $1; }
 892     | ArrayLiteral { $$ = $1; }
 893     | ObjectLiteral { $$ = $1; }
 894     | FunctionExpression { $$ = $1; }
 895     | ClassExpression { $$ = $1; }
 896     | GeneratorExpression { $$ = $1; }
 897     | RegularExpressionLiteral { $$ = $1; }
 898     | TemplateLiteral { $$ = $1; }
 899     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) CYERR(@1, "invalid parenthetical"); $$ = $1; }
 900     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 901     ;
 902
 903 CoverParenthesizedExpressionAndArrowParameterList
 904     : "(" LexPushInOff Expression ")" LexPopIn { $$ = CYNew CYParenthetical($3); }
 905     | "(" LexPushInOff LexSetRegExp ")" LexPopIn { $$ = NULL; }
 906     | "(" LexPushInOff LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 907     | "(" LexPushInOff Expression "," LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 908     ;
 909 /* }}} */
 910 /* 12.2.4 Literals {{{ */
 911 Literal
 912     : NullLiteral { $$ = $1; }
 913     | BooleanLiteral { $$ = $1; }
 914     | NumericLiteral { $$ = $1; }
 915     | StringLiteral { $$ = $1; }
 916     ;
 917 /* }}} */
 918 /* 12.2.5 Array Initializer {{{ */
 919 ArrayLiteral
 920     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 921     ;
 922
 923 ElementList
 924     : AssignmentExpressionOpt "," ElementListOpt { $$ = CYNew CYElementValue($1, $3); }
 925     | LexSetRegExp "..." AssignmentExpression { $$ = CYNew CYElementSpread($3); }
 926     | AssignmentExpression { $$ = CYNew CYElementValue($1, NULL); }
 927     ;
 928
 929 ElementListOpt
 930     : ElementList { $$ = $1; }
 931     | LexSetRegExp { $$ = NULL; }
 932     ;
 933 /* }}} */
 934 /* 12.2.6 Object Initializer {{{ */
 935 ObjectLiteral
 936     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 937     ;
 938
 939 PropertyDefinitionList_
 940     : "," PropertyDefinitionListOpt { $$ = $2; }
 941     | { $$ = NULL; }
 942     ;
 943
 944 PropertyDefinitionList
 945     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 946     ;
 947
 948 PropertyDefinitionListOpt
 949     : LexSetRegExp PropertyDefinitionList { $$ = $2; }
 950     | LexSetRegExp { $$ = NULL; }
 951     ;
 952
 953 PropertyDefinition
 954     : IdentifierReference { $$ = CYNew CYPropertyValue($1->name_, $1); }
 955     | CoverInitializedName { CYNOT(@$); }
 956     | PropertyName ":" AssignmentExpression { $$ = CYNew CYPropertyValue($1, $3); }
 957     | MethodDefinition { $$ = $1; }
 958     ;
 959
 960 PropertyName
 961     : LiteralPropertyName { $$ = $1; }
 962     | ComputedPropertyName { $$ = $1; }
 963     ;
 964
 965 LiteralPropertyName
 966     : IdentifierName { $$ = $1; }
 967     | StringLiteral { $$ = $1; }
 968     | NumericLiteral { $$ = $1; }
 969     ;
 970
 971 ComputedPropertyName
 972     : "[" AssignmentExpression "]" { $$ = CYNew CYComputed($2); }
 973     ;
 974
 975 CoverInitializedName
 976     : IdentifierReference Initializer
 977     ;
 978
 979 Initializer
 980     : "=" AssignmentExpression { $$ = $2; }
 981     ;
 982
 983 InitializerOpt
 984     : Initializer { $$ = $1; }
 985     | { $$ = NULL; }
 986     ;
 987 /* }}} */
 988 /* 12.2.9 Template Literals {{{ */
 989 TemplateLiteral
 990     : NoSubstitutionTemplate { $$ = CYNew CYTemplate($1, NULL); }
 991     | TemplateHead TemplateSpans { $$ = CYNew CYTemplate($1, $2); }
 992     ;
 993
 994 TemplateSpans
 995     : Expression TemplateMiddle TemplateSpans { $$ = CYNew CYSpan($1, $2, $3); }
 996     | Expression TemplateTail { $$ = CYNew CYSpan($1, $2, NULL); }
 997     ;
 998 /* }}} */
 999
1000 /* 12.3 Left-Hand-Side Expressions {{{ */
1001 MemberAccess
1002     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
1003     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
1004     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
1005     | TemplateLiteral { CYNOT(@$); }
1006     ;
1007
1008 MemberExpression
1009     : LexSetRegExp PrimaryExpression { $$ = $2; }
1010     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1011     | SuperProperty { $$ = $1; }
1012     | MetaProperty { CYNOT(@$); }
1013     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
1014     ;
1015
1016 SuperProperty
1017     : LexSetRegExp "super" { if (!driver.super_.top()) CYERR(@2, "invalid super"); } "[" Expression "]" { $$ = CYNew CYSuperAccess($5); }
1018     | LexSetRegExp "super" { if (!driver.super_.top()) CYERR(@2, "invalid super"); } "." IdentifierName { $$ = CYNew CYSuperAccess(CYNew CYString($5)); }
1019     ;
1020
1021 MetaProperty
1022     : NewTarget
1023     ;
1024
1025 NewTarget
1026     : LexSetRegExp "new" LexSetRegExp "." "target"
1027     ;
1028
1029 NewExpression
1030     : MemberExpression { $$ = $1; }
1031     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
1032     ;
1033
1034 CallExpression_
1035     : MemberExpression { $$ = $1; }
1036     | CallExpression { $$ = $1; }
1037     ;
1038
1039 CallExpression
1040     : CallExpression_ Arguments { if (!$1->Eval()) $$ = CYNew CYCall($1, $2); else $$ = CYNew CYEval($2); }
1041     | SuperCall { $$ = $1; }
1042     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1043     ;
1044
1045 SuperCall
1046     : LexSetRegExp "super" { if (!driver.super_.top()) CYERR(@2, "invalid super"); } Arguments { $$ = CYNew CYSuperCall($4); }
1047     ;
1048
1049 Arguments
1050     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
1051     ;
1052
1053 ArgumentList_
1054     : "," ArgumentList { $$ = $2; }
1055     | { $$ = NULL; }
1056     ;
1057
1058 ArgumentList
1059     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
1060     | LexSetRegExp "..." AssignmentExpression { CYNOT(@$); }
1061     ;
1062
1063 ArgumentListOpt
1064     : ArgumentList { $$ = $1; }
1065     | LexSetRegExp { $$ = NULL; }
1066     ;
1067
1068 LeftHandSideExpression
1069     : NewExpression { $$ = $1; }
1070     | CallExpression { $$ = $1; }
1071     ;
1072 /* }}} */
1073 /* 12.4 Postfix Expressions {{{ */
1074 PostfixExpression
1075     : %prec "" LeftHandSideExpression { $$ = $1; }
1076     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
1077     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
1078     ;
1079 /* }}} */
1080 /* 12.5 Unary Operators {{{ */
1081 UnaryExpression_
1082     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
1083     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
1084     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
1085     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1086     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1087     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1088     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1089     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
1090     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
1091     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
1092     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
1093     ;
1094
1095 UnaryExpression
1096     : %prec "" PostfixExpression { $$ = $1; }
1097     | LexSetRegExp UnaryExpression_ { $$ = $2; }
1098     ;
1099 /* }}} */
1100 /* 12.6 Multiplicative Operators {{{ */
1101 MultiplicativeExpression
1102     : UnaryExpression { $$ = $1; }
1103     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
1104     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
1105     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
1106     ;
1107 /* }}} */
1108 /* 12.7 Additive Operators {{{ */
1109 AdditiveExpression
1110     : MultiplicativeExpression { $$ = $1; }
1111     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
1112     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
1113     ;
1114 /* }}} */
1115 /* 12.8 Bitwise Shift Operators {{{ */
1116 ShiftExpression
1117     : AdditiveExpression { $$ = $1; }
1118     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
1119     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
1120     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
1121     ;
1122 /* }}} */
1123 /* 12.9 Relational Operators {{{ */
1124 RelationalExpression
1125     : ShiftExpression { $$ = $1; }
1126     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
1127     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
1128     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
1129     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
1130     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
1131     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
1132     ;
1133 /* }}} */
1134 /* 12.10 Equality Operators {{{ */
1135 EqualityExpression
1136     : RelationalExpression { $$ = $1; }
1137     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1138     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1139     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1140     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1141     ;
1142 /* }}} */
1143 /* 12.11 Binary Bitwise Operators {{{ */
1144 BitwiseANDExpression
1145     : EqualityExpression { $$ = $1; }
1146     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1147     ;
1148
1149 BitwiseXORExpression
1150     : BitwiseANDExpression { $$ = $1; }
1151     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1152     ;
1153
1154 BitwiseORExpression
1155     : BitwiseXORExpression { $$ = $1; }
1156     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1157     ;
1158 /* }}} */
1159 /* 12.12 Binary Logical Operators {{{ */
1160 LogicalANDExpression
1161     : BitwiseORExpression { $$ = $1; }
1162     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1163     ;
1164
1165 LogicalORExpression
1166     : LogicalANDExpression { $$ = $1; }
1167     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1168     ;
1169 /* }}} */
1170 /* 12.13 Conditional Operator ( ? : ) {{{ */
1171 @begin ObjectiveC
1172 ConditionalExpressionClassic
1173     : LogicalORExpression { $$ = $1; }
1174     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpressionClassic { $$ = CYNew CYCondition($1, $4, $7); }
1175     ;
1176 @end
1177
1178 ConditionalExpression
1179     : LogicalORExpression { $$ = $1; }
1180     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1181     ;
1182 /* }}} */
1183 /* 12.14 Assignment Operators {{{ */
1184 LeftHandSideAssignment
1185     : LeftHandSideExpression "=" { $$ = CYNew CYAssign($1, NULL); }
1186     | LeftHandSideExpression "*=" { $$ = CYNew CYMultiplyAssign($1, NULL); }
1187     | LeftHandSideExpression "/=" { $$ = CYNew CYDivideAssign($1, NULL); }
1188     | LeftHandSideExpression "%=" { $$ = CYNew CYModulusAssign($1, NULL); }
1189     | LeftHandSideExpression "+=" { $$ = CYNew CYAddAssign($1, NULL); }
1190     | LeftHandSideExpression "-=" { $$ = CYNew CYSubtractAssign($1, NULL); }
1191     | LeftHandSideExpression "<<=" { $$ = CYNew CYShiftLeftAssign($1, NULL); }
1192     | LeftHandSideExpression ">>=" { $$ = CYNew CYShiftRightSignedAssign($1, NULL); }
1193     | LeftHandSideExpression ">>>=" { $$ = CYNew CYShiftRightUnsignedAssign($1, NULL); }
1194     | LeftHandSideExpression "&=" { $$ = CYNew CYBitwiseAndAssign($1, NULL); }
1195     | LeftHandSideExpression "^=" { $$ = CYNew CYBitwiseXOrAssign($1, NULL); }
1196     | LeftHandSideExpression "|=" { $$ = CYNew CYBitwiseOrAssign($1, NULL); }
1197     ;
1198
1199 @begin ObjectiveC
1200 AssignmentExpressionClassic
1201     : ConditionalExpressionClassic { $$ = $1; }
1202     | LeftHandSideAssignment AssignmentExpressionClassic { $1->SetRight($2); $$ = $1; }
1203     ;
1204 @end
1205
1206 AssignmentExpression
1207     : ConditionalExpression { $$ = $1; }
1208     | LexSetRegExp YieldExpression { $$ = $2; }
1209     | ArrowFunction { $$ = $1; }
1210     | LeftHandSideAssignment AssignmentExpression { $1->SetRight($2); $$ = $1; }
1211     ;
1212
1213 AssignmentExpressionOpt
1214     : AssignmentExpression { $$ = $1; }
1215     | LexSetRegExp { $$ = NULL; }
1216     ;
1217 /* }}} */
1218 /* 12.15 Comma Operator ( , ) {{{ */
1219 Expression
1220     : AssignmentExpression { $$ = $1; }
1221     | Expression "," AssignmentExpression { $$ = CYNew CYCompound($1, $3); }
1222     ;
1223
1224 ExpressionOpt
1225     : Expression { $$ = $1; }
1226     | LexSetRegExp { $$ = NULL; }
1227     ;
1228 /* }}} */
1229
1230 /* 13 Statements and Declarations {{{ */
1231 Statement__
1232     : BlockStatement { $$ = $1; }
1233     | VariableStatement { $$ = $1; }
1234     | EmptyStatement { $$ = $1; }
1235     | IfStatement { $$ = $1; }
1236     | BreakableStatement { $$ = $1; }
1237     | ContinueStatement { $$ = $1; }
1238     | BreakStatement { $$ = $1; }
1239     | ReturnStatement { $$ = $1; }
1240     | WithStatement { $$ = $1; }
1241     | LabelledStatement { $$ = $1; }
1242     | ThrowStatement { $$ = $1; }
1243     | TryStatement { $$ = $1; }
1244     | DebuggerStatement { $$ = $1; }
1245     ;
1246
1247 Statement_
1248     : LexSetRegExp Statement__ { $$ = $2; }
1249     | ExpressionStatement { $$ = $1; }
1250     ;
1251
1252 Statement
1253     : LexSetStatement Statement_ { $$ = $2; }
1254     ;
1255
1256 Declaration__
1257     : HoistableDeclaration { $$ = $1; }
1258     | ClassDeclaration { $$ = $1; }
1259     | LexicalDeclaration { $$ = $1; }
1260     ;
1261
1262 Declaration_
1263     : LexSetRegExp Declaration__ { $$ = $2; }
1264     ;
1265
1266 Declaration
1267     : LexSetStatement Declaration_ { $$ = $2; }
1268     ;
1269
1270 HoistableDeclaration
1271     : FunctionDeclaration { $$ = $1; }
1272     | GeneratorDeclaration { $$ = $1; }
1273     ;
1274
1275 BreakableStatement
1276     : IterationStatement { $$ = $1; }
1277     | SwitchStatement { $$ = $1; }
1278     ;
1279 /* }}} */
1280 /* 13.2 Block {{{ */
1281 BlockStatement
1282     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1283     ;
1284
1285 Block
1286     : BRACE StatementListOpt "}" { $$ = $2; }
1287     ;
1288
1289 StatementList
1290     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1291     ;
1292
1293 StatementListOpt
1294     : StatementList { $$ = $1; }
1295     | LexSetStatement LexSetRegExp { $$ = NULL; }
1296     ;
1297
1298 StatementListItem
1299     : Statement { $$ = $1; }
1300     | Declaration { $$ = $1; }
1301     ;
1302 /* }}} */
1303 /* 13.3 Let and Const Declarations {{{ */
1304 LexicalDeclaration_
1305     : LetOrConst BindingList { $$ = CYNew CYLet($1, $2); }
1306     ;
1307
1308 LexicalDeclaration
1309     : LexicalDeclaration_ Terminator { $$ = $1; }
1310     ;
1311
1312 LetOrConst
1313     : "let" { $$ = false; }
1314     | "const" { $$ = true; }
1315     ;
1316
1317 BindingList_
1318     : "," BindingList { $$ = $2; }
1319     | { $$ = NULL; }
1320     ;
1321
1322 BindingList
1323     : LexicalBinding BindingList_ { $$ = CYNew CYDeclarations($1, $2); }
1324     ;
1325
1326 LexicalBinding
1327     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1328     | BindingPattern Initializer { CYNOT(@1); }
1329     ;
1330 /* }}} */
1331 /* 13.3.2 Variable Statement {{{ */
1332 VariableStatement_
1333     : Var_ VariableDeclarationList { $$ = CYNew CYVar($2); }
1334     ;
1335
1336 VariableStatement
1337     : VariableStatement_ Terminator { $$ = $1; }
1338     ;
1339
1340 VariableDeclarationList_
1341     : "," VariableDeclarationList { $$ = $2; }
1342     | { $$ = NULL; }
1343     ;
1344
1345 VariableDeclarationList
1346     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1347     ;
1348
1349 VariableDeclaration
1350     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1351     | BindingPattern Initializer { CYNOT(@1); }
1352     ;
1353 /* }}} */
1354 /* 13.3.3 Destructuring Binding Patterns {{{ */
1355 BindingPattern
1356     : ObjectBindingPattern
1357     | ArrayBindingPattern
1358     ;
1359
1360 ObjectBindingPattern
1361     : BRACE BindingPropertyListOpt "}"
1362     ;
1363
1364 ArrayBindingPattern
1365     : "[" { CYNOT(@$); }
1366     ;
1367
1368 BindingPropertyList_
1369     : "," BindingPropertyListOpt
1370     |
1371     ;
1372
1373 BindingPropertyList
1374     : BindingProperty BindingPropertyList_
1375     ;
1376
1377 BindingPropertyListOpt
1378     : BindingPropertyList
1379     |
1380     ;
1381
1382 BindingProperty
1383     : SingleNameBinding
1384     | PropertyName ":" BindingElement
1385     ;
1386
1387 BindingElement
1388     : SingleNameBinding { $$ = $1; }
1389     | BindingPattern InitializerOpt { CYNOT(@$); }
1390     ;
1391
1392 SingleNameBinding
1393     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1394     ;
1395
1396 BindingRestElement
1397     : "..." BindingIdentifier
1398     ;
1399 /* }}} */
1400 /* 13.4 Empty Statement {{{ */
1401 EmptyStatement
1402     : ";" { $$ = CYNew CYEmpty(); }
1403     ;
1404 /* }}} */
1405 /* 13.5 Expression Statement {{{ */
1406 ExpressionStatement_
1407     : Expression { $$ = CYNew CYExpress($1); }
1408
1409 ExpressionStatement
1410     : ExpressionStatement_ Terminator { $$ = $1; }
1411     ;
1412 /* }}} */
1413 /* 13.6 The if Statement {{{ */
1414 ElseStatementOpt
1415     : "else" Statement { $$ = $2; }
1416     | %prec "if" { $$ = NULL; }
1417     ;
1418
1419 IfStatement
1420     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1421     ;
1422 /* }}} */
1423 /* 13.7 Iteration Statements {{{ */
1424 IterationStatement
1425     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1426     | "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1427     | "for" "(" LexPushInOn ForStatementInitializer LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $6, $8, $10); }
1428     | "for" "(" LexPushInOn LexSetRegExp Var_ BindingIdentifier Initializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForInitialized(CYNew CYDeclaration($6, $7), $10, $12); }
1429     | "for" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1430     | "for" "(" LexPushInOn ForInStatementInitializer "of" LexPopIn AssignmentExpression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1431     ;
1432
1433 ForStatementInitializer
1434     : LexSetRegExp EmptyStatement { $$ = $2; }
1435     | ExpressionStatement_ ";" { $$ = $1; }
1436     | LexSetRegExp VariableStatement_ ";" { $$ = $2; }
1437     | LexSetRegExp LexicalDeclaration_ ";" { $$ = $2; }
1438     ;
1439
1440 ForInStatementInitializer
1441     : LeftHandSideExpression { $$ = $1; }
1442     | LexSetRegExp Var_ ForBinding { $$ = CYNew CYForVariable($3); }
1443     | LexSetRegExp ForDeclaration { $$ = $2; }
1444     ;
1445
1446 ForDeclaration
1447     : LetOrConst ForBinding { $$ = CYNew CYForLexical($1, $2); }
1448     ;
1449
1450 ForBinding
1451     : BindingIdentifier { $$ = CYNew CYDeclaration($1, NULL); }
1452     | BindingPattern { CYNOT(@1); }
1453     ;
1454 /* }}} */
1455 /* 13.8 The continue Statement {{{ */
1456 Continue
1457     : "continue" LexNewLine
1458     ;
1459
1460 ContinueStatement
1461     : Continue TerminatorSoft { $$ = CYNew CYContinue(NULL); }
1462     | Continue Identifier Terminator { $$ = CYNew CYContinue($2); }
1463     ;
1464 /* }}} */
1465 /* 13.9 The break Statement {{{ */
1466 Break
1467     : "break" LexNewLine
1468     ;
1469
1470 BreakStatement
1471     : Break TerminatorSoft { $$ = CYNew CYBreak(NULL); }
1472     | Break Identifier Terminator { $$ = CYNew CYBreak($2); }
1473     ;
1474 /* }}} */
1475 /* 13.10 The return Statement {{{ */
1476 Return
1477     : "!return" LexNewLine
1478     ;
1479
1480 ReturnStatement
1481     : Return LexSetRegExp TerminatorSoft { $$ = CYNew CYReturn(NULL); }
1482     | Return Expression Terminator { $$ = CYNew CYReturn($2); }
1483     ;
1484 /* }}} */
1485 /* 13.11 The with Statement {{{ */
1486 WithStatement
1487     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1488     ;
1489 /* }}} */
1490 /* 13.12 The switch Statement {{{ */
1491 SwitchStatement
1492     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1493     ;
1494
1495 CaseBlock
1496     : BRACE CaseClausesOpt "}" { $$ = $2; }
1497     ;
1498
1499 CaseClause
1500     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1501     ;
1502
1503 CaseClausesOpt
1504     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1505     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1506     | { $$ = NULL; }
1507     ;
1508
1509 // XXX: the standard makes certain you can only have one of these
1510 DefaultClause
1511     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1512     ;
1513 /* }}} */
1514 /* 13.13 Labelled Statements {{{ */
1515 LabelledStatement
1516     : LabelIdentifier ":" LabelledItem { $$ = CYNew CYLabel($1, $3); }
1517     ;
1518
1519 LabelledItem
1520     : Statement { $$ = $1; }
1521     | LexSetStatement LexSetRegExp FunctionDeclaration { $$ = $3; }
1522     ;
1523 /* }}} */
1524 /* 13.14 The throw Statement {{{ */
1525 Throw
1526     : "throw" LexNewLine
1527     ;
1528
1529 ThrowStatement
1530     : Throw LexSetRegExp TerminatorSoft { CYERR(@1, "throw without exception"); }
1531     | Throw Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1532     ;
1533 /* }}} */
1534 /* 13.15 The try Statement {{{ */
1535 TryStatement
1536     : "try" Block Catch { $$ = CYNew cy::Syntax::Try($2, $3, NULL); }
1537     | "try" Block Finally { $$ = CYNew cy::Syntax::Try($2, NULL, $3); }
1538     | "try" Block Catch Finally { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1539     ;
1540
1541 Catch
1542     : "catch" "(" CatchParameter ")" Block { $$ = CYNew cy::Syntax::Catch($3, $5); }
1543     ;
1544
1545 Finally
1546     : "finally" Block { $$ = CYNew CYFinally($2); }
1547     ;
1548
1549 CatchParameter
1550     : BindingIdentifier { $$ = $1; }
1551     | BindingPattern { CYNOT(@$); }
1552     ;
1553 /* }}} */
1554 /* 13.16 The debugger Statement {{{ */
1555 DebuggerStatement
1556     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1557     ;
1558 /* }}} */
1559
1560 /* 14.1 Function Definitions {{{ */
1561 FunctionDeclaration
1562     : ";function" BindingIdentifier "(" FormalParameters ")" BRACE LexPushSuperOff FunctionBody "}" LexPopSuper { $$ = CYNew CYFunctionStatement($2, $4, $8); }
1563     ;
1564
1565 FunctionExpression
1566     : "function" BindingIdentifierOpt "(" LexPushInOff FormalParameters ")" LexPopIn BRACE LexPushSuperOff LexPushInOff FunctionBody "}" LexPopIn LexPopSuper { $$ = CYNew CYFunctionExpression($2, $5, $11); }
1567     ;
1568
1569 StrictFormalParameters
1570     : FormalParameters { $$ = $1; }
1571     ;
1572
1573 FormalParameters
1574     : { $$ = NULL; }
1575     | FormalParameterList
1576     ;
1577
1578 FormalParameterList_
1579     : "," FormalParameterList { $$ = $2; }
1580     | { $$ = NULL; }
1581     ;
1582
1583 FormalParameterList
1584     : FunctionRestParameter { CYNOT(@$); }
1585     | FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1586     ;
1587
1588 FunctionRestParameter
1589     : BindingRestElement
1590     ;
1591
1592 FormalParameter
1593     : BindingElement { $$ = $1; }
1594     ;
1595
1596 FunctionBody
1597     : LexPushYieldOff FunctionStatementList LexPopYield { $$ = $2; }
1598     ;
1599
1600 FunctionStatementList
1601     : LexPushReturnOn StatementListOpt LexPopReturn { $$ = $2; }
1602     ;
1603 /* }}} */
1604 /* 14.2 Arrow Function Definitions {{{ */
1605 ArrowFunction
1606     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1607     ;
1608
1609 ArrowParameters
1610     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1611     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) $$ = NULL; else { $$ = $1->expression_->Parameter(); if ($$ == NULL) CYERR(@1, "invalid parameter list"); } }
1612     ;
1613
1614 ConciseBody
1615     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1616     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1617     ;
1618 /* }}} */
1619 /* 14.3 Method Definitions {{{ */
1620 MethodDefinition
1621     : PropertyName "(" StrictFormalParameters ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyMethod($1, $3, $6); }
1622     | GeneratorMethod { $$ = $1; }
1623     | "get" PropertyName "(" ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyGetter($2, $6); }
1624     | "set" PropertyName "(" PropertySetParameterList ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertySetter($2, CYNew CYFunctionParameter($4), $7); }
1625     ;
1626
1627 PropertySetParameterList
1628     : FormalParameter { $$ = $1; }
1629     ;
1630 /* }}} */
1631 /* 14.4 Generator Function Definitions {{{ */
1632 GeneratorMethod
1633     : "*" PropertyName "(" StrictFormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorMethod($2, $4, $7); */ }
1634     ;
1635
1636 GeneratorDeclaration
1637     : ";function" "*" BindingIdentifier "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorStatement($3, $5, $8); */ }
1638     ;
1639
1640 GeneratorExpression
1641     : "function" "*" BindingIdentifierOpt "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorExpression($3, $5, $8); */ }
1642     ;
1643
1644 GeneratorBody
1645     : LexPushYieldOn FunctionStatementList LexPopYield { $$ = $2; }
1646     ;
1647
1648 Yield
1649     : "!yield" LexNewLine LexNoStar
1650     ;
1651
1652 YieldExpression
1653     : Yield LexSetRegExp NewLineOpt { CYNOT(@$); /* $$ = CYNew CYYieldValue(NULL); */ }
1654     | Yield AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldValue($2); */ }
1655     | Yield LexSetRegExp YieldStar AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldGenerator($4); */ }
1656     ;
1657 /* }}} */
1658 /* 14.5 Class Definitions {{{ */
1659 ClassDeclaration
1660     : ";class" BindingIdentifier ClassTail { $$ = CYNew CYClassStatement($2, $3); }
1661     ;
1662
1663 ClassExpression
1664     : "class" BindingIdentifierOpt ClassTail { $$ = CYNew CYClassExpression($2, $3); }
1665     ;
1666
1667 ClassTail
1668     : ClassHeritageOpt { driver.class_.push($1); } BRACE LexPushSuperOn ClassBodyOpt "}" LexPopSuper { driver.class_.pop(); $$ = $1; }
1669     ;
1670
1671 ClassHeritage
1672     : "extends" LeftHandSideExpression { $$ = CYNew CYClassTail($2); }
1673     ;
1674
1675 ClassHeritageOpt
1676     : ClassHeritage { $$ = $1; }
1677     | { $$ = CYNew CYClassTail(NULL); }
1678     ;
1679
1680 ClassBody
1681     : ClassElementList
1682     ;
1683
1684 ClassBodyOpt
1685     : ClassBody
1686     |
1687     ;
1688
1689 ClassElementList
1690     : ClassElementListOpt ClassElement
1691     ;
1692
1693 ClassElementListOpt
1694     : ClassElementList
1695     |
1696     ;
1697
1698 ClassElement
1699     : MethodDefinition { if (CYFunctionExpression *constructor = $1->Constructor()) driver.class_.top()->constructor_ = constructor; else driver.class_.top()->instance_->*$1; }
1700     | "static" MethodDefinition { driver.class_.top()->static_->*$2; }
1701     | ";"
1702     ;
1703 /* }}} */
1704
1705 /* 15.1 Scripts {{{ */
1706 Script
1707     : ScriptBodyOpt { driver.script_ = CYNew CYScript($1); }
1708     ;
1709
1710 ScriptBody
1711     : StatementList { $$ = $1; }
1712     ;
1713
1714 ScriptBodyOpt
1715     : ScriptBody { $$ = $1; }
1716     | LexSetStatement LexSetRegExp { $$ = NULL; }
1717     ;
1718 /* }}} */
1719 /* 15.2 Modules {{{ */
1720 Module
1721     : ModuleBodyOpt
1722     ;
1723
1724 ModuleBody
1725     : ModuleItemList
1726     ;
1727
1728 ModuleBodyOpt
1729     : ModuleBody
1730     |
1731     ;
1732
1733 ModuleItemList
1734     : ModuleItemListOpt ModuleItem
1735     ;
1736
1737 ModuleItemListOpt
1738     : ModuleItemList
1739     |
1740     ;
1741
1742 ModuleItem
1743     : LexSetStatement LexSetRegExp ImportDeclaration
1744     | LexSetStatement LexSetRegExp ExportDeclaration
1745     | StatementListItem
1746     ;
1747 /* }}} */
1748 /* 15.2.2 Imports {{{ */
1749 ImportDeclaration
1750     : "import" ImportClause FromClause Terminator
1751     | "import" ModuleSpecifier Terminator
1752     ;
1753
1754 ImportClause
1755     : ImportedDefaultBinding
1756     | NameSpaceImport
1757     | NamedImports
1758     | ImportedDefaultBinding "," NameSpaceImport
1759     | ImportedDefaultBinding "," NamedImports
1760     ;
1761
1762 ImportedDefaultBinding
1763     : ImportedBinding
1764     ;
1765
1766 NameSpaceImport
1767     : "*" "as" ImportedBinding
1768     ;
1769
1770 NamedImports
1771     : BRACE ImportsListOpt "}"
1772     ;
1773
1774 FromClause
1775     : "from" ModuleSpecifier
1776     ;
1777
1778 ImportsList_
1779     : "," ImportsListOpt
1780     |
1781     ;
1782
1783 ImportsList
1784     : ImportSpecifier ImportsList_
1785     ;
1786
1787 ImportsListOpt
1788     : ImportsList
1789     |
1790     ;
1791
1792 ImportSpecifier
1793     : ImportedBinding
1794     | IdentifierName "as" ImportedBinding
1795     ;
1796
1797 ModuleSpecifier
1798     : StringLiteral
1799     ;
1800
1801 ImportedBinding
1802     : BindingIdentifier
1803     ;
1804 /* }}} */
1805 /* 15.2.3 Exports {{{ */
1806 ExportDeclaration_
1807     : "*" FromClause Terminator
1808     | ExportClause FromClause Terminator
1809     | ExportClause Terminator
1810     | VariableStatement
1811     | "default" LexSetStatement LexSetRegExp HoistableDeclaration
1812     | "default" LexSetStatement LexSetRegExp ClassDeclaration
1813     | "default" LexSetStatement AssignmentExpression Terminator
1814     ;
1815
1816 ExportDeclaration
1817     : "export" LexSetStatement LexSetRegExp ExportDeclaration_
1818     | "export" Declaration
1819     ;
1820
1821 ExportClause
1822     : ";{" ExportsListOpt "}"
1823     ;
1824
1825 ExportsList_
1826     : "," ExportsListOpt
1827     |
1828     ;
1829
1830 ExportsList
1831     : ExportSpecifier ExportsList_
1832     ;
1833
1834 ExportsListOpt
1835     : ExportsList
1836     |
1837     ;
1838
1839 ExportSpecifier
1840     : IdentifierName
1841     | IdentifierName "as" IdentifierName
1842     ;
1843 /* }}} */
1844
1845 @begin C
1846 /* Cycript (C): Type Encoding {{{ */
1847 TypeSignifier
1848     : IdentifierType { $$ = CYNew CYTypedIdentifier(@1, $1); }
1849     | "(" LexPushInOff "*" TypeQualifierRight ")" LexPopIn { $$ = $4; }
1850     ;
1851
1852 SuffixedType
1853     : SuffixedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1854     | "(" LexPushInOff "^" TypeQualifierRight ")" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $4; $$->modifier_ = CYNew CYTypeBlockWith($9, $$->modifier_); }
1855     | TypeSignifier "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; $$->modifier_ = CYNew CYTypeFunctionWith($4, $$->modifier_); }
1856     | "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypedIdentifier(@1); $$->modifier_ = CYNew CYTypeFunctionWith($3, $$->modifier_); }
1857     | TypeSignifier { $$ = $1; }
1858     | { $$ = CYNew CYTypedIdentifier(@$); }
1859     ;
1860
1861 PrefixedType
1862     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1863     ;
1864
1865 TypeQualifierLeft
1866     : { $$ = NULL; }
1867     | "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1868     | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); }
1869     ;
1870
1871 TypeQualifierRight
1872     : PrefixedType { $$ = $1; }
1873     | SuffixedType { $$ = $1; }
1874     | "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1875     | "volatile" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeVolatile($$->modifier_); }
1876     ;
1877
1878 IntegerType
1879     : "int" { $$ = CYNew CYTypeVariable("int"); }
1880     | "unsigned" IntegerTypeOpt { $$ = CYNew CYTypeUnsigned($2); }
1881     | "signed" IntegerTypeOpt { $$ = CYNew CYTypeSigned($2); }
1882     | "long" IntegerTypeOpt { $$ = CYNew CYTypeLong($2); }
1883     | "short" IntegerTypeOpt { $$ = CYNew CYTypeShort($2); }
1884     ;
1885
1886 IntegerTypeOpt
1887     : IntegerType { $$ = $1; }
1888     | { $$ = CYNew CYTypeVariable("int"); }
1889     ;
1890
1891 PrimitiveType
1892     : IdentifierType { $$ = CYNew CYTypeVariable($1); }
1893     | IntegerType { $$ = $1; }
1894     | "void" { $$ = CYNew CYTypeVoid(); }
1895     | "char" { $$ = CYNew CYTypeVariable("char"); }
1896     | "signed" "char" { $$ = CYNew CYTypeSigned(CYNew CYTypeVariable("char")); }
1897     | "unsigned" "char" { $$ = CYNew CYTypeUnsigned(CYNew CYTypeVariable("char")); }
1898     ;
1899
1900 TypedIdentifier
1901     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->specifier_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1902     ;
1903
1904 PrimaryExpression
1905     : "@encode" "(" TypedIdentifier ")" { $$ = CYNew CYEncodedType($3); }
1906     ;
1907 /* }}} */
1908 @end
1909
1910 @begin ObjectiveC
1911 /* Cycript (Objective-C): @class Declaration {{{ */
1912 ClassSuperOpt
1913     /* XXX: why the hell did I choose MemberExpression? */
1914     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1915     | { $$ = NULL; }
1916     ;
1917
1918 ImplementationFieldListOpt
1919     : TypedIdentifier ";" ImplementationFieldListOpt { $$ = CYNew CYImplementationField($1, $3); }
1920     | LexSetRegExp { $$ = NULL; }
1921     ;
1922
1923 ImplementationFields
1924     : BRACE ImplementationFieldListOpt "}" { $$ = $2; }
1925     ;
1926
1927 MessageScope
1928     : "+" { $$ = false; }
1929     | "-" { $$ = true; }
1930     ;
1931
1932 TypeOpt
1933     : "(" LexSetRegExp TypedIdentifier ")" { if ($3->identifier_ != NULL) CYERR($3->location_, "unexpected identifier"); $$ = $3; }
1934     | { $$ = CYNew CYTypedIdentifier(CYNew CYTypeVariable("id")); }
1935     ;
1936
1937 MessageParameter
1938     : Word ":" TypeOpt Identifier { $3->identifier_ = $4; $$ = CYNew CYMessageParameter($1, $3); }
1939     ;
1940
1941 MessageParameterList
1942     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1943     ;
1944
1945 MessageParameterListOpt
1946     : MessageParameterList { $$ = $1; }
1947     | { $$ = NULL; }
1948     ;
1949
1950 MessageParameters
1951     : MessageParameterList { $$ = $1; }
1952     | Word { $$ = CYNew CYMessageParameter($1, NULL); }
1953     ;
1954
1955 ClassMessageDeclaration
1956     : MessageScope TypeOpt MessageParameters BRACE LexPushSuperOn FunctionBody "}" LexPopSuper { $$ = CYNew CYMessage($1, $2, $3, $6); }
1957     ;
1958
1959 ClassMessageDeclarationListOpt
1960     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1961     | { $$ = NULL; }
1962     ;
1963
1964 // XXX: this should be AssignmentExpressionNoRight
1965 ClassProtocols
1966     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1967     ;
1968
1969 ClassProtocolsOpt
1970     : "," ClassProtocols { $$ = $2; }
1971     | { $$ = NULL; }
1972     ;
1973
1974 ClassProtocolListOpt
1975     : "<" ClassProtocols ">" { $$ = $2; }
1976     | { $$ = NULL; }
1977     ;
1978
1979 ImplementationStatement
1980     : "@implementation" Identifier ClassSuperOpt ClassProtocolListOpt ImplementationFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYImplementation($2, $3, $4, $5, $6); }
1981     ;
1982
1983 CategoryName
1984     : "(" WordOpt ")"
1985     ;
1986
1987 CategoryStatement
1988     : "@implementation" Identifier CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1989     ;
1990
1991 Statement__
1992     : ImplementationStatement { $$ = $1; }
1993     | CategoryStatement { $$ = $1; }
1994     ;
1995 /* }}} */
1996 /* Cycript (Objective-C): Send Message {{{ */
1997 VariadicCall
1998     : "," AssignmentExpressionClassic VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1999     | { $$ = NULL; }
2000     ;
2001
2002 SelectorWordOpt
2003     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
2004     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
2005     ;
2006
2007 SelectorCall_
2008     : SelectorCall { $$ = $1; }
2009     | VariadicCall { $$ = $1; }
2010     ;
2011
2012 SelectorCall
2013     : SelectorWordOpt ":" AssignmentExpressionClassic SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYWord(""), $3, $4); }
2014     ;
2015
2016 SelectorList
2017     : SelectorCall { $$ = $1; }
2018     | Word { $$ = CYNew CYArgument($1, NULL); }
2019     ;
2020
2021 MessageExpression
2022     : "[" LexPushInOff AssignmentExpressionClassic { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
2023     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
2024     ;
2025
2026 SelectorExpression_
2027     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
2028     ;
2029
2030 SelectorExpression
2031     : SelectorExpression_ { $$ = $1; }
2032     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
2033     ;
2034
2035 SelectorExpressionOpt
2036     : SelectorExpression_ { $$ = $1; }
2037     | { $$ = NULL; }
2038     ;
2039
2040 PrimaryExpression
2041     : MessageExpression { $$ = $1; }
2042     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
2043     ;
2044 /* }}} */
2045 @end
2046
2047 /* Cycript: @import Directive {{{ */
2048 ModulePath
2049     : ModulePath "." Word { $$ = CYNew CYModule($3, $1); }
2050     | Word { $$ = CYNew CYModule($1); }
2051     ;
2052
2053 Declaration__
2054     : "@import" ModulePath { $$ = CYNew CYImport($2); }
2055     ;
2056 /* }}} */
2057
2058 @begin ObjectiveC
2059 /* Cycript (Objective-C): Boxed Expressions {{{ */
2060 BoxableExpression
2061     : NullLiteral { $$ = $1; }
2062     | BooleanLiteral { $$ = $1; }
2063     | NumericLiteral { $$ = $1; }
2064     | StringLiteral { $$ = $1; }
2065     | ArrayLiteral { $$ = $1; }
2066     | ObjectLiteral { $$ = $1; }
2067     | CoverParenthesizedExpressionAndArrowParameterList { $$ = $1; }
2068     | "YES" { $$ = CYNew CYTrue(); }
2069     | "NO" { $$ = CYNew CYFalse(); }
2070     ;
2071
2072 PrimaryExpression
2073     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
2074     | "@YES" { $$ = CYNew CYBox(CYNew CYTrue()); }
2075     | "@NO" { $$ = CYNew CYBox(CYNew CYFalse()); }
2076     | "@true" { $$ = CYNew CYBox(CYNew CYTrue()); }
2077     | "@false" { $$ = CYNew CYBox(CYNew CYFalse()); }
2078     | "@null" { $$ = CYNew CYBox(CYNew CYNull()); }
2079     ;
2080 /* }}} */
2081 /* Cycript (Objective-C): Block Expressions {{{ */
2082 PrimaryExpression
2083     : "^" TypedIdentifier { if ($2->identifier_ != NULL) CYERR($2->location_, "unexpected identifier"); } BRACE LexPushInOff FunctionBody "}" LexPopIn { if (CYTypeFunctionWith *function = $2->Function()) $$ = CYNew CYObjCBlock($2, function->parameters_, $6); else CYERR($2->location_, "expected parameters"); }
2084     ;
2085 /* }}} */
2086 /* Cycript (Objective-C): Instance Literals {{{ */
2087 PrimaryExpression
2088     : "#" NumericLiteral { $$ = CYNew CYInstanceLiteral($2); }
2089     ;
2090 /* }}} */
2091 @end
2092
2093 @begin C
2094 /* Cycript (C): Pointer Indirection/Addressing {{{ */
2095 LeftHandSideExpression
2096     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
2097     ;
2098
2099 UnaryExpression_
2100     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
2101     ;
2102
2103 MemberAccess
2104     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
2105     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
2106     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
2107     ;
2108 /* }}} */
2109 /* Cycript (C): auto Compatibility {{{ */
2110 Var_
2111     : "auto"
2112     ;
2113 /* }}} */
2114 /* Cycript (C): Lambda Expressions {{{ */
2115 TypedParameterList_
2116     : "," TypedParameterList { $$ = $2; }
2117     | { $$ = NULL; }
2118     ;
2119
2120 TypedParameterList
2121     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
2122     ;
2123
2124 TypedParameterListOpt
2125     : TypedParameterList { $$ = $1; }
2126     | { $$ = NULL; }
2127     ;
2128
2129 PrimaryExpression
2130     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
2131     ;
2132 /* }}} */
2133 /* Cycript (C): Type Definitions {{{ */
2134 Statement__
2135     : "typedef" TypedIdentifier { if ($2->identifier_ == NULL) CYERR($2->location_, "expected identifier"); } Terminator { $$ = CYNew CYTypeDefinition($2); }
2136     ;
2137 /* }}} */
2138 /* Cycript (C): extern "C" {{{ */
2139 Statement__
2140     : "extern" StringLiteral { if (strcmp($2->Value(), "C") != 0) CYERR(@2, "unknown extern binding"); } TypedIdentifier { if ($4->identifier_ == NULL) CYERR($4->location_, "expected identifier"); } Terminator { $$ = CYNew CYExternal($2, $4); }
2141     ;
2142 /* }}} */
2143
2144 @end
2145
2146 @begin E4X
2147 /* Lexer State {{{ */
2148 LexPushRegExp
2149     : { driver.PushCondition(CYDriver::RegExpCondition); }
2150     ;
2151
2152 LexPushXMLContent
2153     : { driver.PushCondition(CYDriver::XMLContentCondition); }
2154     ;
2155
2156 LexPushXMLTag
2157     : { driver.PushCondition(CYDriver::XMLTagCondition); }
2158     ;
2159
2160 LexPop
2161     : { driver.PopCondition(); }
2162     ;
2163
2164 LexSetXMLContent
2165     : { driver.SetCondition(CYDriver::XMLContentCondition); }
2166     ;
2167
2168 LexSetXMLTag
2169     : { driver.SetCondition(CYDriver::XMLTagCondition); }
2170     ;
2171 /* }}} */
2172 /* Virtual Tokens {{{ */
2173 XMLWhitespaceOpt
2174     : XMLWhitespace
2175     |
2176     ;
2177 /* }}} */
2178
2179 /* 8.1 Context Keywords {{{ */
2180 Identifier
2181     : "namespace" { $$ = CYNew CYIdentifier("namespace"); }
2182     | "xml" { $$ = CYNew CYIdentifier("xml"); }
2183     ;
2184 /* }}} */
2185 /* 8.3 XML Initializer Input Elements {{{ */
2186 XMLMarkup
2187     : XMLComment { $$ = $1; }
2188     | XMLCDATA { $$ = $1; }
2189     | XMLPI { $$ = $1; }
2190     ;
2191 /* }}} */
2192
2193 /* 11.1 Primary Expressions {{{ */
2194 PrimaryExpression
2195     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
2196     | XMLInitialiser { $$ = $1; }
2197     | XMLListInitialiser { $$ = $1; }
2198     ;
2199
2200 PropertyIdentifier
2201     : AttributeIdentifier { $$ = $1; }
2202     | QualifiedIdentifier { $$ = $1; }
2203     | WildcardIdentifier { $$ = $1; }
2204     ;
2205 /* }}} */
2206 /* 11.1.1 Attribute Identifiers {{{ */
2207 AttributeIdentifier
2208     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
2209     ;
2210
2211 PropertySelector_
2212     : PropertySelector { $$ = $1; }
2213     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
2214     ;
2215
2216 PropertySelector
2217     : Identifier { $$ = CYNew CYSelector($1); }
2218     | WildcardIdentifier { $$ = $1; }
2219     ;
2220 /* }}} */
2221 /* 11.1.2 Qualified Identifiers {{{ */
2222 QualifiedIdentifier_
2223     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
2224     | QualifiedIdentifier { $$ = $1; }
2225     ;
2226
2227 QualifiedIdentifier
2228     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
2229     ;
2230 /* }}} */
2231 /* 11.1.3 Wildcard Identifiers {{{ */
2232 WildcardIdentifier
2233     : "*" { $$ = CYNew CYWildcard(); }
2234     ;
2235 /* }}} */
2236 /* 11.1.4 XML Initializer {{{ */
2237 XMLInitialiser
2238     : XMLMarkup { $$ = $1; }
2239     | XMLElement { $$ = $1; }
2240     ;
2241
2242 XMLElement
2243     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
2244     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
2245     ;
2246
2247 XMLTagContent
2248     : LexPushXMLTag XMLTagName XMLAttributes
2249     ;
2250
2251 XMLExpression
2252     : BRACE LexPushRegExp Expression LexPop "}"
2253     ;
2254
2255 XMLTagName
2256     : XMLExpression
2257     | XMLName
2258     ;
2259
2260 XMLAttributes_
2261     : XMLAttributes_ XMLAttribute
2262     |
2263     ;
2264
2265 XMLAttributes
2266     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
2267     | XMLAttributes_ XMLWhitespaceOpt
2268     ;
2269
2270 XMLAttributeValue_
2271     : XMLExpression
2272     | XMLAttributeValue
2273     ;
2274
2275 XMLAttribute
2276     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
2277     ;
2278
2279 XMLElementContent
2280     : XMLExpression XMLElementContentOpt
2281     | XMLMarkup XMLElementContentOpt
2282     | XMLText XMLElementContentOpt
2283     | XMLElement XMLElementContentOpt
2284     ;
2285
2286 XMLElementContentOpt
2287     : XMLElementContent
2288     |
2289     ;
2290 /* }}} */
2291 /* 11.1.5 XMLList Initializer {{{ */
2292 XMLListInitialiser
2293     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
2294     ;
2295 /* }}} */
2296
2297 /* 11.2 Left-Hand-Side Expressions {{{ */
2298 PropertyIdentifier_
2299     : Identifier { $$ = $1; }
2300     | PropertyIdentifier { $$ = $1; }
2301     ;
2302
2303 MemberAccess
2304     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
2305     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
2306     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
2307     ;
2308 /* }}} */
2309 /* 12.1 The default xml namespace Statement {{{ */
2310 /* XXX: DefaultXMLNamespaceStatement
2311     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
2312     ;
2313
2314 Statement__
2315     : DefaultXMLNamespaceStatement { $$ = $1; }
2316     ; */
2317 /* }}} */
2318 @end
2319
2320 /* JavaScript FTL: Array Comprehensions {{{ */
2321 Comprehension
2322     : AssignmentExpression ComprehensionFor ComprehensionTail { $$ = CYNew CYArrayComprehension($1, $2->Modify($3)); }
2323     ;
2324
2325 ComprehensionFor
2326     : "for" "each" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
2327     ;
2328 /* }}} */
2329 /* JavaScript FTL: for each {{{ */
2330 IterationStatement
2331     : "for" "each" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
2332     ;
2333 /* }}} */
2334
2335 /* JavaScript FTW: Array Comprehensions {{{ */
2336 PrimaryExpression
2337     : ArrayComprehension
2338     ;
2339
2340 ArrayComprehension
2341     : "[" LexPushInOff Comprehension "]" LexPopIn { $$ = $3; }
2342     ;
2343
2344 Comprehension
2345     : LexSetRegExp ComprehensionFor ComprehensionTail AssignmentExpression { $$ = CYNew CYArrayComprehension($4, $2->Modify($3)); }
2346     ;
2347
2348 ComprehensionTail
2349     : { $$ = NULL; }
2350     | ComprehensionFor ComprehensionTail { $$ = $1->Modify($2); }
2351     | ComprehensionIf ComprehensionTail { $$ = $1->Modify($2); }
2352     ;
2353
2354 ComprehensionFor
2355     : "for" "(" LexPushInOn ForBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
2356     | "for" "(" LexPushInOn ForBinding "of" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($4, $7); }
2357     ;
2358
2359 ComprehensionIf
2360     : "if" "(" AssignmentExpression ")" { $$ = CYNew CYIfComprehension($3); }
2361     ;
2362 /* }}} */
2363 /* JavaScript FTW: Coalesce Operator {{{ */
2364 ConditionalExpression
2365     : LogicalORExpression "?" LexPushInOff LexSetRegExp ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $1, $7); }
2366     ;
2367 /* }}} */
2368 /* JavaScript FTW: Named Arguments {{{ */
2369 ArgumentList
2370     : LexSetRegExp Word ":" AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument($2, $4, $5); }
2371     ;
2372 /* }}} */
2373 /* JavaScript FTW: Ruby Blocks {{{ */
2374 RubyProcParameterList_
2375     : "," RubyProcParameterList { $$ = $2; }
2376     | { $$ = NULL; }
2377     ;
2378
2379 RubyProcParameterList
2380     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
2381     | { $$ = NULL; }
2382     ;
2383
2384 RubyProcParameters
2385     : LexSetRegExp "|" RubyProcParameterList "|" { $$ = $3; }
2386     | LexSetRegExp "||" { $$ = NULL; }
2387     ;
2388
2389 RubyProcParametersOpt
2390     : RubyProcParameters { $$ = $1; }
2391     | { $$ = NULL; }
2392     ;
2393
2394 RubyProcExpression
2395     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
2396     ;
2397
2398 PrimaryExpression
2399     : BRACE LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
2400     ;
2401
2402 PostfixExpression
2403     : PostfixExpression RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
2404     ;
2405 /* }}} */
2406
2407 %%
2408
2409 bool CYDriver::Parse(CYMark mark) {
2410     mark_ = mark;
2411     CYLocal<CYPool> local(&pool_);
2412     cy::parser parser(*this);
2413 #ifdef YYDEBUG
2414     parser.set_debug_level(debug_);
2415 #endif
2416     return parser.parse() != 0;
2417 }
2418
2419 void CYDriver::Warning(const cy::parser::location_type &location, const char *message) {
2420     if (!strict_)
2421         return;
2422
2423     CYDriver::Error error;
2424     error.warning_ = true;
2425     error.location_ = location;
2426     error.message_ = message;
2427     errors_.push_back(error);
2428 }
2429
2430 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
2431     CYDriver::Error error;
2432     error.warning_ = false;
2433     error.location_ = location;
2434     error.message_ = message;
2435     driver.errors_.push_back(error);
2436 }