Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 typedef struct {
  43     bool newline_;
  44
  45     union {
  46         bool bool_;
  47
  48         CYDriver::Condition condition_;
  49
  50         CYArgument *argument_;
  51         CYAssignment *assignment_;
  52         CYBoolean *boolean_;
  53         CYClause *clause_;
  54         cy::Syntax::Catch *catch_;
  55         CYComment *comment_;
  56         CYComprehension *comprehension_;
  57         CYCompound *compound_;
  58         CYDeclaration *declaration_;
  59         CYDeclarations *declarations_;
  60         CYElement *element_;
  61         CYExpression *expression_;
  62         CYFalse *false_;
  63         CYFinally *finally_;
  64         CYForInitialiser *for_;
  65         CYForInInitialiser *forin_;
  66         CYFunctionParameter *functionParameter_;
  67         CYIdentifier *identifier_;
  68         CYInfix *infix_;
  69         CYLiteral *literal_;
  70         CYMember *member_;
  71         CYNull *null_;
  72         CYNumber *number_;
  73         CYProgram *program_;
  74         CYProperty *property_;
  75         CYPropertyName *propertyName_;
  76         CYRubyProc *rubyProc_;
  77         CYStatement *statement_;
  78         CYString *string_;
  79         CYThis *this_;
  80         CYTrue *true_;
  81         CYWord *word_;
  82
  83 @begin ObjectiveC
  84         CYClassName *className_;
  85         CYField *field_;
  86         CYMessage *message_;
  87         CYMessageParameter *messageParameter_;
  88         CYProtocol *protocol_;
  89         CYSelectorPart *selector_;
  90 @end
  91
  92 @begin E4X
  93         CYAttribute *attribute_;
  94         CYPropertyIdentifier *propertyIdentifier_;
  95         CYSelector *selector_;
  96 @end
  97     };
  98 } YYSTYPE;
  99
 100 #define YYSTYPE YYSTYPE
 101 @if Bison24 }
 102
 103 @if Bison24 %code provides {
 104 int cylex(YYSTYPE *, cy::location *, void *);
 105 @if Bison24 }
 106
 107 @if Bison23 %}
 108
 109 %name-prefix="cy"
 110
 111 @if Bison23 %skeleton "lalr1.cc"
 112 @if Bison24 %language "C++"
 113
 114 %initial-action {
 115     @$.begin.filename = @$.end.filename = &driver.filename_;
 116 };
 117
 118 %locations
 119 %defines
 120
 121 //%glr-parser
 122 //%expect 1
 123
 124 %error-verbose
 125
 126 %parse-param { CYDriver &driver }
 127 %lex-param { void *cyscanner }
 128
 129 @begin E4X
 130 %token XMLCDATA
 131 %token XMLComment
 132 %token XMLPI
 133
 134 %token XMLAttributeValue
 135 %token XMLName
 136 %token XMLTagCharacters
 137 %token XMLText
 138 %token XMLWhitespace
 139 @end
 140
 141 @begin E4X
 142 %token LeftRight "<>"
 143 %token LeftSlashRight "</>"
 144
 145 %token SlashRight "/>"
 146 %token LeftSlash "</"
 147
 148 %token ColonColon "::"
 149 %token PeriodPeriod ".."
 150 @end
 151
 152 @begin E4X ObjectiveC
 153 %token At "@"
 154 @end
 155
 156 %token Ampersand "&"
 157 %token AmpersandAmpersand "&&"
 158 %token AmpersandEqual "&="
 159 %token Carrot "^"
 160 %token CarrotEqual "^="
 161 %token Equal "="
 162 %token EqualEqual "=="
 163 %token EqualEqualEqual "==="
 164 %token EqualRight "=>"
 165 %token Exclamation "!"
 166 %token ExclamationEqual "!="
 167 %token ExclamationEqualEqual "!=="
 168 %token Hyphen "-"
 169 %token HyphenEqual "-="
 170 %token HyphenHyphen "--"
 171 %token HyphenHyphen_ "\n--"
 172 %token HyphenRight "->"
 173 %token Left "<"
 174 %token LeftEqual "<="
 175 %token LeftLeft "<<"
 176 %token LeftLeftEqual "<<="
 177 %token Percent "%"
 178 %token PercentEqual "%="
 179 %token Period "."
 180 %token PeriodPeriodPeriod "..."
 181 %token Pipe "|"
 182 %token PipeEqual "|="
 183 %token PipePipe "||"
 184 %token Plus "+"
 185 %token PlusEqual "+="
 186 %token PlusPlus "++"
 187 %token PlusPlus_ "\n++"
 188 %token Right ">"
 189 %token RightEqual ">="
 190 %token RightRight ">>"
 191 %token RightRightEqual ">>="
 192 %token RightRightRight ">>>"
 193 %token RightRightRightEqual ">>>="
 194 %token Slash "/"
 195 %token SlashEqual "/="
 196 %token Star "*"
 197 %token StarEqual "*="
 198 %token Tilde "~"
 199
 200 %token Colon ":"
 201 %token Comma ","
 202 %token Question "?"
 203 %token SemiColon ";"
 204 %token NewLine "\n"
 205
 206 %token <comment_> Comment
 207
 208 %token OpenParen "("
 209 %token CloseParen ")"
 210
 211 %token OpenBrace "{"
 212 %token OpenBrace_ "\n{"
 213 %token OpenBrace__ ";{"
 214 %token CloseBrace "}"
 215
 216 %token OpenBracket "["
 217 %token CloseBracket "]"
 218
 219 @begin Java
 220 %token AtClass "@class"
 221 @end
 222
 223 @begin ObjectiveC
 224 %token AtImplementation "@implementation"
 225 %token AtImplementation_ ";@implementation"
 226 %token AtImport "@import"
 227 %token AtEnd "@end"
 228 %token AtSelector "@selector"
 229 @end
 230
 231 %token <false_> False "false"
 232 %token <null_> Null "null"
 233 %token <true_> True "true"
 234
 235 // ES3/ES5/WIE/JSC Reserved
 236 %token <word_> Break "break"
 237 %token <word_> Case "case"
 238 %token <word_> Catch "catch"
 239 %token <word_> Continue "continue"
 240 %token <word_> Default "default"
 241 %token <word_> Delete "delete"
 242 %token <word_> Do "do"
 243 %token <word_> Else "else"
 244 %token <word_> Finally "finally"
 245 %token <word_> For "for"
 246 %token <word_> Function "function"
 247 %token <word_> Function_ ";function"
 248 %token <word_> If "if"
 249 %token <word_> In "in"
 250 %token <word_> In_ "!in"
 251 %token <word_> InstanceOf "instanceof"
 252 %token <word_> New "new"
 253 %token <word_> Return "return"
 254 %token <word_> Switch "switch"
 255 %token <this_> This "this"
 256 %token <word_> Throw "throw"
 257 %token <word_> Try "try"
 258 %token <word_> TypeOf "typeof"
 259 %token <word_> Var "var"
 260 %token <word_> Void "void"
 261 %token <word_> While "while"
 262 %token <word_> With "with"
 263
 264 // ES3/IE6 Future, ES5/JSC Reserved
 265 %token <word_> Debugger "debugger"
 266
 267 // ES3/ES5/IE6 Future, JSC Reserved
 268 %token <word_> Const "const"
 269
 270 // ES3/ES5/IE6/JSC Future
 271 %token <word_> Class "class"
 272 %token <word_> Enum "enum"
 273 %token <word_> Export "export"
 274 %token <word_> Extends "extends"
 275 %token <word_> Import "import"
 276 %token <word_> Super "super"
 277
 278 // ES3 Future, ES5 Strict Future
 279 %token <identifier_> Implements "implements"
 280 %token <identifier_> Interface "interface"
 281 %token <identifier_> Package "package"
 282 %token <identifier_> Private "private"
 283 %token <identifier_> Protected "protected"
 284 %token <identifier_> Public "public"
 285 %token <identifier_> Static "static"
 286
 287 // ES3 Future
 288 %token <identifier_> Abstract "abstract"
 289 %token <identifier_> Boolean "boolean"
 290 %token <identifier_> Byte "byte"
 291 %token <identifier_> Char "char"
 292 %token <identifier_> Double "double"
 293 %token <identifier_> Final "final"
 294 %token <identifier_> Float "float"
 295 %token <identifier_> Goto "goto"
 296 %token <identifier_> Int "int"
 297 %token <identifier_> Long "long"
 298 %token <identifier_> Native "native"
 299 %token <identifier_> Short "short"
 300 %token <identifier_> Synchronized "synchronized"
 301 %token <identifier_> Throws "throws"
 302 %token <identifier_> Transient "transient"
 303 %token <identifier_> Volatile "volatile"
 304
 305 // ES5 Strict
 306 %token <identifier_> Let "let"
 307 %token <identifier_> Yield "yield"
 308
 309 // Woah?!
 310 %token <identifier_> Each "each"
 311
 312 @begin E4X
 313 // E4X Conditional
 314 %token <identifier_> Namespace "namespace"
 315 %token <identifier_> XML "xml"
 316 @end
 317
 318 %token AutoComplete
 319
 320 %token <identifier_> Identifier_
 321 %token <number_> NumericLiteral
 322 %token <string_> StringLiteral
 323 %token <literal_> RegularExpressionLiteral
 324
 325 %type <expression_> AdditiveExpression
 326 %type <argument_> ArgumentList_
 327 %type <argument_> ArgumentList
 328 %type <argument_> ArgumentListOpt
 329 %type <argument_> Arguments
 330 %type <literal_> ArrayLiteral
 331 %type <expression_> ArrowFunction
 332 %type <functionParameter_> ArrowParameters
 333 %type <expression_> AssignmentExpression
 334 %type <identifier_> BindingIdentifier
 335 %type <expression_> BitwiseANDExpression
 336 %type <statement_> Block_
 337 %type <statement_> Block
 338 %type <boolean_> BooleanLiteral
 339 %type <declaration_> BindingElement
 340 %type <expression_> BitwiseORExpression
 341 %type <expression_> BitwiseXORExpression
 342 %type <statement_> BreakStatement
 343 %type <statement_> BreakableStatement
 344 %type <expression_> CallExpression_
 345 %type <expression_> CallExpression
 346 %type <clause_> CaseBlock
 347 %type <clause_> CaseClause
 348 %type <clause_> CaseClausesOpt
 349 %type <catch_> CatchOpt
 350 %type <comprehension_> ComprehensionList
 351 %type <comprehension_> ComprehensionListOpt
 352 %type <expression_> ConditionalExpression
 353 %type <statement_> ContinueStatement
 354 %type <statement_> ConciseBody
 355 %type <statement_> DebuggerStatement
 356 %type <statement_> Declaration__
 357 %type <statement_> Declaration_
 358 %type <statement_> Declaration
 359 %type <clause_> DefaultClause
 360 %type <statement_> DoWhileStatement
 361 %type <expression_> Element
 362 %type <expression_> ElementOpt
 363 %type <element_> ElementList
 364 %type <element_> ElementListOpt
 365 %type <statement_> ElseStatementOpt
 366 %type <statement_> EmptyStatement
 367 %type <expression_> EqualityExpression
 368 %type <compound_> Expression_
 369 %type <compound_> Expression
 370 %type <expression_> ExpressionOpt
 371 %type <statement_> ExpressionStatement
 372 %type <finally_> FinallyOpt
 373 %type <comprehension_> ForComprehension
 374 %type <statement_> ForStatement
 375 %type <for_> ForStatementInitialiser
 376 %type <statement_> ForInStatement
 377 %type <forin_> ForInStatementInitialiser
 378 %type <declaration_> FormalParameter
 379 %type <functionParameter_> FormalParameterList_
 380 %type <functionParameter_> FormalParameterList
 381 %type <functionParameter_> FormalParameterListOpt
 382 %type <statement_> FunctionBody
 383 %type <statement_> FunctionDeclaration
 384 %type <expression_> FunctionExpression
 385 %type <identifier_> Identifier
 386 %type <identifier_> IdentifierOpt
 387 %type <comprehension_> IfComprehension
 388 %type <statement_> IfStatement
 389 %type <expression_> Initialiser
 390 %type <expression_> InitialiserOpt
 391 %type <statement_> IterationStatement
 392 %type <statement_> LabelledStatement
 393 %type <expression_> LeftHandSideExpression
 394 %type <statement_> LetStatement
 395 %type <statement_> LexicalDeclaration
 396 %type <literal_> Literal
 397 %type <literal_> LiteralNoRE
 398 %type <expression_> LogicalANDExpression
 399 %type <expression_> LogicalORExpression
 400 %type <member_> MemberAccess
 401 %type <expression_> MemberExpression_
 402 %type <expression_> MemberExpression
 403 %type <expression_> MultiplicativeExpression
 404 %type <expression_> NewExpression
 405 %type <null_> NullLiteral
 406 %type <literal_> ObjectLiteral
 407 %type <compound_> Parenthetical
 408 %type <compound_> ParentheticalOpt
 409 %type <expression_> PostfixExpression
 410 %type <expression_> PrimaryExpression
 411 %type <statement_> Program
 412 %type <statement_> ProgramBody
 413 %type <statement_> ProgramBodyOpt
 414 %type <propertyName_> PropertyName_
 415 %type <propertyName_> PropertyName
 416 %type <property_> PropertyNameAndValueList_
 417 %type <property_> PropertyNameAndValueList
 418 %type <property_> PropertyNameAndValueListOpt
 419 %type <expression_> RelationalExpression
 420 %type <statement_> ReturnStatement
 421 %type <rubyProc_> RubyProcExpression
 422 %type <functionParameter_> RubyProcParameterList_
 423 %type <functionParameter_> RubyProcParameterList
 424 %type <functionParameter_> RubyProcParameters
 425 %type <functionParameter_> RubyProcParametersOpt
 426 %type <expression_> ShiftExpression
 427 %type <declaration_> SingleNameBinding
 428 %type <statement_> Statement__
 429 %type <statement_> Statement_
 430 %type <statement_> Statement
 431 %type <statement_> StatementList
 432 %type <statement_> StatementListOpt
 433 %type <statement_> StatementListItem
 434 %type <statement_> SwitchStatement
 435 %type <statement_> ThrowStatement
 436 %type <statement_> TryStatement
 437 %type <expression_> UnaryExpression_
 438 %type <expression_> UnaryExpression
 439 %type <declaration_> VariableDeclaration
 440 %type <declarations_> VariableDeclarationList_
 441 %type <declarations_> VariableDeclarationList
 442 %type <statement_> VariableStatement
 443 %type <statement_> WhileStatement
 444 %type <statement_> WithStatement
 445
 446 @begin ObjectiveC
 447 %type <statement_> CategoryStatement
 448 %type <expression_> ClassExpression
 449 %type <statement_> ClassStatement
 450 %type <expression_> ClassSuperOpt
 451 %type <field_> ClassFieldList
 452 %type <message_> ClassMessageDeclaration
 453 %type <message_> ClassMessageDeclarationListOpt
 454 %type <className_> ClassName
 455 %type <className_> ClassNameOpt
 456 %type <protocol_> ClassProtocolListOpt
 457 %type <protocol_> ClassProtocols
 458 %type <protocol_> ClassProtocolsOpt
 459 %type <expression_> MessageExpression
 460 %type <messageParameter_> MessageParameter
 461 %type <messageParameter_> MessageParameters
 462 %type <messageParameter_> MessageParameterList
 463 %type <messageParameter_> MessageParameterListOpt
 464 %type <bool_> MessageScope
 465 %type <argument_> SelectorCall_
 466 %type <argument_> SelectorCall
 467 %type <selector_> SelectorExpression_
 468 %type <selector_> SelectorExpression
 469 %type <selector_> SelectorExpressionOpt
 470 %type <argument_> SelectorList
 471 %type <word_> SelectorWordOpt
 472 %type <expression_> TypeOpt
 473 %type <argument_> VariadicCall
 474 %type <word_> Word
 475 %type <word_> WordOpt
 476 @end
 477
 478 @begin E4X
 479 %type <propertyIdentifier_> PropertyIdentifier_
 480 %type <selector_> PropertySelector_
 481 %type <selector_> PropertySelector
 482 %type <identifier_> QualifiedIdentifier_
 483 %type <identifier_> QualifiedIdentifier
 484 %type <identifier_> WildcardIdentifier
 485 %type <identifier_> XMLComment
 486 %type <identifier_> XMLCDATA
 487 %type <identifier_> XMLElement
 488 %type <identifier_> XMLElementContent
 489 %type <identifier_> XMLMarkup
 490 %type <identifier_> XMLPI
 491
 492 %type <attribute_> AttributeIdentifier
 493 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 494 %type <expression_> PropertyIdentifier
 495 %type <expression_> XMLListInitialiser
 496 %type <expression_> XMLInitialiser
 497 @end
 498
 499 %nonassoc ""
 500 %left "++" "--"
 501
 502 %nonassoc "if"
 503 %nonassoc "else"
 504
 505 %start Program
 506
 507 %%
 508
 509 /* Lexer State {{{ */
 510 LexPushInOn
 511     : { driver.in_.push(true); }
 512     ;
 513
 514 LexPushInOff
 515     : { driver.in_.push(false); }
 516     ;
 517
 518 LexPopIn
 519     : { driver.in_.pop(); }
 520     ;
 521
 522 LexSetRegExp
 523     : { driver.SetCondition(CYDriver::RegExpCondition); }
 524     ;
 525
 526 LexNoBrace
 527     : { if (yychar == yyempty_) driver.nobrace_ = true; else if (yychar == token::OpenBrace || yychar == token::OpenBrace_) yychar = token::OpenBrace__; }
 528     ;
 529
 530 LexNoFunction
 531     : { if (yychar == token::Function) yychar = token::Function_; }
 532     ;
 533
 534 LexSetStatement
 535     : LexNoBrace LexNoFunction
 536     ;
 537 /* }}} */
 538
 539 BRACE
 540     : "{"
 541     | "\n{"
 542     ;
 543
 544 StrictSemi
 545     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 546     ;
 547
 548 Terminator_
 549     : ";"
 550     | "\n" StrictSemi
 551     ;
 552
 553 Terminator
 554     : Terminator_
 555     | error { if (yychar != yyeof_ && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 556     ;
 557
 558 TerminatorOpt
 559     : Terminator_
 560     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 561     ;
 562
 563 /*CommaOpt
 564     : ","
 565     |
 566     ;*/
 567
 568 @begin ObjectiveC
 569 NewLineOpt
 570     : "\n"
 571     |
 572     ;
 573
 574 Word
 575     : Identifier { $$ = $1; }
 576     | "break" NewLineOpt { $$ = $1; }
 577     | "case" { $$ = $1; }
 578     | "catch" { $$ = $1; }
 579     | "class" { $$ = $1; }
 580     | "const" { $$ = $1; }
 581     | "continue" NewLineOpt { $$ = $1; }
 582     | "debugger" { $$ = $1; }
 583     | "default" { $$ = $1; }
 584     | "delete" { $$ = $1; }
 585     | "do" { $$ = $1; }
 586     | "else" { $$ = $1; }
 587     | "enum" { $$ = $1; }
 588     | "export" { $$ = $1; }
 589     | "extends" { $$ = $1; }
 590     | "false" { $$ = $1; }
 591     | "finally" { $$ = $1; }
 592     /* XXX: | "for" { $$ = $1; } */
 593     | "function" { $$ = $1; }
 594     | "if" { $$ = $1; }
 595     | "import" { $$ = $1; }
 596     /* XXX: | "in" { $$ = $1; } */
 597     /* XXX: | "instanceof" { $$ = $1; } */
 598     | "new" { $$ = $1; }
 599     | "null" { $$ = $1; }
 600     | "return" NewLineOpt { $$ = $1; }
 601     | "super" { $$ = $1; }
 602     | "switch" { $$ = $1; }
 603     | "this" { $$ = $1; }
 604     | "throw" NewLineOpt { $$ = $1; }
 605     | "true" { $$ = $1; }
 606     | "try" { $$ = $1; }
 607     | "typeof" { $$ = $1; }
 608     | "var" { $$ = $1; }
 609     | "void" { $$ = $1; }
 610     | "while" { $$ = $1; }
 611     | "with" { $$ = $1; }
 612     ;
 613
 614 WordOpt
 615     : Word { $$ = $1; }
 616     | { $$ = NULL; }
 617     ;
 618
 619 PrimaryExpression
 620     : "@" LiteralNoRE { $$ = CYNew CYBox($2); }
 621     | "@" ArrayLiteral { $$ = CYNew CYBox($2); }
 622     | "@" ObjectLiteral { $$ = CYNew CYBox($2); }
 623     | "@" Parenthetical { $$ = CYNew CYBox($2); }
 624     ;
 625 @end
 626
 627 Identifier
 628     : Identifier_ { $$ = $1; }
 629
 630     | "implements" { $$ = $1; }
 631     | "interface" { $$ = $1; }
 632     | "package" { $$ = $1; }
 633     | "private" { $$ = $1; }
 634     | "protected" { $$ = $1; }
 635     | "public" { $$ = $1; }
 636     | "static" { $$ = $1; }
 637
 638     | "abstract" { $$ = $1; }
 639     | "boolean" { $$ = $1; }
 640     | "byte" { $$ = $1; }
 641     | "char" { $$ = $1; }
 642     | "double" { $$ = $1; }
 643     | "final" { $$ = $1; }
 644     | "float" { $$ = $1; }
 645     | "goto" { $$ = $1; }
 646     | "int" { $$ = $1; }
 647     | "long" { $$ = $1; }
 648     | "native" { $$ = $1; }
 649     | "short" { $$ = $1; }
 650     | "synchronized" { $$ = $1; }
 651     | "throws" { $$ = $1; }
 652     | "transient" { $$ = $1; }
 653     | "volatile" { $$ = $1; }
 654
 655     // XXX: is this allowed?! | "let" { $$ = $1; }
 656     | "yield" { $$ = $1; }
 657
 658     | "each" { $$ = $1; }
 659     ;
 660
 661 IdentifierOpt
 662     : Identifier { $$ = $1; }
 663     | { $$ = NULL; }
 664     ;
 665
 666 LiteralNoRE
 667     : NullLiteral { $$ = $1; }
 668     | BooleanLiteral { $$ = $1; }
 669     | NumericLiteral { $$ = $1; }
 670     | StringLiteral { $$ = $1; }
 671     ;
 672
 673 Literal
 674     : LiteralNoRE { $$ = $1; }
 675     | RegularExpressionLiteral { $$ = $1; }
 676     ;
 677
 678 NullLiteral
 679     : "null" { $$ = $1; }
 680     ;
 681
 682 BooleanLiteral
 683     : "true" { $$ = $1; }
 684     | "false" { $$ = $1; }
 685     ;
 686
 687 /* 11.1 Primary Expressions {{{ */
 688 Parenthetical
 689     : "(" LexPushInOff Expression LexPopIn ")" { $$ = $3; }
 690     ;
 691
 692 ParentheticalOpt
 693     : Parenthetical { $$ = $1; }
 694     | { $$ = NULL; }
 695     ;
 696
 697 PrimaryExpression
 698     : "this" { $$ = $1; }
 699     | Identifier { $$ = CYNew CYVariable($1); }
 700     | Literal { $$ = $1; }
 701     | ArrayLiteral { $$ = $1; }
 702     | ObjectLiteral { $$ = $1; }
 703     | FunctionExpression { $$ = $1; }
 704     | Parenthetical { $$ = $1; }
 705     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 706     ;
 707 /* }}} */
 708 /* 11.1.4.1 Array Initialiser {{{ */
 709 ArrayLiteral
 710     : "[" LexPushInOff ElementListOpt LexPopIn "]" { $$ = CYNew CYArray($3); }
 711     ;
 712
 713 Element
 714     : AssignmentExpression { $$ = $1; }
 715     ;
 716
 717 ElementOpt
 718     : Element { $$ = $1; }
 719     | LexSetRegExp { $$ = NULL; }
 720     ;
 721
 722 ElementList
 723     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 724     | Element { $$ = CYNew CYElement($1, NULL); }
 725     ;
 726
 727 ElementListOpt
 728     : ElementList { $$ = $1; }
 729     | LexSetRegExp { $$ = NULL; }
 730     ;
 731 /* }}} */
 732 /* 11.1.5 Object Initialiser {{{ */
 733 ObjectLiteral
 734     : BRACE LexPushInOff PropertyNameAndValueListOpt LexPopIn "}" { $$ = CYNew CYObject($3); }
 735     ;
 736
 737 PropertyNameAndValueList_
 738     : "," PropertyNameAndValueList { $$ = $2; }
 739     | { $$ = NULL; }
 740     ;
 741
 742 PropertyNameAndValueList
 743     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = CYNew CYProperty($1, $3, $4); }
 744     ;
 745
 746 PropertyNameAndValueListOpt
 747     : PropertyNameAndValueList { $$ = $1; }
 748     | { $$ = NULL; }
 749     ;
 750
 751 PropertyName_
 752     : Identifier { $$ = $1; }
 753     | StringLiteral { $$ = $1; }
 754     | NumericLiteral { $$ = $1; }
 755     ;
 756
 757 PropertyName
 758     : LexSetRegExp PropertyName_ { $$ = $2; }
 759     ;
 760 /* }}} */
 761
 762 /* 11.2 Left-Hand-Side Expressions {{{ */
 763 MemberAccess
 764     : "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYDirectMember(NULL, $3); }
 765     | "." Identifier { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 766     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 767     ;
 768
 769 MemberExpression_
 770     : MemberExpression { $$ = $1; }
 771     //| "super" { $$ = $1; }
 772     ;
 773
 774 MemberExpression
 775     : LexSetRegExp PrimaryExpression { $$ = $2; }
 776     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 777     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 778     ;
 779
 780 NewExpression
 781     : MemberExpression { $$ = $1; }
 782     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 783     ;
 784
 785 CallExpression_
 786     : MemberExpression_
 787     | CallExpression
 788     ;
 789
 790 CallExpression
 791     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 792     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 793     ;
 794
 795 Arguments
 796     : "(" LexPushInOff ArgumentListOpt LexPopIn ")" { $$ = $3; }
 797     ;
 798
 799 ArgumentList_
 800     : "," ArgumentList { $$ = $2; }
 801     | { $$ = NULL; }
 802     ;
 803
 804 ArgumentList
 805     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 806     ;
 807
 808 ArgumentListOpt
 809     : ArgumentList { $$ = $1; }
 810     | LexSetRegExp { $$ = NULL; }
 811     ;
 812
 813 LeftHandSideExpression
 814     : NewExpression { $$ = $1; }
 815     | CallExpression { $$ = $1; }
 816     ;
 817 /* }}} */
 818 /* 11.3 Postfix Expressions {{{ */
 819 PostfixExpression
 820     : %prec "" LeftHandSideExpression { $$ = $1; }
 821     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 822     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 823     ;
 824 /* }}} */
 825 /* 11.4 Unary Operators {{{ */
 826 UnaryExpression_
 827     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 828     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 829     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 830     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 831     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 832     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 833     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 834     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 835     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 836     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 837     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 838     ;
 839
 840 UnaryExpression
 841     : PostfixExpression { $$ = $1; }
 842     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 843     ;
 844 /* }}} */
 845 /* 11.5 Multiplicative Operators {{{ */
 846 MultiplicativeExpression
 847     : UnaryExpression { $$ = $1; }
 848     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 849     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 850     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 851     ;
 852 /* }}} */
 853 /* 11.6 Additive Operators {{{ */
 854 AdditiveExpression
 855     : MultiplicativeExpression { $$ = $1; }
 856     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 857     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 858     ;
 859 /* }}} */
 860 /* 11.7 Bitwise Shift Operators {{{ */
 861 ShiftExpression
 862     : AdditiveExpression { $$ = $1; }
 863     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 864     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 865     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 866     ;
 867 /* }}} */
 868 /* 11.8 Relational Operators {{{ */
 869 RelationalExpression
 870     : ShiftExpression { $$ = $1; }
 871     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 872     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 873     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 874     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 875     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 876     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 877     ;
 878 /* }}} */
 879 /* 11.9 Equality Operators {{{ */
 880 EqualityExpression
 881     : RelationalExpression { $$ = $1; }
 882     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 883     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 884     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 885     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 886     ;
 887 /* }}} */
 888 /* 11.10 Binary Bitwise Operators {{{ */
 889 BitwiseANDExpression
 890     : EqualityExpression { $$ = $1; }
 891     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 892     ;
 893
 894 BitwiseXORExpression
 895     : BitwiseANDExpression { $$ = $1; }
 896     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 897     ;
 898
 899 BitwiseORExpression
 900     : BitwiseXORExpression { $$ = $1; }
 901     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 902     ;
 903 /* }}} */
 904 /* 11.11 Binary Logical Operators {{{ */
 905 LogicalANDExpression
 906     : BitwiseORExpression { $$ = $1; }
 907     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 908     ;
 909
 910 LogicalORExpression
 911     : LogicalANDExpression { $$ = $1; }
 912     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
 913     ;
 914 /* }}} */
 915 /* 11.12 Conditional Operator ( ? : ) {{{ */
 916 ConditionalExpression
 917     : LogicalORExpression { $$ = $1; }
 918     | LogicalORExpression "?" LexPushInOff AssignmentExpression LexPopIn ":" AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
 919     ;
 920 /* }}} */
 921 /* 11.13 Assignment Operators {{{ */
 922 AssignmentExpression
 923     : ConditionalExpression { $$ = $1; }
 924     | ArrowFunction { $$ = $1; }
 925     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
 926     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
 927     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
 928     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
 929     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
 930     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
 931     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
 932     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
 933     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
 934     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
 935     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
 936     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
 937     ;
 938 /* }}} */
 939 /* 11.14 Comma Operator {{{ */
 940 Expression_
 941     : "," Expression { $$ = $2; }
 942     | { $$ = CYNew CYCompound(); }
 943     ;
 944
 945 Expression
 946     : AssignmentExpression Expression_ { $2->AddPrev($1); $$ = $2; }
 947     ;
 948
 949 ExpressionOpt
 950     : Expression { $$ = $1; }
 951     | LexSetRegExp { $$ = NULL; }
 952     ;
 953 /* }}} */
 954
 955 /* 12 Statements {{{ */
 956 Statement__
 957     : Block { $$ = $1; }
 958     | VariableStatement { $$ = $1; }
 959     | EmptyStatement { $$ = $1; }
 960     | IfStatement { $$ = $1; }
 961     | BreakableStatement { $$ = $1; }
 962     | ContinueStatement { $$ = $1; }
 963     | BreakStatement { $$ = $1; }
 964     | ReturnStatement { $$ = $1; }
 965     | WithStatement { $$ = $1; }
 966     | LabelledStatement { $$ = $1; }
 967     | ThrowStatement { $$ = $1; }
 968     | TryStatement { $$ = $1; }
 969     | DebuggerStatement { $$ = $1; }
 970     ;
 971
 972 Statement_
 973     : LexSetRegExp Statement__ { $$ = $2; }
 974     | ExpressionStatement { $$ = $1; }
 975     ;
 976
 977 Statement
 978     : LexSetStatement Statement_ { $$ = $2; }
 979     ;
 980
 981 Declaration__
 982     : FunctionDeclaration { $$ = $1; }
 983     | LexicalDeclaration { $$ = $1; }
 984     ;
 985
 986 Declaration_
 987     : LexSetRegExp Declaration__ { $$ = $2; }
 988     ;
 989
 990 Declaration
 991     : LexSetStatement Declaration_ { $$ = $2; }
 992     ;
 993
 994 BreakableStatement
 995     : IterationStatement { $$ = $1; }
 996     | SwitchStatement { $$ = $1; }
 997     ;
 998 /* }}} */
 999 /* 12.1 Block {{{ */
1000 Block_
1001     : BRACE StatementListOpt "}" { $$ = $2; }
1002     ;
1003
1004 Block
1005     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1006     ;
1007
1008 StatementList
1009     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1010     ;
1011
1012 StatementListOpt
1013     : StatementList { $$ = $1; }
1014     | LexSetRegExp { $$ = NULL; }
1015     ;
1016
1017 StatementListItem
1018     : Statement { $$ = $1; }
1019     | Declaration { $$ = $1; }
1020     ;
1021 /* }}} */
1022 /* 12.2 Declarations {{{ */
1023 BindingIdentifier
1024     : Identifier { $$ = $1; }
1025     ;
1026
1027 // XXX: BindingPattern
1028 /* }}} */
1029 /* 12.2.1 Let and Const Declarations {{{ */
1030 LexicalDeclaration
1031     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1032     ;
1033
1034 LetOrConst
1035     : "let"
1036     | "const"
1037     ;
1038 /* }}} */
1039 /* 12.2.2 Variable Statement {{{ */
1040 VariableStatement
1041     : "var" VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1042     ;
1043
1044 VariableDeclarationList_
1045     : "," VariableDeclarationList { $$ = $2; }
1046     | { $$ = NULL; }
1047     ;
1048
1049 VariableDeclarationList
1050     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1051     ;
1052
1053 VariableDeclaration
1054     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1055     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1056     ;
1057
1058 Initialiser
1059     : "=" AssignmentExpression { $$ = $2; }
1060     ;
1061
1062 InitialiserOpt
1063     : Initialiser { $$ = $1; }
1064     | { $$ = NULL; }
1065     ;
1066 /* }}} */
1067 /* 12.2.4 Destructuring Binding Patterns {{{ */
1068 // XXX: *
1069
1070 BindingElement
1071     : SingleNameBinding { $$ = $1; }
1072     ;
1073
1074 SingleNameBinding
1075     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1076     ;
1077 /* }}} */
1078 /* 12.3 Empty Statement {{{ */
1079 EmptyStatement
1080     : ";" { $$ = CYNew CYEmpty(); }
1081     ;
1082 /* }}} */
1083 /* 12.4 Expression Statement {{{ */
1084 ExpressionStatement
1085     : Expression Terminator { $$ = CYNew CYExpress($1); }
1086     ;
1087 /* }}} */
1088 /* 12.5 The if Statement {{{ */
1089 ElseStatementOpt
1090     : "else" Statement { $$ = $2; }
1091     | %prec "if" { $$ = NULL; }
1092     ;
1093
1094 IfStatement
1095     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1096     ;
1097 /* }}} */
1098
1099 /* 12.6 Iteration Statements {{{ */
1100 IterationStatement
1101     : DoWhileStatement { $$ = $1; }
1102     | WhileStatement { $$ = $1; }
1103     | ForStatement { $$ = $1; }
1104     | ForInStatement { $$ = $1; }
1105     ;
1106 /* }}} */
1107 /* 12.6.1 The do-while Statement {{{ */
1108 DoWhileStatement
1109     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1110     ;
1111 /* }}} */
1112 /* 12.6.2 The while Statement {{{ */
1113 WhileStatement
1114     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1115     ;
1116 /* }}} */
1117 /* 12.6.3 The for Statement {{{ */
1118 ForStatement
1119     : "for" "(" LexPushInOn ForStatementInitialiser LexPopIn ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1120     ;
1121
1122 ForStatementInitialiser
1123     : ExpressionOpt { $$ = $1; }
1124     | LexSetRegExp "var" VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1125     ;
1126 /* }}} */
1127 /* 12.6.4 The for-in Statement {{{ */
1128 ForInStatement
1129     : "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1130     ;
1131
1132 ForInStatementInitialiser
1133     : LeftHandSideExpression { $$ = $1; }
1134     | LexSetRegExp "var" VariableDeclaration { $$ = $3; }
1135     ;
1136 /* }}} */
1137
1138 /* 12.7 The continue Statement {{{ */
1139 ContinueStatement
1140     : "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1141     ;
1142 /* }}} */
1143 /* 12.8 The break Statement {{{ */
1144 BreakStatement
1145     : "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1146     ;
1147 /* }}} */
1148 /* 12.9 The return Statement {{{ */
1149 ReturnStatement
1150     : "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1151     ;
1152 /* }}} */
1153 /* 12.10 The with Statement {{{ */
1154 WithStatement
1155     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1156     ;
1157 /* }}} */
1158
1159 /* 12.11 The switch Statement {{{ */
1160 SwitchStatement
1161     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1162     ;
1163
1164 CaseBlock
1165     : BRACE CaseClausesOpt "}" { $$ = $2; }
1166     ;
1167
1168 CaseClause
1169     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1170     ;
1171
1172 CaseClausesOpt
1173     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1174     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1175     | { $$ = NULL; }
1176     ;
1177
1178 DefaultClause
1179     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1180     ;
1181 /* }}} */
1182 /* 12.12 Labelled Statements {{{ */
1183 LabelledStatement
1184     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1185     ;
1186 /* }}} */
1187 /* 12.13 The throw Statement {{{ */
1188 ThrowStatement
1189     : "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1190     ;
1191 /* }}} */
1192 /* 12.14 The try Statement {{{ */
1193 TryStatement
1194     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1195     ;
1196
1197 CatchOpt
1198     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1199     | { $$ = NULL; }
1200     ;
1201
1202 FinallyOpt
1203     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1204     | { $$ = NULL; }
1205     ;
1206 /* }}} */
1207 /* 12.14 The debugger Statement {{{ */
1208 DebuggerStatement
1209     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1210     ;
1211 /* }}} */
1212
1213 /* 13.1 Function Definitions {{{ */
1214 FunctionDeclaration
1215     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1216     ;
1217
1218 FunctionExpression
1219     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt LexPopIn ")" BRACE LexPushInOff FunctionBody LexPopIn "}" { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1220     ;
1221
1222 FormalParameterList_
1223     : "," FormalParameterList { $$ = $2; }
1224     | { $$ = NULL; }
1225     ;
1226
1227 FormalParameterList
1228     // XXX: : FunctionRestParameter { $$ = $1; }
1229     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1230     ;
1231
1232 FormalParameterListOpt
1233     : FormalParameterList
1234     | { $$ = NULL; }
1235     ;
1236
1237 /* XXX: FunctionRestParameter
1238     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1239     ;*/
1240
1241 FormalParameter
1242     : BindingElement { $$ = $1; }
1243     ;
1244
1245 FunctionBody
1246     : StatementListOpt { $$ = $1; }
1247     ;
1248 /* }}} */
1249 /* 13.2 Arrow Function Definitions {{{ */
1250 ArrowFunction
1251     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFunctionExpression(NULL, $2, $5); }
1252     ;
1253
1254 ArrowParameters
1255     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1256     //| ParentheticalOpt { $$ = $1; }
1257     ;
1258
1259 ConciseBody
1260     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1261     | ";{" LexPushInOff FunctionBody LexPopIn "}" { $$ = $3; }
1262     ;
1263 /* }}} */
1264 /* 14 Program {{{ */
1265 Program
1266     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1267     ;
1268
1269 ProgramBody
1270     : StatementList { $$ = $1; }
1271     ;
1272
1273 ProgramBodyOpt
1274     : ProgramBody { $$ = $1; }
1275     | { $$ = NULL; }
1276     ;
1277 /* }}} */
1278
1279 @begin ObjectiveC
1280 /* Cycript (Objective-C): @class Declaration {{{ */
1281 ClassSuperOpt
1282     /* XXX: why the hell did I choose MemberExpression? */
1283     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1284     | { $$ = NULL; }
1285     ;
1286
1287 ClassField
1288     : Expression Identifier ";"
1289     ;
1290
1291 ClassFieldList
1292     : BRACE ClassFieldListOpt "}" { $$ = NULL; }
1293     ;
1294
1295 ClassFieldListOpt
1296     : ClassFieldListOpt ClassField
1297     |
1298     ;
1299
1300 MessageScope
1301     : "+" { $$ = false; }
1302     | "-" { $$ = true; }
1303     ;
1304
1305 TypeOpt
1306     : "(" Expression ")" { $$ = $2; }
1307     | "(" LexSetRegExp "void" ")" { $$ = NULL; }
1308     | { $$ = NULL; }
1309     ;
1310
1311 MessageParameter
1312     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1313     ;
1314
1315 MessageParameterList
1316     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1317     ;
1318
1319 MessageParameterListOpt
1320     : MessageParameterList { $$ = $1; }
1321     | { $$ = NULL; }
1322     ;
1323
1324 MessageParameters
1325     : MessageParameterList { $$ = $1; }
1326     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1327     ;
1328
1329 ClassMessageDeclaration
1330     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1331     ;
1332
1333 ClassMessageDeclarationListOpt
1334     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1335     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1336     | { $$ = NULL; }
1337     ;
1338
1339 ClassName
1340     : Identifier { $$ = $1; }
1341     | "(" AssignmentExpression ")" { $$ = $2; }
1342     ;
1343
1344 ClassNameOpt
1345     : ClassName { $$ = $1; }
1346     | { $$ = NULL; }
1347     ;
1348
1349 // XXX: this should be AssignmentExpressionNoRight
1350 ClassProtocols
1351     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1352     ;
1353
1354 ClassProtocolsOpt
1355     : "," ClassProtocols { $$ = $2; }
1356     | { $$ = NULL; }
1357     ;
1358
1359 ClassProtocolListOpt
1360     : "<" ClassProtocols ">" { $$ = $2; }
1361     | { $$ = NULL; }
1362     ;
1363
1364 ClassExpression
1365     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt LexPopIn "@end" { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1366     ;
1367
1368 ClassStatement
1369     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1370     ;
1371
1372 CategoryName
1373     : "(" WordOpt ")"
1374     ;
1375
1376 CategoryStatement
1377     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1378     ;
1379
1380 PrimaryExpression
1381     : ClassExpression { $$ = $1; }
1382     ;
1383
1384 Statement__
1385     : ClassStatement { $$ = $1; }
1386     | CategoryStatement { $$ = $1; }
1387     ;
1388 /* }}} */
1389 /* Cycript (Objective-C): Send Message {{{ */
1390 VariadicCall
1391     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1392     | { $$ = NULL; }
1393     ;
1394
1395 SelectorWordOpt
1396     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1397     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1398     ;
1399
1400 SelectorCall_
1401     : SelectorCall { $$ = $1; }
1402     | VariadicCall { $$ = $1; }
1403     ;
1404
1405 SelectorCall
1406     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1407     ;
1408
1409 SelectorList
1410     : SelectorCall { $$ = $1; }
1411     | Word { $$ = CYNew CYArgument($1, NULL); }
1412     ;
1413
1414 MessageExpression
1415     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList LexPopIn "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1416     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList LexPopIn "]" { $$ = CYNew CYSendSuper($6); }
1417     ;
1418
1419 SelectorExpression_
1420     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1421     ;
1422
1423 SelectorExpression
1424     : SelectorExpression_ { $$ = $1; }
1425     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1426     ;
1427
1428 SelectorExpressionOpt
1429     : SelectorExpression_ { $$ = $1; }
1430     | { $$ = NULL; }
1431     ;
1432
1433 PrimaryExpression
1434     : MessageExpression { $$ = $1; }
1435     | "@selector" "(" LexPushInOff SelectorExpression LexPopIn ")" { $$ = CYNew CYSelector($4); }
1436     ;
1437 /* }}} */
1438 /* Cycript (Objective-C): @import Directive {{{ */
1439 PathName
1440     : "/" PathName
1441     | "." PathName
1442     | Word PathName
1443     |
1444     ;
1445
1446 ImportPath
1447     : "<" PathName ">"
1448     | StringLiteral
1449     ;
1450
1451 StatementListItem
1452     : "@import" ImportPath { $$ = CYNew CYImport(); }
1453     ;
1454 /* }}} */
1455 @end
1456
1457 @begin C
1458 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1459 LeftHandSideExpression
1460     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1461     ;
1462
1463 UnaryExpression_
1464     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1465     ;
1466
1467 MemberAccess
1468     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1469     | "->" Identifier { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1470     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1471     ;
1472 /* }}} */
1473 @end
1474
1475 /* YUI: Documentation Comments {{{ */
1476 Statement__
1477     : Comment { $$ = $1; }
1478     ;
1479 /* }}} */
1480
1481 @begin E4X
1482 /* Lexer State {{{ */
1483 LexPushRegExp
1484     : { driver.PushCondition(CYDriver::RegExpCondition); }
1485     ;
1486
1487 LexPushXMLContent
1488     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1489     ;
1490
1491 LexPushXMLTag
1492     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1493     ;
1494
1495 LexPop
1496     : { driver.PopCondition(); }
1497     ;
1498
1499 LexSetXMLContent
1500     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1501     ;
1502
1503 LexSetXMLTag
1504     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1505     ;
1506 /* }}} */
1507
1508 XMLWhitespaceOpt
1509     : XMLWhitespace
1510     |
1511     ;
1512
1513 /* 8.1 Context Keywords {{{ */
1514 Identifier
1515     : "namespace" { $$ = $1; }
1516     | "xml" { $$ = $1; }
1517     ;
1518 /* }}} */
1519 /* 8.3 XML Initialiser Input Elements {{{ */
1520 XMLMarkup
1521     : XMLComment { $$ = $1; }
1522     | XMLCDATA { $$ = $1; }
1523     | XMLPI { $$ = $1; }
1524     ;
1525 /* }}} */
1526 /* 11.1 Primary Expressions {{{ */
1527 PrimaryExpression
1528     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1529     | XMLInitialiser { $$ = $1; }
1530     | XMLListInitialiser { $$ = $1; }
1531     ;
1532
1533 PropertyIdentifier
1534     : AttributeIdentifier { $$ = $1; }
1535     | QualifiedIdentifier { $$ = $1; }
1536     | WildcardIdentifier { $$ = $1; }
1537     ;
1538 /* }}} */
1539 /* 11.1.1 Attribute Identifiers {{{ */
1540 AttributeIdentifier
1541     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1542     ;
1543
1544 PropertySelector_
1545     : PropertySelector { $$ = $1; }
1546     | "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYSelector($3); }
1547     ;
1548
1549 PropertySelector
1550     : Identifier { $$ = CYNew CYSelector($1); }
1551     | WildcardIdentifier { $$ = $1; }
1552     ;
1553 /* }}} */
1554 /* 11.1.2 Qualified Identifiers {{{ */
1555 QualifiedIdentifier_
1556     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1557     | QualifiedIdentifier { $$ = $1; }
1558     ;
1559
1560 QualifiedIdentifier
1561     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1562     ;
1563 /* }}} */
1564 /* 11.1.3 Wildcard Identifiers {{{ */
1565 WildcardIdentifier
1566     : "*" { $$ = CYNew CYWildcard(); }
1567     ;
1568 /* }}} */
1569 /* 11.1.4 XML Initialiser {{{ */
1570 XMLInitialiser
1571     : XMLMarkup { $$ = $1; }
1572     | XMLElement { $$ = $1; }
1573     ;
1574
1575 XMLElement
1576     : "<" LexPushInOff XMLTagContent LexPop LexPopIn "/>"
1577     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop LexPopIn ">"
1578     ;
1579
1580 XMLTagContent
1581     : LexPushXMLTag XMLTagName XMLAttributes
1582     ;
1583
1584 XMLExpression
1585     : BRACE LexPushRegExp Expression LexPop "}"
1586     ;
1587
1588 XMLTagName
1589     : XMLExpression
1590     | XMLName
1591     ;
1592
1593 XMLAttributes_
1594     : XMLAttributes_ XMLAttribute
1595     |
1596     ;
1597
1598 XMLAttributes
1599     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1600     | XMLAttributes_ XMLWhitespaceOpt
1601     ;
1602
1603 XMLAttributeValue_
1604     : XMLExpression
1605     | XMLAttributeValue
1606     ;
1607
1608 XMLAttribute
1609     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1610     ;
1611
1612 XMLElementContent
1613     : XMLExpression XMLElementContentOpt
1614     | XMLMarkup XMLElementContentOpt
1615     | XMLText XMLElementContentOpt
1616     | XMLElement XMLElementContentOpt
1617     ;
1618
1619 XMLElementContentOpt
1620     : XMLElementContent
1621     |
1622     ;
1623 /* }}} */
1624 /* 11.1.5 XMLList Initialiser {{{ */
1625 XMLListInitialiser
1626     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop LexPopIn "</>" { $$ = CYNew CYXMLList($4); }
1627     ;
1628 /* }}} */
1629 /* 11.2 Left-Hand-Side Expressions {{{ */
1630 PropertyIdentifier_
1631     : Identifier { $$ = $1; }
1632     | PropertyIdentifier { $$ = $1; }
1633     ;
1634
1635 MemberAccess
1636     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1637     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1638     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1639     ;
1640 /* }}} */
1641 /* 12.1 The default xml namespace Statement {{{ */
1642 /* XXX: DefaultXMLNamespaceStatement
1643     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1644     ;
1645
1646 Statement__
1647     : DefaultXMLNamespaceStatement { $$ = $1; }
1648     ; */
1649 /* }}} */
1650 @end
1651
1652 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1653 PropertyNameAndValueList_
1654     : "," { $$ = NULL; }
1655     ;
1656 /* }}} */
1657
1658 /* JavaScript 1.7: Array Comprehensions {{{ */
1659 IfComprehension
1660     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1661     ;
1662
1663 ForComprehension
1664     : "for" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
1665     | "for" "each" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForEachInComprehension($5, $8); }
1666     ;
1667
1668 ComprehensionList
1669     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1670     ;
1671
1672 ComprehensionListOpt
1673     : ComprehensionList { $$ = $1; }
1674     | IfComprehension { $$ = $1; }
1675     | { $$ = NULL; }
1676     ;
1677
1678 PrimaryExpression
1679     : "[" LexPushInOff AssignmentExpression ComprehensionList LexPopIn "]" { $$ = CYNew CYArrayComprehension($3, $4); }
1680     ;
1681 /* }}} */
1682 /* JavaScript 1.7: for each {{{ */
1683 ForInStatement
1684     : "for" "each" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForEachIn($5, $8, $10); }
1685     ;
1686 /* }}} */
1687 /* JavaScript 1.7: let Statements {{{ */
1688 LetStatement
1689     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1690     ;
1691
1692 Statement__
1693     : LetStatement
1694     ;
1695 /* }}} */
1696
1697 /* JavaScript FTW: Ruby Blocks {{{ */
1698 RubyProcParameterList_
1699     : "," RubyProcParameterList { $$ = $2; }
1700     | { $$ = NULL; }
1701     ;
1702
1703 RubyProcParameterList
1704     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1705     | { $$ = NULL; }
1706     ;
1707
1708 RubyProcParameters
1709     : "|" RubyProcParameterList "|" { $$ = $2; }
1710     | "||" { $$ = NULL; }
1711     ;
1712
1713 RubyProcParametersOpt
1714     : RubyProcParameters
1715     | { $$ = NULL; }
1716     ;
1717
1718 RubyProcExpression
1719     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1720     ;
1721
1722 PrimaryExpression
1723     : "{" LexPushInOff RubyProcParameters StatementListOpt LexPopIn "}" { $$ = CYNew CYRubyProc($3, $4); }
1724     ;
1725
1726 CallExpression
1727     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1728     ;
1729 /* }}} */
1730
1731 %%