Tweak.mm

   1 /* Cyrker - Remove Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #include <substrate.h>
  41 #include "Struct.hpp"
  42
  43 #include "sig/parse.hpp"
  44 #include "sig/ffi_type.hpp"
  45
  46 #include <apr-1/apr_pools.h>
  47 #include <apr-1/apr_strings.h>
  48
  49 #include <unistd.h>
  50
  51 #include <CoreFoundation/CoreFoundation.h>
  52 #include <CoreFoundation/CFLogUtilities.h>
  53
  54 #include <CFNetwork/CFNetwork.h>
  55 #include <Foundation/Foundation.h>
  56
  57 #include <JavaScriptCore/JSBase.h>
  58 #include <JavaScriptCore/JSValueRef.h>
  59 #include <JavaScriptCore/JSObjectRef.h>
  60 #include <JavaScriptCore/JSContextRef.h>
  61 #include <JavaScriptCore/JSStringRef.h>
  62 #include <JavaScriptCore/JSStringRefCF.h>
  63
  64 #include <WebKit/WebScriptObject.h>
  65
  66 #include <sys/types.h>
  67 #include <sys/socket.h>
  68 #include <netinet/in.h>
  69
  70 #undef _assert
  71 #undef _trace
  72
  73 /* XXX: bad _assert */
  74 #define _assert(test) do { \
  75     if (!(test)) \
  76         @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"_assert(%s):%s(%u):%s", #test, __FILE__, __LINE__, __FUNCTION__] userInfo:nil]; \
  77 } while (false)
  78
  79 #define _trace() do { \
  80     CFLog(kCFLogLevelNotice, CFSTR("_trace():%u"), __LINE__); \
  81 } while (false)
  82
  83 /* Objective-C Handle<> {{{ */
  84 template <typename Type_>
  85 class _H {
  86     typedef _H<Type_> This_;
  87
  88   private:
  89     Type_ *value_;
  90
  91     _finline void Retain_() {
  92         if (value_ != nil)
  93             [value_ retain];
  94     }
  95
  96     _finline void Clear_() {
  97         if (value_ != nil)
  98             [value_ release];
  99     }
 100
 101   public:
 102     _finline _H(const This_ &rhs) :
 103         value_(rhs.value_ == nil ? nil : [rhs.value_ retain])
 104     {
 105     }
 106
 107     _finline _H(Type_ *value = NULL, bool mended = false) :
 108         value_(value)
 109     {
 110         if (!mended)
 111             Retain_();
 112     }
 113
 114     _finline ~_H() {
 115         Clear_();
 116     }
 117
 118     _finline operator Type_ *() const {
 119         return value_;
 120     }
 121
 122     _finline This_ &operator =(Type_ *value) {
 123         if (value_ != value) {
 124             Type_ *old(value_);
 125             value_ = value;
 126             Retain_();
 127             if (old != nil)
 128                 [old release];
 129         } return *this;
 130     }
 131 };
 132 /* }}} */
 133 /* APR Pool Helpers {{{ */
 134 void *operator new(size_t size, apr_pool_t *pool) {
 135     return apr_palloc(pool, size);
 136 }
 137
 138 void *operator new [](size_t size, apr_pool_t *pool) {
 139     return apr_palloc(pool, size);
 140 }
 141
 142 class CYPool {
 143   private:
 144     apr_pool_t *pool_;
 145
 146   public:
 147     CYPool() {
 148         apr_pool_create(&pool_, NULL);
 149     }
 150
 151     ~CYPool() {
 152         apr_pool_destroy(pool_);
 153     }
 154
 155     operator apr_pool_t *() const {
 156         return pool_;
 157     }
 158 };
 159 /* }}} */
 160
 161 #define _pooled _H<NSAutoreleasePool> _pool([[NSAutoreleasePool alloc] init], true);
 162
 163 static JSContextRef Context_;
 164
 165 static JSClassRef Functor_;
 166 static JSClassRef Instance_;
 167 static JSClassRef Pointer_;
 168 static JSClassRef Selector_;
 169
 170 static JSObjectRef Array_;
 171
 172 static JSStringRef name_;
 173 static JSStringRef message_;
 174 static JSStringRef length_;
 175
 176 static Class NSCFBoolean_;
 177
 178 static NSMutableDictionary *Bridge_;
 179
 180 struct Client {
 181     CFHTTPMessageRef message_;
 182     CFSocketRef socket_;
 183 };
 184
 185 JSObjectRef CYMakeObject(JSContextRef context, id object) {
 186     return JSObjectMake(context, Instance_, [object retain]);
 187 }
 188
 189 @interface NSMethodSignature (Cyrver)
 190 - (NSString *) _typeString;
 191 @end
 192
 193 @interface NSObject (Cyrver)
 194 - (NSString *) cy$toJSON;
 195 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 196 @end
 197
 198 @interface NSString (Cyrver)
 199 - (void *) cy$symbol;
 200 @end
 201
 202 @interface NSNumber (Cyrver)
 203 - (void *) cy$symbol;
 204 @end
 205
 206 @implementation NSObject (Cyrver)
 207
 208 - (NSString *) cy$toJSON {
 209     return [self description];
 210 }
 211
 212 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 213     return CYMakeObject(context, self);
 214 }
 215
 216 @end
 217
 218 @implementation WebUndefined (Cyrver)
 219
 220 - (NSString *) cy$toJSON {
 221     return @"undefined";
 222 }
 223
 224 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 225     return JSValueMakeUndefined(context);
 226 }
 227
 228 @end
 229
 230 @implementation NSArray (Cyrver)
 231
 232 - (NSString *) cy$toJSON {
 233     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 234     [json appendString:@"["];
 235
 236     bool comma(false);
 237     for (id object in self) {
 238         if (comma)
 239             [json appendString:@","];
 240         else
 241             comma = true;
 242         [json appendString:[object cy$toJSON]];
 243     }
 244
 245     [json appendString:@"]"];
 246     return json;
 247 }
 248
 249 @end
 250
 251 @implementation NSDictionary (Cyrver)
 252
 253 - (NSString *) cy$toJSON {
 254     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 255     [json appendString:@"("];
 256     [json appendString:@"{"];
 257
 258     bool comma(false);
 259     for (id key in self) {
 260         if (comma)
 261             [json appendString:@","];
 262         else
 263             comma = true;
 264         [json appendString:[key cy$toJSON]];
 265         [json appendString:@":"];
 266         NSObject *object([self objectForKey:key]);
 267         [json appendString:[object cy$toJSON]];
 268     }
 269
 270     [json appendString:@"})"];
 271     return json;
 272 }
 273
 274 @end
 275
 276 @implementation NSNumber (Cyrver)
 277
 278 - (NSString *) cy$toJSON {
 279     return [self class] != NSCFBoolean_ ? [self stringValue] : [self boolValue] ? @"true" : @"false";
 280 }
 281
 282 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 283     return [self class] != NSCFBoolean_ ? JSValueMakeNumber(context, [self doubleValue]) : JSValueMakeBoolean(context, [self boolValue]);
 284 }
 285
 286 - (void *) cy$symbol {
 287     return [self pointerValue];
 288 }
 289
 290 @end
 291
 292 @implementation NSString (Cyrver)
 293
 294 - (NSString *) cy$toJSON {
 295     CFMutableStringRef json(CFStringCreateMutableCopy(kCFAllocatorDefault, 0, (CFStringRef) self));
 296
 297     CFStringFindAndReplace(json, CFSTR("\\"), CFSTR("\\\\"), CFRangeMake(0, CFStringGetLength(json)), 0);
 298     CFStringFindAndReplace(json, CFSTR("\""), CFSTR("\\\""), CFRangeMake(0, CFStringGetLength(json)), 0);
 299     CFStringFindAndReplace(json, CFSTR("\t"), CFSTR("\\t"), CFRangeMake(0, CFStringGetLength(json)), 0);
 300     CFStringFindAndReplace(json, CFSTR("\r"), CFSTR("\\r"), CFRangeMake(0, CFStringGetLength(json)), 0);
 301     CFStringFindAndReplace(json, CFSTR("\n"), CFSTR("\\n"), CFRangeMake(0, CFStringGetLength(json)), 0);
 302
 303     CFStringInsert(json, 0, CFSTR("\""));
 304     CFStringAppend(json, CFSTR("\""));
 305
 306     return [reinterpret_cast<const NSString *>(json) autorelease];
 307 }
 308
 309 - (void *) cy$symbol {
 310     return dlsym(RTLD_DEFAULT, [self UTF8String]);
 311 }
 312
 313 @end
 314
 315 @interface CYJSObject : NSDictionary {
 316     JSObjectRef object_;
 317     JSContextRef context_;
 318 }
 319
 320 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 321
 322 - (NSUInteger) count;
 323 - (id) objectForKey:(id)key;
 324 - (NSEnumerator *) keyEnumerator;
 325 - (void) setObject:(id)object forKey:(id)key;
 326 - (void) removeObjectForKey:(id)key;
 327
 328 @end
 329
 330 @interface CYJSArray : NSArray {
 331     JSObjectRef object_;
 332     JSContextRef context_;
 333 }
 334
 335 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 336
 337 - (NSUInteger) count;
 338 - (id) objectAtIndex:(NSUInteger)index;
 339
 340 @end
 341
 342 JSContextRef JSGetContext() {
 343     return Context_;
 344 }
 345
 346 #define CYCatch \
 347     @catch (id error) { \
 348         CYThrow(context, error, exception); \
 349         return NULL; \
 350     }
 351
 352 void CYThrow(JSContextRef context, JSValueRef value);
 353
 354 id CYCastNSObject(JSContextRef context, JSObjectRef object) {
 355     if (JSValueIsObjectOfClass(context, object, Instance_))
 356         return reinterpret_cast<id>(JSObjectGetPrivate(object));
 357     JSValueRef exception(NULL);
 358     bool array(JSValueIsInstanceOfConstructor(context, object, Array_, &exception));
 359     CYThrow(context, exception);
 360     if (array)
 361         return [[[CYJSArray alloc] initWithJSObject:object inContext:context] autorelease];
 362     return [[[CYJSObject alloc] initWithJSObject:object inContext:context] autorelease];
 363 }
 364
 365 JSStringRef CYCopyJSString(id value) {
 366     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>([value description]));
 367 }
 368
 369 JSStringRef CYCopyJSString(const char *value) {
 370     return JSStringCreateWithUTF8CString(value);
 371 }
 372
 373 JSStringRef CYCopyJSString(JSStringRef value) {
 374     return JSStringRetain(value);
 375 }
 376
 377 JSStringRef CYCopyJSString(JSContextRef context, JSValueRef value) {
 378     JSValueRef exception(NULL);
 379     JSStringRef string(JSValueToStringCopy(context, value, &exception));
 380     CYThrow(context, exception);
 381     return string;
 382 }
 383
 384 // XXX: this is not a safe handle
 385 class CYString {
 386   private:
 387     JSStringRef string_;
 388
 389   public:
 390     template <typename Arg0_>
 391     CYString(Arg0_ arg0) {
 392         string_ = CYCopyJSString(arg0);
 393     }
 394
 395     template <typename Arg0_, typename Arg1_>
 396     CYString(Arg0_ arg0, Arg1_ arg1) {
 397         string_ = CYCopyJSString(arg0, arg1);
 398     }
 399
 400     ~CYString() {
 401         JSStringRelease(string_);
 402     }
 403
 404     operator JSStringRef() const {
 405         return string_;
 406     }
 407 };
 408
 409 CFStringRef CYCopyCFString(JSStringRef value) {
 410     return JSStringCopyCFString(kCFAllocatorDefault, value);
 411 }
 412
 413 CFStringRef CYCopyCFString(JSContextRef context, JSValueRef value) {
 414     return CYCopyCFString(CYString(context, value));
 415 }
 416
 417 CFNumberRef CYCopyCFNumber(JSContextRef context, JSValueRef value) {
 418     JSValueRef exception(NULL);
 419     double number(JSValueToNumber(context, value, &exception));
 420     CYThrow(context, exception);
 421     return CFNumberCreate(kCFAllocatorDefault, kCFNumberDoubleType, &number);
 422 }
 423
 424 NSString *CYCastNSString(JSStringRef value) {
 425     return [reinterpret_cast<const NSString *>(CYCopyCFString(value)) autorelease];
 426 }
 427
 428 CFTypeRef CYCopyCFType(JSContextRef context, JSValueRef value) {
 429     JSType type(JSValueGetType(context, value));
 430     switch (type) {
 431         case kJSTypeUndefined:
 432             return CFRetain([WebUndefined undefined]);
 433         case kJSTypeNull:
 434             return nil;
 435         case kJSTypeBoolean:
 436             return CFRetain(JSValueToBoolean(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 437         case kJSTypeNumber:
 438             return CYCopyCFNumber(context, value);
 439         case kJSTypeString:
 440             return CYCopyCFString(context, value);
 441         case kJSTypeObject:
 442             return CFRetain((CFTypeRef) CYCastNSObject(context, (JSObjectRef) value));
 443         default:
 444             @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"JSValueGetType() == 0x%x", type] userInfo:nil];
 445     }
 446 }
 447
 448 NSArray *CYCastNSArray(JSPropertyNameArrayRef names) {
 449     size_t size(JSPropertyNameArrayGetCount(names));
 450     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
 451     for (size_t index(0); index != size; ++index)
 452         [array addObject:CYCastNSString(JSPropertyNameArrayGetNameAtIndex(names, index))];
 453     return array;
 454 }
 455
 456 id CYCastNSObject(JSContextRef context, JSValueRef value) {
 457     const NSObject *object(reinterpret_cast<const NSObject *>(CYCopyCFType(context, value)));
 458     return object == nil ? nil : [object autorelease];
 459 }
 460
 461 void CYThrow(JSContextRef context, JSValueRef value) {
 462     if (value == NULL)
 463         return;
 464     @throw CYCastNSObject(context, value);
 465 }
 466
 467 JSValueRef CYCastJSValue(JSContextRef context, id value) {
 468     return value == nil ? JSValueMakeNull(context) : [value cy$JSValueInContext:context];
 469 }
 470
 471 void CYThrow(JSContextRef context, id error, JSValueRef *exception) {
 472     *exception = CYCastJSValue(context, error);
 473 }
 474
 475 @implementation CYJSObject
 476
 477 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
 478     if ((self = [super init]) != nil) {
 479         object_ = object;
 480         context_ = context;
 481     } return self;
 482 }
 483
 484 - (NSUInteger) count {
 485     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
 486     size_t size(JSPropertyNameArrayGetCount(names));
 487     JSPropertyNameArrayRelease(names);
 488     return size;
 489 }
 490
 491 - (id) objectForKey:(id)key {
 492     JSValueRef exception(NULL);
 493     JSValueRef value(JSObjectGetProperty(context_, object_, CYString(key), &exception));
 494     CYThrow(context_, exception);
 495     return CYCastNSObject(context_, value);
 496 }
 497
 498 - (NSEnumerator *) keyEnumerator {
 499     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
 500     NSEnumerator *enumerator([CYCastNSArray(names) objectEnumerator]);
 501     JSPropertyNameArrayRelease(names);
 502     return enumerator;
 503 }
 504
 505 - (void) setObject:(id)object forKey:(id)key {
 506     JSValueRef exception(NULL);
 507     JSObjectSetProperty(context_, object_, CYString(key), CYCastJSValue(context_, object), kJSPropertyAttributeNone, &exception);
 508     CYThrow(context_, exception);
 509 }
 510
 511 - (void) removeObjectForKey:(id)key {
 512     JSValueRef exception(NULL);
 513     // XXX: this returns a bool
 514     JSObjectDeleteProperty(context_, object_, CYString(key), &exception);
 515     CYThrow(context_, exception);
 516 }
 517
 518 @end
 519
 520 @implementation CYJSArray
 521
 522 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
 523     if ((self = [super init]) != nil) {
 524         object_ = object;
 525         context_ = context;
 526     } return self;
 527 }
 528
 529 - (NSUInteger) count {
 530     JSValueRef exception(NULL);
 531     JSValueRef value(JSObjectGetProperty(context_, object_, length_, &exception));
 532     CYThrow(context_, exception);
 533     double number(JSValueToNumber(context_, value, &exception));
 534     CYThrow(context_, exception);
 535     return number;
 536 }
 537
 538 - (id) objectAtIndex:(NSUInteger)index {
 539     JSValueRef exception(NULL);
 540     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
 541     CYThrow(context_, exception);
 542     id object(CYCastNSObject(context_, value));
 543     return object == nil ? [NSNull null] : object;
 544 }
 545
 546 @end
 547
 548 CFStringRef JSValueToJSONCopy(JSContextRef context, JSValueRef value) {
 549     id object(CYCastNSObject(context, value));
 550     return reinterpret_cast<CFStringRef>([(object == nil ? @"null" : [object cy$toJSON]) retain]);
 551 }
 552
 553 static void OnData(CFSocketRef socket, CFSocketCallBackType type, CFDataRef address, const void *value, void *info) {
 554     switch (type) {
 555         case kCFSocketDataCallBack:
 556             CFDataRef data(reinterpret_cast<CFDataRef>(value));
 557             Client *client(reinterpret_cast<Client *>(info));
 558
 559             if (client->message_ == NULL)
 560                 client->message_ = CFHTTPMessageCreateEmpty(kCFAllocatorDefault, TRUE);
 561
 562             if (!CFHTTPMessageAppendBytes(client->message_, CFDataGetBytePtr(data), CFDataGetLength(data)))
 563                 CFLog(kCFLogLevelError, CFSTR("CFHTTPMessageAppendBytes()"));
 564             else if (CFHTTPMessageIsHeaderComplete(client->message_)) {
 565                 CFURLRef url(CFHTTPMessageCopyRequestURL(client->message_));
 566                 Boolean absolute;
 567                 CFStringRef path(CFURLCopyStrictPath(url, &absolute));
 568                 CFRelease(client->message_);
 569
 570                 CFStringRef code(CFURLCreateStringByReplacingPercentEscapes(kCFAllocatorDefault, path, CFSTR("")));
 571                 CFRelease(path);
 572
 573                 JSStringRef script(JSStringCreateWithCFString(code));
 574                 CFRelease(code);
 575
 576                 JSValueRef result(JSEvaluateScript(JSGetContext(), script, NULL, NULL, 0, NULL));
 577                 JSStringRelease(script);
 578
 579                 CFHTTPMessageRef response(CFHTTPMessageCreateResponse(kCFAllocatorDefault, 200, NULL, kCFHTTPVersion1_1));
 580                 CFHTTPMessageSetHeaderFieldValue(response, CFSTR("Content-Type"), CFSTR("application/json; charset=utf-8"));
 581
 582                 CFStringRef json(JSValueToJSONCopy(JSGetContext(), result));
 583                 CFDataRef body(CFStringCreateExternalRepresentation(kCFAllocatorDefault, json, kCFStringEncodingUTF8, NULL));
 584                 CFRelease(json);
 585
 586                 CFStringRef length(CFStringCreateWithFormat(kCFAllocatorDefault, NULL, CFSTR("%u"), CFDataGetLength(body)));
 587                 CFHTTPMessageSetHeaderFieldValue(response, CFSTR("Content-Length"), length);
 588                 CFRelease(length);
 589
 590                 CFHTTPMessageSetBody(response, body);
 591                 CFRelease(body);
 592
 593                 CFDataRef serialized(CFHTTPMessageCopySerializedMessage(response));
 594                 CFRelease(response);
 595
 596                 CFSocketSendData(socket, NULL, serialized, 0);
 597                 CFRelease(serialized);
 598
 599                 CFRelease(url);
 600             }
 601         break;
 602     }
 603 }
 604
 605 static void OnAccept(CFSocketRef socket, CFSocketCallBackType type, CFDataRef address, const void *value, void *info) {
 606     switch (type) {
 607         case kCFSocketAcceptCallBack:
 608             Client *client(new Client());
 609
 610             client->message_ = NULL;
 611
 612             CFSocketContext context;
 613             context.version = 0;
 614             context.info = client;
 615             context.retain = NULL;
 616             context.release = NULL;
 617             context.copyDescription = NULL;
 618
 619             client->socket_ = CFSocketCreateWithNative(kCFAllocatorDefault, *reinterpret_cast<const CFSocketNativeHandle *>(value), kCFSocketDataCallBack, &OnData, &context);
 620
 621             CFRunLoopAddSource(CFRunLoopGetCurrent(), CFSocketCreateRunLoopSource(kCFAllocatorDefault, client->socket_, 0), kCFRunLoopDefaultMode);
 622         break;
 623     }
 624 }
 625
 626 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef propertyName, JSValueRef *exception) {
 627     return NULL;
 628 }
 629
 630 typedef id jocData;
 631
 632 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { _pooled
 633     @try {
 634         id data(reinterpret_cast<jocData>(JSObjectGetPrivate(object)));
 635         return CYMakeObject(context, [[data alloc] autorelease]);
 636     } CYCatch
 637 }
 638
 639 struct ptrData {
 640     apr_pool_t *pool_;
 641     void *value_;
 642     sig::Type type_;
 643
 644     void *operator new(size_t size) {
 645         apr_pool_t *pool;
 646         apr_pool_create(&pool, NULL);
 647         void *data(apr_palloc(pool, size));
 648         reinterpret_cast<ptrData *>(data)->pool_ = pool;
 649         return data;;
 650     }
 651
 652     ptrData(void *value) :
 653         value_(value)
 654     {
 655     }
 656 };
 657
 658 struct ffiData : ptrData {
 659     sig::Signature signature_;
 660     ffi_cif cif_;
 661
 662     ffiData(void (*value)(), const char *type) :
 663         ptrData(reinterpret_cast<void *>(value))
 664     {
 665         sig::Parse(pool_, &signature_, type);
 666         sig::sig_ffi_cif(pool_, &sig::ObjectiveC, &signature_, &cif_);
 667     }
 668 };
 669
 670 struct selData : ptrData {
 671     selData(SEL value) :
 672         ptrData(value)
 673     {
 674     }
 675 };
 676
 677 static void Pointer_finalize(JSObjectRef object) {
 678     ptrData *data(reinterpret_cast<ptrData *>(JSObjectGetPrivate(object)));
 679     apr_pool_destroy(data->pool_);
 680 }
 681
 682 static void Instance_finalize(JSObjectRef object) {
 683     id data(reinterpret_cast<jocData>(JSObjectGetPrivate(object)));
 684     [data release];
 685 }
 686
 687 JSObjectRef CYMakeFunction(JSContextRef context, void (*function)(), const char *type) {
 688     ffiData *data(new ffiData(function, type));
 689     return JSObjectMake(context, Functor_, data);
 690 }
 691
 692
 693 JSObjectRef CYMakeFunction(JSContextRef context, void *function, const char *type) {
 694     return CYMakeFunction(context, reinterpret_cast<void (*)()>(function), type);
 695 }
 696
 697 void CYSetProperty(JSContextRef context, JSObjectRef object, const char *name, JSValueRef value) {
 698     JSValueRef exception(NULL);
 699     JSObjectSetProperty(context, object, CYString(name), value, kJSPropertyAttributeNone, &exception);
 700     CYThrow(context, exception);
 701 }
 702
 703 char *CYPoolCString(apr_pool_t *pool, JSStringRef value) {
 704     size_t size(JSStringGetMaximumUTF8CStringSize(value));
 705     char *string(new(pool) char[size]);
 706     JSStringGetUTF8CString(value, string, size);
 707     JSStringRelease(value);
 708     return string;
 709 }
 710
 711 char *CYPoolCString(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
 712     return CYPoolCString(pool, CYString(context, value));
 713 }
 714
 715 // XXX: this macro is dangerous
 716 #define CYCastCString(context, value) ({ \
 717     JSValueRef exception(NULL); \
 718     JSStringRef string(JSValueToStringCopy(context, value, &exception)); \
 719     CYThrow(context, exception); \
 720     size_t size(JSStringGetMaximumUTF8CStringSize(string)); \
 721     char *utf8(reinterpret_cast<char *>(alloca(size))); \
 722     JSStringGetUTF8CString(string, utf8, size); \
 723     JSStringRelease(string); \
 724     utf8; \
 725 })
 726
 727 SEL CYCastSEL(JSContextRef context, JSValueRef value) {
 728     if (JSValueIsNull(context, value))
 729         return NULL;
 730     else if (JSValueIsObjectOfClass(context, value, Selector_)) {
 731         selData *data(reinterpret_cast<selData *>(JSObjectGetPrivate((JSObjectRef) value)));
 732         return reinterpret_cast<SEL>(data->value_);
 733     } else
 734         return sel_registerName(CYCastCString(context, value));
 735 }
 736
 737 void *CYCastPointer(JSContextRef context, JSValueRef value) {
 738     switch (JSValueGetType(context, value)) {
 739         case kJSTypeNull:
 740             return NULL;
 741         case kJSTypeString:
 742             return dlsym(RTLD_DEFAULT, CYCastCString(context, value));
 743         case kJSTypeObject:
 744             // XXX: maybe support more than just pointers, like ffis and sels
 745             if (JSValueIsObjectOfClass(context, value, Pointer_)) {
 746                 ptrData *data(reinterpret_cast<ptrData *>(JSObjectGetPrivate((JSObjectRef) value)));
 747                 return data->value_;
 748             }
 749         default:
 750             JSValueRef exception(NULL);
 751             double number(JSValueToNumber(context, value, &exception));
 752             CYThrow(context, exception);
 753             return reinterpret_cast<void *>(static_cast<uintptr_t>(number));
 754     }
 755 }
 756
 757 void CYPoolFFI(apr_pool_t *pool, JSContextRef context, sig::Type *type, void *data, JSValueRef value) {
 758     switch (type->primitive) {
 759         case sig::boolean_P:
 760             *reinterpret_cast<bool *>(data) = JSValueToBoolean(context, value);
 761         break;
 762
 763 #define CYPoolFFI_(primitive, native) \
 764         case sig::primitive ## _P: { \
 765             JSValueRef exception(NULL); \
 766             double number(JSValueToNumber(context, value, &exception)); \
 767             CYThrow(context, exception); \
 768             *reinterpret_cast<native *>(data) = number; \
 769         } break;
 770
 771         CYPoolFFI_(uchar, unsigned char)
 772         CYPoolFFI_(char, char)
 773         CYPoolFFI_(ushort, unsigned short)
 774         CYPoolFFI_(short, short)
 775         CYPoolFFI_(ulong, unsigned long)
 776         CYPoolFFI_(long, long)
 777         CYPoolFFI_(uint, unsigned int)
 778         CYPoolFFI_(int, int)
 779         CYPoolFFI_(ulonglong, unsigned long long)
 780         CYPoolFFI_(longlong, long long)
 781         CYPoolFFI_(float, float)
 782         CYPoolFFI_(double, double)
 783
 784         case sig::object_P:
 785         case sig::typename_P:
 786             *reinterpret_cast<id *>(data) = CYCastNSObject(context, value);
 787         break;
 788
 789         case sig::selector_P:
 790             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
 791         break;
 792
 793         case sig::pointer_P:
 794             *reinterpret_cast<void **>(data) = CYCastPointer(context, value);
 795         break;
 796
 797         case sig::string_P:
 798             *reinterpret_cast<char **>(data) = CYPoolCString(pool, context, value);
 799         break;
 800
 801         case sig::struct_P:
 802             goto fail;
 803
 804         case sig::void_P:
 805         break;
 806
 807         default: fail:
 808             NSLog(@"CYPoolFFI(%c)\n", type->primitive);
 809             _assert(false);
 810     }
 811 }
 812
 813 JSValueRef CYFromFFI(JSContextRef context, sig::Type *type, void *data) {
 814     JSValueRef value;
 815
 816     switch (type->primitive) {
 817         case sig::boolean_P:
 818             value = JSValueMakeBoolean(context, *reinterpret_cast<bool *>(data));
 819         break;
 820
 821 #define CYFromFFI_(primitive, native) \
 822         case sig::primitive ## _P: \
 823             value = JSValueMakeNumber(context, *reinterpret_cast<native *>(data)); \
 824         break;
 825
 826         CYFromFFI_(uchar, unsigned char)
 827         CYFromFFI_(char, char)
 828         CYFromFFI_(ushort, unsigned short)
 829         CYFromFFI_(short, short)
 830         CYFromFFI_(ulong, unsigned long)
 831         CYFromFFI_(long, long)
 832         CYFromFFI_(uint, unsigned int)
 833         CYFromFFI_(int, int)
 834         CYFromFFI_(ulonglong, unsigned long long)
 835         CYFromFFI_(longlong, long long)
 836         CYFromFFI_(float, float)
 837         CYFromFFI_(double, double)
 838
 839         case sig::object_P:
 840         case sig::typename_P: {
 841             value = CYCastJSValue(context, *reinterpret_cast<id *>(data));
 842         } break;
 843
 844         case sig::selector_P: {
 845             if (SEL sel = *reinterpret_cast<SEL *>(data)) {
 846                 selData *data(new selData(sel));
 847                 value = JSObjectMake(context, Selector_, data);
 848             } else value = JSValueMakeNull(context);
 849         } break;
 850
 851         case sig::pointer_P: {
 852             if (void *pointer = *reinterpret_cast<void **>(data)) {
 853                 ptrData *data(new ptrData(pointer));
 854                 value = JSObjectMake(context, Pointer_, data);
 855             } else value = JSValueMakeNull(context);
 856         } break;
 857
 858         case sig::string_P: {
 859             char *utf8(*reinterpret_cast<char **>(data));
 860             value = utf8 == NULL ? JSValueMakeNull(context) : JSValueMakeString(context, CYString(utf8));
 861         } break;
 862
 863         case sig::struct_P:
 864             goto fail;
 865
 866         case sig::void_P:
 867             value = NULL;
 868         break;
 869
 870         default: fail:
 871             NSLog(@"CYFromFFI(%c)\n", type->primitive);
 872             _assert(false);
 873     }
 874
 875     return value;
 876 }
 877
 878 static JSValueRef CYCallFunction(JSContextRef context, size_t count, const JSValueRef *arguments, JSValueRef *exception, sig::Signature *signature, ffi_cif *cif, void (*function)()) { _pooled
 879     @try {
 880         if (count != signature->count - 1)
 881             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to ffi function" userInfo:nil];
 882
 883         CYPool pool;
 884         void *values[count];
 885
 886         for (unsigned index(0); index != count; ++index) {
 887             sig::Element *element(&signature->elements[index + 1]);
 888             // XXX: alignment?
 889             values[index] = new(pool) uint8_t[cif->arg_types[index]->size];
 890             CYPoolFFI(pool, context, element->type, values[index], arguments[index]);
 891         }
 892
 893         uint8_t value[cif->rtype->size];
 894         ffi_call(cif, function, value, values);
 895
 896         return CYFromFFI(context, signature->elements[0].type, value);
 897     } CYCatch
 898 }
 899
 900 static JSValueRef Global_getProperty(JSContextRef context, JSObjectRef object, JSStringRef name, JSValueRef *exception) { _pooled
 901     @try {
 902         NSString *string(CYCastNSString(name));
 903         if (Class _class = NSClassFromString(string))
 904             return CYMakeObject(context, _class);
 905         if (NSMutableArray *entry = [Bridge_ objectForKey:string])
 906             switch ([[entry objectAtIndex:0] intValue]) {
 907                 case 0:
 908                     return JSEvaluateScript(JSGetContext(), CYString([entry objectAtIndex:1]), NULL, NULL, 0, NULL);
 909                 case 1:
 910                     return CYMakeFunction(context, [string cy$symbol], [[entry objectAtIndex:1] UTF8String]);
 911                 case 2:
 912                     CYPool pool;
 913                     sig::Signature signature;
 914                     sig::Parse(pool, &signature, [[entry objectAtIndex:1] UTF8String]);
 915                     return CYFromFFI(context, signature.elements[0].type, [string cy$symbol]);
 916             }
 917         return NULL;
 918     } CYCatch
 919 }
 920
 921 bool stret(ffi_type *ffi_type) {
 922     return ffi_type->type == FFI_TYPE_STRUCT && (
 923         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
 924         struct_forward_array[ffi_type->size] != 0
 925     );
 926 }
 927
 928 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { _pooled
 929     const char *type;
 930
 931     @try {
 932         if (count < 2)
 933             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"too few arguments to objc_msgSend" userInfo:nil];
 934
 935         id self(CYCastNSObject(context, arguments[0]));
 936         if (self == nil)
 937             return JSValueMakeNull(context);
 938
 939         SEL _cmd(CYCastSEL(context, arguments[1]));
 940         NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
 941         if (method == nil)
 942             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:[NSString stringWithFormat:@"unrecognized selector %s sent to object %p", sel_getName(_cmd), self] userInfo:nil];
 943
 944         type = [[method _typeString] UTF8String];
 945     } CYCatch
 946
 947     CYPool pool;
 948
 949     sig::Signature signature;
 950     sig::Parse(pool, &signature, type);
 951
 952     ffi_cif cif;
 953     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
 954
 955     void (*function)() = stret(cif.rtype) ? reinterpret_cast<void (*)()>(&objc_msgSend_stret) : reinterpret_cast<void (*)()>(&objc_msgSend);
 956     return CYCallFunction(context, count, arguments, exception, &signature, &cif, function);
 957 }
 958
 959 static JSValueRef ffi_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
 960     ffiData *data(reinterpret_cast<ffiData *>(JSObjectGetPrivate(object)));
 961     return CYCallFunction(context, count, arguments, exception, &data->signature_, &data->cif_, reinterpret_cast<void (*)()>(data->value_));
 962 }
 963
 964 JSObjectRef ffi(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
 965     @try {
 966         if (count != 2)
 967             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to ffi constructor" userInfo:nil];
 968         void *function(CYCastPointer(context, arguments[0]));
 969         const char *type(CYCastCString(context, arguments[1]));
 970         return CYMakeFunction(context, function, type);
 971     } CYCatch
 972 }
 973
 974 JSValueRef Pointer_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef name, JSValueRef *exception) {
 975     ptrData *data(reinterpret_cast<ptrData *>(JSObjectGetPrivate(object)));
 976     return JSValueMakeNumber(context, reinterpret_cast<uintptr_t>(data->value_));
 977 }
 978
 979 static JSStaticValue Pointer_staticValues[2] = {
 980     {"value", &Pointer_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
 981     {NULL, NULL, NULL, 0}
 982 };
 983
 984 MSInitialize { _pooled
 985     apr_initialize();
 986
 987     NSCFBoolean_ = objc_getClass("NSCFBoolean");
 988
 989     pid_t pid(getpid());
 990
 991     struct sockaddr_in address;
 992     address.sin_len = sizeof(address);
 993     address.sin_family = AF_INET;
 994     address.sin_addr.s_addr = INADDR_ANY;
 995     address.sin_port = htons(10000 + pid);
 996
 997     CFDataRef data(CFDataCreate(kCFAllocatorDefault, reinterpret_cast<UInt8 *>(&address), sizeof(address)));
 998
 999     CFSocketSignature signature;
1000     signature.protocolFamily = AF_INET;
1001     signature.socketType = SOCK_STREAM;
1002     signature.protocol = IPPROTO_TCP;
1003     signature.address = data;
1004
1005     CFSocketRef socket(CFSocketCreateWithSocketSignature(kCFAllocatorDefault, &signature, kCFSocketAcceptCallBack, &OnAccept, NULL));
1006     CFRunLoopAddSource(CFRunLoopGetCurrent(), CFSocketCreateRunLoopSource(kCFAllocatorDefault, socket, 0), kCFRunLoopDefaultMode);
1007
1008     JSClassDefinition definition;
1009
1010     definition = kJSClassDefinitionEmpty;
1011     definition.className = "Pointer";
1012     definition.staticValues = Pointer_staticValues;
1013     definition.finalize = &Pointer_finalize;
1014     Pointer_ = JSClassCreate(&definition);
1015
1016     definition = kJSClassDefinitionEmpty;
1017     definition.className = "Functor";
1018     definition.parentClass = Pointer_;
1019     definition.callAsFunction = &ffi_callAsFunction;
1020     Functor_ = JSClassCreate(&definition);
1021
1022     definition = kJSClassDefinitionEmpty;
1023     definition.className = "Selector";
1024     definition.parentClass = Pointer_;
1025     Selector_ = JSClassCreate(&definition);
1026
1027     definition = kJSClassDefinitionEmpty;
1028     definition.className = "Instance_";
1029     definition.getProperty = &Instance_getProperty;
1030     definition.callAsConstructor = &Instance_callAsConstructor;
1031     definition.finalize = &Instance_finalize;
1032     Instance_ = JSClassCreate(&definition);
1033
1034     definition = kJSClassDefinitionEmpty;
1035     definition.getProperty = &Global_getProperty;
1036     JSClassRef Global(JSClassCreate(&definition));
1037
1038     JSContextRef context(JSGlobalContextCreate(Global));
1039     Context_ = context;
1040
1041     JSObjectRef global(JSContextGetGlobalObject(context));
1042
1043     CYSetProperty(context, global, "ffi", JSObjectMakeConstructor(context, Functor_, &ffi));
1044
1045     CYSetProperty(context, global, "objc_msgSend", JSObjectMakeFunctionWithCallback(context, CYString("objc_msgSend"), &$objc_msgSend));
1046
1047     Bridge_ = [[NSMutableDictionary dictionaryWithContentsOfFile:@"/usr/lib/libcyrver.plist"] retain];
1048
1049     name_ = JSStringCreateWithUTF8CString("name");
1050     message_ = JSStringCreateWithUTF8CString("message");
1051     length_ = JSStringCreateWithUTF8CString("length");
1052
1053     JSValueRef exception(NULL);
1054     JSValueRef value(JSObjectGetProperty(JSGetContext(), global, CYString("Array"), &exception));
1055     CYThrow(context, exception);
1056     Array_ = JSValueToObject(JSGetContext(), value, &exception);
1057     CYThrow(context, exception);
1058 }