Cycript.l

   1 %{
   2 #define YYLTYPE cy::location
   3 #include "Cycript.tab.hh"
   4 typedef cy::parser::token tk;
   5
   6 #define YY_EXTRA_TYPE CYDriver *
   7
   8 #define T yylval->newline_ = yyextra->state_ == CYNewLine;
   9 #define C T yyextra->state_ = CYClear;
  10 #define R T yyextra->state_ = CYRestricted;
  11
  12 #define E(prefix) L C BEGIN(INITIAL); { \
  13     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng + sizeof(prefix)))); \
  14     memcpy(value, prefix, sizeof(prefix) - 1); \
  15     memcpy(value + sizeof(prefix) - 1, yytext, yyleng); \
  16     value[yyleng + sizeof(prefix) - 1] = '\0'; \
  17     yylval->literal_ = new(yyextra->pool_) CYRegEx(value); \
  18     return tk::RegularExpressionLiteral; \
  19 }
  20
  21 #define N \
  22     if (yyextra->state_ != CYNewLine) { \
  23         bool restricted(yyextra->state_ == CYRestricted); \
  24         if (restricted) { \
  25             yyextra->state_ = CYClear; \
  26             return tk::NewLine; \
  27         } else \
  28             yyextra->state_ = CYNewLine; \
  29     }
  30
  31 #define L { \
  32     yylloc->step(); \
  33     yylloc->columns(yyleng); \
  34 }
  35
  36 int H(char c) {
  37     if (c >= '0' && c <= '9')
  38         return c - '0';
  39     if (c >= 'a' && c <= 'f')
  40         return c - 'a' + 10;
  41     if (c >= 'A' && c <= 'F')
  42         return c - 'A' + 10;
  43     return -1;
  44 }
  45
  46 #define YY_INPUT(data, value, size) { \
  47     if (yyextra->file_ != NULL) { \
  48         size_t copy(fread(data, 1, size, yyextra->file_)); \
  49         value = copy == 0 ? YY_NULL : copy; \
  50     } else if (yyextra->size_ == 0) \
  51         value = YY_NULL; \
  52     else { \
  53         size_t copy(std::min(size, yyextra->size_)); \
  54         memcpy(data, yyextra->data_, copy); \
  55         yyextra->data_ += copy; \
  56         yyextra->size_ -= copy; \
  57         value = copy; \
  58     } \
  59 }
  60
  61 %}
  62
  63 %option prefix="cy"
  64 %option bison-bridge
  65 %option bison-locations
  66 %option noyywrap
  67 %option yylineno
  68 %option nounput
  69 %option interactive
  70 %option reentrant
  71
  72 Exponent [eE][+-]?[0-9]+
  73 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
  74
  75 IdentifierStart [a-zA-Z$_]
  76 IdentifierPart  [a-zA-Z$_0-9]
  77
  78 NonTerminator [^\n]
  79 BackslashSequence \\{NonTerminator}
  80 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
  81 RegularExpressionChar [^\n\\/]|{BackslashSequence}
  82 RegularExpressionFlags {IdentifierPart}*
  83 RegularExpressionChars {RegularExpressionChar}*
  84 RegularExpressionBody_ {RegularExpressionChars}
  85 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionBody_}
  86
  87 RegularExpressionEnd_ \/{RegularExpressionFlags}
  88 RegularExpressionRest_ {RegularExpressionBody_}{RegularExpressionEnd_}
  89 RegularExpressionStart_ {RegularExpressionBody}{RegularExpressionEnd_}
  90
  91 %x res
  92 %x rer
  93
  94 %%
  95
  96 <res>{RegularExpressionStart_} E("/")
  97 <rer>{RegularExpressionRest_} E("/=")
  98
  99 \/\/[^\n]* L
 100
 101 \/\*(\n|[^\*]|\*[^/])*\*\/ {
 102     // XXX: supposedly I will be screwed on very very long multi-line comments and need to replace this with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf
 103
 104     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) {
 105         unsigned lines(0);
 106         size_t left;
 107
 108         do {
 109             ++lines;
 110             left = yyleng - (nl - yytext) - 1;
 111             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left));
 112         } while (nl != NULL);
 113
 114         yylloc->end.lines(lines);
 115         yylloc->end.columns(left);
 116         yylloc->step();
 117
 118         N
 119     } else L
 120 }
 121
 122 "&"    L C return tk::Ampersand;
 123 "&&"   L C return tk::AmpersandAmpersand;
 124 "&="   L C return tk::AmpersandEqual;
 125 "^"    L C return tk::Carrot;
 126 "^="   L C return tk::CarrotEqual;
 127 "="    L C return tk::Equal;
 128 "=="   L C return tk::EqualEqual;
 129 "==="  L C return tk::EqualEqualEqual;
 130 "!"    L C return tk::Exclamation;
 131 "!="   L C return tk::ExclamationEqual;
 132 "!=="  L C return tk::ExclamationEqualEqual;
 133 "-"    L C return tk::Hyphen;
 134 "-="   L C return tk::HyphenEqual;
 135 "--"   L C return yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen;
 136 "->"   L C return tk::HyphenRight;
 137 "<"    L C return tk::Left;
 138 "<="   L C return tk::LeftEqual;
 139 "<<"   L C return tk::LeftLeft;
 140 "<<="  L C return tk::LeftLeftEqual;
 141 "%"    L C return tk::Percent;
 142 "%="   L C return tk::PercentEqual;
 143 "."    L C return tk::Period;
 144 "|"    L C return tk::Pipe;
 145 "|="   L C return tk::PipeEqual;
 146 "||"   L C return tk::PipePipe;
 147 "+"    L C return tk::Plus;
 148 "+="   L C return tk::PlusEqual;
 149 "++"   L C return yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus;
 150 ">"    L C return tk::Right;
 151 ">="   L C return tk::RightEqual;
 152 ">>"   L C return tk::RightRight;
 153 ">>="  L C return tk::RightRightEqual;
 154 ">>>"  L C return tk::RightRightRight;
 155 ">>>=" L C return tk::RightRightRightEqual;
 156 "/"    L C return tk::Slash;
 157 "/="   L C return tk::SlashEqual;
 158 "*"    L C return tk::Star;
 159 "*="   L C return tk::StarEqual;
 160 "~"    L C return tk::Tilde;
 161
 162 ":"    L C return tk::Colon;
 163 ","    L C return tk::Comma;
 164 "?"    L C return tk::Question;
 165 ";"    L C return tk::SemiColon;
 166
 167 "("    L C return tk::OpenParen;
 168 ")"    L C return tk::CloseParen;
 169
 170 "{"    L C return tk::OpenBrace;
 171 "}"    L C return tk::CloseBrace;
 172
 173 "["    L C return tk::OpenBracket;
 174 "]"    L C return tk::CloseBracket;
 175
 176 "@class"       L C return tk::AtClass;
 177 "@end"         L C return tk::AtEnd;
 178 "@selector"    L C return tk::AtSelector;
 179
 180 "false"        L C yylval->false_ = new(yyextra->pool_) CYFalse(); return tk::False;
 181 "null"         L C yylval->null_ = new(yyextra->pool_) CYNull(); return tk::Null;
 182 "true"         L C yylval->true_ = new(yyextra->pool_) CYTrue(); return tk::True;
 183
 184 "break"        L R yylval->word_ = new(yyextra->pool_) CYWord("break"); return tk::Break;
 185 "case"         L C yylval->word_ = new(yyextra->pool_) CYWord("case"); return tk::Case;
 186 "catch"        L C yylval->word_ = new(yyextra->pool_) CYWord("catch"); return tk::Catch;
 187 "continue"     L R yylval->word_ = new(yyextra->pool_) CYWord("continue"); return tk::Continue;
 188 "default"      L C yylval->word_ = new(yyextra->pool_) CYWord("default"); return tk::Default;
 189 "delete"       L C yylval->word_ = new(yyextra->pool_) CYWord("delete"); return tk::Delete;
 190 "do"           L C yylval->word_ = new(yyextra->pool_) CYWord("do"); return tk::Do;
 191 "else"         L C yylval->word_ = new(yyextra->pool_) CYWord("else"); return tk::Else;
 192 "finally"      L C yylval->word_ = new(yyextra->pool_) CYWord("finally"); return tk::Finally;
 193 "for"          L C yylval->word_ = new(yyextra->pool_) CYWord("for"); return tk::For;
 194 "function"     L C yylval->word_ = new(yyextra->pool_) CYWord("function"); return tk::Function;
 195 "if"           L C yylval->word_ = new(yyextra->pool_) CYWord("if"); return tk::If;
 196 "in"           L C yylval->word_ = new(yyextra->pool_) CYWord("in"); return tk::In;
 197 "instanceof"   L C yylval->word_ = new(yyextra->pool_) CYWord("instanceof"); return tk::InstanceOf;
 198 "new"          L C yylval->word_ = new(yyextra->pool_) CYWord("new"); return tk::New;
 199 "return"       L R yylval->word_ = new(yyextra->pool_) CYWord("return"); return tk::Return;
 200 "switch"       L C yylval->word_ = new(yyextra->pool_) CYWord("switch"); return tk::Switch;
 201 "this"         L C yylval->this_ = new(yyextra->pool_) CYThis(); return tk::This;
 202 "throw"        L R yylval->word_ = new(yyextra->pool_) CYWord("throw"); return tk::Throw;
 203 "try"          L C yylval->word_ = new(yyextra->pool_) CYWord("try"); return tk::Try;
 204 "typeof"       L C yylval->word_ = new(yyextra->pool_) CYWord("typeof"); return tk::TypeOf;
 205 "var"          L C yylval->word_ = new(yyextra->pool_) CYWord("var"); return tk::Var;
 206 "void"         L C yylval->word_ = new(yyextra->pool_) CYWord("void"); return tk::Void;
 207 "while"        L C yylval->word_ = new(yyextra->pool_) CYWord("while"); return tk::While;
 208 "with"         L C yylval->word_ = new(yyextra->pool_) CYWord("with"); return tk::With;
 209
 210 "debugger"     L C yylval->word_ = new(yyextra->pool_) CYWord("debugger"); return tk::Debugger;
 211
 212 "const"        L C yylval->word_ = new(yyextra->pool_) CYWord("const"); return tk::Const;
 213
 214 "class"        L C yylval->word_ = new(yyextra->pool_) CYWord("class"); return tk::Class;
 215 "enum"         L C yylval->word_ = new(yyextra->pool_) CYWord("enum"); return tk::Enum;
 216 "export"       L C yylval->word_ = new(yyextra->pool_) CYWord("export"); return tk::Export;
 217 "extends"      L C yylval->word_ = new(yyextra->pool_) CYWord("extends"); return tk::Extends;
 218 "import"       L C yylval->word_ = new(yyextra->pool_) CYWord("import"); return tk::Import;
 219 "super"        L C yylval->word_ = new(yyextra->pool_) CYWord("super"); return tk::Super;
 220
 221 "implements"   L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("implements"); return tk::Implements;
 222 "interface"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("interface"); return tk::Interface;
 223 "package"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("package"); return tk::Package;
 224 "private"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("private"); return tk::Private;
 225 "protected"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("protected"); return tk::Protected;
 226 "public"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("public"); return tk::Public;
 227 "static"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("static"); return tk::Static;
 228
 229 "abstract"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("abstract"); return tk::Abstract;
 230 "boolean"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("boolean"); return tk::Boolean;
 231 "byte"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("byte"); return tk::Byte;
 232 "char"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("char"); return tk::Char;
 233 "double"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("double"); return tk::Double;
 234 "final"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("final"); return tk::Final;
 235 "float"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("float"); return tk::Float;
 236 "goto"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("goto"); return tk::Goto;
 237 "int"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("int"); return tk::Int;
 238 "long"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("long"); return tk::Long;
 239 "native"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("native"); return tk::Native;
 240 "short"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("short"); return tk::Short;
 241 "synchronized" L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("synchronized"); return tk::Synchronized;
 242 "throws"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("throws"); return tk::Throws;
 243 "transient"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("transient"); return tk::Transient;
 244 "volatile"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("volatile"); return tk::Volatile;
 245
 246 "let"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("let"); return tk::Let;
 247 "yield"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("yield"); return tk::Yield;
 248
 249 "each"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("each"); return tk::Each;
 250
 251 {IdentifierStart}{IdentifierPart}* yylval->identifier_ = new(yyextra->pool_) CYIdentifier(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); L C return tk::Identifier_;
 252
 253 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? yylval->number_ = new(yyextra->pool_) CYNumber(strtod(yytext, NULL)); L C return tk::NumericLiteral;
 254
 255 0[xX][0-9a-fA-F]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 16)); return tk::NumericLiteral;
 256
 257 0[bB][0-1]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 2)); return tk::NumericLiteral;
 258
 259 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 260     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng)));
 261     char *local(value);
 262
 263     for (int i(1); i != yyleng - 1; ++i) {
 264         char next(yytext[i]);
 265
 266         if (yytext[i] == '\\')
 267             switch (next = yytext[++i]) {
 268                 case '\n': continue;
 269                 case '\\': next = '\\'; break;
 270                 case '\'': next = '\''; break;
 271                 case '"': next = '"'; break;
 272                 case 'b': next = '\b'; break;
 273                 case 'f': next = '\f'; break;
 274                 case 'n': next = '\n'; break;
 275                 case 'r': next = '\r'; break;
 276                 case 't': next = '\t'; break;
 277                 case 'v': next = '\v'; break;
 278                 case '0': next = '\0'; break;
 279
 280                 case 'x':
 281                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 282                     i += 2;
 283                 break;
 284             }
 285
 286         *local++ = next;
 287     }
 288
 289     *local = '\0';
 290     yylval->string_ = new(yyextra->pool_) CYString(value, local - value);
 291     return tk::StringLiteral;
 292 }
 293
 294 \r?\n yylloc->end.lines(); yylloc->step(); N
 295
 296 [ \t] L
 297 <<EOF>> L yyterminate();
 298
 299 . L {
 300     CYDriver::Error error;
 301     error.location_ = *yylloc;
 302     error.message_ = "syntax error, unknown token";
 303     yyextra->errors_.push_back(error);
 304     yyterminate();
 305 }
 306
 307 %%
 308
 309 void CYDriver::ScannerInit() {
 310     cylex_init(&scanner_);
 311     cyset_extra(this, scanner_);
 312 }
 313
 314 void CYDriver::ScannerDestroy() {
 315     cylex_destroy(scanner_);
 316 }
 317
 318 void CYDriver::SetCondition(Condition condition) {
 319     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 320
 321     switch (condition) {
 322         case RegExStart:
 323             BEGIN(res);
 324             break;
 325         case RegExRest:
 326             BEGIN(rer);
 327             break;
 328         default:
 329             _assert(false);
 330     }
 331 }