configure.ac

   1 AC_PREREQ([2.65])
   2 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
   3 AC_CONFIG_SRCDIR([Console.cpp])
   4 AC_CONFIG_AUX_DIR([.])
   5 LT_INIT([disable-static])
   6 PKG_PROG_PKG_CONFIG([0.22])
   7 CHECK_GNU_MAKE
   8 AS_IF([test "x$_cv_gnu_make_command" = x], [AC_MSG_ERROR([You need GNU make])])
   9 AC_PROG_CXX
  10 AC_PROG_OBJCXX
  11 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
  12         [--with-frameworks=DIRS],
  13         [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
  14 )], [
  15         for framework in $withval; do
  16                 AC_LIB_APPENDTOVAR([CFLAGS], [-F$framework])
  17                 AC_LIB_APPENDTOVAR([CXXFLAGS], [-F$framework])
  18                 AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], [-F$framework])
  19         done
  20 ])
  21 AC_LANG([C++])
  22 AC_PROG_SED
  23 AX_PROG_BISON([
  24         BISON=`echo $YACC | $SED -e 's/ -y//'`
  25         BISON_VERSION=`$BISON -V | $SED -e 's/^bison (GNU Bison) \(.*\)$/\1/p;d'`
  26 ], [AC_MSG_ERROR([You need bison 2.3 or greater])])
  27 AC_PROG_AWK
  28 AC_MSG_CHECKING([if bison is >= 2.3])
  29 AS_VERSION_COMPARE([$BISON_VERSION], [2.3], [
  30         AC_MSG_RESULT([no])
  31         AC_MSG_ERROR([You need bison 2.3 or greater])
  32 ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([yes])])
  33 AC_SUBST([BISON])
  34 AX_PROG_FLEX([
  35         FLEX=$LEX
  36         FLEX_VERSION=[`$FLEX --version | $SED -e 's/^.* \([0-9.]*\)$/\1/p;d'`]
  37 ], [AC_MSG_ERROR([You need flex 2.5.33 or greater])])
  38 AC_MSG_CHECKING([if flex is >= 2.5.33])
  39 AS_VERSION_COMPARE([$FLEX_VERSION], [2.5.33], [
  40         AC_MSG_RESULT([no])
  41         AC_MSG_ERROR([You need flex 2.5.33 or greater])
  42 ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([yes])])
  43 AC_SUBST([FLEX])
  44 AC_CHECK_PROGS([_BASH], [bash])
  45 AC_ARG_VAR([GPERF], [perfect hash function generator])
  46 AC_CHECK_PROGS([GPERF], [gperf])
  47 AC_MSG_CHECKING([if gperf >= 3.0.3])
  48 GPERF_VERSION=[`$GPERF --version | $SED -e 's/^.* \([0-9.]*\)$/\1/p;d'`]
  49 AS_VERSION_COMPARE([$GPERF_VERSION], [3.0.3], [
  50         AC_MSG_RESULT([no])
  51         AC_MSG_ERROR([You need gperf 3.0.3 or greater])
  52 ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([yes])])
  53 AC_CHECK_PROGS([TIME], [time])
  54 APR_FIND_APR([], [], [1], [1])
  55 AS_CASE([$apr_found], [yes], [
  56         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
  57         AC_SUBST([LTLIBAPR], [`$apr_config --link-libtool`])
  58 ], [AC_MSG_ERROR([You need apr])])
  59 VL_LIB_READLINE
  60 AC_PROG_INSTALL
  61 AC_LANG_PUSH([C])
  62 AM_ICONV
  63 AC_LANG_POP([C])
  64 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([You need iconv])])
  65 PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
  66         CY_EXECUTE=1
  67         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
  68         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
  69 ], [
  70         PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
  71                 CY_EXECUTE=1
  72                 AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
  73                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
  74         ], [
  75                 AC_CHECK_FRAMEWORK([JavaScriptCore], [
  76                         #include <JavaScriptCore/JSBase.h>
  77                 ], [JSEvaluateScript(0, 0, 0, 0, 0, 0);], [CY_EXECUTE=1])
  78         ])
  79 ])
  80 AS_CASE([$CY_EXECUTE], [1], [
  81         AC_SUBST([CY_EXECUTE])
  82         PKG_CHECK_MODULES([LIBFFI], [libffi], [
  83                 AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
  84                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
  85         ], [
  86                 AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
  87                 AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
  88                         AC_MSG_ERROR([You need libffi])
  89                 ])
  90                 AC_SEARCH_LIBS([ffi_call], [ffi])
  91                 AS_CASE([$ac_cv_search_ffi_call], [no], [
  92                         AC_MSG_ERROR([You need libffi])
  93                 ])
  94         ])
  95         AC_LANG_PUSH([Objective C++])
  96         AC_MSG_CHECKING([if we really have Objective C++])
  97         AC_COMPILE_IFELSE([
  98                 // This space intentionally left blank
  99         ], [
 100                 CY_OBJECTIVEC=1
 101                 AC_MSG_RESULT([yes])
 102         ], [AC_MSG_RESULT([no])])
 103         AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 104                 AC_CHECK_FRAMEWORK([CoreFoundation], [
 105                         #include <CoreFoundation/CFBase.h>
 106                 ], [CFAllocatorGetDefault();], [
 107                         AC_SUBST([CY_OBJECTIVEC])
 108                         AC_CHECK_FRAMEWORK([Foundation], [
 109                                 #include <Foundation/NSObject.h>
 110                         ], [[[[NSObject alloc] init];]])
 111                         AC_CHECK_FRAMEWORK([WebKit], [
 112                                 #include <WebKit/WebScriptObject.h>
 113                         ], [[[[WebScriptObject alloc] init];]])
 114                 ], [
 115                         AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 116                         AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 117                                 AC_SUBST([CY_OBJECTIVEC])
 118                                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 119                                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 120                         ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 121                 ])
 122         ])
 123         AC_LANG_POP([Objective C++])
 124 ], [
 125         AC_MSG_WARN([No JavaScript engine!])
 126 ])
 127 AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 128         AC_CHECK_HEADER([mach/mach.h], [
 129                 AS_CASE([$OTOOL], [:], [AC_MSG_WARN([Missing otool?])], [AC_SUBST([CY_OBJECTIVEC_MACH], [1])])
 130         ])
 131 ])
 132 AC_CONFIG_FILES([GNUmakefile])
 133 AC_OUTPUT