Cycript.l.in

   1 /* Cycript - Inlining/Optimizing JavaScript Compiler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 /* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */
  41
  42 %{
  43 #define YYLTYPE cy::location
  44 #include "Cycript.tab.hh"
  45 typedef cy::parser::token tk;
  46
  47 #define YY_EXTRA_TYPE CYDriver *
  48
  49 #define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
  50 #define C T yyextra->state_ = CYClear;
  51 #define R T yyextra->state_ = CYRestricted;
  52
  53 #define E(prefix) L C { \
  54     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng + sizeof(prefix)))); \
  55     memcpy(value, prefix, sizeof(prefix) - 1); \
  56     memcpy(value + sizeof(prefix) - 1, yytext, yyleng); \
  57     value[yyleng + sizeof(prefix) - 1] = '\0'; \
  58     yylval->literal_ = new(yyextra->pool_) CYRegEx(value); \
  59     return tk::RegularExpressionLiteral; \
  60 }
  61
  62 #define N \
  63     if (yyextra->state_ != CYNewLine) { \
  64         bool restricted(yyextra->state_ == CYRestricted); \
  65         if (restricted) { \
  66             yyextra->state_ = CYClear; \
  67             return tk::NewLine; \
  68         } else \
  69             yyextra->state_ = CYNewLine; \
  70     }
  71
  72 #define V(more) { \
  73     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
  74         unsigned lines(0); \
  75         size_t left; \
  76         do { \
  77             ++lines; \
  78             left = yyleng - (nl - yytext) - 1; \
  79             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
  80         } while (nl != NULL); \
  81         yylloc->end.lines(lines); \
  82         yylloc->end.columns(left); \
  83         yylloc->step(); \
  84         more \
  85     } else L \
  86 }
  87
  88 #define L { \
  89     yylloc->step(); \
  90     yylloc->columns(yyleng); \
  91 }
  92
  93 int H(char c) {
  94     if (c >= '0' && c <= '9')
  95         return c - '0';
  96     if (c >= 'a' && c <= 'f')
  97         return c - 'a' + 10;
  98     if (c >= 'A' && c <= 'F')
  99         return c - 'A' + 10;
 100     return -1;
 101 }
 102
 103 #define YY_INPUT(data, value, size) { \
 104     if (yyextra->file_ != NULL) { \
 105         size_t copy(fread(data, 1, size, yyextra->file_)); \
 106         value = copy == 0 ? YY_NULL : copy; \
 107     } else if (yyextra->size_ == 0) \
 108         value = YY_NULL; \
 109     else { \
 110         size_t copy(std::min(size, yyextra->size_)); \
 111         memcpy(data, yyextra->data_, copy); \
 112         yyextra->data_ += copy; \
 113         yyextra->size_ -= copy; \
 114         value = copy; \
 115     } \
 116 }
 117
 118 %}
 119
 120 %option prefix="cy"
 121 %option bison-bridge
 122 %option bison-locations
 123 %option noyywrap
 124 %option yylineno
 125 %option nounput
 126 %option interactive
 127 %option reentrant
 128 %option stack
 129
 130 Exponent [eE][+-]?[0-9]+
 131 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
 132
 133 IdentifierStart [a-zA-Z$_]
 134 IdentifierPart  [a-zA-Z$_0-9]
 135
 136 NonTerminator [^\n]
 137 BackslashSequence \\{NonTerminator}
 138 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
 139 RegularExpressionChar [^\n\\/]|{BackslashSequence}
 140 RegularExpressionFlags {IdentifierPart}*
 141 RegularExpressionChars {RegularExpressionChar}*
 142 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
 143
 144 @begin E4X
 145 XMLNameStart [a-zA-Z_:]
 146 XMLNamePart [a-zA-Z0-9.-_:]
 147 XMLName {XMLNameStart}{XMLNamePart}*
 148 @end
 149
 150 %s Div
 151 %s RegExp
 152
 153 @begin E4X
 154 %x XMLContent
 155 %x XMLTag
 156 @end
 157
 158 %%
 159
 160 <RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} E("")
 161
 162 \/\/[^\n]* L
 163 \/\*(\n|[^\*]|\*[^/])*\*\/ V(N)
 164
 165 @begin E4X
 166 <RegExp>"<>"      L return tk::LeftRight;
 167 <XMLContent>"</>" L return tk::LeftSlashRight;
 168
 169 <RegExp,XMLContent>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]> V() return tk::XMLCDATA;
 170 <RegExp,XMLContent>\<!--(\n|[^-]|-[^-])*--> V() return tk::XMLComment;
 171 <RegExp,XMLContent>\<?(\n|[^?]|\?[^>])*?> V() return tk::XMLPI;
 172
 173 <XMLTag>"="  L return tk::Equal;
 174 <XMLTag>">"  L return tk::Right;
 175 <XMLTag>"/>" L return tk::SlashRight;
 176 <XMLTag>"{"  L return tk::OpenBrace;
 177
 178 <XMLTag>\"(\n|[^"])*\"|'(\n|[^'])*' V() {
 179     return tk::XMLAttributeValue;
 180 }
 181
 182 <XMLTag>{XMLName} L return tk::XMLName;
 183 <XMLTag>[ \t\r\n] V() return tk::XMLWhitespace;
 184
 185 <XMLContent>"{"  L return tk::OpenBrace;
 186 <XMLContent>"<"  L return tk::Left;
 187 <XMLContent>"</" L return tk::LeftSlash;
 188 @end
 189
 190 @begin E4X
 191 "::"   L C return tk::ColonColon;
 192 ".."   L C return tk::PeriodPeriod;
 193 @end
 194
 195 @begin E4X ObjectiveC
 196 "@"    L C return tk::At;
 197 @end
 198
 199 "&"    L C return tk::Ampersand;
 200 "&&"   L C return tk::AmpersandAmpersand;
 201 "&="   L C return tk::AmpersandEqual;
 202 "^"    L C return tk::Carrot;
 203 "^="   L C return tk::CarrotEqual;
 204 "="    L C return tk::Equal;
 205 "=="   L C return tk::EqualEqual;
 206 "==="  L C return tk::EqualEqualEqual;
 207 "!"    L C return tk::Exclamation;
 208 "!="   L C return tk::ExclamationEqual;
 209 "!=="  L C return tk::ExclamationEqualEqual;
 210 "-"    L C return tk::Hyphen;
 211 "-="   L C return tk::HyphenEqual;
 212 "--"   L C return yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen;
 213 "->"   L C return tk::HyphenRight;
 214 "<"    L C return tk::Left;
 215 "<="   L C return tk::LeftEqual;
 216 "<<"   L C return tk::LeftLeft;
 217 "<<="  L C return tk::LeftLeftEqual;
 218 "%"    L C return tk::Percent;
 219 "%="   L C return tk::PercentEqual;
 220 "."    L C return tk::Period;
 221 "|"    L C return tk::Pipe;
 222 "|="   L C return tk::PipeEqual;
 223 "||"   L C return tk::PipePipe;
 224 "+"    L C return tk::Plus;
 225 "+="   L C return tk::PlusEqual;
 226 "++"   L C return yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus;
 227 ">"    L C return tk::Right;
 228 ">="   L C return tk::RightEqual;
 229 ">>"   L C return tk::RightRight;
 230 ">>="  L C return tk::RightRightEqual;
 231 ">>>"  L C return tk::RightRightRight;
 232 ">>>=" L C return tk::RightRightRightEqual;
 233 "*"    L C return tk::Star;
 234 "*="   L C return tk::StarEqual;
 235 "~"    L C return tk::Tilde;
 236
 237 <Div>"/"  L C return tk::Slash;
 238 <Div>"/=" L C return tk::SlashEqual;
 239
 240 ":"    L C return tk::Colon;
 241 ","    L C return tk::Comma;
 242 "?"    L C return tk::Question;
 243 ";"    L C return tk::SemiColon;
 244
 245 "("    L C return tk::OpenParen;
 246 ")"    L C return tk::CloseParen;
 247
 248 "{"    L C return tk::OpenBrace;
 249 "}"    L C return tk::CloseBrace;
 250
 251 "["    L C return tk::OpenBracket;
 252 "]"    L C return tk::CloseBracket;
 253
 254 @begin ObjectiveC
 255 "@class"       L C return tk::AtClass;
 256 "@end"         L C return tk::AtEnd;
 257 "@selector"    L C return tk::AtSelector;
 258 @end
 259
 260 "false"        L C yylval->false_ = new(yyextra->pool_) CYFalse(); return tk::False;
 261 "null"         L C yylval->null_ = new(yyextra->pool_) CYNull(); return tk::Null;
 262 "true"         L C yylval->true_ = new(yyextra->pool_) CYTrue(); return tk::True;
 263
 264 "break"        L R yylval->word_ = new(yyextra->pool_) CYWord("break"); return tk::Break;
 265 "case"         L C yylval->word_ = new(yyextra->pool_) CYWord("case"); return tk::Case;
 266 "catch"        L C yylval->word_ = new(yyextra->pool_) CYWord("catch"); return tk::Catch;
 267 "continue"     L R yylval->word_ = new(yyextra->pool_) CYWord("continue"); return tk::Continue;
 268 "default"      L C yylval->word_ = new(yyextra->pool_) CYWord("default"); return tk::Default;
 269 "delete"       L C yylval->word_ = new(yyextra->pool_) CYWord("delete"); return tk::Delete;
 270 "do"           L C yylval->word_ = new(yyextra->pool_) CYWord("do"); return tk::Do;
 271 "else"         L C yylval->word_ = new(yyextra->pool_) CYWord("else"); return tk::Else;
 272 "finally"      L C yylval->word_ = new(yyextra->pool_) CYWord("finally"); return tk::Finally;
 273 "for"          L C yylval->word_ = new(yyextra->pool_) CYWord("for"); return tk::For;
 274 "function"     L C yylval->word_ = new(yyextra->pool_) CYWord("function"); return tk::Function;
 275 "if"           L C yylval->word_ = new(yyextra->pool_) CYWord("if"); return tk::If;
 276 "in"           L C yylval->word_ = new(yyextra->pool_) CYWord("in"); return tk::In;
 277 "instanceof"   L C yylval->word_ = new(yyextra->pool_) CYWord("instanceof"); return tk::InstanceOf;
 278 "new"          L C yylval->word_ = new(yyextra->pool_) CYWord("new"); return tk::New;
 279 "return"       L R yylval->word_ = new(yyextra->pool_) CYWord("return"); return tk::Return;
 280 "switch"       L C yylval->word_ = new(yyextra->pool_) CYWord("switch"); return tk::Switch;
 281 "this"         L C yylval->this_ = new(yyextra->pool_) CYThis(); return tk::This;
 282 "throw"        L R yylval->word_ = new(yyextra->pool_) CYWord("throw"); return tk::Throw;
 283 "try"          L C yylval->word_ = new(yyextra->pool_) CYWord("try"); return tk::Try;
 284 "typeof"       L C yylval->word_ = new(yyextra->pool_) CYWord("typeof"); return tk::TypeOf;
 285 "var"          L C yylval->word_ = new(yyextra->pool_) CYWord("var"); return tk::Var;
 286 "void"         L C yylval->word_ = new(yyextra->pool_) CYWord("void"); return tk::Void;
 287 "while"        L C yylval->word_ = new(yyextra->pool_) CYWord("while"); return tk::While;
 288 "with"         L C yylval->word_ = new(yyextra->pool_) CYWord("with"); return tk::With;
 289
 290 "debugger"     L C yylval->word_ = new(yyextra->pool_) CYWord("debugger"); return tk::Debugger;
 291
 292 "const"        L C yylval->word_ = new(yyextra->pool_) CYWord("const"); return tk::Const;
 293
 294 "class"        L C yylval->word_ = new(yyextra->pool_) CYWord("class"); return tk::Class;
 295 "enum"         L C yylval->word_ = new(yyextra->pool_) CYWord("enum"); return tk::Enum;
 296 "export"       L C yylval->word_ = new(yyextra->pool_) CYWord("export"); return tk::Export;
 297 "extends"      L C yylval->word_ = new(yyextra->pool_) CYWord("extends"); return tk::Extends;
 298 "import"       L C yylval->word_ = new(yyextra->pool_) CYWord("import"); return tk::Import;
 299 "super"        L C yylval->word_ = new(yyextra->pool_) CYWord("super"); return tk::Super;
 300
 301 "implements"   L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("implements"); return tk::Implements;
 302 "interface"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("interface"); return tk::Interface;
 303 "package"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("package"); return tk::Package;
 304 "private"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("private"); return tk::Private;
 305 "protected"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("protected"); return tk::Protected;
 306 "public"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("public"); return tk::Public;
 307 "static"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("static"); return tk::Static;
 308
 309 "abstract"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("abstract"); return tk::Abstract;
 310 "boolean"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("boolean"); return tk::Boolean;
 311 "byte"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("byte"); return tk::Byte;
 312 "char"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("char"); return tk::Char;
 313 "double"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("double"); return tk::Double;
 314 "final"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("final"); return tk::Final;
 315 "float"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("float"); return tk::Float;
 316 "goto"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("goto"); return tk::Goto;
 317 "int"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("int"); return tk::Int;
 318 "long"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("long"); return tk::Long;
 319 "native"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("native"); return tk::Native;
 320 "short"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("short"); return tk::Short;
 321 "synchronized" L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("synchronized"); return tk::Synchronized;
 322 "throws"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("throws"); return tk::Throws;
 323 "transient"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("transient"); return tk::Transient;
 324 "volatile"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("volatile"); return tk::Volatile;
 325
 326 "let"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("let"); return tk::Let;
 327 "yield"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("yield"); return tk::Yield;
 328
 329 "each"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("each"); return tk::Each;
 330
 331 @begin E4X
 332 "namespace"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("namespace"); return tk::Namespace;
 333 "xml"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("xml"); return tk::XML;
 334 @end
 335
 336 {IdentifierStart}{IdentifierPart}* L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); return tk::Identifier_;
 337
 338 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? L C yylval->number_ = new(yyextra->pool_) CYNumber(strtod(yytext, NULL)); return tk::NumericLiteral;
 339
 340 0[xX][0-9a-fA-F]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 16)); return tk::NumericLiteral;
 341
 342 0[bB][0-1]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 2)); return tk::NumericLiteral;
 343
 344 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 345     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng)));
 346     char *local(value);
 347
 348     for (int i(1); i != yyleng - 1; ++i) {
 349         char next(yytext[i]);
 350
 351         if (yytext[i] == '\\')
 352             switch (next = yytext[++i]) {
 353                 case '\n': continue;
 354                 case '\\': next = '\\'; break;
 355                 case '\'': next = '\''; break;
 356                 case '"': next = '"'; break;
 357                 case 'b': next = '\b'; break;
 358                 case 'f': next = '\f'; break;
 359                 case 'n': next = '\n'; break;
 360                 case 'r': next = '\r'; break;
 361                 case 't': next = '\t'; break;
 362                 case 'v': next = '\v'; break;
 363                 case '0': next = '\0'; break;
 364
 365                 case 'x':
 366                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 367                     i += 2;
 368                 break;
 369             }
 370
 371         *local++ = next;
 372     }
 373
 374     *local = '\0';
 375     yylval->string_ = new(yyextra->pool_) CYString(value, local - value);
 376     return tk::StringLiteral;
 377 }
 378
 379 \r?\n yylloc->end.lines(); yylloc->step(); N
 380
 381 [ \t] L
 382 <<EOF>> L yyterminate();
 383
 384 . L {
 385     CYDriver::Error error;
 386     error.location_ = *yylloc;
 387     error.message_ = "syntax error, unknown token";
 388     yyextra->errors_.push_back(error);
 389     yyterminate();
 390 }
 391
 392 %%
 393
 394 void CYDriver::ScannerInit() {
 395     cylex_init(&scanner_);
 396     cyset_extra(this, scanner_);
 397 }
 398
 399 void CYDriver::ScannerDestroy() {
 400     cylex_destroy(scanner_);
 401 }
 402
 403 CYDriver::Condition CYDriver::GetCondition() {
 404     switch (yy_top_state(scanner_)) {
 405         case RegExp:
 406             return RegExpCondition;
 407 @begin E4X
 408         case XMLContent:
 409             return XMLContentCondition;
 410         case XMLTag:
 411             return XMLTagCondition;
 412 @end
 413         default:
 414             _assert(false);
 415     }
 416 }
 417
 418 void CYDriver::SetCondition(Condition condition) {
 419     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 420
 421     switch (condition) {
 422         case RegExpCondition:
 423             BEGIN(RegExp);
 424             break;
 425 @begin E4X
 426         case XMLContentCondition:
 427             BEGIN(XMLContent);
 428             break;
 429         case XMLTagCondition:
 430             BEGIN(XMLTag);
 431             break;
 432 @end
 433         default:
 434             _assert(false);
 435     }
 436 }
 437
 438 void CYDriver::PushCondition(Condition condition) {
 439     switch (condition) {
 440         case RegExpCondition:
 441             yy_push_state(RegExp, scanner_);
 442             break;
 443 @begin E4X
 444         case XMLContentCondition:
 445             yy_push_state(XMLContent, scanner_);
 446             break;
 447         case XMLTagCondition:
 448             yy_push_state(XMLTag, scanner_);
 449             break;
 450 @end
 451         default:
 452             _assert(false);
 453     }
 454 }
 455
 456 void CYDriver::PopCondition() {
 457     yy_pop_state(scanner_);
 458 }