Cycript.l

   1 %{
   2 #define YYLTYPE cy::location
   3 #include "Cycript.tab.hh"
   4 typedef cy::parser::token tk;
   5
   6 #define YY_EXTRA_TYPE CYDriver *
   7
   8 #define T yylval->newline_ = yyextra->state_ == CYNewLine;
   9 #define C T yyextra->state_ = CYClear;
  10 #define R T yyextra->state_ = CYRestricted;
  11
  12 #define E(prefix) L C BEGIN(INITIAL); { \
  13     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng + sizeof(prefix)))); \
  14     memcpy(value, prefix, sizeof(prefix) - 1); \
  15     memcpy(value + sizeof(prefix) - 1, yytext, yyleng); \
  16     value[yyleng + sizeof(prefix) - 1] = '\0'; \
  17     yylval->literal_ = new(yyextra->pool_) CYRegEx(value); \
  18     return tk::RegularExpressionLiteral; \
  19 }
  20
  21 #define N \
  22     if (yyextra->state_ != CYNewLine) { \
  23         bool restricted(yyextra->state_ == CYRestricted); \
  24         if (restricted) { \
  25             yyextra->state_ = CYClear; \
  26             return tk::NewLine; \
  27         } else \
  28             yyextra->state_ = CYNewLine; \
  29     }
  30
  31 #define L { \
  32     yylloc->step(); \
  33     yylloc->columns(yyleng); \
  34 }
  35
  36 int H(char c) {
  37     if (c >= '0' && c <= '9')
  38         return c - '0';
  39     if (c >= 'a' && c <= 'f')
  40         return c - 'a' + 10;
  41     if (c >= 'A' && c <= 'F')
  42         return c - 'A' + 10;
  43     return -1;
  44 }
  45
  46 #define YY_INPUT(data, value, size) { \
  47     if (yyextra->file_ != NULL) { \
  48         size_t copy(fread(data, 1, size, yyextra->file_)); \
  49         value = copy == 0 ? YY_NULL : copy; \
  50     } else if (yyextra->size_ == 0) \
  51         value = YY_NULL; \
  52     else { \
  53         size_t copy(std::min(size, yyextra->size_)); \
  54         memcpy(data, yyextra->data_, copy); \
  55         yyextra->data_ += copy; \
  56         yyextra->size_ -= copy; \
  57         value = copy; \
  58     } \
  59 }
  60
  61 %}
  62
  63 %option prefix="cy"
  64 %option bison-bridge
  65 %option bison-locations
  66 %option noyywrap
  67 %option yylineno
  68 %option nounput
  69 %option interactive
  70 %option reentrant
  71
  72 Exponent [eE][+-]?[0-9]+
  73 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
  74
  75 IdentifierStart [a-zA-Z$_]
  76 IdentifierPart  [a-zA-Z$_0-9]
  77
  78 NonTerminator [^\n]
  79 BackslashSequence \\{NonTerminator}
  80 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
  81 RegularExpressionChar [^\n\\/]|{BackslashSequence}
  82 RegularExpressionFlags {IdentifierPart}*
  83 RegularExpressionChars {RegularExpressionChar}*
  84 RegularExpressionBody_ {RegularExpressionChars}
  85 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionBody_}
  86
  87 RegularExpressionEnd_ \/{RegularExpressionFlags}
  88 RegularExpressionRest_ {RegularExpressionBody_}{RegularExpressionEnd_}
  89 RegularExpressionStart_ {RegularExpressionBody}{RegularExpressionEnd_}
  90
  91 %x res
  92 %x rer
  93
  94 %%
  95
  96 <res>{RegularExpressionStart_} E("/")
  97 <rer>{RegularExpressionRest_} E("/=")
  98
  99 \/\/[^\n]* L
 100
 101 \/\*(\n|[^\*]|\*[^/])*\*\/ {
 102     // XXX: supposedly I will be screwed on very very long multi-line comments and need to replace this with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf
 103
 104     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) {
 105         unsigned lines(0);
 106         size_t left;
 107
 108         do {
 109             ++lines;
 110             left = yyleng - (nl - yytext) - 1;
 111             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left));
 112         } while (nl != NULL);
 113
 114         yylloc->end.lines(lines);
 115         yylloc->end.columns(left);
 116         yylloc->step();
 117     } else L
 118 }
 119
 120 "&"    L C return tk::Ampersand;
 121 "&&"   L C return tk::AmpersandAmpersand;
 122 "&="   L C return tk::AmpersandEqual;
 123 "^"    L C return tk::Carrot;
 124 "^="   L C return tk::CarrotEqual;
 125 "="    L C return tk::Equal;
 126 "=="   L C return tk::EqualEqual;
 127 "==="  L C return tk::EqualEqualEqual;
 128 "!"    L C return tk::Exclamation;
 129 "!="   L C return tk::ExclamationEqual;
 130 "!=="  L C return tk::ExclamationEqualEqual;
 131 "-"    L C return tk::Hyphen;
 132 "-="   L C return tk::HyphenEqual;
 133 "--"   L C return yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen;
 134 "->"   L C return tk::HyphenRight;
 135 "<"    L C return tk::Left;
 136 "<="   L C return tk::LeftEqual;
 137 "<<"   L C return tk::LeftLeft;
 138 "<<="  L C return tk::LeftLeftEqual;
 139 "%"    L C return tk::Percent;
 140 "%="   L C return tk::PercentEqual;
 141 "."    L C return tk::Period;
 142 "|"    L C return tk::Pipe;
 143 "|="   L C return tk::PipeEqual;
 144 "||"   L C return tk::PipePipe;
 145 "+"    L C return tk::Plus;
 146 "+="   L C return tk::PlusEqual;
 147 "++"   L C return yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus;
 148 ">"    L C return tk::Right;
 149 ">="   L C return tk::RightEqual;
 150 ">>"   L C return tk::RightRight;
 151 ">>="  L C return tk::RightRightEqual;
 152 ">>>"  L C return tk::RightRightRight;
 153 ">>>=" L C return tk::RightRightRightEqual;
 154 "/"    L C return tk::Slash;
 155 "/="   L C return tk::SlashEqual;
 156 "*"    L C return tk::Star;
 157 "*="   L C return tk::StarEqual;
 158 "~"    L C return tk::Tilde;
 159
 160 ":"    L C return tk::Colon;
 161 ","    L C return tk::Comma;
 162 "?"    L C return tk::Question;
 163 ";"    L C return tk::SemiColon;
 164
 165 "("    L C return tk::OpenParen;
 166 ")"    L C return tk::CloseParen;
 167
 168 "{"    L C return tk::OpenBrace;
 169 "}"    L C return tk::CloseBrace;
 170
 171 "["    L C return tk::OpenBracket;
 172 "]"    L C return tk::CloseBracket;
 173
 174 "@class"       L C return tk::AtClass;
 175 "@end"         L C return tk::AtEnd;
 176 "@selector"    L C return tk::AtSelector;
 177
 178 "false"        L C yylval->false_ = new(yyextra->pool_) CYFalse(); return tk::False;
 179 "null"         L C yylval->null_ = new(yyextra->pool_) CYNull(); return tk::Null;
 180 "true"         L C yylval->true_ = new(yyextra->pool_) CYTrue(); return tk::True;
 181
 182 "break"        L R yylval->word_ = new(yyextra->pool_) CYWord("break"); return tk::Break;
 183 "case"         L C yylval->word_ = new(yyextra->pool_) CYWord("case"); return tk::Case;
 184 "catch"        L C yylval->word_ = new(yyextra->pool_) CYWord("catch"); return tk::Catch;
 185 "continue"     L R yylval->word_ = new(yyextra->pool_) CYWord("continue"); return tk::Continue;
 186 "default"      L C yylval->word_ = new(yyextra->pool_) CYWord("default"); return tk::Default;
 187 "delete"       L C yylval->word_ = new(yyextra->pool_) CYWord("delete"); return tk::Delete;
 188 "do"           L C yylval->word_ = new(yyextra->pool_) CYWord("do"); return tk::Do;
 189 "else"         L C yylval->word_ = new(yyextra->pool_) CYWord("else"); return tk::Else;
 190 "finally"      L C yylval->word_ = new(yyextra->pool_) CYWord("finally"); return tk::Finally;
 191 "for"          L C yylval->word_ = new(yyextra->pool_) CYWord("for"); return tk::For;
 192 "function"     L C yylval->word_ = new(yyextra->pool_) CYWord("function"); return tk::Function;
 193 "if"           L C yylval->word_ = new(yyextra->pool_) CYWord("if"); return tk::If;
 194 "in"           L C yylval->word_ = new(yyextra->pool_) CYWord("in"); return tk::In;
 195 "instanceof"   L C yylval->word_ = new(yyextra->pool_) CYWord("instanceof"); return tk::InstanceOf;
 196 "new"          L C yylval->word_ = new(yyextra->pool_) CYWord("new"); return tk::New;
 197 "return"       L R yylval->word_ = new(yyextra->pool_) CYWord("return"); return tk::Return;
 198 "switch"       L C yylval->word_ = new(yyextra->pool_) CYWord("switch"); return tk::Switch;
 199 "this"         L C yylval->this_ = new(yyextra->pool_) CYThis(); return tk::This;
 200 "throw"        L R yylval->word_ = new(yyextra->pool_) CYWord("throw"); return tk::Throw;
 201 "try"          L C yylval->word_ = new(yyextra->pool_) CYWord("try"); return tk::Try;
 202 "typeof"       L C yylval->word_ = new(yyextra->pool_) CYWord("typeof"); return tk::TypeOf;
 203 "var"          L C yylval->word_ = new(yyextra->pool_) CYWord("var"); return tk::Var;
 204 "void"         L C yylval->word_ = new(yyextra->pool_) CYWord("void"); return tk::Void;
 205 "while"        L C yylval->word_ = new(yyextra->pool_) CYWord("while"); return tk::While;
 206 "with"         L C yylval->word_ = new(yyextra->pool_) CYWord("with"); return tk::With;
 207
 208 "debugger"     L C yylval->word_ = new(yyextra->pool_) CYWord("debugger"); return tk::Debugger;
 209
 210 "const"        L C yylval->word_ = new(yyextra->pool_) CYWord("const"); return tk::Const;
 211
 212 "class"        L C yylval->word_ = new(yyextra->pool_) CYWord("class"); return tk::Class;
 213 "enum"         L C yylval->word_ = new(yyextra->pool_) CYWord("enum"); return tk::Enum;
 214 "export"       L C yylval->word_ = new(yyextra->pool_) CYWord("export"); return tk::Export;
 215 "extends"      L C yylval->word_ = new(yyextra->pool_) CYWord("extends"); return tk::Extends;
 216 "import"       L C yylval->word_ = new(yyextra->pool_) CYWord("import"); return tk::Import;
 217 "super"        L C yylval->word_ = new(yyextra->pool_) CYWord("super"); return tk::Super;
 218
 219 "implements"   L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("implements"); return tk::Implements;
 220 "interface"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("interface"); return tk::Interface;
 221 "package"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("package"); return tk::Package;
 222 "private"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("private"); return tk::Private;
 223 "protected"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("protected"); return tk::Protected;
 224 "public"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("public"); return tk::Public;
 225 "static"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("static"); return tk::Static;
 226
 227 "abstract"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("abstract"); return tk::Abstract;
 228 "boolean"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("boolean"); return tk::Boolean;
 229 "byte"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("byte"); return tk::Byte;
 230 "char"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("char"); return tk::Char;
 231 "double"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("double"); return tk::Double;
 232 "final"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("final"); return tk::Final;
 233 "float"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("float"); return tk::Float;
 234 "goto"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("goto"); return tk::Goto;
 235 "int"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("int"); return tk::Int;
 236 "long"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("long"); return tk::Long;
 237 "native"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("native"); return tk::Native;
 238 "short"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("short"); return tk::Short;
 239 "synchronized" L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("synchronized"); return tk::Synchronized;
 240 "throws"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("throws"); return tk::Throws;
 241 "transient"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("transient"); return tk::Transient;
 242 "volatile"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("volatile"); return tk::Volatile;
 243
 244 "let"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("let"); return tk::Let;
 245 "yield"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("yield"); return tk::Yield;
 246
 247 "each"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("each"); return tk::Each;
 248
 249 {IdentifierStart}{IdentifierPart}* yylval->identifier_ = new(yyextra->pool_) CYIdentifier(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); L C return tk::Identifier_;
 250
 251 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? yylval->number_ = new(yyextra->pool_) CYNumber(strtod(yytext, NULL)); L C return tk::NumericLiteral;
 252
 253 0[xX][0-9a-fA-F]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 16)); return tk::NumericLiteral;
 254
 255 0[bB][0-1]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 2)); return tk::NumericLiteral;
 256
 257 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 258     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng)));
 259     char *local(value);
 260
 261     for (int i(1); i != yyleng - 1; ++i) {
 262         char next(yytext[i]);
 263
 264         if (yytext[i] == '\\')
 265             switch (next = yytext[++i]) {
 266                 case '\n': continue;
 267                 case '\\': next = '\\'; break;
 268                 case '\'': next = '\''; break;
 269                 case '"': next = '"'; break;
 270                 case 'b': next = '\b'; break;
 271                 case 'f': next = '\f'; break;
 272                 case 'n': next = '\n'; break;
 273                 case 'r': next = '\r'; break;
 274                 case 't': next = '\t'; break;
 275                 case 'v': next = '\v'; break;
 276                 case '0': next = '\0'; break;
 277
 278                 case 'x':
 279                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 280                     i += 2;
 281                 break;
 282             }
 283
 284         *local++ = next;
 285     }
 286
 287     *local = '\0';
 288     yylval->string_ = new(yyextra->pool_) CYString(value, local - value);
 289     return tk::StringLiteral;
 290 }
 291
 292 \n yylloc->end.lines(); yylloc->step(); N
 293
 294 [ \t] L
 295 <<EOF>> L yyterminate();
 296
 297 . L {
 298     CYDriver::Error error;
 299     error.location_ = *yylloc;
 300     error.message_ = "syntax error, unknown token";
 301     yyextra->errors_.push_back(error);
 302     yyterminate();
 303 }
 304
 305 %%
 306
 307 void CYDriver::ScannerInit() {
 308     cylex_init(&scanner_);
 309     cyset_extra(this, scanner_);
 310 }
 311
 312 void CYDriver::ScannerDestroy() {
 313     cylex_destroy(scanner_);
 314 }
 315
 316 void CYDriver::SetCondition(Condition condition) {
 317     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 318
 319     switch (condition) {
 320         case RegExStart:
 321             BEGIN(res);
 322             break;
 323         case RegExRest:
 324             BEGIN(rer);
 325             break;
 326         default:
 327             _assert(false);
 328     }
 329 }