Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 typedef struct {
  43     bool newline_;
  44
  45     union {
  46         bool bool_;
  47
  48         CYDriver::Condition condition_;
  49
  50         CYArgument *argument_;
  51         CYAssignment *assignment_;
  52         CYBoolean *boolean_;
  53         CYClause *clause_;
  54         cy::Syntax::Catch *catch_;
  55         CYComment *comment_;
  56         CYComprehension *comprehension_;
  57         CYCompound *compound_;
  58         CYDeclaration *declaration_;
  59         CYDeclarations *declarations_;
  60         CYElement *element_;
  61         CYExpression *expression_;
  62         CYFalse *false_;
  63         CYFinally *finally_;
  64         CYForInitialiser *for_;
  65         CYForInInitialiser *forin_;
  66         CYFunctionParameter *functionParameter_;
  67         CYIdentifier *identifier_;
  68         CYInfix *infix_;
  69         CYLiteral *literal_;
  70         CYMember *member_;
  71         CYNull *null_;
  72         CYNumber *number_;
  73         CYProgram *program_;
  74         CYProperty *property_;
  75         CYPropertyName *propertyName_;
  76         CYRubyProc *rubyProc_;
  77         CYStatement *statement_;
  78         CYString *string_;
  79         CYThis *this_;
  80         CYTrue *true_;
  81         CYWord *word_;
  82
  83 @begin ObjectiveC
  84         CYClassName *className_;
  85         CYField *field_;
  86         CYMessage *message_;
  87         CYMessageParameter *messageParameter_;
  88         CYProtocol *protocol_;
  89         CYSelectorPart *selector_;
  90 @end
  91
  92 @begin E4X
  93         CYAttribute *attribute_;
  94         CYPropertyIdentifier *propertyIdentifier_;
  95         CYSelector *selector_;
  96 @end
  97     };
  98 } YYSTYPE;
  99
 100 #define YYSTYPE YYSTYPE
 101 @if Bison24 }
 102
 103 @if Bison24 %code provides {
 104 int cylex(YYSTYPE *, cy::location *, void *);
 105 @if Bison24 }
 106
 107 @if Bison23 %}
 108
 109 %name-prefix="cy"
 110
 111 @if Bison23 %skeleton "lalr1.cc"
 112 @if Bison24 %language "C++"
 113
 114 %initial-action {
 115     @$.begin.filename = @$.end.filename = &driver.filename_;
 116 };
 117
 118 %locations
 119 %defines
 120
 121 //%glr-parser
 122 //%expect 1
 123
 124 %error-verbose
 125
 126 %parse-param { CYDriver &driver }
 127 %lex-param { void *cyscanner }
 128
 129 @begin E4X
 130 %token XMLCDATA
 131 %token XMLComment
 132 %token XMLPI
 133
 134 %token XMLAttributeValue
 135 %token XMLName
 136 %token XMLTagCharacters
 137 %token XMLText
 138 %token XMLWhitespace
 139 @end
 140
 141 @begin E4X
 142 %token LeftRight "<>"
 143 %token LeftSlashRight "</>"
 144
 145 %token SlashRight "/>"
 146 %token LeftSlash "</"
 147
 148 %token ColonColon "::"
 149 %token PeriodPeriod ".."
 150 @end
 151
 152 @begin E4X ObjectiveC
 153 %token At "@"
 154 @end
 155
 156 %token Ampersand "&"
 157 %token AmpersandAmpersand "&&"
 158 %token AmpersandEqual "&="
 159 %token Carrot "^"
 160 %token CarrotEqual "^="
 161 %token Equal "="
 162 %token EqualEqual "=="
 163 %token EqualEqualEqual "==="
 164 %token EqualRight "=>"
 165 %token Exclamation "!"
 166 %token ExclamationEqual "!="
 167 %token ExclamationEqualEqual "!=="
 168 %token Hyphen "-"
 169 %token HyphenEqual "-="
 170 %token HyphenHyphen "--"
 171 %token HyphenHyphen_ "\n--"
 172 %token HyphenRight "->"
 173 %token Left "<"
 174 %token LeftEqual "<="
 175 %token LeftLeft "<<"
 176 %token LeftLeftEqual "<<="
 177 %token Percent "%"
 178 %token PercentEqual "%="
 179 %token Period "."
 180 %token PeriodPeriodPeriod "..."
 181 %token Pipe "|"
 182 %token PipeEqual "|="
 183 %token PipePipe "||"
 184 %token Plus "+"
 185 %token PlusEqual "+="
 186 %token PlusPlus "++"
 187 %token PlusPlus_ "\n++"
 188 %token Right ">"
 189 %token RightEqual ">="
 190 %token RightRight ">>"
 191 %token RightRightEqual ">>="
 192 %token RightRightRight ">>>"
 193 %token RightRightRightEqual ">>>="
 194 %token Slash "/"
 195 %token SlashEqual "/="
 196 %token Star "*"
 197 %token StarEqual "*="
 198 %token Tilde "~"
 199
 200 %token Colon ":"
 201 %token Comma ","
 202 %token Question "?"
 203 %token SemiColon ";"
 204 %token NewLine "\n"
 205
 206 %token <comment_> Comment
 207
 208 %token OpenParen "("
 209 %token CloseParen ")"
 210
 211 %token OpenBrace "{"
 212 %token OpenBrace_ "\n{"
 213 %token OpenBrace__ ";{"
 214 %token CloseBrace "}"
 215
 216 %token OpenBracket "["
 217 %token CloseBracket "]"
 218
 219 @begin Java
 220 %token AtClass "@class"
 221 @end
 222
 223 @begin ObjectiveC
 224 %token AtImplementation "@implementation"
 225 %token AtImplementation_ ";@implementation"
 226 %token AtImport "@import"
 227 %token AtEnd "@end"
 228 %token AtSelector "@selector"
 229 @end
 230
 231 %token <false_> False "false"
 232 %token <null_> Null "null"
 233 %token <true_> True "true"
 234
 235 // ES3/ES5/WIE/JSC Reserved
 236 %token <word_> Break "break"
 237 %token <word_> Case "case"
 238 %token <word_> Catch "catch"
 239 %token <word_> Continue "continue"
 240 %token <word_> Default "default"
 241 %token <word_> Delete "delete"
 242 %token <word_> Do "do"
 243 %token <word_> Else "else"
 244 %token <word_> Finally "finally"
 245 %token <word_> For "for"
 246 %token <word_> Function "function"
 247 %token <word_> Function_ ";function"
 248 %token <word_> If "if"
 249 %token <word_> In "in"
 250 %token <word_> In_ "!in"
 251 %token <word_> InstanceOf "instanceof"
 252 %token <word_> New "new"
 253 %token <word_> Return "return"
 254 %token <word_> Switch "switch"
 255 %token <this_> This "this"
 256 %token <word_> Throw "throw"
 257 %token <word_> Try "try"
 258 %token <word_> TypeOf "typeof"
 259 %token <word_> Var "var"
 260 %token <word_> Void "void"
 261 %token <word_> While "while"
 262 %token <word_> With "with"
 263
 264 // ES3/IE6 Future, ES5/JSC Reserved
 265 %token <word_> Debugger "debugger"
 266
 267 // ES3/ES5/IE6 Future, JSC Reserved
 268 %token <word_> Const "const"
 269
 270 // ES3/ES5/IE6/JSC Future
 271 %token <word_> Class "class"
 272 %token <word_> Enum "enum"
 273 %token <word_> Export "export"
 274 %token <word_> Extends "extends"
 275 %token <word_> Import "import"
 276 %token <word_> Super "super"
 277
 278 // ES3 Future, ES5 Strict Future
 279 %token <identifier_> Implements "implements"
 280 %token <identifier_> Interface "interface"
 281 %token <identifier_> Package "package"
 282 %token <identifier_> Private "private"
 283 %token <identifier_> Protected "protected"
 284 %token <identifier_> Public "public"
 285 %token <identifier_> Static "static"
 286
 287 // ES3 Future
 288 %token <identifier_> Abstract "abstract"
 289 %token <identifier_> Boolean "boolean"
 290 %token <identifier_> Byte "byte"
 291 %token <identifier_> Char "char"
 292 %token <identifier_> Double "double"
 293 %token <identifier_> Final "final"
 294 %token <identifier_> Float "float"
 295 %token <identifier_> Goto "goto"
 296 %token <identifier_> Int "int"
 297 %token <identifier_> Long "long"
 298 %token <identifier_> Native "native"
 299 %token <identifier_> Short "short"
 300 %token <identifier_> Synchronized "synchronized"
 301 %token <identifier_> Throws "throws"
 302 %token <identifier_> Transient "transient"
 303 %token <identifier_> Volatile "volatile"
 304
 305 // ES5 Strict
 306 %token <identifier_> Let "let"
 307 %token <identifier_> Yield "yield"
 308
 309 // Woah?!
 310 %token <identifier_> Each "each"
 311 %token <identifier_> Of "of"
 312
 313 @begin E4X
 314 // E4X Conditional
 315 %token <identifier_> Namespace "namespace"
 316 %token <identifier_> XML "xml"
 317 @end
 318
 319 %token AutoComplete
 320
 321 %token <identifier_> Identifier_
 322 %token <number_> NumericLiteral
 323 %token <string_> StringLiteral
 324 %token <literal_> RegularExpressionLiteral
 325
 326 %type <expression_> AdditiveExpression
 327 %type <argument_> ArgumentList_
 328 %type <argument_> ArgumentList
 329 %type <argument_> ArgumentListOpt
 330 %type <argument_> Arguments
 331 %type <literal_> ArrayLiteral
 332 %type <expression_> ArrowFunction
 333 %type <functionParameter_> ArrowParameters
 334 %type <expression_> AssignmentExpression
 335 %type <identifier_> BindingIdentifier
 336 %type <expression_> BitwiseANDExpression
 337 %type <statement_> Block_
 338 %type <statement_> Block
 339 %type <boolean_> BooleanLiteral
 340 %type <declaration_> BindingElement
 341 %type <expression_> BitwiseORExpression
 342 %type <expression_> BitwiseXORExpression
 343 %type <statement_> BreakStatement
 344 %type <statement_> BreakableStatement
 345 %type <expression_> CallExpression_
 346 %type <expression_> CallExpression
 347 %type <clause_> CaseBlock
 348 %type <clause_> CaseClause
 349 %type <clause_> CaseClausesOpt
 350 %type <catch_> CatchOpt
 351 %type <comprehension_> ComprehensionList
 352 %type <comprehension_> ComprehensionListOpt
 353 %type <expression_> ConditionalExpression
 354 %type <statement_> ContinueStatement
 355 %type <statement_> ConciseBody
 356 %type <statement_> DebuggerStatement
 357 %type <statement_> Declaration__
 358 %type <statement_> Declaration_
 359 %type <statement_> Declaration
 360 %type <clause_> DefaultClause
 361 %type <expression_> Element
 362 %type <expression_> ElementOpt
 363 %type <element_> ElementList
 364 %type <element_> ElementListOpt
 365 %type <statement_> ElseStatementOpt
 366 %type <statement_> EmptyStatement
 367 %type <expression_> EqualityExpression
 368 %type <compound_> Expression_
 369 %type <compound_> Expression
 370 %type <expression_> ExpressionOpt
 371 %type <statement_> ExpressionStatement
 372 %type <finally_> FinallyOpt
 373 %type <comprehension_> ForComprehension
 374 %type <for_> ForStatementInitialiser
 375 %type <forin_> ForInStatementInitialiser
 376 %type <declaration_> FormalParameter
 377 %type <functionParameter_> FormalParameterList_
 378 %type <functionParameter_> FormalParameterList
 379 %type <functionParameter_> FormalParameterListOpt
 380 %type <statement_> FunctionBody
 381 %type <statement_> FunctionDeclaration
 382 %type <expression_> FunctionExpression
 383 %type <identifier_> Identifier
 384 %type <identifier_> IdentifierOpt
 385 %type <comprehension_> IfComprehension
 386 %type <statement_> IfStatement
 387 %type <expression_> Initialiser
 388 %type <expression_> InitialiserOpt
 389 %type <statement_> IterationStatement
 390 %type <statement_> LabelledStatement
 391 %type <expression_> LeftHandSideExpression
 392 %type <statement_> LetStatement
 393 %type <statement_> LexicalDeclaration
 394 %type <literal_> Literal
 395 %type <literal_> LiteralNoRE
 396 %type <expression_> LogicalANDExpression
 397 %type <expression_> LogicalORExpression
 398 %type <member_> MemberAccess
 399 %type <expression_> MemberExpression_
 400 %type <expression_> MemberExpression
 401 %type <expression_> MultiplicativeExpression
 402 %type <expression_> NewExpression
 403 %type <null_> NullLiteral
 404 %type <literal_> ObjectLiteral
 405 %type <compound_> Parenthetical
 406 %type <compound_> ParentheticalOpt
 407 %type <expression_> PostfixExpression
 408 %type <expression_> PrimaryExpression
 409 %type <statement_> Program
 410 %type <statement_> ProgramBody
 411 %type <statement_> ProgramBodyOpt
 412 %type <propertyName_> PropertyName_
 413 %type <propertyName_> PropertyName
 414 %type <property_> PropertyNameAndValueList_
 415 %type <property_> PropertyNameAndValueList
 416 %type <property_> PropertyNameAndValueListOpt
 417 %type <expression_> RelationalExpression
 418 %type <statement_> ReturnStatement
 419 %type <rubyProc_> RubyProcExpression
 420 %type <functionParameter_> RubyProcParameterList_
 421 %type <functionParameter_> RubyProcParameterList
 422 %type <functionParameter_> RubyProcParameters
 423 %type <functionParameter_> RubyProcParametersOpt
 424 %type <expression_> ShiftExpression
 425 %type <declaration_> SingleNameBinding
 426 %type <statement_> Statement__
 427 %type <statement_> Statement_
 428 %type <statement_> Statement
 429 %type <statement_> StatementList
 430 %type <statement_> StatementListOpt
 431 %type <statement_> StatementListItem
 432 %type <statement_> SwitchStatement
 433 %type <statement_> ThrowStatement
 434 %type <statement_> TryStatement
 435 %type <expression_> UnaryExpression_
 436 %type <expression_> UnaryExpression
 437 %type <declaration_> VariableDeclaration
 438 %type <declarations_> VariableDeclarationList_
 439 %type <declarations_> VariableDeclarationList
 440 %type <statement_> VariableStatement
 441 %type <statement_> WithStatement
 442
 443 @begin ObjectiveC
 444 %type <statement_> CategoryStatement
 445 %type <expression_> ClassExpression
 446 %type <statement_> ClassStatement
 447 %type <expression_> ClassSuperOpt
 448 %type <field_> ClassFieldList
 449 %type <message_> ClassMessageDeclaration
 450 %type <message_> ClassMessageDeclarationListOpt
 451 %type <className_> ClassName
 452 %type <className_> ClassNameOpt
 453 %type <protocol_> ClassProtocolListOpt
 454 %type <protocol_> ClassProtocols
 455 %type <protocol_> ClassProtocolsOpt
 456 %type <expression_> MessageExpression
 457 %type <messageParameter_> MessageParameter
 458 %type <messageParameter_> MessageParameters
 459 %type <messageParameter_> MessageParameterList
 460 %type <messageParameter_> MessageParameterListOpt
 461 %type <bool_> MessageScope
 462 %type <argument_> SelectorCall_
 463 %type <argument_> SelectorCall
 464 %type <selector_> SelectorExpression_
 465 %type <selector_> SelectorExpression
 466 %type <selector_> SelectorExpressionOpt
 467 %type <argument_> SelectorList
 468 %type <word_> SelectorWordOpt
 469 %type <expression_> TypeOpt
 470 %type <argument_> VariadicCall
 471 %type <word_> Word
 472 %type <word_> WordOpt
 473 @end
 474
 475 @begin E4X
 476 %type <propertyIdentifier_> PropertyIdentifier_
 477 %type <selector_> PropertySelector_
 478 %type <selector_> PropertySelector
 479 %type <identifier_> QualifiedIdentifier_
 480 %type <identifier_> QualifiedIdentifier
 481 %type <identifier_> WildcardIdentifier
 482 %type <identifier_> XMLComment
 483 %type <identifier_> XMLCDATA
 484 %type <identifier_> XMLElement
 485 %type <identifier_> XMLElementContent
 486 %type <identifier_> XMLMarkup
 487 %type <identifier_> XMLPI
 488
 489 %type <attribute_> AttributeIdentifier
 490 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 491 %type <expression_> PropertyIdentifier
 492 %type <expression_> XMLListInitialiser
 493 %type <expression_> XMLInitialiser
 494 @end
 495
 496 %nonassoc ""
 497 %left "++" "--"
 498
 499 %nonassoc "if"
 500 %nonassoc "else"
 501
 502 %start Program
 503
 504 %%
 505
 506 /* Lexer State {{{ */
 507 LexPushInOn
 508     : { driver.in_.push(true); }
 509     ;
 510
 511 LexPushInOff
 512     : { driver.in_.push(false); }
 513     ;
 514
 515 LexPopIn
 516     : { driver.in_.pop(); }
 517     ;
 518
 519 LexSetRegExp
 520     : { driver.SetCondition(CYDriver::RegExpCondition); }
 521     ;
 522
 523 LexNoBrace
 524     : { if (yychar == yyempty_) driver.nobrace_ = true; else if (yychar == token::OpenBrace || yychar == token::OpenBrace_) yychar = token::OpenBrace__; }
 525     ;
 526
 527 LexNoFunction
 528     : { if (yychar == token::Function) yychar = token::Function_; }
 529     ;
 530
 531 LexSetStatement
 532     : LexNoBrace LexNoFunction
 533     ;
 534 /* }}} */
 535
 536 BRACE
 537     : "{"
 538     | "\n{"
 539     ;
 540
 541 StrictSemi
 542     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 543     ;
 544
 545 Terminator_
 546     : ";"
 547     | "\n" StrictSemi
 548     ;
 549
 550 Terminator
 551     : Terminator_
 552     | error { if (yychar != yyeof_ && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 553     ;
 554
 555 TerminatorOpt
 556     : Terminator_
 557     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 558     ;
 559
 560 /*CommaOpt
 561     : ","
 562     |
 563     ;*/
 564
 565 @begin ObjectiveC
 566 NewLineOpt
 567     : "\n"
 568     |
 569     ;
 570
 571 Word
 572     : Identifier { $$ = $1; }
 573     | "break" NewLineOpt { $$ = $1; }
 574     | "case" { $$ = $1; }
 575     | "catch" { $$ = $1; }
 576     | "class" { $$ = $1; }
 577     | "const" { $$ = $1; }
 578     | "continue" NewLineOpt { $$ = $1; }
 579     | "debugger" { $$ = $1; }
 580     | "default" { $$ = $1; }
 581     | "delete" { $$ = $1; }
 582     | "do" { $$ = $1; }
 583     | "else" { $$ = $1; }
 584     | "enum" { $$ = $1; }
 585     | "export" { $$ = $1; }
 586     | "extends" { $$ = $1; }
 587     | "false" { $$ = $1; }
 588     | "finally" { $$ = $1; }
 589     /* XXX: | "for" { $$ = $1; } */
 590     | "function" { $$ = $1; }
 591     | "if" { $$ = $1; }
 592     | "import" { $$ = $1; }
 593     /* XXX: | "in" { $$ = $1; } */
 594     /* XXX: | "instanceof" { $$ = $1; } */
 595
 596     // XXX: as it currently is not an Identifier
 597     | "let" { $$ = $1; }
 598
 599     | "new" { $$ = $1; }
 600     | "null" { $$ = $1; }
 601     | "return" NewLineOpt { $$ = $1; }
 602     | "super" { $$ = $1; }
 603     | "switch" { $$ = $1; }
 604     | "this" { $$ = $1; }
 605     | "throw" NewLineOpt { $$ = $1; }
 606     | "true" { $$ = $1; }
 607     | "try" { $$ = $1; }
 608     | "typeof" { $$ = $1; }
 609     | "var" { $$ = $1; }
 610     | "void" { $$ = $1; }
 611     | "while" { $$ = $1; }
 612     | "with" { $$ = $1; }
 613     ;
 614
 615 WordOpt
 616     : Word { $$ = $1; }
 617     | { $$ = NULL; }
 618     ;
 619
 620 PrimaryExpression
 621     : "@" LiteralNoRE { $$ = CYNew CYBox($2); }
 622     | "@" ArrayLiteral { $$ = CYNew CYBox($2); }
 623     | "@" ObjectLiteral { $$ = CYNew CYBox($2); }
 624     | "@" Parenthetical { $$ = CYNew CYBox($2); }
 625     ;
 626 @end
 627
 628 Identifier
 629     : Identifier_ { $$ = $1; }
 630
 631     | "implements" { $$ = $1; }
 632     | "interface" { $$ = $1; }
 633     | "package" { $$ = $1; }
 634     | "private" { $$ = $1; }
 635     | "protected" { $$ = $1; }
 636     | "public" { $$ = $1; }
 637     | "static" { $$ = $1; }
 638
 639     | "abstract" { $$ = $1; }
 640     | "boolean" { $$ = $1; }
 641     | "byte" { $$ = $1; }
 642     | "char" { $$ = $1; }
 643     | "double" { $$ = $1; }
 644     | "final" { $$ = $1; }
 645     | "float" { $$ = $1; }
 646     | "goto" { $$ = $1; }
 647     | "int" { $$ = $1; }
 648     | "long" { $$ = $1; }
 649     | "native" { $$ = $1; }
 650     | "short" { $$ = $1; }
 651     | "synchronized" { $$ = $1; }
 652     | "throws" { $$ = $1; }
 653     | "transient" { $$ = $1; }
 654     | "volatile" { $$ = $1; }
 655
 656     // XXX: currently I only have this as Word
 657     // | "let" { $$ = $1; }
 658
 659     | "yield" { $$ = $1; }
 660
 661     | "each" { $$ = $1; }
 662     | "of" { $$ = $1; }
 663     ;
 664
 665 IdentifierOpt
 666     : Identifier { $$ = $1; }
 667     | { $$ = NULL; }
 668     ;
 669
 670 LiteralNoRE
 671     : NullLiteral { $$ = $1; }
 672     | BooleanLiteral { $$ = $1; }
 673     | NumericLiteral { $$ = $1; }
 674     | StringLiteral { $$ = $1; }
 675     ;
 676
 677 Literal
 678     : LiteralNoRE { $$ = $1; }
 679     | RegularExpressionLiteral { $$ = $1; }
 680     ;
 681
 682 NullLiteral
 683     : "null" { $$ = $1; }
 684     ;
 685
 686 BooleanLiteral
 687     : "true" { $$ = $1; }
 688     | "false" { $$ = $1; }
 689     ;
 690
 691 /* 11.1 Primary Expressions {{{ */
 692 Parenthetical
 693     : "(" LexPushInOff Expression LexPopIn ")" { $$ = $3; }
 694     ;
 695
 696 ParentheticalOpt
 697     : Parenthetical { $$ = $1; }
 698     | { $$ = NULL; }
 699     ;
 700
 701 PrimaryExpression
 702     : "this" { $$ = $1; }
 703     | Identifier { $$ = CYNew CYVariable($1); }
 704     | Literal { $$ = $1; }
 705     | ArrayLiteral { $$ = $1; }
 706     | ObjectLiteral { $$ = $1; }
 707     | FunctionExpression { $$ = $1; }
 708     | Parenthetical { $$ = $1; }
 709     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 710     ;
 711 /* }}} */
 712 /* 11.1.4.1 Array Initialiser {{{ */
 713 ArrayLiteral
 714     : "[" LexPushInOff ElementListOpt LexPopIn "]" { $$ = CYNew CYArray($3); }
 715     ;
 716
 717 Element
 718     : AssignmentExpression { $$ = $1; }
 719     ;
 720
 721 ElementOpt
 722     : Element { $$ = $1; }
 723     | LexSetRegExp { $$ = NULL; }
 724     ;
 725
 726 ElementList
 727     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 728     | Element { $$ = CYNew CYElement($1, NULL); }
 729     ;
 730
 731 ElementListOpt
 732     : ElementList { $$ = $1; }
 733     | LexSetRegExp { $$ = NULL; }
 734     ;
 735 /* }}} */
 736 /* 11.1.5 Object Initialiser {{{ */
 737 ObjectLiteral
 738     : BRACE LexPushInOff PropertyNameAndValueListOpt LexPopIn "}" { $$ = CYNew CYObject($3); }
 739     ;
 740
 741 PropertyNameAndValueList_
 742     : "," PropertyNameAndValueList { $$ = $2; }
 743     | { $$ = NULL; }
 744     ;
 745
 746 PropertyNameAndValueList
 747     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = CYNew CYProperty($1, $3, $4); }
 748     ;
 749
 750 PropertyNameAndValueListOpt
 751     : PropertyNameAndValueList { $$ = $1; }
 752     | { $$ = NULL; }
 753     ;
 754
 755 PropertyName_
 756     : Identifier { $$ = $1; }
 757     | StringLiteral { $$ = $1; }
 758     | NumericLiteral { $$ = $1; }
 759     ;
 760
 761 PropertyName
 762     : LexSetRegExp PropertyName_ { $$ = $2; }
 763     ;
 764 /* }}} */
 765
 766 /* 11.2 Left-Hand-Side Expressions {{{ */
 767 MemberAccess
 768     : "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYDirectMember(NULL, $3); }
 769     | "." Identifier { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 770     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 771     ;
 772
 773 MemberExpression_
 774     : MemberExpression { $$ = $1; }
 775     //| "super" { $$ = $1; }
 776     ;
 777
 778 MemberExpression
 779     : LexSetRegExp PrimaryExpression { $$ = $2; }
 780     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 781     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 782     ;
 783
 784 NewExpression
 785     : MemberExpression { $$ = $1; }
 786     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 787     ;
 788
 789 CallExpression_
 790     : MemberExpression_
 791     | CallExpression
 792     ;
 793
 794 CallExpression
 795     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 796     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 797     ;
 798
 799 Arguments
 800     : "(" LexPushInOff ArgumentListOpt LexPopIn ")" { $$ = $3; }
 801     ;
 802
 803 ArgumentList_
 804     : "," ArgumentList { $$ = $2; }
 805     | { $$ = NULL; }
 806     ;
 807
 808 ArgumentList
 809     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 810     ;
 811
 812 ArgumentListOpt
 813     : ArgumentList { $$ = $1; }
 814     | LexSetRegExp { $$ = NULL; }
 815     ;
 816
 817 LeftHandSideExpression
 818     : NewExpression { $$ = $1; }
 819     | CallExpression { $$ = $1; }
 820     ;
 821 /* }}} */
 822 /* 11.3 Postfix Expressions {{{ */
 823 PostfixExpression
 824     : %prec "" LeftHandSideExpression { $$ = $1; }
 825     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 826     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 827     ;
 828 /* }}} */
 829 /* 11.4 Unary Operators {{{ */
 830 UnaryExpression_
 831     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 832     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 833     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 834     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 835     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 836     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 837     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 838     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 839     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 840     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 841     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 842     ;
 843
 844 UnaryExpression
 845     : PostfixExpression { $$ = $1; }
 846     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 847     ;
 848 /* }}} */
 849 /* 11.5 Multiplicative Operators {{{ */
 850 MultiplicativeExpression
 851     : UnaryExpression { $$ = $1; }
 852     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 853     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 854     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 855     ;
 856 /* }}} */
 857 /* 11.6 Additive Operators {{{ */
 858 AdditiveExpression
 859     : MultiplicativeExpression { $$ = $1; }
 860     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 861     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 862     ;
 863 /* }}} */
 864 /* 11.7 Bitwise Shift Operators {{{ */
 865 ShiftExpression
 866     : AdditiveExpression { $$ = $1; }
 867     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 868     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 869     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 870     ;
 871 /* }}} */
 872 /* 11.8 Relational Operators {{{ */
 873 RelationalExpression
 874     : ShiftExpression { $$ = $1; }
 875     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 876     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 877     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 878     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 879     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 880     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 881     ;
 882 /* }}} */
 883 /* 11.9 Equality Operators {{{ */
 884 EqualityExpression
 885     : RelationalExpression { $$ = $1; }
 886     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 887     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 888     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 889     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 890     ;
 891 /* }}} */
 892 /* 11.10 Binary Bitwise Operators {{{ */
 893 BitwiseANDExpression
 894     : EqualityExpression { $$ = $1; }
 895     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 896     ;
 897
 898 BitwiseXORExpression
 899     : BitwiseANDExpression { $$ = $1; }
 900     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 901     ;
 902
 903 BitwiseORExpression
 904     : BitwiseXORExpression { $$ = $1; }
 905     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 906     ;
 907 /* }}} */
 908 /* 11.11 Binary Logical Operators {{{ */
 909 LogicalANDExpression
 910     : BitwiseORExpression { $$ = $1; }
 911     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 912     ;
 913
 914 LogicalORExpression
 915     : LogicalANDExpression { $$ = $1; }
 916     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
 917     ;
 918 /* }}} */
 919 /* 11.12 Conditional Operator ( ? : ) {{{ */
 920 ConditionalExpression
 921     : LogicalORExpression { $$ = $1; }
 922     | LogicalORExpression "?" LexPushInOff AssignmentExpression LexPopIn ":" AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
 923     ;
 924 /* }}} */
 925 /* 11.13 Assignment Operators {{{ */
 926 AssignmentExpression
 927     : ConditionalExpression { $$ = $1; }
 928     | ArrowFunction { $$ = $1; }
 929     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
 930     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
 931     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
 932     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
 933     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
 934     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
 935     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
 936     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
 937     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
 938     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
 939     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
 940     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
 941     ;
 942 /* }}} */
 943 /* 11.14 Comma Operator {{{ */
 944 Expression_
 945     : "," Expression { $$ = $2; }
 946     | { $$ = CYNew CYCompound(); }
 947     ;
 948
 949 Expression
 950     : AssignmentExpression Expression_ { $2->AddPrev($1); $$ = $2; }
 951     ;
 952
 953 ExpressionOpt
 954     : Expression { $$ = $1; }
 955     | LexSetRegExp { $$ = NULL; }
 956     ;
 957 /* }}} */
 958
 959 /* 12 Statements {{{ */
 960 Statement__
 961     : Block { $$ = $1; }
 962     | VariableStatement { $$ = $1; }
 963     | EmptyStatement { $$ = $1; }
 964     | IfStatement { $$ = $1; }
 965     | BreakableStatement { $$ = $1; }
 966     | ContinueStatement { $$ = $1; }
 967     | BreakStatement { $$ = $1; }
 968     | ReturnStatement { $$ = $1; }
 969     | WithStatement { $$ = $1; }
 970     | LabelledStatement { $$ = $1; }
 971     | ThrowStatement { $$ = $1; }
 972     | TryStatement { $$ = $1; }
 973     | DebuggerStatement { $$ = $1; }
 974     ;
 975
 976 Statement_
 977     : LexSetRegExp Statement__ { $$ = $2; }
 978     | ExpressionStatement { $$ = $1; }
 979     ;
 980
 981 Statement
 982     : LexSetStatement Statement_ { $$ = $2; }
 983     ;
 984
 985 Declaration__
 986     : FunctionDeclaration { $$ = $1; }
 987     | LexicalDeclaration { $$ = $1; }
 988     ;
 989
 990 Declaration_
 991     : LexSetRegExp Declaration__ { $$ = $2; }
 992     ;
 993
 994 Declaration
 995     : LexSetStatement Declaration_ { $$ = $2; }
 996     ;
 997
 998 BreakableStatement
 999     : IterationStatement { $$ = $1; }
1000     | SwitchStatement { $$ = $1; }
1001     ;
1002 /* }}} */
1003 /* 12.1 Block {{{ */
1004 Block_
1005     : BRACE StatementListOpt "}" { $$ = $2; }
1006     ;
1007
1008 Block
1009     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1010     ;
1011
1012 StatementList
1013     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1014     ;
1015
1016 StatementListOpt
1017     : StatementList { $$ = $1; }
1018     | LexSetRegExp { $$ = NULL; }
1019     ;
1020
1021 StatementListItem
1022     : Statement { $$ = $1; }
1023     | Declaration { $$ = $1; }
1024     ;
1025 /* }}} */
1026 /* 12.2 Declarations {{{ */
1027 BindingIdentifier
1028     : Identifier { $$ = $1; }
1029     ;
1030
1031 // XXX: BindingPattern
1032 /* }}} */
1033 /* 12.2.1 Let and Const Declarations {{{ */
1034 LexicalDeclaration
1035     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1036     ;
1037
1038 LetOrConst
1039     : "let"
1040     | "const"
1041     ;
1042 /* }}} */
1043 /* 12.2.2 Variable Statement {{{ */
1044 VariableStatement
1045     : "var" VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1046     ;
1047
1048 VariableDeclarationList_
1049     : "," VariableDeclarationList { $$ = $2; }
1050     | { $$ = NULL; }
1051     ;
1052
1053 VariableDeclarationList
1054     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1055     ;
1056
1057 VariableDeclaration
1058     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1059     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1060     ;
1061
1062 Initialiser
1063     : "=" AssignmentExpression { $$ = $2; }
1064     ;
1065
1066 InitialiserOpt
1067     : Initialiser { $$ = $1; }
1068     | { $$ = NULL; }
1069     ;
1070 /* }}} */
1071 /* 12.2.4 Destructuring Binding Patterns {{{ */
1072 // XXX: *
1073
1074 BindingElement
1075     : SingleNameBinding { $$ = $1; }
1076     ;
1077
1078 SingleNameBinding
1079     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1080     ;
1081 /* }}} */
1082 /* 12.3 Empty Statement {{{ */
1083 EmptyStatement
1084     : ";" { $$ = CYNew CYEmpty(); }
1085     ;
1086 /* }}} */
1087 /* 12.4 Expression Statement {{{ */
1088 ExpressionStatement
1089     : Expression Terminator { $$ = CYNew CYExpress($1); }
1090     ;
1091 /* }}} */
1092 /* 12.5 The if Statement {{{ */
1093 ElseStatementOpt
1094     : "else" Statement { $$ = $2; }
1095     | %prec "if" { $$ = NULL; }
1096     ;
1097
1098 IfStatement
1099     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1100     ;
1101 /* }}} */
1102
1103 /* 12.6.1 The do-while Statement {{{ */
1104 IterationStatement
1105     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1106     ;
1107 /* }}} */
1108 /* 12.6.2 The while Statement {{{ */
1109 IterationStatement
1110     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1111     ;
1112 /* }}} */
1113 /* 12.6.3 The for Statement {{{ */
1114 IterationStatement
1115     : "for" "(" LexPushInOn ForStatementInitialiser LexPopIn ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1116     ;
1117
1118 ForStatementInitialiser
1119     : ExpressionOpt { $$ = $1; }
1120     | LexSetRegExp "var" VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1121     ;
1122 /* }}} */
1123 /* 12.6.4 The for-in and for-of Statements {{{ */
1124 IterationStatement
1125     : "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1126     | "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "of" Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1127     ;
1128
1129 ForInStatementInitialiser
1130     : LeftHandSideExpression { $$ = $1; }
1131     | LexSetRegExp "var" VariableDeclaration { $$ = $3; }
1132     ;
1133 /* }}} */
1134
1135 /* 12.7 The continue Statement {{{ */
1136 ContinueStatement
1137     : "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1138     ;
1139 /* }}} */
1140 /* 12.8 The break Statement {{{ */
1141 BreakStatement
1142     : "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1143     ;
1144 /* }}} */
1145 /* 12.9 The return Statement {{{ */
1146 ReturnStatement
1147     : "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1148     ;
1149 /* }}} */
1150 /* 12.10 The with Statement {{{ */
1151 WithStatement
1152     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1153     ;
1154 /* }}} */
1155
1156 /* 12.11 The switch Statement {{{ */
1157 SwitchStatement
1158     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1159     ;
1160
1161 CaseBlock
1162     : BRACE CaseClausesOpt "}" { $$ = $2; }
1163     ;
1164
1165 CaseClause
1166     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1167     ;
1168
1169 CaseClausesOpt
1170     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1171     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1172     | { $$ = NULL; }
1173     ;
1174
1175 DefaultClause
1176     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1177     ;
1178 /* }}} */
1179 /* 12.12 Labelled Statements {{{ */
1180 LabelledStatement
1181     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1182     ;
1183 /* }}} */
1184 /* 12.13 The throw Statement {{{ */
1185 ThrowStatement
1186     : "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1187     ;
1188 /* }}} */
1189 /* 12.14 The try Statement {{{ */
1190 TryStatement
1191     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1192     ;
1193
1194 CatchOpt
1195     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1196     | { $$ = NULL; }
1197     ;
1198
1199 FinallyOpt
1200     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1201     | { $$ = NULL; }
1202     ;
1203 /* }}} */
1204 /* 12.14 The debugger Statement {{{ */
1205 DebuggerStatement
1206     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1207     ;
1208 /* }}} */
1209
1210 /* 13.1 Function Definitions {{{ */
1211 FunctionDeclaration
1212     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1213     ;
1214
1215 FunctionExpression
1216     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt LexPopIn ")" BRACE LexPushInOff FunctionBody LexPopIn "}" { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1217     ;
1218
1219 FormalParameterList_
1220     : "," FormalParameterList { $$ = $2; }
1221     | { $$ = NULL; }
1222     ;
1223
1224 FormalParameterList
1225     // XXX: : FunctionRestParameter { $$ = $1; }
1226     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1227     ;
1228
1229 FormalParameterListOpt
1230     : FormalParameterList
1231     | { $$ = NULL; }
1232     ;
1233
1234 /* XXX: FunctionRestParameter
1235     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1236     ;*/
1237
1238 FormalParameter
1239     : BindingElement { $$ = $1; }
1240     ;
1241
1242 FunctionBody
1243     : StatementListOpt { $$ = $1; }
1244     ;
1245 /* }}} */
1246 /* 13.2 Arrow Function Definitions {{{ */
1247 ArrowFunction
1248     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFunctionExpression(NULL, $2, $5); }
1249     ;
1250
1251 ArrowParameters
1252     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1253     //| ParentheticalOpt { $$ = $1; }
1254     ;
1255
1256 ConciseBody
1257     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1258     | ";{" LexPushInOff FunctionBody LexPopIn "}" { $$ = $3; }
1259     ;
1260 /* }}} */
1261 /* 14 Program {{{ */
1262 Program
1263     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1264     ;
1265
1266 ProgramBody
1267     : StatementList { $$ = $1; }
1268     ;
1269
1270 ProgramBodyOpt
1271     : ProgramBody { $$ = $1; }
1272     | { $$ = NULL; }
1273     ;
1274 /* }}} */
1275
1276 @begin ObjectiveC
1277 /* Cycript (Objective-C): @class Declaration {{{ */
1278 ClassSuperOpt
1279     /* XXX: why the hell did I choose MemberExpression? */
1280     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1281     | { $$ = NULL; }
1282     ;
1283
1284 ClassField
1285     : Expression Identifier ";"
1286     ;
1287
1288 ClassFieldList
1289     : BRACE ClassFieldListOpt "}" { $$ = NULL; }
1290     ;
1291
1292 ClassFieldListOpt
1293     : ClassFieldListOpt ClassField
1294     |
1295     ;
1296
1297 MessageScope
1298     : "+" { $$ = false; }
1299     | "-" { $$ = true; }
1300     ;
1301
1302 TypeOpt
1303     : "(" Expression ")" { $$ = $2; }
1304     | "(" LexSetRegExp "void" ")" { $$ = NULL; }
1305     | { $$ = NULL; }
1306     ;
1307
1308 MessageParameter
1309     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1310     ;
1311
1312 MessageParameterList
1313     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1314     ;
1315
1316 MessageParameterListOpt
1317     : MessageParameterList { $$ = $1; }
1318     | { $$ = NULL; }
1319     ;
1320
1321 MessageParameters
1322     : MessageParameterList { $$ = $1; }
1323     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1324     ;
1325
1326 ClassMessageDeclaration
1327     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1328     ;
1329
1330 ClassMessageDeclarationListOpt
1331     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1332     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1333     | { $$ = NULL; }
1334     ;
1335
1336 ClassName
1337     : Identifier { $$ = $1; }
1338     | "(" AssignmentExpression ")" { $$ = $2; }
1339     ;
1340
1341 ClassNameOpt
1342     : ClassName { $$ = $1; }
1343     | { $$ = NULL; }
1344     ;
1345
1346 // XXX: this should be AssignmentExpressionNoRight
1347 ClassProtocols
1348     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1349     ;
1350
1351 ClassProtocolsOpt
1352     : "," ClassProtocols { $$ = $2; }
1353     | { $$ = NULL; }
1354     ;
1355
1356 ClassProtocolListOpt
1357     : "<" ClassProtocols ">" { $$ = $2; }
1358     | { $$ = NULL; }
1359     ;
1360
1361 ClassExpression
1362     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt LexPopIn "@end" { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1363     ;
1364
1365 ClassStatement
1366     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1367     ;
1368
1369 CategoryName
1370     : "(" WordOpt ")"
1371     ;
1372
1373 CategoryStatement
1374     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1375     ;
1376
1377 PrimaryExpression
1378     : ClassExpression { $$ = $1; }
1379     ;
1380
1381 Statement__
1382     : ClassStatement { $$ = $1; }
1383     | CategoryStatement { $$ = $1; }
1384     ;
1385 /* }}} */
1386 /* Cycript (Objective-C): Send Message {{{ */
1387 VariadicCall
1388     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1389     | { $$ = NULL; }
1390     ;
1391
1392 SelectorWordOpt
1393     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1394     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1395     ;
1396
1397 SelectorCall_
1398     : SelectorCall { $$ = $1; }
1399     | VariadicCall { $$ = $1; }
1400     ;
1401
1402 SelectorCall
1403     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1404     ;
1405
1406 SelectorList
1407     : SelectorCall { $$ = $1; }
1408     | Word { $$ = CYNew CYArgument($1, NULL); }
1409     ;
1410
1411 MessageExpression
1412     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList LexPopIn "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1413     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList LexPopIn "]" { $$ = CYNew CYSendSuper($6); }
1414     ;
1415
1416 SelectorExpression_
1417     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1418     ;
1419
1420 SelectorExpression
1421     : SelectorExpression_ { $$ = $1; }
1422     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1423     ;
1424
1425 SelectorExpressionOpt
1426     : SelectorExpression_ { $$ = $1; }
1427     | { $$ = NULL; }
1428     ;
1429
1430 PrimaryExpression
1431     : MessageExpression { $$ = $1; }
1432     | "@selector" "(" LexPushInOff SelectorExpression LexPopIn ")" { $$ = CYNew CYSelector($4); }
1433     ;
1434 /* }}} */
1435 /* Cycript (Objective-C): @import Directive {{{ */
1436 PathName
1437     : "/" PathName
1438     | "." PathName
1439     | Word PathName
1440     |
1441     ;
1442
1443 ImportPath
1444     : "<" PathName ">"
1445     | StringLiteral
1446     ;
1447
1448 StatementListItem
1449     : "@import" ImportPath { $$ = CYNew CYImport(); }
1450     ;
1451 /* }}} */
1452 @end
1453
1454 @begin C
1455 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1456 LeftHandSideExpression
1457     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1458     ;
1459
1460 UnaryExpression_
1461     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1462     ;
1463
1464 MemberAccess
1465     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1466     | "->" Identifier { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1467     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1468     ;
1469 /* }}} */
1470 @end
1471
1472 /* YUI: Documentation Comments {{{ */
1473 Statement__
1474     : Comment { $$ = $1; }
1475     ;
1476 /* }}} */
1477
1478 @begin E4X
1479 /* Lexer State {{{ */
1480 LexPushRegExp
1481     : { driver.PushCondition(CYDriver::RegExpCondition); }
1482     ;
1483
1484 LexPushXMLContent
1485     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1486     ;
1487
1488 LexPushXMLTag
1489     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1490     ;
1491
1492 LexPop
1493     : { driver.PopCondition(); }
1494     ;
1495
1496 LexSetXMLContent
1497     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1498     ;
1499
1500 LexSetXMLTag
1501     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1502     ;
1503 /* }}} */
1504
1505 XMLWhitespaceOpt
1506     : XMLWhitespace
1507     |
1508     ;
1509
1510 /* 8.1 Context Keywords {{{ */
1511 Identifier
1512     : "namespace" { $$ = $1; }
1513     | "xml" { $$ = $1; }
1514     ;
1515 /* }}} */
1516 /* 8.3 XML Initialiser Input Elements {{{ */
1517 XMLMarkup
1518     : XMLComment { $$ = $1; }
1519     | XMLCDATA { $$ = $1; }
1520     | XMLPI { $$ = $1; }
1521     ;
1522 /* }}} */
1523 /* 11.1 Primary Expressions {{{ */
1524 PrimaryExpression
1525     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1526     | XMLInitialiser { $$ = $1; }
1527     | XMLListInitialiser { $$ = $1; }
1528     ;
1529
1530 PropertyIdentifier
1531     : AttributeIdentifier { $$ = $1; }
1532     | QualifiedIdentifier { $$ = $1; }
1533     | WildcardIdentifier { $$ = $1; }
1534     ;
1535 /* }}} */
1536 /* 11.1.1 Attribute Identifiers {{{ */
1537 AttributeIdentifier
1538     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1539     ;
1540
1541 PropertySelector_
1542     : PropertySelector { $$ = $1; }
1543     | "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYSelector($3); }
1544     ;
1545
1546 PropertySelector
1547     : Identifier { $$ = CYNew CYSelector($1); }
1548     | WildcardIdentifier { $$ = $1; }
1549     ;
1550 /* }}} */
1551 /* 11.1.2 Qualified Identifiers {{{ */
1552 QualifiedIdentifier_
1553     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1554     | QualifiedIdentifier { $$ = $1; }
1555     ;
1556
1557 QualifiedIdentifier
1558     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1559     ;
1560 /* }}} */
1561 /* 11.1.3 Wildcard Identifiers {{{ */
1562 WildcardIdentifier
1563     : "*" { $$ = CYNew CYWildcard(); }
1564     ;
1565 /* }}} */
1566 /* 11.1.4 XML Initialiser {{{ */
1567 XMLInitialiser
1568     : XMLMarkup { $$ = $1; }
1569     | XMLElement { $$ = $1; }
1570     ;
1571
1572 XMLElement
1573     : "<" LexPushInOff XMLTagContent LexPop LexPopIn "/>"
1574     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop LexPopIn ">"
1575     ;
1576
1577 XMLTagContent
1578     : LexPushXMLTag XMLTagName XMLAttributes
1579     ;
1580
1581 XMLExpression
1582     : BRACE LexPushRegExp Expression LexPop "}"
1583     ;
1584
1585 XMLTagName
1586     : XMLExpression
1587     | XMLName
1588     ;
1589
1590 XMLAttributes_
1591     : XMLAttributes_ XMLAttribute
1592     |
1593     ;
1594
1595 XMLAttributes
1596     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1597     | XMLAttributes_ XMLWhitespaceOpt
1598     ;
1599
1600 XMLAttributeValue_
1601     : XMLExpression
1602     | XMLAttributeValue
1603     ;
1604
1605 XMLAttribute
1606     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1607     ;
1608
1609 XMLElementContent
1610     : XMLExpression XMLElementContentOpt
1611     | XMLMarkup XMLElementContentOpt
1612     | XMLText XMLElementContentOpt
1613     | XMLElement XMLElementContentOpt
1614     ;
1615
1616 XMLElementContentOpt
1617     : XMLElementContent
1618     |
1619     ;
1620 /* }}} */
1621 /* 11.1.5 XMLList Initialiser {{{ */
1622 XMLListInitialiser
1623     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop LexPopIn "</>" { $$ = CYNew CYXMLList($4); }
1624     ;
1625 /* }}} */
1626 /* 11.2 Left-Hand-Side Expressions {{{ */
1627 PropertyIdentifier_
1628     : Identifier { $$ = $1; }
1629     | PropertyIdentifier { $$ = $1; }
1630     ;
1631
1632 MemberAccess
1633     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1634     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1635     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1636     ;
1637 /* }}} */
1638 /* 12.1 The default xml namespace Statement {{{ */
1639 /* XXX: DefaultXMLNamespaceStatement
1640     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1641     ;
1642
1643 Statement__
1644     : DefaultXMLNamespaceStatement { $$ = $1; }
1645     ; */
1646 /* }}} */
1647 @end
1648
1649 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1650 PropertyNameAndValueList_
1651     : "," { $$ = NULL; }
1652     ;
1653 /* }}} */
1654
1655 /* JavaScript 1.7: Array Comprehensions {{{ */
1656 IfComprehension
1657     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1658     ;
1659
1660 ForComprehension
1661     : "for" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
1662     | "for" "each" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
1663     ;
1664
1665 ComprehensionList
1666     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1667     ;
1668
1669 ComprehensionListOpt
1670     : ComprehensionList { $$ = $1; }
1671     | IfComprehension { $$ = $1; }
1672     | { $$ = NULL; }
1673     ;
1674
1675 PrimaryExpression
1676     : "[" LexPushInOff AssignmentExpression ComprehensionList LexPopIn "]" { $$ = CYNew CYArrayComprehension($3, $4); }
1677     ;
1678 /* }}} */
1679 /* JavaScript 1.7: for each {{{ */
1680 IterationStatement
1681     : "for" "each" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
1682     ;
1683 /* }}} */
1684 /* JavaScript 1.7: let Statements {{{ */
1685 LetStatement
1686     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1687     ;
1688
1689 Statement__
1690     : LetStatement
1691     ;
1692 /* }}} */
1693
1694 /* JavaScript FTW: Ruby Blocks {{{ */
1695 RubyProcParameterList_
1696     : "," RubyProcParameterList { $$ = $2; }
1697     | { $$ = NULL; }
1698     ;
1699
1700 RubyProcParameterList
1701     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1702     | { $$ = NULL; }
1703     ;
1704
1705 RubyProcParameters
1706     : "|" RubyProcParameterList "|" { $$ = $2; }
1707     | "||" { $$ = NULL; }
1708     ;
1709
1710 RubyProcParametersOpt
1711     : RubyProcParameters
1712     | { $$ = NULL; }
1713     ;
1714
1715 RubyProcExpression
1716     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1717     ;
1718
1719 PrimaryExpression
1720     : "{" LexPushInOff RubyProcParameters StatementListOpt LexPopIn "}" { $$ = CYNew CYRubyProc($3, $4); }
1721     ;
1722
1723 CallExpression
1724     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1725     ;
1726 /* }}} */
1727
1728 %%