configure.ac

   1 AC_PREREQ([2.65])
   2 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
   3 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
   4
   5 AC_CONFIG_SRCDIR([Console.cpp])
   6 AC_CONFIG_AUX_DIR([.])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AM_INIT_AUTOMAKE
  10 LT_INIT([disable-static])
  11
  12 AC_LANG([C++])
  13
  14 PKG_PROG_PKG_CONFIG([0.22])
  15
  16 AX_CHECK_GNU_MAKE
  17 AC_SUBST([GMAKE], [$_cv_gnu_make_command])
  18 AS_IF([test "x$GMAKE" = x], [AC_MSG_ERROR([You need GNU make])])
  19
  20 AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
  21 AC_PATH_PROG([GIT], [git])
  22 AC_PATH_PROG([TIME], [time])
  23
  24 dnl CY_CHECK_PROGS_VERSION {{{
  25 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  26     AC_ARG_VAR(]$1[, ]$3[)
  27
  28     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  29     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  30         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  31         AS_VAR_IF(version, [], ,
  32             AS_VERSION_COMPARE($version, ]$5[, ,
  33                 ac_cv_path_]$1[=$ac_path_]$1[,
  34                 ac_cv_path_]$1[=$ac_path_]$1[))
  35     , AC_MSG_RESULT(no))
  36
  37     AS_IF([true], [
  38         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  39         AC_MSG_RESULT($]$1[)
  40     ], AS_IF([true], [
  41         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  42     ], [
  43         AC_SUBST(]$1[, [:])
  44         AC_MSG_RESULT([no])
  45     ]))
  46 ]) dnl }}}
  47
  48 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  49     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  50 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  51     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  52 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  53     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  54 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  55     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  56
  57 AC_PROG_INSTALL
  58
  59 AC_PROG_CXX
  60 AC_PROG_OBJCXX
  61
  62 dnl CY_TRY {{{
  63 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  64 AC_DEFUN([CY_FAILURE], [cy_good=0])
  65
  66 AC_DEFUN([CY_TRY], [
  67     cy_save=$]$1[
  68         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  69         ]$3[
  70     ]$1[=$cy_save
  71     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
  72 ]) dnl }}}
  73
  74 AC_DEFUN([CY_COMPILE_FLAG], [
  75     AC_LIB_APPENDTOVAR([CFLAGS], ]$1[)
  76     AC_LIB_APPENDTOVAR([CXXFLAGS], ]$1[)
  77     AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], ]$1[)
  78 ])
  79
  80 AC_DEFUN([CY_TEST_FLAG], [
  81     AC_MSG_CHECKING([for ]]$1[)
  82     CY_TRY([CXXFLAGS], $1, [
  83         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
  84             [CY_SUCCESS], [CY_FAILURE])
  85     ], [
  86         AC_MSG_RESULT([yes])
  87         CY_COMPILE_FLAG($1)
  88     ], [AC_MSG_RESULT([no])])
  89 ])
  90
  91 AX_CFLAGS_WARN_ALL
  92 AX_CXXFLAGS_WARN_ALL
  93
  94 CY_TEST_FLAG([-Wno-overloaded-virtual])
  95 CY_TEST_FLAG([-Wno-parentheses])
  96 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
  97
  98 dnl -arch * {{{
  99 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 100     AC_MSG_CHECKING([for -arch $cy_arch])
 101     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 102         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 103     ], [
 104         AC_MSG_RESULT([yes])
 105         CY_COMPILE_FLAG(["-arch $cy_arch"])
 106         AC_LIB_APPENDTOVAR([LDFLAGS], ["-arch $cy_arch"])
 107     ], [AC_MSG_RESULT([no])])
 108 done dnl }}}
 109
 110 dnl --with-frameworks {{{
 111 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
 112     [--with-frameworks=DIRS],
 113     [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
 114 )], [
 115     for cy_framework in $withval; do
 116         CY_COMPILE_FLAG([-F$cy_framework])
 117     done
 118 ]) dnl }}}
 119 dnl --enable-javascript {{{
 120 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 121     PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
 122         AC_SUBST([CY_EXECUTE], [1])
 123         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
 124         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
 125     ], [
 126         PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
 127             AC_SUBST([CY_EXECUTE], [1])
 128             AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
 129             AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
 130         ], [
 131             AC_CHECK_FRAMEWORK([JavaScriptCore], [
 132                 #include <JavaScriptCore/JSBase.h>
 133             ], [
 134                 JSEvaluateScript(0, 0, 0, 0, 0, 0);
 135             ], [
 136                 AC_SUBST([CY_EXECUTE], [1])
 137             ])
 138         ])
 139     ])
 140 ])
 141
 142 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 143     CY_CHECK_JAVASCRIPTCORE])
 144
 145 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 146     [--enable-javascript@<:@=ENGINE@:>@],
 147     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 148 )], [
 149     AS_CASE([$enableval],
 150         [yes], [
 151             CY_CHECK_JAVASCRIPT],
 152         [no], [
 153             AC_SUBST([CY_EXECUTE], [0])],
 154         [JavaScriptCore], [
 155             CY_CHECK_JAVASCRIPTCORE],
 156         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 157 ], [CY_CHECK_JAVASCRIPT])
 158 dnl }}}
 159
 160 dnl APR_FIND_APR {{{
 161 APR_FIND_APR([], [], [1], [1])
 162 AS_CASE([$apr_found], [yes], [
 163     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 164     AC_SUBST([LTLIBAPR], [`$apr_config --link-libtool`])
 165 ], [AC_MSG_ERROR([missing "libapr"])])
 166 dnl }}}
 167
 168 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 169     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 170         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
 171         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 172     ], [AC_MSG_ERROR([missing "libffi"])])])
 173
 174 AS_CASE([$CY_EXECUTE], [1], [
 175     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 176     AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 177         CY_CHECK_PKG_CONFIG_LIBFFI
 178     ], [
 179         AC_SEARCH_LIBS([ffi_call], [ffi])
 180         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 181     ])
 182
 183     AC_LANG_PUSH([Objective C++])
 184
 185     AC_MSG_CHECKING([if we really have Objective C++])
 186     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 187         CY_OBJECTIVEC=1
 188         AC_MSG_RESULT([yes])
 189     ], [AC_MSG_RESULT([no])])
 190
 191     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 192         AC_CHECK_FRAMEWORK([CoreFoundation], [
 193             #include <CoreFoundation/CFBase.h>
 194         ], [CFAllocatorGetDefault();], [
 195             AC_SUBST([CY_OBJECTIVEC])
 196
 197             AC_CHECK_FRAMEWORK([Foundation], [
 198                 #include <Foundation/NSObject.h>
 199             ], [[[[NSObject alloc] init];]])
 200
 201             AC_CHECK_FRAMEWORK([WebKit], [
 202                 #include <WebKit/WebScriptObject.h>
 203             ], [[[[WebScriptObject alloc] init];]])
 204         ], [
 205             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 206             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 207
 208             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 209                 AC_SUBST([CY_OBJECTIVEC])
 210                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 211                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 212             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 213         ])
 214     ])
 215
 216     AC_LANG_POP([Objective C++])
 217 ])
 218
 219 VL_LIB_READLINE
 220 AS_CASE([$vl_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 221
 222 dnl XXX: saurik doesn't understand what this does
 223 dnl AM_ICONV {{{
 224 AC_LANG_PUSH([C])
 225 AM_ICONV
 226 AS_CASE([$am_cv_func_iconv], [yes], [], [
 227     for cy_iconv_prefix_arg in $CFLAGS $CXXFLAGS $OBJCXXFLAGS $LDFLAGS $LIBS; do
 228         AS_CASE([$cy_iconv_prefix_arg], [-I*], [
 229             AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-I//;s|/include$||'`])
 230         ], [-L*], [
 231             AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-L//;s|/lib$||'`])
 232         ])
 233     done
 234     for with_libiconv_prefix in $cy_iconv_prefixes; do
 235         AS_UNSET([am_cv_func_iconv])
 236         AM_ICONV_LINKFLAGS_BODY
 237         AM_ICONV
 238     done
 239 ])
 240 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 241 AC_LANG_POP([C])
 242 dnl }}}
 243
 244 AC_SUBST([LTFLAGS])
 245 AC_SUBST([SO], [$acl_shlibext])
 246
 247 AC_CHECK_HEADER([mach/mach.h], [
 248     AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 249     AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 250     AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 251     AC_SUBST([CY_MACH], [1])
 252     AC_SUBST([CY_ATTACH_GROUP], [procmod])
 253 ])
 254
 255 AS_IF([test "x$GMAKE" != xmake], [
 256     AC_CONFIG_FILES([Makefile])])
 257 AC_CONFIG_FILES([GNUmakefile])
 258
 259 AC_OUTPUT