Parser.ypp.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 %code top {
  23 #define YYSTACKEXPANDABLE 1
  24 }
  25
  26 %code requires {
  27 #include "Driver.hpp"
  28 #include "Parser.hpp"
  29 #include "Stack.hpp"
  30 #define CYNew new(driver.pool_)
  31
  32 @begin ObjectiveC
  33 #include "ObjectiveC/Syntax.hpp"
  34 @end
  35
  36 @begin E4X
  37 #include "E4X/Syntax.hpp"
  38 @end
  39
  40 #include "Highlight.hpp"
  41 }
  42
  43 %union { bool bool_; }
  44
  45 %union { CYMember *access_; }
  46 %union { CYArgument *argument_; }
  47 %union { CYAssignment *assignment_; }
  48 %union { CYBoolean *boolean_; }
  49 %union { CYClause *clause_; }
  50 %union { cy::Syntax::Catch *catch_; }
  51 %union { CYClassTail *classTail_; }
  52 %union { CYComprehension *comprehension_; }
  53 %union { CYDeclaration *declaration_; }
  54 %union { CYDeclarations *declarations_; }
  55 %union { CYElement *element_; }
  56 %union { CYExpression *expression_; }
  57 %union { CYFalse *false_; }
  58 %union { CYVariable *variable_; }
  59 %union { CYFinally *finally_; }
  60 %union { CYForInitializer *for_; }
  61 %union { CYForInInitializer *forin_; }
  62 %union { CYFunctionParameter *functionParameter_; }
  63 %union { CYIdentifier *identifier_; }
  64 %union { CYInfix *infix_; }
  65 %union { CYLiteral *literal_; }
  66 %union { CYMethod *method_; }
  67 %union { CYModule *module_; }
  68 %union { CYNull *null_; }
  69 %union { CYNumber *number_; }
  70 %union { CYParenthetical *parenthetical_; }
  71 %union { CYProperty *property_; }
  72 %union { CYPropertyName *propertyName_; }
  73 %union { CYRubyProc *rubyProc_; }
  74 %union { CYSpan *span_; }
  75 %union { CYStatement *statement_; }
  76 %union { CYString *string_; }
  77 %union { CYThis *this_; }
  78 %union { CYTrue *true_; }
  79 %union { CYWord *word_; }
  80
  81 @begin C
  82 %union { CYTypeModifier *modifier_; }
  83 %union { CYTypeSpecifier *specifier_; }
  84 %union { CYTypedIdentifier *typedIdentifier_; }
  85 %union { CYTypedParameter *typedParameter_; }
  86 @end
  87
  88 @begin ObjectiveC
  89 %union { CYMessage *message_; }
  90 %union { CYMessageParameter *messageParameter_; }
  91 %union { CYImplementationField *implementationField_; }
  92 %union { CYProtocol *protocol_; }
  93 %union { CYSelectorPart *selector_; }
  94 @end
  95
  96 @begin E4X
  97 %union { CYAttribute *attribute_; }
  98 %union { CYPropertyIdentifier *propertyIdentifier_; }
  99 %union { CYSelector *selector_; }
 100 @end
 101
 102 %code provides {
 103
 104 struct YYSTYPE {
 105     cy::parser::semantic_type semantic_;
 106     hi::Value highlight_;
 107 };
 108
 109 int cylex(YYSTYPE *, CYLocation *, void *);
 110
 111 }
 112
 113 %code {
 114
 115 #undef yylex
 116 _finline int yylex(cy::parser::semantic_type *semantic, CYLocation *location, CYDriver &driver) {
 117     if (driver.mark_ == CYMarkIgnore);
 118     else if (driver.mark_ == CYMarkScript) {
 119         driver.mark_ = CYMarkIgnore;
 120         return cy::parser::token::MarkScript;
 121     } else if (driver.mark_ == CYMarkModule) {
 122         driver.mark_ = CYMarkIgnore;
 123         return cy::parser::token::MarkModule;
 124     }
 125
 126     YYSTYPE data;
 127     int token(cylex(&data, location, driver.scanner_));
 128     *semantic = data.semantic_;
 129     return token;
 130 }
 131
 132 #define CYMAP(to, from) do { \
 133     if (yyla.empty()) \
 134         yyla.type = yytranslate_(yylex(&yyla.value, &yyla.location, driver)); \
 135     if (yyla.type == yytranslate_(token::from)) \
 136         yyla.type = yytranslate_(token::to); \
 137 } while (false)
 138
 139 #define CYERR(location, message) do { \
 140     error(location, message); \
 141     YYABORT; \
 142 } while (false)
 143
 144 #define CYNOT(location) \
 145     CYERR(location, "unimplemented feature")
 146
 147 }
 148
 149 %name-prefix "cy"
 150
 151 %language "C++"
 152
 153 %initial-action {
 154     @$.begin.filename = @$.end.filename = &driver.filename_;
 155 };
 156
 157 %locations
 158 %defines
 159
 160 %define api.location.type { CYLocation }
 161
 162 //%glr-parser
 163 //%expect 1
 164
 165 %error-verbose
 166
 167 %param { CYDriver &driver }
 168
 169 /* Token Declarations {{{ */
 170 @begin E4X
 171 %token XMLCDATA
 172 %token XMLComment
 173 %token XMLPI
 174
 175 %token XMLAttributeValue
 176 %token XMLName
 177 %token XMLTagCharacters
 178 %token XMLText
 179 %token XMLWhitespace
 180 @end
 181
 182 @begin E4X
 183 %token LeftRight "<>"
 184 %token LeftSlashRight "</>"
 185
 186 %token SlashRight "/>"
 187 %token LeftSlash "</"
 188
 189 %token ColonColon "::"
 190 %token PeriodPeriod ".."
 191 @end
 192
 193 @begin E4X ObjectiveC
 194 %token At "@"
 195 %token Pound "#"
 196 @end
 197
 198 %token Ampersand "&"
 199 %token AmpersandAmpersand "&&"
 200 %token AmpersandEqual "&="
 201 %token Carrot "^"
 202 %token CarrotEqual "^="
 203 %token Equal "="
 204 %token EqualEqual "=="
 205 %token EqualEqualEqual "==="
 206 %token EqualRight "=>"
 207 %token EqualRight_ "\n=>"
 208 %token Exclamation "!"
 209 %token ExclamationEqual "!="
 210 %token ExclamationEqualEqual "!=="
 211 %token Hyphen "-"
 212 %token HyphenEqual "-="
 213 %token HyphenHyphen "--"
 214 %token HyphenHyphen_ "\n--"
 215 %token HyphenRight "->"
 216 %token Left "<"
 217 %token LeftEqual "<="
 218 %token LeftLeft "<<"
 219 %token LeftLeftEqual "<<="
 220 %token Percent "%"
 221 %token PercentEqual "%="
 222 %token Period "."
 223 %token PeriodPeriodPeriod "..."
 224 %token Pipe "|"
 225 %token PipeEqual "|="
 226 %token PipePipe "||"
 227 %token Plus "+"
 228 %token PlusEqual "+="
 229 %token PlusPlus "++"
 230 %token PlusPlus_ "\n++"
 231 %token Right ">"
 232 %token RightEqual ">="
 233 %token RightRight ">>"
 234 %token RightRightEqual ">>="
 235 %token RightRightRight ">>>"
 236 %token RightRightRightEqual ">>>="
 237 %token Slash "/"
 238 %token SlashEqual "/="
 239 %token Star "*"
 240 %token StarEqual "*="
 241 %token Tilde "~"
 242
 243 %token Colon ":"
 244 %token Comma ","
 245 %token Question "?"
 246 %token SemiColon ";"
 247 %token NewLine "\n"
 248
 249 %token Comment
 250
 251 %token OpenParen "("
 252 %token CloseParen ")"
 253
 254 %token OpenBrace "{"
 255 %token OpenBrace_ "\n{"
 256 %token OpenBrace__ ";{"
 257 %token CloseBrace "}"
 258
 259 %token OpenBracket "["
 260 %token CloseBracket "]"
 261
 262 %token At_error_ "@error"
 263
 264 @begin Java
 265 %token At_class_ "@class"
 266 @end
 267
 268 @begin C
 269 %token _typedef_ "typedef"
 270 %token _unsigned_ "unsigned"
 271 %token _signed_ "signed"
 272 %token _extern_ "extern"
 273 @end
 274
 275 @begin C
 276 %token At_encode_ "@encode"
 277 @end
 278
 279 @begin ObjectiveC
 280 %token At_implementation_ "@implementation"
 281 %token At_import_ "@import"
 282 %token At_end_ "@end"
 283 %token At_selector_ "@selector"
 284 %token At_null_ "@null"
 285 %token At_YES_ "@YES"
 286 %token At_NO_ "@NO"
 287 %token At_true_ "@true"
 288 %token At_false_ "@false"
 289 %token _YES_ "YES"
 290 %token _NO_ "NO"
 291 @end
 292
 293 %token _false_ "false"
 294 %token _null_ "null"
 295 %token _true_ "true"
 296
 297 %token _break_ "break"
 298 %token _case_ "case"
 299 %token _catch_ "catch"
 300 %token _class_ "class"
 301 %token _class__ ";class"
 302 %token _const_ "const"
 303 %token _continue_ "continue"
 304 %token _debugger_ "debugger"
 305 %token _default_ "default"
 306 %token _delete_ "delete"
 307 %token _do_ "do"
 308 %token _else_ "else"
 309 %token _enum_ "enum"
 310 %token _export_ "export"
 311 %token _extends_ "extends"
 312 %token _finally_ "finally"
 313 %token _for_ "for"
 314 %token _function_ "function"
 315 %token _function__ ";function"
 316 %token _if_ "if"
 317 %token _import_ "import"
 318 %token _in_ "in"
 319 %token _in__ "!in"
 320 %token _instanceof_ "instanceof"
 321 %token _new_ "new"
 322 %token _return_ "return"
 323 %token _return__ "!return"
 324 %token _super_ "super"
 325 %token _super__ "!super"
 326 %token _switch_ "switch"
 327 %token _this_ "this"
 328 %token _throw_ "throw"
 329 %token _try_ "try"
 330 %token _typeof_ "typeof"
 331 %token _var_ "var"
 332 %token _void_ "void"
 333 %token _while_ "while"
 334 %token _with_ "with"
 335
 336 %token _abstract_ "abstract"
 337 %token _await_ "await"
 338 %token _boolean_ "boolean"
 339 %token _byte_ "byte"
 340 %token _char_ "char"
 341 %token _constructor_ "constructor"
 342 %token _double_ "double"
 343 %token _final_ "final"
 344 %token _float_ "float"
 345 %token _from_ "from"
 346 %token _get_ "get"
 347 %token _goto_ "goto"
 348 %token _implements_ "implements"
 349 %token _int_ "int"
 350 %token _interface_ "interface"
 351 %token _let_ "let"
 352 %token _long_ "long"
 353 %token _native_ "native"
 354 %token _package_ "package"
 355 %token _private_ "private"
 356 %token _protected_ "protected"
 357 %token _prototype_ "prototype"
 358 %token _public_ "public"
 359 %token _set_ "set"
 360 %token _short_ "short"
 361 %token _static_ "static"
 362 %token _synchronized_ "synchronized"
 363 %token _throws_ "throws"
 364 %token _transient_ "transient"
 365 %token _volatile_ "volatile"
 366 %token _yield_ "yield"
 367 %token _yield__ "!yield"
 368
 369 %token _undefined_ "undefined"
 370
 371 @begin ObjectiveC
 372 %token _bool_ "bool"
 373 %token _BOOL_ "BOOL"
 374 %token _id_ "id"
 375 %token _nil_ "nil"
 376 %token _NULL_ "NULL"
 377 %token _SEL_ "SEL"
 378 @end
 379
 380 %token _auto_ "auto"
 381 %token _each_ "each"
 382 %token _of_ "of"
 383
 384 @begin E4X
 385 %token _namespace_ "namespace"
 386 %token _xml_ "xml"
 387 @end
 388
 389 %token AutoComplete
 390 %token YieldStar
 391
 392 %token <identifier_> Identifier_
 393 %token <number_> NumericLiteral
 394 %token <string_> StringLiteral
 395 %token <literal_> RegularExpressionLiteral
 396
 397 %token <string_> NoSubstitutionTemplate
 398 %token <string_> TemplateHead
 399 %token <string_> TemplateMiddle
 400 %token <string_> TemplateTail
 401
 402 %type <expression_> AdditiveExpression
 403 %type <argument_> ArgumentList_
 404 %type <argument_> ArgumentList
 405 %type <argument_> ArgumentListOpt
 406 %type <argument_> Arguments
 407 %type <expression_> ArrayComprehension
 408 %type <literal_> ArrayLiteral
 409 %type <expression_> ArrowFunction
 410 %type <functionParameter_> ArrowParameters
 411 %type <expression_> AssignmentExpression
 412 %type <expression_> AssignmentExpressionOpt
 413 %type <identifier_> BindingIdentifier
 414 %type <identifier_> BindingIdentifierOpt
 415 %type <declarations_> BindingList_
 416 %type <declarations_> BindingList
 417 %type <expression_> BitwiseANDExpression
 418 %type <statement_> Block
 419 %type <statement_> BlockStatement
 420 %type <boolean_> BooleanLiteral
 421 %type <declaration_> BindingElement
 422 %type <expression_> BitwiseORExpression
 423 %type <expression_> BitwiseXORExpression
 424 %type <statement_> BreakStatement
 425 %type <statement_> BreakableStatement
 426 %type <expression_> CallExpression_
 427 %type <expression_> CallExpression
 428 %type <clause_> CaseBlock
 429 %type <clause_> CaseClause
 430 %type <clause_> CaseClausesOpt
 431 %type <catch_> Catch
 432 %type <identifier_> CatchParameter
 433 %type <statement_> ClassDeclaration
 434 %type <expression_> ClassExpression
 435 %type <classTail_> ClassHeritage
 436 %type <classTail_> ClassHeritageOpt
 437 %type <classTail_> ClassTail
 438 %type <expression_> Comprehension
 439 %type <comprehension_> ComprehensionFor
 440 %type <comprehension_> ComprehensionIf
 441 %type <comprehension_> ComprehensionTail
 442 %type <propertyName_> ComputedPropertyName
 443 %type <expression_> ConditionalExpression
 444 %type <statement_> ContinueStatement
 445 %type <statement_> ConciseBody
 446 %type <parenthetical_> CoverParenthesizedExpressionAndArrowParameterList
 447 %type <statement_> DebuggerStatement
 448 %type <statement_> Declaration__
 449 %type <statement_> Declaration_
 450 %type <statement_> Declaration
 451 %type <clause_> DefaultClause
 452 %type <element_> ElementList
 453 %type <element_> ElementListOpt
 454 %type <statement_> ElseStatementOpt
 455 %type <statement_> EmptyStatement
 456 %type <expression_> EqualityExpression
 457 %type <expression_> Expression
 458 %type <expression_> ExpressionOpt
 459 %type <statement_> ExpressionStatement
 460 %type <finally_> Finally
 461 %type <declaration_> ForBinding
 462 %type <declaration_> ForDeclaration
 463 %type <forin_> ForInStatementInitializer
 464 %type <for_> ForStatementInitializer
 465 %type <declaration_> FormalParameter
 466 %type <functionParameter_> FormalParameterList_
 467 %type <functionParameter_> FormalParameterList
 468 %type <functionParameter_> FormalParameters
 469 %type <statement_> FunctionBody
 470 %type <statement_> FunctionDeclaration
 471 %type <expression_> FunctionExpression
 472 %type <statement_> FunctionStatementList
 473 %type <statement_> GeneratorBody
 474 %type <statement_> GeneratorDeclaration
 475 %type <expression_> GeneratorExpression
 476 %type <method_> GeneratorMethod
 477 %type <statement_> HoistableDeclaration
 478 %type <identifier_> Identifier
 479 %type <identifier_> IdentifierType
 480 %type <word_> IdentifierName
 481 %type <variable_> IdentifierReference
 482 %type <statement_> IfStatement
 483 %type <expression_> Initializer
 484 %type <expression_> InitializerOpt
 485 %type <statement_> IterationStatement
 486 %type <identifier_> LabelIdentifier
 487 %type <statement_> LabelledItem
 488 %type <statement_> LabelledStatement
 489 %type <expression_> LeftHandSideExpression
 490 %type <statement_> LetStatement
 491 %type <declaration_> LexicalBinding
 492 %type <statement_> LexicalDeclaration
 493 %type <literal_> Literal
 494 %type <propertyName_> LiteralPropertyName
 495 %type <expression_> LogicalANDExpression
 496 %type <expression_> LogicalORExpression
 497 %type <access_> MemberAccess
 498 %type <expression_> MemberExpression
 499 %type <method_> MethodDefinition
 500 %type <module_> ModulePath
 501 %type <expression_> MultiplicativeExpression
 502 %type <expression_> NewExpression
 503 %type <null_> NullLiteral
 504 %type <literal_> ObjectLiteral
 505 %type <expression_> PostfixExpression
 506 %type <expression_> PrimaryExpression
 507 %type <propertyName_> PropertyName
 508 %type <property_> PropertyDefinition
 509 %type <property_> PropertyDefinitionList_
 510 %type <property_> PropertyDefinitionList
 511 %type <property_> PropertyDefinitionListOpt
 512 %type <declaration_> PropertySetParameterList
 513 %type <expression_> RelationalExpression
 514 %type <statement_> ReturnStatement
 515 %type <rubyProc_> RubyProcExpression
 516 %type <functionParameter_> RubyProcParameterList_
 517 %type <functionParameter_> RubyProcParameterList
 518 %type <functionParameter_> RubyProcParameters
 519 %type <functionParameter_> RubyProcParametersOpt
 520 %type <statement_> Script
 521 %type <statement_> ScriptBody
 522 %type <statement_> ScriptBodyOpt
 523 %type <expression_> ShiftExpression
 524 %type <declaration_> SingleNameBinding
 525 %type <statement_> Statement__
 526 %type <statement_> Statement_
 527 %type <statement_> Statement
 528 %type <statement_> StatementList
 529 %type <statement_> StatementListOpt
 530 %type <statement_> StatementListItem
 531 %type <functionParameter_> StrictFormalParameters
 532 %type <expression_> SuperCall
 533 %type <expression_> SuperProperty
 534 %type <statement_> SwitchStatement
 535 %type <expression_> TemplateLiteral
 536 %type <span_> TemplateSpans
 537 %type <statement_> ThrowStatement
 538 %type <statement_> TryStatement
 539 %type <expression_> UnaryExpression_
 540 %type <expression_> UnaryExpression
 541 %type <declaration_> VariableDeclaration
 542 %type <declarations_> VariableDeclarationList_
 543 %type <declarations_> VariableDeclarationList
 544 %type <statement_> VariableStatement
 545 %type <statement_> WithStatement
 546 %type <word_> Word
 547 @begin ObjectiveC
 548 %type <word_> WordOpt
 549 @end
 550 %type <expression_> YieldExpression
 551
 552 @begin C
 553 %type <specifier_> IntegerType
 554 %type <specifier_> IntegerTypeOpt
 555 %type <typedIdentifier_> PrefixedType
 556 %type <specifier_> PrimitiveType
 557 %type <typedIdentifier_> SuffixedType
 558 %type <typedIdentifier_> TypeSignifier
 559 %type <modifier_> TypeQualifierLeft
 560 %type <typedIdentifier_> TypeQualifierRight
 561 %type <typedIdentifier_> TypedIdentifier
 562 %type <typedParameter_> TypedParameterList_
 563 %type <typedParameter_> TypedParameterList
 564 %type <typedParameter_> TypedParameterListOpt
 565 @end
 566
 567 @begin ObjectiveC
 568 %type <expression_> BoxableExpression
 569 %type <statement_> CategoryStatement
 570 %type <expression_> ClassSuperOpt
 571 %type <implementationField_> ImplementationFieldListOpt
 572 %type <implementationField_> ImplementationFields
 573 %type <message_> ClassMessageDeclaration
 574 %type <message_> ClassMessageDeclarationListOpt
 575 %type <protocol_> ClassProtocolListOpt
 576 %type <protocol_> ClassProtocols
 577 %type <protocol_> ClassProtocolsOpt
 578 %type <statement_> ImplementationStatement
 579 %type <expression_> MessageExpression
 580 %type <messageParameter_> MessageParameter
 581 %type <messageParameter_> MessageParameters
 582 %type <messageParameter_> MessageParameterList
 583 %type <messageParameter_> MessageParameterListOpt
 584 %type <bool_> MessageScope
 585 %type <argument_> SelectorCall_
 586 %type <argument_> SelectorCall
 587 %type <selector_> SelectorExpression_
 588 %type <selector_> SelectorExpression
 589 %type <selector_> SelectorExpressionOpt
 590 %type <argument_> SelectorList
 591 %type <word_> SelectorWordOpt
 592 %type <typedIdentifier_> TypeOpt
 593 %type <argument_> VariadicCall
 594 @end
 595
 596 @begin E4X
 597 %type <propertyIdentifier_> PropertyIdentifier_
 598 %type <selector_> PropertySelector_
 599 %type <selector_> PropertySelector
 600 %type <identifier_> QualifiedIdentifier_
 601 %type <identifier_> QualifiedIdentifier
 602 %type <identifier_> WildcardIdentifier
 603 %type <identifier_> XMLComment
 604 %type <identifier_> XMLCDATA
 605 %type <identifier_> XMLElement
 606 %type <identifier_> XMLElementContent
 607 %type <identifier_> XMLMarkup
 608 %type <identifier_> XMLPI
 609
 610 %type <attribute_> AttributeIdentifier
 611 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 612 %type <expression_> PropertyIdentifier
 613 %type <expression_> XMLListInitialiser
 614 %type <expression_> XMLInitialiser
 615 @end
 616 /* }}} */
 617 /* Token Priorities {{{ */
 618 %nonassoc ""
 619 %left "++" "--" "{"
 620
 621 %nonassoc "if"
 622 %nonassoc "else"
 623 /* }}} */
 624
 625 %start Program
 626 %token MarkModule
 627 %token MarkScript
 628
 629 %%
 630
 631 Program
 632     : MarkScript Script
 633     | MarkModule Module
 634     ;
 635
 636 /* Lexer State {{{ */
 637 LexPushInOn: { driver.in_.push(true); };
 638 LexPushInOff: { driver.in_.push(false); };
 639 LexPopIn: { driver.in_.pop(); };
 640
 641 LexPushReturnOn: { driver.return_.push(true); };
 642 LexPopReturn: { driver.return_.pop(); };
 643
 644 LexPushSuperOn: { driver.super_.push(true); };
 645 LexPushSuperOff: { driver.super_.push(false); };
 646 LexPopSuper: { driver.super_.pop(); };
 647
 648 LexPushYieldOn: { driver.yield_.push(true); };
 649 LexPushYieldOff: { driver.yield_.push(false); };
 650 LexPopYield: { driver.yield_.pop(); };
 651
 652 LexSetRegExp
 653     : { driver.SetCondition(CYDriver::RegExpCondition); }
 654     ;
 655
 656 LexNewLine
 657     : { if (!yyla.empty() && yyla.type_get() != yyeof_) CYERR(@$, "unexpected lookahead"); driver.next_ = true; }
 658     ;
 659
 660 LexNoStar
 661     : { CYMAP(YieldStar, Star); }
 662     ;
 663
 664 LexNoBrace
 665     : { CYMAP(OpenBrace__, OpenBrace); CYMAP(OpenBrace__, OpenBrace_); }
 666     ;
 667
 668 LexNoClass
 669     : { CYMAP(_class__, _class_); }
 670     ;
 671
 672 LexNoFunction
 673     : { CYMAP(_function__, _function_); }
 674     ;
 675
 676 LexSetStatement
 677     : LexNoBrace LexNoClass LexNoFunction
 678     ;
 679 /* }}} */
 680 /* Virtual Tokens {{{ */
 681 BRACE
 682     : "{"
 683     | "\n{"
 684     ;
 685
 686 Var_
 687     : "var"
 688     ;
 689 /* }}} */
 690
 691 /* 11.6 Names and Keywords {{{ */
 692 IdentifierName
 693     : Word { $$ = $1; }
 694     | "for" { $$ = CYNew CYWord("for"); }
 695     | "in" { $$ = CYNew CYWord("in"); }
 696     | "instanceof" { $$ = CYNew CYWord("instanceof"); }
 697     ;
 698
 699 NewLineOpt
 700     : "\n"
 701     |
 702     ;
 703
 704 Word
 705     : Identifier { $$ = $1; }
 706     | "auto" { $$ = CYNew CYWord("auto"); }
 707     | "break" { $$ = CYNew CYWord("break"); }
 708     | "case" { $$ = CYNew CYWord("case"); }
 709     | "catch" { $$ = CYNew CYWord("catch"); }
 710     | "class" { $$ = CYNew CYWord("class"); }
 711     | ";class" { $$ = CYNew CYWord("class"); }
 712     | "const" { $$ = CYNew CYWord("const"); }
 713     | "continue" { $$ = CYNew CYWord("continue"); }
 714     | "debugger" { $$ = CYNew CYWord("debugger"); }
 715     | "default" { $$ = CYNew CYWord("default"); }
 716     | "delete" LexSetRegExp { $$ = CYNew CYWord("delete"); }
 717     | "do" { $$ = CYNew CYWord("do"); }
 718     | "else" { $$ = CYNew CYWord("else"); }
 719     | "enum" { $$ = CYNew CYWord("enum"); }
 720     | "export" { $$ = CYNew CYWord("export"); }
 721     | "extends" { $$ = CYNew CYWord("extends"); }
 722     | "false" { $$ = CYNew CYWord("false"); }
 723     | "finally" { $$ = CYNew CYWord("finally"); }
 724     | "function" { $$ = CYNew CYWord("function"); }
 725     | "if" { $$ = CYNew CYWord("if"); }
 726     | "import" { $$ = CYNew CYWord("import"); }
 727     | "!in" { $$ = CYNew CYWord("in"); }
 728     | "new" LexSetRegExp { $$ = CYNew CYWord("new"); }
 729     | "null" { $$ = CYNew CYWord("null"); }
 730     | "return" { $$ = CYNew CYWord("return"); }
 731     | "!return" { $$ = CYNew CYWord("return"); }
 732     | "super" { $$ = CYNew CYWord("super"); }
 733     | "!super" { $$ = CYNew CYWord("super"); }
 734     | "switch" { $$ = CYNew CYWord("switch"); }
 735     | "this" { $$ = CYNew CYWord("this"); }
 736     | "throw" { $$ = CYNew CYWord("throw"); }
 737     | "true" { $$ = CYNew CYWord("true"); }
 738     | "try" { $$ = CYNew CYWord("try"); }
 739     | "typeof" LexSetRegExp { $$ = CYNew CYWord("typeof"); }
 740     | "var" { $$ = CYNew CYWord("var"); }
 741     | "void" LexSetRegExp { $$ = CYNew CYWord("void"); }
 742     | "while" { $$ = CYNew CYWord("while"); }
 743     | "with" { $$ = CYNew CYWord("with"); }
 744     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 745
 746     | Yield LexSetRegExp NewLineOpt { $$ = CYNew CYIdentifier("yield"); }
 747
 748     // XXX: should be Identifier
 749     | "let" { $$ = CYNew CYIdentifier("let"); }
 750     ;
 751
 752 @begin ObjectiveC
 753 WordOpt
 754     : Word { $$ = $1; }
 755     | { $$ = NULL; }
 756     ;
 757 @end
 758 /* }}} */
 759 /* 11.8.1 Null Literals {{{ */
 760 NullLiteral
 761     : "null" { $$ = CYNew CYNull(); }
 762     ;
 763 /* }}} */
 764 /* 11.8.2 Boolean Literals {{{ */
 765 BooleanLiteral
 766     : "true" { $$ = CYNew CYTrue(); }
 767     | "false" { $$ = CYNew CYFalse(); }
 768     ;
 769 /* }}} */
 770
 771 /* 11.9 Automatic Semicolon Insertion {{{ */
 772 StrictSemi
 773     : { driver.Warning(@$, "warning, automatic semi-colon insertion required"); }
 774     ;
 775
 776 TerminatorSoft
 777     : ";"
 778     | "\n" StrictSemi
 779     ;
 780
 781 Terminator
 782     : ";"
 783     | error { if (yyla.type_get() != yyeof_ && yyla.type != yytranslate_(token::CloseBrace) && !driver.newline_) { CYERR(@1, "required semi-colon"); } else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 784     ;
 785
 786 TerminatorOpt
 787     : ";"
 788     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 789     ;
 790 /* }}} */
 791
 792 /* 12.1 Identifiers {{{ */
 793 IdentifierReference
 794     : Identifier { $$ = CYNew CYVariable($1); }
 795     | "yield" { $$ = CYNew CYVariable(CYNew CYIdentifier("yield")); }
 796     ;
 797
 798 BindingIdentifier
 799     : Identifier { $$ = $1; }
 800     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 801     ;
 802
 803 BindingIdentifierOpt
 804     : BindingIdentifier { $$ = $1; }
 805     | { $$ = NULL; }
 806     ;
 807
 808 LabelIdentifier
 809     : Identifier { $$ = $1; }
 810     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 811     ;
 812
 813 IdentifierType
 814     : Identifier_ { $$ = $1; }
 815     | "abstract" { $$ = CYNew CYIdentifier("abstract"); }
 816     | "await" { $$ = CYNew CYIdentifier("await"); }
 817     | "boolean" { $$ = CYNew CYIdentifier("boolean"); }
 818     | "byte" { $$ = CYNew CYIdentifier("byte"); }
 819     | "constructor" { $$ = CYNew CYIdentifier("constructor"); }
 820     | "double" { $$ = CYNew CYIdentifier("double"); }
 821     | "each" { $$ = CYNew CYIdentifier("each"); }
 822     | "final" { $$ = CYNew CYIdentifier("final"); }
 823     | "float" { $$ = CYNew CYIdentifier("float"); }
 824     | "from" { $$ = CYNew CYIdentifier("from"); }
 825     | "get" { $$ = CYNew CYIdentifier("get"); }
 826     | "goto" { $$ = CYNew CYIdentifier("goto"); }
 827     | "implements" { $$ = CYNew CYIdentifier("implements"); }
 828     | "interface" { $$ = CYNew CYIdentifier("interface"); }
 829     | "native" { $$ = CYNew CYIdentifier("native"); }
 830     | "of" { $$ = CYNew CYIdentifier("of"); }
 831     | "package" { $$ = CYNew CYIdentifier("package"); }
 832     | "private" { $$ = CYNew CYIdentifier("private"); }
 833     | "protected" { $$ = CYNew CYIdentifier("protected"); }
 834     | "prototype" { $$ = CYNew CYIdentifier("prototype"); }
 835     | "public" { $$ = CYNew CYIdentifier("public"); }
 836     | "set" { $$ = CYNew CYIdentifier("set"); }
 837     | "synchronized" { $$ = CYNew CYIdentifier("synchronized"); }
 838     | "throws" { $$ = CYNew CYIdentifier("throws"); }
 839     | "transient" { $$ = CYNew CYIdentifier("transient"); }
 840     | "undefined" { $$ = CYNew CYIdentifier("undefined"); }
 841 @begin ObjectiveC
 842     | "bool" { $$ = CYNew CYIdentifier("bool"); }
 843     | "BOOL" { $$ = CYNew CYIdentifier("BOOL"); }
 844     | "id" { $$ = CYNew CYIdentifier("id"); }
 845     | "SEL" { $$ = CYNew CYIdentifier("SEL"); }
 846 @end
 847     ;
 848
 849 Identifier
 850     : IdentifierType
 851     | "char" { $$ = CYNew CYIdentifier("char"); }
 852     | "int" { $$ = CYNew CYIdentifier("int"); }
 853     | "long" { $$ = CYNew CYIdentifier("long"); }
 854     | "short" { $$ = CYNew CYIdentifier("short"); }
 855     | "static" { $$ = CYNew CYIdentifier("static"); }
 856     | "volatile" { $$ = CYNew CYIdentifier("volatile"); }
 857 @begin C
 858     | "extern" { $$ = CYNew CYIdentifier("extern"); }
 859     | "signed" { $$ = CYNew CYIdentifier("signed"); }
 860     | "typedef" { $$ = CYNew CYIdentifier("typedef"); }
 861     | "unsigned" { $$ = CYNew CYIdentifier("unsigned"); }
 862 @end
 863 @begin ObjectiveC
 864     | "nil" { $$ = CYNew CYIdentifier("nil"); }
 865     | "NO" { $$ = CYNew CYIdentifier("NO"); }
 866     | "NULL" { $$ = CYNew CYIdentifier("NULL"); }
 867     | "YES" { $$ = CYNew CYIdentifier("YES"); }
 868 @end
 869     ;
 870 /* }}} */
 871 /* 12.2 Primary Expression {{{ */
 872 PrimaryExpression
 873     : "this" { $$ = CYNew CYThis(); }
 874     | IdentifierReference { $$ = $1; }
 875     | Literal { $$ = $1; }
 876     | ArrayLiteral { $$ = $1; }
 877     | ObjectLiteral { $$ = $1; }
 878     | FunctionExpression { $$ = $1; }
 879     | ClassExpression { $$ = $1; }
 880     | GeneratorExpression { $$ = $1; }
 881     | RegularExpressionLiteral { $$ = $1; }
 882     | TemplateLiteral { $$ = $1; }
 883     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) CYERR(@1, "invalid parenthetical"); $$ = $1; }
 884     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 885     ;
 886
 887 CoverParenthesizedExpressionAndArrowParameterList
 888     : "(" LexPushInOff Expression ")" LexPopIn { $$ = CYNew CYParenthetical($3); }
 889     | "(" LexPushInOff LexSetRegExp ")" LexPopIn { $$ = NULL; }
 890     | "(" LexPushInOff LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 891     | "(" LexPushInOff Expression "," LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 892     ;
 893 /* }}} */
 894 /* 12.2.4 Literals {{{ */
 895 Literal
 896     : NullLiteral { $$ = $1; }
 897     | BooleanLiteral { $$ = $1; }
 898     | NumericLiteral { $$ = $1; }
 899     | StringLiteral { $$ = $1; }
 900     ;
 901 /* }}} */
 902 /* 12.2.5 Array Initializer {{{ */
 903 ArrayLiteral
 904     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 905     ;
 906
 907 ElementList
 908     : AssignmentExpressionOpt "," ElementListOpt { $$ = CYNew CYElementValue($1, $3); }
 909     | LexSetRegExp "..." AssignmentExpression { $$ = CYNew CYElementSpread($3); }
 910     | AssignmentExpression { $$ = CYNew CYElementValue($1, NULL); }
 911     ;
 912
 913 ElementListOpt
 914     : ElementList { $$ = $1; }
 915     | LexSetRegExp { $$ = NULL; }
 916     ;
 917 /* }}} */
 918 /* 12.2.6 Object Initializer {{{ */
 919 ObjectLiteral
 920     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 921     ;
 922
 923 PropertyDefinitionList_
 924     : "," PropertyDefinitionListOpt { $$ = $2; }
 925     | { $$ = NULL; }
 926     ;
 927
 928 PropertyDefinitionList
 929     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 930     ;
 931
 932 PropertyDefinitionListOpt
 933     : LexSetRegExp PropertyDefinitionList { $$ = $2; }
 934     | LexSetRegExp { $$ = NULL; }
 935     ;
 936
 937 PropertyDefinition
 938     : IdentifierReference { $$ = CYNew CYPropertyValue($1->name_, $1); }
 939     | CoverInitializedName { CYNOT(@$); }
 940     | PropertyName ":" AssignmentExpression { $$ = CYNew CYPropertyValue($1, $3); }
 941     | MethodDefinition { $$ = $1; }
 942     ;
 943
 944 PropertyName
 945     : LiteralPropertyName { $$ = $1; }
 946     | ComputedPropertyName { $$ = $1; }
 947     ;
 948
 949 LiteralPropertyName
 950     : IdentifierName { $$ = $1; }
 951     | StringLiteral { $$ = $1; }
 952     | NumericLiteral { $$ = $1; }
 953     ;
 954
 955 ComputedPropertyName
 956     : "[" AssignmentExpression "]" { $$ = CYNew CYComputed($2); }
 957     ;
 958
 959 CoverInitializedName
 960     : IdentifierReference Initializer
 961     ;
 962
 963 Initializer
 964     : "=" AssignmentExpression { $$ = $2; }
 965     ;
 966
 967 InitializerOpt
 968     : Initializer { $$ = $1; }
 969     | { $$ = NULL; }
 970     ;
 971 /* }}} */
 972 /* 12.2.9 Template Literals {{{ */
 973 TemplateLiteral
 974     : NoSubstitutionTemplate { $$ = CYNew CYTemplate($1, NULL); }
 975     | TemplateHead TemplateSpans { $$ = CYNew CYTemplate($1, $2); }
 976     ;
 977
 978 TemplateSpans
 979     : Expression TemplateMiddle TemplateSpans { $$ = CYNew CYSpan($1, $2, $3); }
 980     | Expression TemplateTail { $$ = CYNew CYSpan($1, $2, NULL); }
 981     ;
 982 /* }}} */
 983
 984 /* 12.3 Left-Hand-Side Expressions {{{ */
 985 MemberAccess
 986     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
 987     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 988     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 989     | TemplateLiteral { CYNOT(@$); }
 990     ;
 991
 992 MemberExpression
 993     : LexSetRegExp PrimaryExpression { $$ = $2; }
 994     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 995     | SuperProperty { $$ = $1; }
 996     | MetaProperty { CYNOT(@$); }
 997     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 998     ;
 999
1000 SuperProperty
1001     : LexSetRegExp "!super" "[" Expression "]" { $$ = CYNew CYSuperAccess($4); }
1002     | LexSetRegExp "!super" "." IdentifierName { $$ = CYNew CYSuperAccess(CYNew CYString($4)); }
1003     ;
1004
1005 MetaProperty
1006     : NewTarget
1007     ;
1008
1009 NewTarget
1010     : LexSetRegExp "new" LexSetRegExp "." "target"
1011     ;
1012
1013 NewExpression
1014     : MemberExpression { $$ = $1; }
1015     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
1016     ;
1017
1018 CallExpression_
1019     : MemberExpression
1020     | CallExpression
1021     ;
1022
1023 CallExpression
1024     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
1025     | SuperCall { $$ = $1; }
1026     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1027     ;
1028
1029 SuperCall
1030     : LexSetRegExp "!super" Arguments { $$ = CYNew CYSuperCall($3); }
1031     ;
1032
1033 Arguments
1034     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
1035     ;
1036
1037 ArgumentList_
1038     : "," ArgumentList { $$ = $2; }
1039     | { $$ = NULL; }
1040     ;
1041
1042 ArgumentList
1043     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
1044     | LexSetRegExp "..." AssignmentExpression { CYNOT(@$); }
1045     ;
1046
1047 ArgumentListOpt
1048     : ArgumentList { $$ = $1; }
1049     | LexSetRegExp { $$ = NULL; }
1050     ;
1051
1052 LeftHandSideExpression
1053     : NewExpression { $$ = $1; }
1054     | CallExpression { $$ = $1; }
1055     ;
1056 /* }}} */
1057 /* 12.4 Postfix Expressions {{{ */
1058 PostfixExpression
1059     : %prec "" LeftHandSideExpression { $$ = $1; }
1060     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
1061     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
1062     ;
1063 /* }}} */
1064 /* 12.5 Unary Operators {{{ */
1065 UnaryExpression_
1066     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
1067     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
1068     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
1069     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1070     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1071     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1072     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1073     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
1074     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
1075     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
1076     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
1077     ;
1078
1079 UnaryExpression
1080     : %prec "" PostfixExpression { $$ = $1; }
1081     | LexSetRegExp UnaryExpression_ { $$ = $2; }
1082     ;
1083 /* }}} */
1084 /* 12.6 Multiplicative Operators {{{ */
1085 MultiplicativeExpression
1086     : UnaryExpression { $$ = $1; }
1087     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
1088     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
1089     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
1090     ;
1091 /* }}} */
1092 /* 12.7 Additive Operators {{{ */
1093 AdditiveExpression
1094     : MultiplicativeExpression { $$ = $1; }
1095     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
1096     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
1097     ;
1098 /* }}} */
1099 /* 12.8 Bitwise Shift Operators {{{ */
1100 ShiftExpression
1101     : AdditiveExpression { $$ = $1; }
1102     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
1103     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
1104     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
1105     ;
1106 /* }}} */
1107 /* 12.9 Relational Operators {{{ */
1108 RelationalExpression
1109     : ShiftExpression { $$ = $1; }
1110     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
1111     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
1112     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
1113     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
1114     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
1115     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
1116     ;
1117 /* }}} */
1118 /* 12.10 Equality Operators {{{ */
1119 EqualityExpression
1120     : RelationalExpression { $$ = $1; }
1121     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1122     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1123     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1124     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1125     ;
1126 /* }}} */
1127 /* 12.11 Binary Bitwise Operators {{{ */
1128 BitwiseANDExpression
1129     : EqualityExpression { $$ = $1; }
1130     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1131     ;
1132
1133 BitwiseXORExpression
1134     : BitwiseANDExpression { $$ = $1; }
1135     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1136     ;
1137
1138 BitwiseORExpression
1139     : BitwiseXORExpression { $$ = $1; }
1140     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1141     ;
1142 /* }}} */
1143 /* 12.12 Binary Logical Operators {{{ */
1144 LogicalANDExpression
1145     : BitwiseORExpression { $$ = $1; }
1146     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1147     ;
1148
1149 LogicalORExpression
1150     : LogicalANDExpression { $$ = $1; }
1151     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1152     ;
1153 /* }}} */
1154 /* 12.13 Conditional Operator ( ? : ) {{{ */
1155 ConditionalExpression
1156     : LogicalORExpression { $$ = $1; }
1157     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1158     ;
1159 /* }}} */
1160 /* 12.14 Assignment Operators {{{ */
1161 AssignmentExpression
1162     : ConditionalExpression { $$ = $1; }
1163     | LexSetRegExp YieldExpression { $$ = $2; }
1164     | ArrowFunction { $$ = $1; }
1165     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
1166     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
1167     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
1168     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
1169     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
1170     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
1171     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
1172     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1173     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1174     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1175     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1176     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1177     ;
1178
1179 AssignmentExpressionOpt
1180     : AssignmentExpression { $$ = $1; }
1181     | LexSetRegExp { $$ = NULL; }
1182     ;
1183 /* }}} */
1184 /* 12.15 Comma Operator ( , ) {{{ */
1185 Expression
1186     : AssignmentExpression { $$ = $1; }
1187     | Expression "," AssignmentExpression { $$ = CYNew CYCompound($1, $3); }
1188     ;
1189
1190 ExpressionOpt
1191     : Expression { $$ = $1; }
1192     | LexSetRegExp { $$ = NULL; }
1193     ;
1194 /* }}} */
1195
1196 /* 13 Statements and Declarations {{{ */
1197 Statement__
1198     : BlockStatement { $$ = $1; }
1199     | VariableStatement { $$ = $1; }
1200     | EmptyStatement { $$ = $1; }
1201     | IfStatement { $$ = $1; }
1202     | BreakableStatement { $$ = $1; }
1203     | ContinueStatement { $$ = $1; }
1204     | BreakStatement { $$ = $1; }
1205     | ReturnStatement { $$ = $1; }
1206     | WithStatement { $$ = $1; }
1207     | LabelledStatement { $$ = $1; }
1208     | ThrowStatement { $$ = $1; }
1209     | TryStatement { $$ = $1; }
1210     | DebuggerStatement { $$ = $1; }
1211     ;
1212
1213 Statement_
1214     : LexSetRegExp Statement__ { $$ = $2; }
1215     | ExpressionStatement { $$ = $1; }
1216     ;
1217
1218 Statement
1219     : LexSetStatement Statement_ { $$ = $2; }
1220     ;
1221
1222 Declaration__
1223     : HoistableDeclaration { $$ = $1; }
1224     | ClassDeclaration { $$ = $1; }
1225     | LexicalDeclaration { $$ = $1; }
1226     ;
1227
1228 Declaration_
1229     : LexSetRegExp Declaration__ { $$ = $2; }
1230     ;
1231
1232 Declaration
1233     : LexSetStatement Declaration_ { $$ = $2; }
1234     ;
1235
1236 HoistableDeclaration
1237     : FunctionDeclaration { $$ = $1; }
1238     | GeneratorDeclaration { $$ = $1; }
1239     ;
1240
1241 BreakableStatement
1242     : IterationStatement { $$ = $1; }
1243     | SwitchStatement { $$ = $1; }
1244     ;
1245 /* }}} */
1246 /* 13.2 Block {{{ */
1247 BlockStatement
1248     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1249     ;
1250
1251 Block
1252     : BRACE StatementListOpt "}" { $$ = $2; }
1253     ;
1254
1255 StatementList
1256     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1257     ;
1258
1259 StatementListOpt
1260     : StatementList { $$ = $1; }
1261     | LexSetStatement LexSetRegExp { $$ = NULL; }
1262     ;
1263
1264 StatementListItem
1265     : Statement { $$ = $1; }
1266     | Declaration { $$ = $1; }
1267     ;
1268 /* }}} */
1269 /* 13.3 Let and Const Declarations {{{ */
1270 LexicalDeclaration
1271     : LetOrConst BindingList Terminator { $$ = CYNew CYVar($2); }
1272     ;
1273
1274 LetOrConst
1275     : "let"
1276     | "const"
1277     ;
1278
1279 BindingList_
1280     : "," BindingList { $$ = $2; }
1281     | { $$ = NULL; }
1282     ;
1283
1284 BindingList
1285     : LexicalBinding BindingList_ { $$ = CYNew CYDeclarations($1, $2); }
1286     ;
1287
1288 LexicalBinding
1289     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1290     | BindingPattern Initializer { CYNOT(@1); }
1291     ;
1292 /* }}} */
1293 /* 13.3.2 Variable Statement {{{ */
1294 VariableStatement
1295     : Var_ VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1296     ;
1297
1298 VariableDeclarationList_
1299     : "," VariableDeclarationList { $$ = $2; }
1300     | { $$ = NULL; }
1301     ;
1302
1303 VariableDeclarationList
1304     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1305     ;
1306
1307 VariableDeclaration
1308     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1309     | BindingPattern Initializer { CYNOT(@1); }
1310     ;
1311 /* }}} */
1312 /* 13.3.3 Destructuring Binding Patterns {{{ */
1313 BindingPattern
1314     : ObjectBindingPattern
1315     | ArrayBindingPattern
1316     ;
1317
1318 ObjectBindingPattern
1319     : BRACE BindingPropertyListOpt "}"
1320     ;
1321
1322 ArrayBindingPattern
1323     : "[" { CYNOT(@$); }
1324     ;
1325
1326 BindingPropertyList_
1327     : "," BindingPropertyListOpt
1328     |
1329     ;
1330
1331 BindingPropertyList
1332     : BindingProperty BindingPropertyList_
1333     ;
1334
1335 BindingPropertyListOpt
1336     : BindingPropertyList
1337     |
1338     ;
1339
1340 BindingProperty
1341     : SingleNameBinding
1342     | PropertyName ":" BindingElement
1343     ;
1344
1345 BindingElement
1346     : SingleNameBinding { $$ = $1; }
1347     | BindingPattern InitializerOpt { CYNOT(@$); }
1348     ;
1349
1350 SingleNameBinding
1351     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1352     ;
1353
1354 BindingRestElement
1355     : "..." BindingIdentifier
1356     ;
1357 /* }}} */
1358 /* 13.4 Empty Statement {{{ */
1359 EmptyStatement
1360     : ";" { $$ = CYNew CYEmpty(); }
1361     ;
1362 /* }}} */
1363 /* 13.5 Expression Statement {{{ */
1364 ExpressionStatement
1365     : Expression Terminator { $$ = CYNew CYExpress($1); }
1366     ;
1367 /* }}} */
1368 /* 13.6 The if Statement {{{ */
1369 ElseStatementOpt
1370     : "else" Statement { $$ = $2; }
1371     | %prec "if" { $$ = NULL; }
1372     ;
1373
1374 IfStatement
1375     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1376     ;
1377 /* }}} */
1378 /* 13.7 Iteration Statements {{{ */
1379 IterationStatement
1380     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1381     | "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1382     | "for" "(" LexPushInOn ForStatementInitializer ";" LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1383     | "for" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1384     | "for" "(" LexPushInOn ForInStatementInitializer "of" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1385     ;
1386
1387 ForStatementInitializer
1388     : ExpressionOpt { $$ = $1; }
1389     | LexSetRegExp Var_ VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1390     | LexSetRegExp LexicalDeclaration { CYNOT(@$); }
1391     ;
1392
1393 ForInStatementInitializer
1394     : LeftHandSideExpression { $$ = $1; }
1395     | LexSetRegExp Var_ ForBinding { $$ = $3; }
1396     | LexSetRegExp ForDeclaration { $$ = $2; }
1397     ;
1398
1399 ForDeclaration
1400     : LetOrConst ForBinding { $$ = $2; }
1401     ;
1402
1403 ForBinding
1404     : BindingIdentifier { $$ = CYNew CYDeclaration($1, NULL); }
1405     | BindingPattern { CYNOT(@1); }
1406     ;
1407 /* }}} */
1408 /* 13.8 The continue Statement {{{ */
1409 Continue
1410     : "continue" LexNewLine
1411     ;
1412
1413 ContinueStatement
1414     : Continue TerminatorSoft { $$ = CYNew CYContinue(NULL); }
1415     | Continue Identifier Terminator { $$ = CYNew CYContinue($2); }
1416     ;
1417 /* }}} */
1418 /* 13.9 The break Statement {{{ */
1419 Break
1420     : "break" LexNewLine
1421     ;
1422
1423 BreakStatement
1424     : Break TerminatorSoft { $$ = CYNew CYBreak(NULL); }
1425     | Break Identifier Terminator { $$ = CYNew CYBreak($2); }
1426     ;
1427 /* }}} */
1428 /* 13.10 The return Statement {{{ */
1429 Return
1430     : "!return" LexNewLine
1431     ;
1432
1433 ReturnStatement
1434     : Return LexSetRegExp TerminatorSoft { $$ = CYNew CYReturn(NULL); }
1435     | Return Expression Terminator { $$ = CYNew CYReturn($2); }
1436     ;
1437 /* }}} */
1438 /* 13.11 The with Statement {{{ */
1439 WithStatement
1440     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1441     ;
1442 /* }}} */
1443 /* 13.12 The switch Statement {{{ */
1444 SwitchStatement
1445     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1446     ;
1447
1448 CaseBlock
1449     : BRACE CaseClausesOpt "}" { $$ = $2; }
1450     ;
1451
1452 CaseClause
1453     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1454     ;
1455
1456 CaseClausesOpt
1457     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1458     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1459     | { $$ = NULL; }
1460     ;
1461
1462 // XXX: the standard makes certain you can only have one of these
1463 DefaultClause
1464     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1465     ;
1466 /* }}} */
1467 /* 13.13 Labelled Statements {{{ */
1468 LabelledStatement
1469     : LabelIdentifier ":" LabelledItem { $$ = CYNew CYLabel($1, $3); }
1470     ;
1471
1472 LabelledItem
1473     : Statement { $$ = $1; }
1474     | LexSetStatement LexSetRegExp FunctionDeclaration { $$ = $3; }
1475     ;
1476 /* }}} */
1477 /* 13.14 The throw Statement {{{ */
1478 Throw
1479     : "throw" LexNewLine
1480     ;
1481
1482 ThrowStatement
1483     : Throw LexSetRegExp TerminatorSoft { CYERR(@1, "throw without exception"); }
1484     | Throw Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1485     ;
1486 /* }}} */
1487 /* 13.15 The try Statement {{{ */
1488 TryStatement
1489     : "try" Block Catch { $$ = CYNew cy::Syntax::Try($2, $3, NULL); }
1490     | "try" Block Finally { $$ = CYNew cy::Syntax::Try($2, NULL, $3); }
1491     | "try" Block Catch Finally { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1492     ;
1493
1494 Catch
1495     : "catch" "(" CatchParameter ")" Block { $$ = CYNew cy::Syntax::Catch($3, $5); }
1496     ;
1497
1498 Finally
1499     : "finally" Block { $$ = CYNew CYFinally($2); }
1500     ;
1501
1502 CatchParameter
1503     : BindingIdentifier { $$ = $1; }
1504     | BindingPattern { CYNOT(@$); }
1505     ;
1506 /* }}} */
1507 /* 13.16 The debugger Statement {{{ */
1508 DebuggerStatement
1509     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1510     ;
1511 /* }}} */
1512
1513 /* 14.1 Function Definitions {{{ */
1514 FunctionDeclaration
1515     : ";function" BindingIdentifier "(" FormalParameters ")" BRACE LexPushSuperOff FunctionBody "}" LexPopSuper { $$ = CYNew CYFunctionStatement($2, $4, $8); }
1516     ;
1517
1518 FunctionExpression
1519     : "function" BindingIdentifierOpt "(" LexPushInOff FormalParameters ")" LexPopIn BRACE LexPushSuperOff LexPushInOff FunctionBody "}" LexPopIn LexPopSuper { $$ = CYNew CYFunctionExpression($2, $5, $11); }
1520     ;
1521
1522 StrictFormalParameters
1523     : FormalParameters { $$ = $1; }
1524     ;
1525
1526 FormalParameters
1527     : { $$ = NULL; }
1528     | FormalParameterList
1529     ;
1530
1531 FormalParameterList_
1532     : "," FormalParameterList { $$ = $2; }
1533     | { $$ = NULL; }
1534     ;
1535
1536 FormalParameterList
1537     : FunctionRestParameter { CYNOT(@$); }
1538     | FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1539     ;
1540
1541 FunctionRestParameter
1542     : BindingRestElement
1543     ;
1544
1545 FormalParameter
1546     : BindingElement { $$ = $1; }
1547     ;
1548
1549 FunctionBody
1550     : LexPushYieldOff FunctionStatementList LexPopYield { $$ = $2; }
1551     ;
1552
1553 FunctionStatementList
1554     : LexPushReturnOn StatementListOpt LexPopReturn { $$ = $2; }
1555     ;
1556 /* }}} */
1557 /* 14.2 Arrow Function Definitions {{{ */
1558 ArrowFunction
1559     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1560     ;
1561
1562 ArrowParameters
1563     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1564     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) $$ = NULL; else { $$ = $1->expression_->Parameter(); if ($$ == NULL) CYERR(@1, "invalid parameter list"); } }
1565     ;
1566
1567 ConciseBody
1568     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1569     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1570     ;
1571 /* }}} */
1572 /* 14.3 Method Definitions {{{ */
1573 MethodDefinition
1574     : PropertyName "(" StrictFormalParameters ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyMethod($1, $3, $6); }
1575     | GeneratorMethod { $$ = $1; }
1576     | "get" PropertyName "(" ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyGetter($2, $6); }
1577     | "set" PropertyName "(" PropertySetParameterList ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertySetter($2, CYNew CYFunctionParameter($4), $7); }
1578     ;
1579
1580 PropertySetParameterList
1581     : FormalParameter { $$ = $1; }
1582     ;
1583 /* }}} */
1584 /* 14.4 Generator Function Definitions {{{ */
1585 GeneratorMethod
1586     : "*" PropertyName "(" StrictFormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorMethod($2, $4, $7); */ }
1587     ;
1588
1589 GeneratorDeclaration
1590     : ";function" "*" BindingIdentifier "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorStatement($3, $5, $8); */ }
1591     ;
1592
1593 GeneratorExpression
1594     : "function" "*" BindingIdentifierOpt "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorExpression($3, $5, $8); */ }
1595     ;
1596
1597 GeneratorBody
1598     : LexPushYieldOn FunctionStatementList LexPopYield { $$ = $2; }
1599     ;
1600
1601 Yield
1602     : "!yield" LexNewLine LexNoStar
1603     ;
1604
1605 YieldExpression
1606     : Yield LexSetRegExp "\n" { CYNOT(@$); /* $$ = CYNew CYYieldValue(NULL); */ }
1607     | Yield AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldValue($2); */ }
1608     | Yield LexSetRegExp YieldStar AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldGenerator($4); */ }
1609     ;
1610 /* }}} */
1611 /* 14.5 Class Definitions {{{ */
1612 ClassDeclaration
1613     : ";class" BindingIdentifier ClassTail { $$ = CYNew CYClassStatement($2, $3); }
1614     ;
1615
1616 ClassExpression
1617     : "class" BindingIdentifierOpt ClassTail { $$ = CYNew CYClassExpression($2, $3); }
1618     ;
1619
1620 ClassTail
1621     : ClassHeritageOpt { driver.class_.push($1); } BRACE LexPushSuperOn ClassBodyOpt "}" LexPopSuper { driver.class_.pop(); $$ = $1; }
1622     ;
1623
1624 ClassHeritage
1625     : "extends" LeftHandSideExpression { $$ = CYNew CYClassTail($2); }
1626     ;
1627
1628 ClassHeritageOpt
1629     : ClassHeritage { $$ = $1; }
1630     | { $$ = CYNew CYClassTail(NULL); }
1631     ;
1632
1633 ClassBody
1634     : ClassElementList
1635     ;
1636
1637 ClassBodyOpt
1638     : ClassBody
1639     |
1640     ;
1641
1642 ClassElementList
1643     : ClassElementListOpt ClassElement
1644     ;
1645
1646 ClassElementListOpt
1647     : ClassElementList
1648     |
1649     ;
1650
1651 ClassElement
1652     : MethodDefinition { if (CYFunctionExpression *constructor = $1->Constructor()) driver.class_.top()->constructor_ = constructor; else driver.class_.top()->instance_->*$1; }
1653     | "static" MethodDefinition { driver.class_.top()->static_->*$2; }
1654     | ";"
1655     ;
1656 /* }}} */
1657
1658 /* 15.1 Scripts {{{ */
1659 Script
1660     : ScriptBodyOpt { driver.script_ = CYNew CYScript($1); }
1661     ;
1662
1663 ScriptBody
1664     : StatementList { $$ = $1; }
1665     ;
1666
1667 ScriptBodyOpt
1668     : ScriptBody { $$ = $1; }
1669     | LexSetStatement LexSetRegExp { $$ = NULL; }
1670     ;
1671 /* }}} */
1672 /* 15.2 Modules {{{ */
1673 Module
1674     : ModuleBodyOpt
1675     ;
1676
1677 ModuleBody
1678     : ModuleItemList
1679     ;
1680
1681 ModuleBodyOpt
1682     : ModuleBody
1683     |
1684     ;
1685
1686 ModuleItemList
1687     : ModuleItemListOpt ModuleItem
1688     ;
1689
1690 ModuleItemListOpt
1691     : ModuleItemList
1692     |
1693     ;
1694
1695 ModuleItem
1696     : LexSetStatement LexSetRegExp ImportDeclaration
1697     | LexSetStatement LexSetRegExp ExportDeclaration
1698     | StatementListItem
1699     ;
1700 /* }}} */
1701 /* 15.2.2 Imports {{{ */
1702 ImportDeclaration
1703     : "import" ImportClause FromClause Terminator
1704     | "import" ModuleSpecifier Terminator
1705     ;
1706
1707 ImportClause
1708     : ImportedDefaultBinding
1709     | NameSpaceImport
1710     | NamedImports
1711     | ImportedDefaultBinding "," NameSpaceImport
1712     | ImportedDefaultBinding "," NamedImports
1713     ;
1714
1715 ImportedDefaultBinding
1716     : ImportedBinding
1717     ;
1718
1719 NameSpaceImport
1720     : "*" "as" ImportedBinding
1721     ;
1722
1723 NamedImports
1724     : BRACE ImportsListOpt "}"
1725     ;
1726
1727 FromClause
1728     : "from" ModuleSpecifier
1729     ;
1730
1731 ImportsList_
1732     : "," ImportsListOpt
1733     |
1734     ;
1735
1736 ImportsList
1737     : ImportSpecifier ImportsList_
1738     ;
1739
1740 ImportsListOpt
1741     : ImportsList
1742     |
1743     ;
1744
1745 ImportSpecifier
1746     : ImportedBinding
1747     | IdentifierName "as" ImportedBinding
1748     ;
1749
1750 ModuleSpecifier
1751     : StringLiteral
1752     ;
1753
1754 ImportedBinding
1755     : BindingIdentifier
1756     ;
1757 /* }}} */
1758 /* 15.2.3 Exports {{{ */
1759 ExportDeclaration_
1760     : "*" FromClause Terminator
1761     | ExportClause FromClause Terminator
1762     | ExportClause Terminator
1763     | VariableStatement
1764     | "default" LexSetStatement LexSetRegExp HoistableDeclaration
1765     | "default" LexSetStatement LexSetRegExp ClassDeclaration
1766     | "default" LexSetStatement AssignmentExpression Terminator
1767     ;
1768
1769 ExportDeclaration
1770     : "export" LexSetStatement LexSetRegExp ExportDeclaration_
1771     | "export" Declaration
1772     ;
1773
1774 ExportClause
1775     : ";{" ExportsListOpt "}"
1776     ;
1777
1778 ExportsList_
1779     : "," ExportsListOpt
1780     |
1781     ;
1782
1783 ExportsList
1784     : ExportSpecifier ExportsList_
1785     ;
1786
1787 ExportsListOpt
1788     : ExportsList
1789     |
1790     ;
1791
1792 ExportSpecifier
1793     : IdentifierName
1794     | IdentifierName "as" IdentifierName
1795     ;
1796 /* }}} */
1797
1798 @begin C
1799 /* Cycript (C): Type Encoding {{{ */
1800 TypeSignifier
1801     : IdentifierType { $$ = CYNew CYTypedIdentifier(@1, $1); }
1802     | "(" LexPushInOff "*" TypeQualifierRight ")" LexPopIn { $$ = $4; }
1803     ;
1804
1805 SuffixedType
1806     : SuffixedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1807     | "(" LexPushInOff "^" TypeQualifierRight ")" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $4; $$->modifier_ = CYNew CYTypeBlockWith($9, $$->modifier_); }
1808     | TypeSignifier "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; $$->modifier_ = CYNew CYTypeFunctionWith($4, $$->modifier_); }
1809     | "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypedIdentifier(@1); $$->modifier_ = CYNew CYTypeFunctionWith($3, $$->modifier_); }
1810     | TypeSignifier { $$ = $1; }
1811     | { $$ = CYNew CYTypedIdentifier(@$); }
1812     ;
1813
1814 PrefixedType
1815     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1816     ;
1817
1818 TypeQualifierLeft
1819     : { $$ = NULL; }
1820     | "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1821     | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); }
1822     ;
1823
1824 TypeQualifierRight
1825     : PrefixedType { $$ = $1; }
1826     | SuffixedType { $$ = $1; }
1827     | "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1828     | "volatile" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeVolatile($$->modifier_); }
1829     ;
1830
1831 IntegerType
1832     : "int" { $$ = CYNew CYTypeVariable("int"); }
1833     | "unsigned" IntegerTypeOpt { $$ = CYNew CYTypeUnsigned($2); }
1834     | "signed" IntegerTypeOpt { $$ = CYNew CYTypeSigned($2); }
1835     | "long" IntegerTypeOpt { $$ = CYNew CYTypeLong($2); }
1836     | "short" IntegerTypeOpt { $$ = CYNew CYTypeShort($2); }
1837     ;
1838
1839 IntegerTypeOpt
1840     : IntegerType { $$ = $1; }
1841     | { $$ = CYNew CYTypeVariable("int"); }
1842     ;
1843
1844 PrimitiveType
1845     : IdentifierType { $$ = CYNew CYTypeVariable($1); }
1846     | IntegerType { $$ = $1; }
1847     | "void" { $$ = CYNew CYTypeVoid(); }
1848     | "char" { $$ = CYNew CYTypeVariable("char"); }
1849     | "signed" "char" { $$ = CYNew CYTypeSigned(CYNew CYTypeVariable("char")); }
1850     | "unsigned" "char" { $$ = CYNew CYTypeUnsigned(CYNew CYTypeVariable("char")); }
1851     ;
1852
1853 TypedIdentifier
1854     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->specifier_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1855     ;
1856
1857 PrimaryExpression
1858     : "@encode" "(" TypedIdentifier ")" { $$ = CYNew CYEncodedType($3); }
1859     ;
1860 /* }}} */
1861 @end
1862
1863 @begin ObjectiveC
1864 /* Cycript (Objective-C): @class Declaration {{{ */
1865 ClassSuperOpt
1866     /* XXX: why the hell did I choose MemberExpression? */
1867     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1868     | { $$ = NULL; }
1869     ;
1870
1871 ImplementationFieldListOpt
1872     : TypedIdentifier ";" ImplementationFieldListOpt { $$ = CYNew CYImplementationField($1, $3); }
1873     | LexSetRegExp { $$ = NULL; }
1874     ;
1875
1876 ImplementationFields
1877     : BRACE ImplementationFieldListOpt "}" { $$ = $2; }
1878     ;
1879
1880 MessageScope
1881     : "+" { $$ = false; }
1882     | "-" { $$ = true; }
1883     ;
1884
1885 TypeOpt
1886     : "(" LexSetRegExp TypedIdentifier ")" { if ($3->identifier_ != NULL) CYERR($3->location_, "unexpected identifier"); $$ = $3; }
1887     | { $$ = CYNew CYTypedIdentifier(CYNew CYTypeVariable("id")); }
1888     ;
1889
1890 MessageParameter
1891     : Word ":" TypeOpt Identifier { $3->identifier_ = $4; $$ = CYNew CYMessageParameter($1, $3); }
1892     ;
1893
1894 MessageParameterList
1895     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1896     ;
1897
1898 MessageParameterListOpt
1899     : MessageParameterList { $$ = $1; }
1900     | { $$ = NULL; }
1901     ;
1902
1903 MessageParameters
1904     : MessageParameterList { $$ = $1; }
1905     | Word { $$ = CYNew CYMessageParameter($1, NULL); }
1906     ;
1907
1908 ClassMessageDeclaration
1909     : MessageScope TypeOpt MessageParameters BRACE LexPushSuperOn FunctionBody "}" LexPopSuper { $$ = CYNew CYMessage($1, $2, $3, $6); }
1910     ;
1911
1912 ClassMessageDeclarationListOpt
1913     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1914     | { $$ = NULL; }
1915     ;
1916
1917 // XXX: this should be AssignmentExpressionNoRight
1918 ClassProtocols
1919     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1920     ;
1921
1922 ClassProtocolsOpt
1923     : "," ClassProtocols { $$ = $2; }
1924     | { $$ = NULL; }
1925     ;
1926
1927 ClassProtocolListOpt
1928     : "<" ClassProtocols ">" { $$ = $2; }
1929     | { $$ = NULL; }
1930     ;
1931
1932 ImplementationStatement
1933     : "@implementation" Identifier ClassSuperOpt ClassProtocolListOpt ImplementationFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYImplementation($2, $3, $4, $5, $6); }
1934     ;
1935
1936 CategoryName
1937     : "(" WordOpt ")"
1938     ;
1939
1940 CategoryStatement
1941     : "@implementation" Identifier CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1942     ;
1943
1944 Statement__
1945     : ImplementationStatement { $$ = $1; }
1946     | CategoryStatement { $$ = $1; }
1947     ;
1948 /* }}} */
1949 /* Cycript (Objective-C): Send Message {{{ */
1950 VariadicCall
1951     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1952     | { $$ = NULL; }
1953     ;
1954
1955 SelectorWordOpt
1956     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1957     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1958     ;
1959
1960 SelectorCall_
1961     : SelectorCall { $$ = $1; }
1962     | VariadicCall { $$ = $1; }
1963     ;
1964
1965 SelectorCall
1966     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYWord(""), $3, $4); }
1967     ;
1968
1969 SelectorList
1970     : SelectorCall { $$ = $1; }
1971     | Word { $$ = CYNew CYArgument($1, NULL); }
1972     ;
1973
1974 MessageExpression
1975     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1976     | "[" LexPushInOff LexSetRegExp "!super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
1977     ;
1978
1979 SelectorExpression_
1980     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1981     ;
1982
1983 SelectorExpression
1984     : SelectorExpression_ { $$ = $1; }
1985     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1986     ;
1987
1988 SelectorExpressionOpt
1989     : SelectorExpression_ { $$ = $1; }
1990     | { $$ = NULL; }
1991     ;
1992
1993 PrimaryExpression
1994     : MessageExpression { $$ = $1; }
1995     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
1996     ;
1997 /* }}} */
1998 @end
1999
2000 /* Cycript: @import Directive {{{ */
2001 ModulePath
2002     : ModulePath "." Word { $$ = CYNew CYModule($3, $1); }
2003     | Word { $$ = CYNew CYModule($1); }
2004     ;
2005
2006 Declaration__
2007     : "@import" ModulePath { $$ = CYNew CYImport($2); }
2008     ;
2009 /* }}} */
2010
2011 @begin ObjectiveC
2012 /* Cycript (Objective-C): Boxed Expressions {{{ */
2013 BoxableExpression
2014     : NullLiteral { $$ = $1; }
2015     | BooleanLiteral { $$ = $1; }
2016     | NumericLiteral { $$ = $1; }
2017     | StringLiteral { $$ = $1; }
2018     | ArrayLiteral { $$ = $1; }
2019     | ObjectLiteral { $$ = $1; }
2020     | CoverParenthesizedExpressionAndArrowParameterList { $$ = $1; }
2021     | "YES" { $$ = CYNew CYTrue(); }
2022     | "NO" { $$ = CYNew CYFalse(); }
2023     ;
2024
2025 PrimaryExpression
2026     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
2027     | "@YES" { $$ = CYNew CYBox(CYNew CYTrue()); }
2028     | "@NO" { $$ = CYNew CYBox(CYNew CYFalse()); }
2029     | "@true" { $$ = CYNew CYBox(CYNew CYTrue()); }
2030     | "@false" { $$ = CYNew CYBox(CYNew CYFalse()); }
2031     | "@null" { $$ = CYNew CYBox(CYNew CYNull()); }
2032     ;
2033 /* }}} */
2034 /* Cycript (Objective-C): Block Expressions {{{ */
2035 PrimaryExpression
2036     : "^" TypedIdentifier { if ($2->identifier_ != NULL) CYERR($2->location_, "unexpected identifier"); } BRACE LexPushInOff FunctionBody "}" LexPopIn { if (CYTypeFunctionWith *function = $2->Function()) $$ = CYNew CYObjCBlock($2, function->parameters_, $6); else CYERR($2->location_, "expected parameters"); }
2037     ;
2038 /* }}} */
2039 /* Cycript (Objective-C): Instance Literals {{{ */
2040 PrimaryExpression
2041     : "#" NumericLiteral { $$ = CYNew CYInstanceLiteral($2); }
2042     ;
2043 /* }}} */
2044 @end
2045
2046 @begin C
2047 /* Cycript (C): Pointer Indirection/Addressing {{{ */
2048 LeftHandSideExpression
2049     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
2050     ;
2051
2052 UnaryExpression_
2053     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
2054     ;
2055
2056 MemberAccess
2057     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
2058     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
2059     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
2060     ;
2061 /* }}} */
2062 /* Cycript (C): auto Compatibility {{{ */
2063 Var_
2064     : "auto"
2065     ;
2066 /* }}} */
2067 /* Cycript (C): Lambda Expressions {{{ */
2068 TypedParameterList_
2069     : "," TypedParameterList { $$ = $2; }
2070     | { $$ = NULL; }
2071     ;
2072
2073 TypedParameterList
2074     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
2075     ;
2076
2077 TypedParameterListOpt
2078     : TypedParameterList { $$ = $1; }
2079     | { $$ = NULL; }
2080     ;
2081
2082 PrimaryExpression
2083     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
2084     ;
2085 /* }}} */
2086 /* Cycript (C): Type Definitions {{{ */
2087 Statement__
2088     : "typedef" TypedIdentifier { if ($2->identifier_ == NULL) CYERR($2->location_, "expected identifier"); } Terminator { $$ = CYNew CYTypeDefinition($2); }
2089     ;
2090 /* }}} */
2091 /* Cycript (C): extern "C" {{{ */
2092 Statement__
2093     : "extern" StringLiteral { if (strcmp($2->Value(), "C") != 0) CYERR(@2, "unknown extern binding"); } TypedIdentifier { if ($4->identifier_ == NULL) CYERR($4->location_, "expected identifier"); } Terminator { $$ = CYNew CYExternal($2, $4); }
2094     ;
2095 /* }}} */
2096
2097 @end
2098
2099 @begin E4X
2100 /* Lexer State {{{ */
2101 LexPushRegExp
2102     : { driver.PushCondition(CYDriver::RegExpCondition); }
2103     ;
2104
2105 LexPushXMLContent
2106     : { driver.PushCondition(CYDriver::XMLContentCondition); }
2107     ;
2108
2109 LexPushXMLTag
2110     : { driver.PushCondition(CYDriver::XMLTagCondition); }
2111     ;
2112
2113 LexPop
2114     : { driver.PopCondition(); }
2115     ;
2116
2117 LexSetXMLContent
2118     : { driver.SetCondition(CYDriver::XMLContentCondition); }
2119     ;
2120
2121 LexSetXMLTag
2122     : { driver.SetCondition(CYDriver::XMLTagCondition); }
2123     ;
2124 /* }}} */
2125 /* Virtual Tokens {{{ */
2126 XMLWhitespaceOpt
2127     : XMLWhitespace
2128     |
2129     ;
2130 /* }}} */
2131
2132 /* 8.1 Context Keywords {{{ */
2133 Identifier
2134     : "namespace" { $$ = CYNew CYIdentifier("namespace"); }
2135     | "xml" { $$ = CYNew CYIdentifier("xml"); }
2136     ;
2137 /* }}} */
2138 /* 8.3 XML Initializer Input Elements {{{ */
2139 XMLMarkup
2140     : XMLComment { $$ = $1; }
2141     | XMLCDATA { $$ = $1; }
2142     | XMLPI { $$ = $1; }
2143     ;
2144 /* }}} */
2145
2146 /* 11.1 Primary Expressions {{{ */
2147 PrimaryExpression
2148     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
2149     | XMLInitialiser { $$ = $1; }
2150     | XMLListInitialiser { $$ = $1; }
2151     ;
2152
2153 PropertyIdentifier
2154     : AttributeIdentifier { $$ = $1; }
2155     | QualifiedIdentifier { $$ = $1; }
2156     | WildcardIdentifier { $$ = $1; }
2157     ;
2158 /* }}} */
2159 /* 11.1.1 Attribute Identifiers {{{ */
2160 AttributeIdentifier
2161     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
2162     ;
2163
2164 PropertySelector_
2165     : PropertySelector { $$ = $1; }
2166     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
2167     ;
2168
2169 PropertySelector
2170     : Identifier { $$ = CYNew CYSelector($1); }
2171     | WildcardIdentifier { $$ = $1; }
2172     ;
2173 /* }}} */
2174 /* 11.1.2 Qualified Identifiers {{{ */
2175 QualifiedIdentifier_
2176     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
2177     | QualifiedIdentifier { $$ = $1; }
2178     ;
2179
2180 QualifiedIdentifier
2181     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
2182     ;
2183 /* }}} */
2184 /* 11.1.3 Wildcard Identifiers {{{ */
2185 WildcardIdentifier
2186     : "*" { $$ = CYNew CYWildcard(); }
2187     ;
2188 /* }}} */
2189 /* 11.1.4 XML Initializer {{{ */
2190 XMLInitialiser
2191     : XMLMarkup { $$ = $1; }
2192     | XMLElement { $$ = $1; }
2193     ;
2194
2195 XMLElement
2196     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
2197     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
2198     ;
2199
2200 XMLTagContent
2201     : LexPushXMLTag XMLTagName XMLAttributes
2202     ;
2203
2204 XMLExpression
2205     : BRACE LexPushRegExp Expression LexPop "}"
2206     ;
2207
2208 XMLTagName
2209     : XMLExpression
2210     | XMLName
2211     ;
2212
2213 XMLAttributes_
2214     : XMLAttributes_ XMLAttribute
2215     |
2216     ;
2217
2218 XMLAttributes
2219     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
2220     | XMLAttributes_ XMLWhitespaceOpt
2221     ;
2222
2223 XMLAttributeValue_
2224     : XMLExpression
2225     | XMLAttributeValue
2226     ;
2227
2228 XMLAttribute
2229     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
2230     ;
2231
2232 XMLElementContent
2233     : XMLExpression XMLElementContentOpt
2234     | XMLMarkup XMLElementContentOpt
2235     | XMLText XMLElementContentOpt
2236     | XMLElement XMLElementContentOpt
2237     ;
2238
2239 XMLElementContentOpt
2240     : XMLElementContent
2241     |
2242     ;
2243 /* }}} */
2244 /* 11.1.5 XMLList Initializer {{{ */
2245 XMLListInitialiser
2246     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
2247     ;
2248 /* }}} */
2249
2250 /* 11.2 Left-Hand-Side Expressions {{{ */
2251 PropertyIdentifier_
2252     : Identifier { $$ = $1; }
2253     | PropertyIdentifier { $$ = $1; }
2254     ;
2255
2256 MemberAccess
2257     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
2258     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
2259     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
2260     ;
2261 /* }}} */
2262 /* 12.1 The default xml namespace Statement {{{ */
2263 /* XXX: DefaultXMLNamespaceStatement
2264     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
2265     ;
2266
2267 Statement__
2268     : DefaultXMLNamespaceStatement { $$ = $1; }
2269     ; */
2270 /* }}} */
2271 @end
2272
2273 /* JavaScript FTL: Array Comprehensions {{{ */
2274 Comprehension
2275     : AssignmentExpression ComprehensionFor ComprehensionTail { $$ = CYNew CYArrayComprehension($1, $2->Modify($3)); }
2276     ;
2277
2278 ComprehensionFor
2279     : "for" "each" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
2280     ;
2281 /* }}} */
2282 /* JavaScript FTL: for each {{{ */
2283 IterationStatement
2284     : "for" "each" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
2285     ;
2286 /* }}} */
2287 /* JavaScript FTL: let Statements {{{ */
2288 LetStatement
2289     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
2290     ;
2291
2292 Statement__
2293     : LetStatement
2294     ;
2295 /* }}} */
2296
2297 /* JavaScript FTW: Array Comprehensions {{{ */
2298 PrimaryExpression
2299     : ArrayComprehension
2300     ;
2301
2302 ArrayComprehension
2303     : "[" LexPushInOff Comprehension "]" LexPopIn { $$ = $3; }
2304     ;
2305
2306 Comprehension
2307     : LexSetRegExp ComprehensionFor ComprehensionTail AssignmentExpression { $$ = CYNew CYArrayComprehension($4, $2->Modify($3)); }
2308     ;
2309
2310 ComprehensionTail
2311     : { $$ = NULL; }
2312     | ComprehensionFor ComprehensionTail { $$ = $1->Modify($2); }
2313     | ComprehensionIf ComprehensionTail { $$ = $1->Modify($2); }
2314     ;
2315
2316 ComprehensionFor
2317     : "for" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
2318     | "for" "(" LexPushInOn LexicalBinding "of" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($4, $7); }
2319     ;
2320
2321 ComprehensionIf
2322     : "if" "(" AssignmentExpression ")" { $$ = CYNew CYIfComprehension($3); }
2323     ;
2324 /* }}} */
2325 /* JavaScript FTW: Coalesce Operator {{{ */
2326 ConditionalExpression
2327     : LogicalORExpression "?" LexPushInOff LexSetRegExp ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $1, $7); }
2328     ;
2329 /* }}} */
2330 /* JavaScript FTW: Named Arguments {{{ */
2331 ArgumentList
2332     : LexSetRegExp Word ":" AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument($2, $4, $5); }
2333     ;
2334 /* }}} */
2335 /* JavaScript FTW: Ruby Blocks {{{ */
2336 RubyProcParameterList_
2337     : "," RubyProcParameterList { $$ = $2; }
2338     | { $$ = NULL; }
2339     ;
2340
2341 RubyProcParameterList
2342     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
2343     | { $$ = NULL; }
2344     ;
2345
2346 RubyProcParameters
2347     : LexSetRegExp "|" RubyProcParameterList "|" { $$ = $3; }
2348     | LexSetRegExp "||" { $$ = NULL; }
2349     ;
2350
2351 RubyProcParametersOpt
2352     : RubyProcParameters { $$ = $1; }
2353     | { $$ = NULL; }
2354     ;
2355
2356 RubyProcExpression
2357     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
2358     ;
2359
2360 PrimaryExpression
2361     : BRACE LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
2362     ;
2363
2364 PostfixExpression
2365     : PostfixExpression RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
2366     ;
2367 /* }}} */
2368
2369 %%
2370
2371 bool CYDriver::Parse(CYMark mark) {
2372     mark_ = mark;
2373     CYLocal<CYPool> local(&pool_);
2374     cy::parser parser(*this);
2375 #ifdef YYDEBUG
2376     parser.set_debug_level(debug_);
2377 #endif
2378     return parser.parse() != 0;
2379 }
2380
2381 void CYDriver::Warning(const cy::parser::location_type &location, const char *message) {
2382     if (!strict_)
2383         return;
2384
2385     CYDriver::Error error;
2386     error.warning_ = true;
2387     error.location_ = location;
2388     error.message_ = message;
2389     errors_.push_back(error);
2390 }
2391
2392 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
2393     CYDriver::Error error;
2394     error.warning_ = false;
2395     error.location_ = location;
2396     error.message_ = message;
2397     driver.errors_.push_back(error);
2398 }