configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 dnl XXX: do this only on Mac OS X
  33 am_cv_CC_dependencies_compiler_type=none
  34 am_cv_CXX_dependencies_compiler_type=none
  35 am_cv_OBJCXX_dependencies_compiler_type=none
  36
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 AC_PROG_OBJCXX
  40
  41 AM_PROG_AR
  42 AC_PROG_INSTALL
  43
  44 LT_INIT([disable-static])
  45
  46 AC_LANG([C++])
  47
  48 PKG_PROG_PKG_CONFIG([0.22])
  49
  50 AC_PATH_PROG([GIT], [git])
  51 AC_PATH_PROG([TIME], [time])
  52
  53 dnl CY_CHECK_PROGS_VERSION {{{
  54 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  55     AC_ARG_VAR(]$1[, ]$3[)
  56
  57     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  58     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  59         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  60         AS_VAR_IF(version, [], ,
  61             AS_VERSION_COMPARE($version, ]$5[, ,
  62                 ac_cv_path_]$1[=$ac_path_]$1[,
  63                 ac_cv_path_]$1[=$ac_path_]$1[))
  64     , AC_MSG_RESULT(no))
  65
  66     AS_IF([true], [
  67         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  68         AC_MSG_RESULT($]$1[)
  69     ], AS_IF([true], [
  70         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  71     ], [
  72         AC_SUBST(]$1[, [:])
  73         AC_MSG_RESULT([no])
  74     ]))
  75 ]) dnl }}}
  76
  77 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  78     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  79 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  80     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  81 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  82     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  83 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  84     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  85
  86 AC_MSG_CHECKING([bison for %code{}])
  87 echo '%code{}%%_:' >conftest.y
  88 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  89     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  90     AC_MSG_RESULT([yes])
  91 else
  92     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  93     AC_MSG_RESULT([no])
  94 fi
  95
  96 rm -f conftest.y
  97 AC_SUBST([CY_FILTERS])
  98
  99 dnl CY_TRY {{{
 100 AC_DEFUN([CY_SUCCESS], [cy_good=1])
 101 AC_DEFUN([CY_FAILURE], [cy_good=0])
 102
 103 AC_DEFUN([CY_TRY], [
 104     cy_save=$]$1[
 105         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
 106         ]$3[
 107     ]$1[=$cy_save
 108     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 109 ]) dnl }}}
 110
 111 AC_DEFUN([CY_TEST_FLAG_], [
 112     AC_LANG_PUSH(]$2[)
 113     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 114     CY_TRY(]$3[, $1, [
 115         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 116             [CY_SUCCESS], [CY_FAILURE])
 117     ], [
 118         AC_MSG_RESULT([yes])
 119         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 120     ], [AC_MSG_RESULT([no])])
 121     AC_LANG_POP(]$2[)
 122 ])
 123
 124 AC_DEFUN([CY_TEST_FLAG], [
 125     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 126     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 127     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 128 ])
 129
 130 AX_CFLAGS_WARN_ALL
 131 AX_CXXFLAGS_WARN_ALL
 132 AX_FLAGS_WARN_ALL
 133
 134 CY_TEST_FLAG([-Werror])
 135
 136 dnl XXX: this is used to support GNU Objective-C struct objc_method
 137 CY_TEST_FLAG([-Wno-deprecated-declarations])
 138
 139 CY_TEST_FLAG([-Wno-dangling-else])
 140 CY_TEST_FLAG([-Wno-overloaded-virtual])
 141 CY_TEST_FLAG([-Wno-parentheses])
 142 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 143
 144 AC_DEFUN([CY_LT_LIB], [
 145     cy_save=$LIBS
 146     LIBS=
 147     ]$2[
 148     ]$1[=$LIBS
 149     LIBS=$cy_save
 150     AC_SUBST(]$1[)
 151 ])
 152
 153 dnl --enable-javascript {{{
 154 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 155     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 156         #include <JavaScriptCore/JSBase.h>
 157     ], [
 158         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 159     ], [
 160         AC_SUBST([CY_EXECUTE], [1])
 161     ], [
 162         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 163             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 164                 AC_SUBST([CY_EXECUTE], [1])
 165                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 166                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 167             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 168         done
 169     ])])
 170 ])
 171
 172 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 173     CY_CHECK_JAVASCRIPTCORE])
 174
 175 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 176     [--enable-javascript@<:@=ENGINE@:>@],
 177     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 178 )], [
 179     AS_CASE([$enableval],
 180         [yes], [
 181             CY_CHECK_JAVASCRIPT],
 182         [no], [
 183             AC_SUBST([CY_EXECUTE], [0])],
 184         [JavaScriptCore], [
 185             CY_CHECK_JAVASCRIPTCORE],
 186         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 187 ], [CY_CHECK_JAVASCRIPT])
 188 dnl }}}
 189
 190 AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
 191 AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])
 192
 193 AM_COND_IF([CY_CONSOLE], [
 194 dnl APR_FIND_APR {{{
 195 AS_IF([test "x$LTLIBAPR" != x], [
 196     AC_SUBST([LTLIBAPR])
 197 ], [
 198     APR_FIND_APR([], [], [1], [1])
 199 AS_CASE([$apr_found], [yes], [
 200     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 201     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 202     AC_SUBST([LTLIBAPR])
 203 ], [
 204     AC_MSG_ERROR([missing "libapr"])
 205 ])])
 206 dnl }}}
 207 ])
 208
 209 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 210     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 211         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 212         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 213     ], [AC_MSG_ERROR([missing "libffi"])])])
 214
 215 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 216
 217 AS_CASE([$CY_EXECUTE], [1], [
 218     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 219
 220     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 221         CY_CHECK_PKG_CONFIG_LIBFFI
 222     ], [
 223         AC_SEARCH_LIBS([ffi_call], [ffi])
 224         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 225     ]))
 226
 227     AC_LANG_PUSH([Objective C++])
 228
 229     AC_MSG_CHECKING([if we really have Objective C++])
 230     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 231         CY_OBJECTIVEC=1
 232         AC_MSG_RESULT([yes])
 233     ], [AC_MSG_RESULT([no])])
 234
 235     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 236         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 237             #include <CoreFoundation/CFBase.h>
 238         ], [CFAllocatorGetDefault();], [
 239             AC_SUBST([CY_OBJECTIVEC])
 240
 241             AC_CHECK_FRAMEWORK([Foundation], [
 242                 #include <Foundation/NSObject.h>
 243             ], [[[[NSObject alloc] init];]])
 244         ], [
 245             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 246             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 247
 248             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 249                 AC_SUBST([CY_OBJECTIVEC])
 250                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 251                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 252             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 253         ])])
 254     ])
 255
 256     AC_LANG_POP([Objective C++])
 257 ])
 258
 259 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 260
 261 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 262 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 263
 264 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
 265
 266 AC_SUBST([LTFLAGS])
 267 AC_SUBST([SO], [$acl_shlibext])
 268
 269 AS_IF([test "x$CY_EXECUTE" = x1], [
 270     AC_CHECK_HEADER([mach/mach.h], [
 271         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 272         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 273         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 274         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 275         AC_SUBST([CY_MACH], [1])])])
 276 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 277
 278 AC_CONFIG_FILES([Makefile])
 279 AC_OUTPUT