configure.ac

   1 AC_PREREQ([2.65])
   2 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
   3 AC_CONFIG_SRCDIR([Console.cpp])
   4 AC_CONFIG_AUX_DIR([.])
   5 LT_INIT([disable-static])
   6 PKG_PROG_PKG_CONFIG([0.22])
   7 CHECK_GNU_MAKE
   8 AC_SUBST([GMAKE], [$_cv_gnu_make_command])
   9 AS_IF([test "x$GMAKE" = x], [AC_MSG_ERROR([You need GNU make])])
  10 AC_PATH_PROGS([_BASH], [bash])
  11 AS_IF([test "x$_BASH" = x], [AC_MSG_ERROR([You need GNU bash])])
  12 AC_PATH_PROGS([TIME], [time])
  13 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  14         AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  15         AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$3[,
  16                 AS_VERSION_COMPARE(`$ac_path_]$1[ ]$4[`, ]$5[, ,
  17                         ac_cv_path_]$1[=$ac_path_]$1[
  18                 ,
  19                         ac_cv_path_]$1[=$ac_path_]$1[
  20                 )
  21         ,
  22                 AC_MSG_RESULT(not found)
  23                 AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  24         )
  25         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  26         AC_MSG_RESULT($]$1[)
  27 ])
  28 AC_ARG_VAR([BISON], [GNU Project parser generator (yacc replacement)])
  29 CY_CHECK_PROGS_VERSION([BISON], [bison], [bison],
  30         [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  31 AC_ARG_VAR([FLEX], [the fast lexical analyser generator])
  32 CY_CHECK_PROGS_VERSION([FLEX], [flex], [flex],
  33         [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [2.5.33])
  34 AC_ARG_VAR([GPERF], [perfect hash function generator])
  35 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [gperf],
  36         [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  37 AC_PROG_INSTALL
  38 AC_MSG_CHECKING([for GNU tar])
  39 AC_PATH_PROGS_FEATURE_CHECK([GNUTAR], [tar gtar gnutar], [
  40         AS_IF([test "x`$ac_path_GNUTAR --version | $SED -e '1 s/^tar (GNU tar)/&/p;d'`" != x], [
  41                 ac_cv_path_GNUTAR=$ac_path_GNUTAR
  42         ])
  43 ])
  44 AS_IF([test "x$ac_cv_path_GNUTAR" != x], [
  45         AC_SUBST([GNUTAR], [$ac_cv_path_GNUTAR])
  46         AC_MSG_RESULT([$GNUTAR])
  47 ], [
  48         AC_SUBST([GNUTAR], [:])
  49         AC_MSG_RESULT([not found])
  50 ])
  51 AC_CHECK_PROGS([SVN], [svn])
  52 AC_CHECK_PROGS([SVNVERSION], [svnversion])
  53 AC_PROG_CXX
  54 AC_PROG_OBJCXX
  55 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
  56         [--with-frameworks=DIRS],
  57         [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
  58 )], [
  59         for framework in $withval; do
  60                 AC_LIB_APPENDTOVAR([CFLAGS], [-F$framework])
  61                 AC_LIB_APPENDTOVAR([CXXFLAGS], [-F$framework])
  62                 AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], [-F$framework])
  63         done
  64 ])
  65 AC_LANG([C++])
  66 APR_FIND_APR([], [], [1], [1])
  67 AS_CASE([$apr_found], [yes], [
  68         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
  69         AC_SUBST([LTLIBAPR], [`$apr_config --link-libtool`])
  70 ], [AC_MSG_ERROR([You need apr])])
  71 VL_LIB_READLINE
  72 AC_LANG_PUSH([C])
  73 AM_ICONV
  74 AC_LANG_POP([C])
  75 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([You need iconv])])
  76 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
  77         PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
  78                 CY_EXECUTE=1
  79                 AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
  80                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
  81         ], [
  82                 PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
  83                         CY_EXECUTE=1
  84                         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
  85                         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
  86                 ], [
  87                         AC_CHECK_FRAMEWORK([JavaScriptCore], [
  88                                 #include <JavaScriptCore/JSBase.h>
  89                         ], [JSEvaluateScript(0, 0, 0, 0, 0, 0);], [CY_EXECUTE=1])
  90                 ])
  91         ])
  92 ])
  93 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
  94         CY_CHECK_JAVASCRIPTCORE
  95 ])
  96 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
  97         [--enable-javascript@<:@=ENGINE@:>@],
  98         [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
  99 )], [
 100         AS_CASE([$enableval], [yes], [CY_CHECK_JAVASCRIPT], [no], [
 101                 AC_SUBST([CY_EXECUTE], [0])
 102         ], [JavaScriptCore], [
 103                 CY_CHECK_JAVASCRIPTCORE
 104         ], [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 105 ], [CY_CHECK_JAVASCRIPT])
 106 AS_CASE([$CY_EXECUTE], [1], [
 107         AC_SUBST([CY_EXECUTE])
 108         PKG_CHECK_MODULES([LIBFFI], [libffi], [
 109                 AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
 110                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 111         ], [
 112                 AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 113                 AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 114                         AC_MSG_ERROR([You need libffi])
 115                 ])
 116                 AC_SEARCH_LIBS([ffi_call], [ffi])
 117                 AS_CASE([$ac_cv_search_ffi_call], [no], [
 118                         AC_MSG_ERROR([You need libffi])
 119                 ])
 120         ])
 121         AC_LANG_PUSH([Objective C++])
 122         AC_MSG_CHECKING([if we really have Objective C++])
 123         AC_COMPILE_IFELSE([
 124                 // This space intentionally left blank
 125         ], [
 126                 CY_OBJECTIVEC=1
 127                 AC_MSG_RESULT([yes])
 128         ], [AC_MSG_RESULT([no])])
 129         AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 130                 AC_CHECK_FRAMEWORK([CoreFoundation], [
 131                         #include <CoreFoundation/CFBase.h>
 132                 ], [CFAllocatorGetDefault();], [
 133                         AC_SUBST([CY_OBJECTIVEC])
 134                         AC_CHECK_FRAMEWORK([Foundation], [
 135                                 #include <Foundation/NSObject.h>
 136                         ], [[[[NSObject alloc] init];]])
 137                         AC_CHECK_FRAMEWORK([WebKit], [
 138                                 #include <WebKit/WebScriptObject.h>
 139                         ], [[[[WebScriptObject alloc] init];]])
 140                 ], [
 141                         AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 142                         AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 143                         AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 144                                 AC_SUBST([CY_OBJECTIVEC])
 145                                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 146                                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 147                         ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 148                 ])
 149         ])
 150         AC_LANG_POP([Objective C++])
 151 ])
 152 AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 153         AC_CHECK_HEADER([mach/mach.h], [
 154                 AS_CASE([$OTOOL], [:], [AC_MSG_WARN([Missing otool?])], [AC_SUBST([CY_OBJECTIVEC_MACH], [1])])
 155         ])
 156 ])
 157 AS_IF([test "x$GMAKE" != xmake], [
 158         AC_CONFIG_FILES([Makefile])
 159 ])
 160 AC_CONFIG_FILES([GNUmakefile])
 161 AC_OUTPUT