Library.mm

   1 /* Cycript - Remote Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #include <substrate.h>
  41 #include "cycript.hpp"
  42
  43 #include "sig/parse.hpp"
  44 #include "sig/ffi_type.hpp"
  45
  46 #include "Pooling.hpp"
  47 #include "Struct.hpp"
  48
  49 #ifdef __APPLE__
  50 #include <CoreFoundation/CoreFoundation.h>
  51 #include <CoreFoundation/CFLogUtilities.h>
  52 #include <JavaScriptCore/JSStringRefCF.h>
  53 #endif
  54
  55 #include <Foundation/Foundation.h>
  56
  57 #include <WebKit/WebScriptObject.h>
  58
  59 #include <sys/mman.h>
  60
  61 #include <iostream>
  62 #include <ext/stdio_filebuf.h>
  63 #include <set>
  64 #include <map>
  65
  66 #include <sstream>
  67 #include <cmath>
  68
  69 #include "Parser.hpp"
  70 #include "Cycript.tab.hh"
  71
  72 #include <apr_thread_proc.h>
  73
  74 #undef _assert
  75 #undef _trace
  76
  77 #define _assert(test) do { \
  78     if (!(test)) \
  79         @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"_assert(%s):%s(%u):%s", #test, __FILE__, __LINE__, __FUNCTION__] userInfo:nil]; \
  80 } while (false)
  81
  82 #define _trace() do { \
  83     CFLog(kCFLogLevelNotice, CFSTR("_trace():%u"), __LINE__); \
  84 } while (false)
  85
  86 #define CYPoolTry { \
  87     id _saved(nil); \
  88     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  89     @try
  90 #define CYPoolCatch(value) \
  91     @catch (NSException *error) { \
  92         _saved = [error retain]; \
  93         @throw; \
  94         return value; \
  95     } @finally { \
  96         [_pool release]; \
  97         if (_saved != nil) \
  98             [_saved autorelease]; \
  99     } \
 100 }
 101
 102 void CYThrow(JSContextRef context, JSValueRef value);
 103
 104 const char *CYPoolCCYON(apr_pool_t *pool, JSContextRef context, JSValueRef value, JSValueRef *exception);
 105 JSStringRef CYCopyJSString(const char *value);
 106
 107 void CYSetProperty(JSContextRef context, JSObjectRef object, JSStringRef name, JSValueRef value);
 108
 109 JSValueRef CYCallFunction(apr_pool_t *pool, JSContextRef context, size_t setups, void *setup[], size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception, sig::Signature *signature, ffi_cif *cif, void (*function)());
 110 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception);
 111
 112 /* JavaScript Properties {{{ */
 113 JSValueRef CYGetProperty(JSContextRef context, JSObjectRef object, size_t index) {
 114     JSValueRef exception(NULL);
 115     JSValueRef value(JSObjectGetPropertyAtIndex(context, object, index, &exception));
 116     CYThrow(context, exception);
 117     return value;
 118 }
 119
 120 JSValueRef CYGetProperty(JSContextRef context, JSObjectRef object, JSStringRef name) {
 121     JSValueRef exception(NULL);
 122     JSValueRef value(JSObjectGetProperty(context, object, name, &exception));
 123     CYThrow(context, exception);
 124     return value;
 125 }
 126
 127 void CYSetProperty(JSContextRef context, JSObjectRef object, size_t index, JSValueRef value) {
 128     JSValueRef exception(NULL);
 129     JSObjectSetPropertyAtIndex(context, object, index, value, &exception);
 130     CYThrow(context, exception);
 131 }
 132
 133 void CYSetProperty(JSContextRef context, JSObjectRef object, JSStringRef name, JSValueRef value) {
 134     JSValueRef exception(NULL);
 135     JSObjectSetProperty(context, object, name, value, kJSPropertyAttributeNone, &exception);
 136     CYThrow(context, exception);
 137 }
 138 /* }}} */
 139 /* JavaScript Strings {{{ */
 140 JSStringRef CYCopyJSString(const char *value) {
 141     return value == NULL ? NULL : JSStringCreateWithUTF8CString(value);
 142 }
 143
 144 JSStringRef CYCopyJSString(JSStringRef value) {
 145     return value == NULL ? NULL : JSStringRetain(value);
 146 }
 147
 148 JSStringRef CYCopyJSString(JSContextRef context, JSValueRef value) {
 149     if (JSValueIsNull(context, value))
 150         return NULL;
 151     JSValueRef exception(NULL);
 152     JSStringRef string(JSValueToStringCopy(context, value, &exception));
 153     CYThrow(context, exception);
 154     return string;
 155 }
 156
 157 class CYJSString {
 158   private:
 159     JSStringRef string_;
 160
 161     void Clear_() {
 162         if (string_ != NULL)
 163             JSStringRelease(string_);
 164     }
 165
 166   public:
 167     CYJSString(const CYJSString &rhs) :
 168         string_(CYCopyJSString(rhs.string_))
 169     {
 170     }
 171
 172     template <typename Arg0_>
 173     CYJSString(Arg0_ arg0) :
 174         string_(CYCopyJSString(arg0))
 175     {
 176     }
 177
 178     template <typename Arg0_, typename Arg1_>
 179     CYJSString(Arg0_ arg0, Arg1_ arg1) :
 180         string_(CYCopyJSString(arg0, arg1))
 181     {
 182     }
 183
 184     CYJSString &operator =(const CYJSString &rhs) {
 185         Clear_();
 186         string_ = CYCopyJSString(rhs.string_);
 187         return *this;
 188     }
 189
 190     ~CYJSString() {
 191         Clear_();
 192     }
 193
 194     void Clear() {
 195         Clear_();
 196         string_ = NULL;
 197     }
 198
 199     operator JSStringRef() const {
 200         return string_;
 201     }
 202 };
 203 /* }}} */
 204 /* Objective-C Strings {{{ */
 205 JSStringRef CYCopyJSString_(NSString *value) {
 206 #ifdef __APPLE__
 207     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>(value));
 208 #else
 209     return CYCopyJSString([value UTF8String]);
 210 #endif
 211 }
 212
 213 JSStringRef CYCopyJSString(id value) {
 214     if (value == nil)
 215         return NULL;
 216     // XXX: this definition scares me; is anyone using this?!
 217     NSString *string([value description]);
 218     return CYCopyJSString_(string);
 219 }
 220
 221 #ifdef __APPLE__
 222 CFStringRef CYCopyCFString(JSStringRef value) {
 223     return JSStringCopyCFString(kCFAllocatorDefault, value);
 224 }
 225
 226 CFStringRef CYCopyCFString(JSContextRef context, JSValueRef value) {
 227     return CYCopyCFString(CYJSString(context, value));
 228 }
 229 #endif
 230 /* }}} */
 231
 232 static JSGlobalContextRef Context_;
 233 static JSObjectRef System_;
 234 static JSObjectRef ObjectiveC_;
 235
 236 static JSClassRef Functor_;
 237 static JSClassRef Instance_;
 238 static JSClassRef Internal_;
 239 static JSClassRef Message_;
 240 static JSClassRef Messages_;
 241 static JSClassRef NSArrayPrototype_;
 242 static JSClassRef Pointer_;
 243 static JSClassRef Runtime_;
 244 static JSClassRef Selector_;
 245 static JSClassRef Struct_;
 246
 247 static JSClassRef ObjectiveC_Classes_;
 248 static JSClassRef ObjectiveC_Image_Classes_;
 249 static JSClassRef ObjectiveC_Images_;
 250 static JSClassRef ObjectiveC_Protocols_;
 251
 252 static JSObjectRef Array_;
 253 static JSObjectRef Function_;
 254 static JSObjectRef String_;
 255
 256 static JSStringRef Result_;
 257
 258 static JSStringRef length_;
 259 static JSStringRef message_;
 260 static JSStringRef name_;
 261 static JSStringRef prototype_;
 262 static JSStringRef toCYON_;
 263 static JSStringRef toJSON_;
 264
 265 static JSObjectRef Instance_prototype_;
 266 static JSObjectRef Object_prototype_;
 267
 268 static JSObjectRef Array_prototype_;
 269 static JSObjectRef Array_pop_;
 270 static JSObjectRef Array_push_;
 271 static JSObjectRef Array_splice_;
 272
 273 static Class NSArray_;
 274 static Class NSCFBoolean_;
 275 static Class NSCFType_;
 276 static Class NSDictionary_;
 277 static Class NSMessageBuilder_;
 278 static Class NSZombie_;
 279 static Class Object_;
 280
 281 static NSArray *Bridge_;
 282
 283 static void Finalize(JSObjectRef object) {
 284     delete reinterpret_cast<CYData *>(JSObjectGetPrivate(object));
 285 }
 286
 287 class Type_privateData;
 288
 289 struct CYValue :
 290     CYData
 291 {
 292     void *value_;
 293
 294     CYValue() {
 295     }
 296
 297     CYValue(const void *value) :
 298         value_(const_cast<void *>(value))
 299     {
 300     }
 301
 302     CYValue(const CYValue &rhs) :
 303         value_(rhs.value_)
 304     {
 305     }
 306
 307     virtual Type_privateData *GetType() const {
 308         return NULL;
 309     }
 310 };
 311
 312 struct Selector_privateData :
 313     CYValue
 314 {
 315     Selector_privateData(SEL value) :
 316         CYValue(value)
 317     {
 318     }
 319
 320     SEL GetValue() const {
 321         return reinterpret_cast<SEL>(value_);
 322     }
 323
 324     virtual Type_privateData *GetType() const;
 325 };
 326
 327 // XXX: trick this out with associated objects!
 328 JSValueRef CYGetClassPrototype(JSContextRef context, id self) {
 329     if (self == nil)
 330         return Instance_prototype_;
 331
 332     // XXX: I need to think through multi-context
 333     typedef std::map<id, JSValueRef> CacheMap;
 334     static CacheMap cache_;
 335
 336     JSValueRef &value(cache_[self]);
 337     if (value != NULL)
 338         return value;
 339
 340     JSClassRef _class(NULL);
 341     JSValueRef prototype;
 342
 343     if (self == NSArray_)
 344         prototype = Array_prototype_;
 345     else if (self == NSDictionary_)
 346         prototype = Object_prototype_;
 347     else
 348         prototype = CYGetClassPrototype(context, class_getSuperclass(self));
 349
 350     JSObjectRef object(JSObjectMake(context, _class, NULL));
 351     JSObjectSetPrototype(context, object, prototype);
 352
 353     JSValueProtect(context, object);
 354     value = object;
 355     return object;
 356 }
 357
 358 struct Instance :
 359     CYValue
 360 {
 361     enum Flags {
 362         None          = 0,
 363         Transient     = (1 << 0),
 364         Uninitialized = (1 << 1),
 365     };
 366
 367     Flags flags_;
 368
 369     Instance(id value, Flags flags) :
 370         CYValue(value),
 371         flags_(flags)
 372     {
 373     }
 374
 375     virtual ~Instance() {
 376         if ((flags_ & Transient) == 0)
 377             // XXX: does this handle background threads correctly?
 378             // XXX: this simply does not work on the console because I'm stupid
 379             [GetValue() performSelector:@selector(release) withObject:nil afterDelay:0];
 380     }
 381
 382     static JSObjectRef Make(JSContextRef context, id object, Flags flags = None) {
 383         JSObjectRef value(JSObjectMake(context, Instance_, new Instance(object, flags)));
 384         JSObjectSetPrototype(context, value, CYGetClassPrototype(context, object == nil ? nil : object_getClass(object)));
 385         return value;
 386     }
 387
 388     id GetValue() const {
 389         return reinterpret_cast<id>(value_);
 390     }
 391
 392     bool IsUninitialized() const {
 393         return (flags_ & Uninitialized) != 0;
 394     }
 395
 396     virtual Type_privateData *GetType() const;
 397 };
 398
 399 struct Messages :
 400     CYValue
 401 {
 402     Messages(Class value) :
 403         CYValue(value)
 404     {
 405     }
 406
 407     static JSObjectRef Make(JSContextRef context, Class _class, bool array = false) {
 408         JSObjectRef value(JSObjectMake(context, Messages_, new Messages(_class)));
 409         if (_class == NSArray_)
 410             array = true;
 411         if (Class super = class_getSuperclass(_class))
 412             JSObjectSetPrototype(context, value, Messages::Make(context, super, array));
 413         /*else if (array)
 414             JSObjectSetPrototype(context, value, Array_prototype_);*/
 415         return value;
 416     }
 417
 418     Class GetValue() const {
 419         return reinterpret_cast<Class>(value_);
 420     }
 421 };
 422
 423 struct CYOwned :
 424     CYValue
 425 {
 426   private:
 427     JSContextRef context_;
 428     JSObjectRef owner_;
 429
 430   public:
 431     CYOwned(void *value, JSContextRef context, JSObjectRef owner) :
 432         CYValue(value),
 433         context_(context),
 434         owner_(owner)
 435     {
 436         JSValueProtect(context_, owner_);
 437     }
 438
 439     virtual ~CYOwned() {
 440         JSValueUnprotect(context_, owner_);
 441     }
 442
 443     JSObjectRef GetOwner() const {
 444         return owner_;
 445     }
 446 };
 447
 448 struct Internal :
 449     CYOwned
 450 {
 451     Internal(id value, JSContextRef context, JSObjectRef owner) :
 452         CYOwned(value, context, owner)
 453     {
 454     }
 455
 456     static JSObjectRef Make(JSContextRef context, id object, JSObjectRef owner) {
 457         return JSObjectMake(context, Internal_, new Internal(object, context, owner));
 458     }
 459
 460     id GetValue() const {
 461         return reinterpret_cast<id>(value_);
 462     }
 463 };
 464
 465 namespace sig {
 466
 467 void Copy(apr_pool_t *pool, Type &lhs, Type &rhs);
 468
 469 void Copy(apr_pool_t *pool, Element &lhs, Element &rhs) {
 470     lhs.name = apr_pstrdup(pool, rhs.name);
 471     if (rhs.type == NULL)
 472         lhs.type = NULL;
 473     else {
 474         lhs.type = new(pool) Type;
 475         Copy(pool, *lhs.type, *rhs.type);
 476     }
 477     lhs.offset = rhs.offset;
 478 }
 479
 480 void Copy(apr_pool_t *pool, Signature &lhs, Signature &rhs) {
 481     size_t count(rhs.count);
 482     lhs.count = count;
 483     lhs.elements = new(pool) Element[count];
 484     for (size_t index(0); index != count; ++index)
 485         Copy(pool, lhs.elements[index], rhs.elements[index]);
 486 }
 487
 488 void Copy(apr_pool_t *pool, Type &lhs, Type &rhs) {
 489     lhs.primitive = rhs.primitive;
 490     lhs.name = apr_pstrdup(pool, rhs.name);
 491     lhs.flags = rhs.flags;
 492
 493     if (sig::IsAggregate(rhs.primitive))
 494         Copy(pool, lhs.data.signature, rhs.data.signature);
 495     else {
 496         sig::Type *&lht(lhs.data.data.type);
 497         sig::Type *&rht(rhs.data.data.type);
 498
 499         if (rht == NULL)
 500             lht = NULL;
 501         else {
 502             lht = new(pool) Type;
 503             Copy(pool, *lht, *rht);
 504         }
 505
 506         lhs.data.data.size = rhs.data.data.size;
 507     }
 508 }
 509
 510 void Copy(apr_pool_t *pool, ffi_type &lhs, ffi_type &rhs) {
 511     lhs.size = rhs.size;
 512     lhs.alignment = rhs.alignment;
 513     lhs.type = rhs.type;
 514     if (rhs.elements == NULL)
 515         lhs.elements = NULL;
 516     else {
 517         size_t count(0);
 518         while (rhs.elements[count] != NULL)
 519             ++count;
 520
 521         lhs.elements = new(pool) ffi_type *[count + 1];
 522         lhs.elements[count] = NULL;
 523
 524         for (size_t index(0); index != count; ++index) {
 525             // XXX: if these are libffi native then you can just take them
 526             ffi_type *ffi(new(pool) ffi_type);
 527             lhs.elements[index] = ffi;
 528             sig::Copy(pool, *ffi, *rhs.elements[index]);
 529         }
 530     }
 531 }
 532
 533 }
 534
 535 struct CStringMapLess :
 536     std::binary_function<const char *, const char *, bool>
 537 {
 538     _finline bool operator ()(const char *lhs, const char *rhs) const {
 539         return strcmp(lhs, rhs) < 0;
 540     }
 541 };
 542
 543 void Structor_(apr_pool_t *pool, const char *name, const char *types, sig::Type *&type) {
 544     if (name == NULL)
 545         return;
 546
 547     CYPoolTry {
 548         if (NSMutableArray *entry = [[Bridge_ objectAtIndex:2] objectForKey:[NSString stringWithUTF8String:name]])
 549             switch ([[entry objectAtIndex:0] intValue]) {
 550                 case 0: {
 551                     sig::Parse(pool, &type->data.signature, [[entry objectAtIndex:1] UTF8String], &Structor_);
 552                 } break;
 553
 554                 case 1: {
 555                     sig::Signature signature;
 556                     sig::Parse(pool, &signature, [[entry objectAtIndex:1] UTF8String], &Structor_);
 557                     type = signature.elements[0].type;
 558                 } break;
 559             }
 560     } CYPoolCatch()
 561 }
 562
 563 struct Type_privateData :
 564     CYData
 565 {
 566     static Type_privateData *Object;
 567     static Type_privateData *Selector;
 568
 569     static JSClassRef Class_;
 570
 571     ffi_type *ffi_;
 572     sig::Type *type_;
 573
 574     void Set(sig::Type *type) {
 575         type_ = new(pool_) sig::Type;
 576         sig::Copy(pool_, *type_, *type);
 577     }
 578
 579     Type_privateData(apr_pool_t *pool, const char *type) :
 580         ffi_(NULL)
 581     {
 582         if (pool != NULL)
 583             pool_ = pool;
 584
 585         sig::Signature signature;
 586         sig::Parse(pool_, &signature, type, &Structor_);
 587         type_ = signature.elements[0].type;
 588     }
 589
 590     Type_privateData(sig::Type *type) :
 591         ffi_(NULL)
 592     {
 593         if (type != NULL)
 594             Set(type);
 595     }
 596
 597     Type_privateData(sig::Type *type, ffi_type *ffi) {
 598         ffi_ = new(pool_) ffi_type;
 599         sig::Copy(pool_, *ffi_, *ffi);
 600         Set(type);
 601     }
 602
 603     ffi_type *GetFFI() {
 604         if (ffi_ == NULL) {
 605             ffi_ = new(pool_) ffi_type;
 606
 607             sig::Element element;
 608             element.name = NULL;
 609             element.type = type_;
 610             element.offset = 0;
 611
 612             sig::Signature signature;
 613             signature.elements = &element;
 614             signature.count = 1;
 615
 616             ffi_cif cif;
 617             sig::sig_ffi_cif(pool_, &sig::ObjectiveC, &signature, &cif);
 618             *ffi_ = *cif.rtype;
 619         }
 620
 621         return ffi_;
 622     }
 623 };
 624
 625 JSClassRef Type_privateData::Class_;
 626 Type_privateData *Type_privateData::Object;
 627 Type_privateData *Type_privateData::Selector;
 628
 629 Type_privateData *Instance::GetType() const {
 630     return Type_privateData::Object;
 631 }
 632
 633 Type_privateData *Selector_privateData::GetType() const {
 634     return Type_privateData::Selector;
 635 }
 636
 637 struct Pointer :
 638     CYOwned
 639 {
 640     Type_privateData *type_;
 641
 642     Pointer(void *value, JSContextRef context, JSObjectRef owner, sig::Type *type) :
 643         CYOwned(value, context, owner),
 644         type_(new(pool_) Type_privateData(type))
 645     {
 646     }
 647 };
 648
 649 struct Struct_privateData :
 650     CYOwned
 651 {
 652     Type_privateData *type_;
 653
 654     Struct_privateData(JSContextRef context, JSObjectRef owner) :
 655         CYOwned(NULL, context, owner)
 656     {
 657     }
 658 };
 659
 660 typedef std::map<const char *, Type_privateData *, CStringMapLess> TypeMap;
 661 static TypeMap Types_;
 662
 663 JSObjectRef CYMakeStruct(JSContextRef context, void *data, sig::Type *type, ffi_type *ffi, JSObjectRef owner) {
 664     Struct_privateData *internal(new Struct_privateData(context, owner));
 665     apr_pool_t *pool(internal->pool_);
 666     Type_privateData *typical(new(pool) Type_privateData(type, ffi));
 667     internal->type_ = typical;
 668
 669     if (owner != NULL)
 670         internal->value_ = data;
 671     else {
 672         size_t size(typical->GetFFI()->size);
 673         void *copy(apr_palloc(internal->pool_, size));
 674         memcpy(copy, data, size);
 675         internal->value_ = copy;
 676     }
 677
 678     return JSObjectMake(context, Struct_, internal);
 679 }
 680
 681 struct Functor_privateData :
 682     CYValue
 683 {
 684     sig::Signature signature_;
 685     ffi_cif cif_;
 686
 687
 688     Functor_privateData(const char *type, void (*value)()) :
 689         CYValue(reinterpret_cast<void *>(value))
 690     {
 691         sig::Parse(pool_, &signature_, type, &Structor_);
 692         sig::sig_ffi_cif(pool_, &sig::ObjectiveC, &signature_, &cif_);
 693     }
 694
 695     void (*GetValue())() const {
 696         return reinterpret_cast<void (*)()>(value_);
 697     }
 698 };
 699
 700 struct Closure_privateData :
 701     Functor_privateData
 702 {
 703     JSContextRef context_;
 704     JSObjectRef function_;
 705
 706     Closure_privateData(JSContextRef context, JSObjectRef function, const char *type) :
 707         Functor_privateData(type, NULL),
 708         context_(context),
 709         function_(function)
 710     {
 711         JSValueProtect(context_, function_);
 712     }
 713
 714     virtual ~Closure_privateData() {
 715         JSValueUnprotect(context_, function_);
 716     }
 717 };
 718
 719 struct Message_privateData :
 720     Functor_privateData
 721 {
 722     SEL sel_;
 723
 724     Message_privateData(SEL sel, const char *type, IMP value = NULL) :
 725         Functor_privateData(type, reinterpret_cast<void (*)()>(value)),
 726         sel_(sel)
 727     {
 728     }
 729 };
 730
 731 JSObjectRef CYMakeInstance(JSContextRef context, id object, bool transient) {
 732     Instance::Flags flags;
 733
 734     if (transient)
 735         flags = Instance::Transient;
 736     else {
 737         flags = Instance::None;
 738         object = [object retain];
 739     }
 740
 741     return Instance::Make(context, object, flags);
 742 }
 743
 744 const char *CYPoolCString(apr_pool_t *pool, NSString *value) {
 745     if (pool == NULL)
 746         return [value UTF8String];
 747     else {
 748         size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 749         char *string(new(pool) char[size]);
 750         if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 751             @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:@"[NSString getCString:maxLength:encoding:] == NO" userInfo:nil];
 752         return string;
 753     }
 754 }
 755
 756 JSValueRef CYCastJSValue(JSContextRef context, bool value) {
 757     return JSValueMakeBoolean(context, value);
 758 }
 759
 760 JSValueRef CYCastJSValue(JSContextRef context, double value) {
 761     return JSValueMakeNumber(context, value);
 762 }
 763
 764 #define CYCastJSValue_(Type_) \
 765     JSValueRef CYCastJSValue(JSContextRef context, Type_ value) { \
 766         return JSValueMakeNumber(context, static_cast<double>(value)); \
 767     }
 768
 769 CYCastJSValue_(int)
 770 CYCastJSValue_(unsigned int)
 771 CYCastJSValue_(long int)
 772 CYCastJSValue_(long unsigned int)
 773 CYCastJSValue_(long long int)
 774 CYCastJSValue_(long long unsigned int)
 775
 776 JSValueRef CYJSUndefined(JSContextRef context) {
 777     return JSValueMakeUndefined(context);
 778 }
 779
 780 size_t CYGetIndex(const char *value) {
 781     if (value[0] != '0') {
 782         char *end;
 783         size_t index(strtoul(value, &end, 10));
 784         if (value + strlen(value) == end)
 785             return index;
 786     } else if (value[1] == '\0')
 787         return 0;
 788     return _not(size_t);
 789 }
 790
 791 // XXX: fix this
 792 static const char *CYPoolCString(apr_pool_t *pool, JSStringRef value);
 793
 794 size_t CYGetIndex(apr_pool_t *pool, NSString *value) {
 795     return CYGetIndex(CYPoolCString(pool, value));
 796 }
 797
 798 size_t CYGetIndex(apr_pool_t *pool, JSStringRef value) {
 799     return CYGetIndex(CYPoolCString(pool, value));
 800 }
 801
 802 bool CYGetOffset(const char *value, ssize_t &index) {
 803     if (value[0] != '0') {
 804         char *end;
 805         index = strtol(value, &end, 10);
 806         if (value + strlen(value) == end)
 807             return true;
 808     } else if (value[1] == '\0') {
 809         index = 0;
 810         return true;
 811     }
 812
 813     return false;
 814 }
 815
 816 bool CYGetOffset(apr_pool_t *pool, NSString *value, ssize_t &index) {
 817     return CYGetOffset(CYPoolCString(pool, value), index);
 818 }
 819
 820 NSString *CYPoolNSCYON(apr_pool_t *pool, id value);
 821
 822 @interface NSMethodSignature (Cycript)
 823 - (NSString *) _typeString;
 824 @end
 825
 826 @interface NSObject (Cycript)
 827
 828 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 829 - (JSType) cy$JSType;
 830
 831 - (NSObject *) cy$toJSON:(NSString *)key;
 832 - (NSString *) cy$toCYON;
 833 - (NSString *) cy$toKey;
 834
 835 - (bool) cy$hasProperty:(NSString *)name;
 836 - (NSObject *) cy$getProperty:(NSString *)name;
 837 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 838 - (bool) cy$deleteProperty:(NSString *)name;
 839
 840 @end
 841
 842 @protocol Cycript
 843 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 844 @end
 845
 846 @interface NSString (Cycript)
 847 - (void *) cy$symbol;
 848 @end
 849
 850 #ifdef __APPLE__
 851 struct PropertyAttributes {
 852     CYPool pool_;
 853
 854     const char *name;
 855
 856     const char *variable;
 857
 858     const char *getter_;
 859     const char *setter_;
 860
 861     bool readonly;
 862     bool copy;
 863     bool retain;
 864     bool nonatomic;
 865     bool dynamic;
 866     bool weak;
 867     bool garbage;
 868
 869     PropertyAttributes(objc_property_t property) :
 870         variable(NULL),
 871         getter_(NULL),
 872         setter_(NULL),
 873         readonly(false),
 874         copy(false),
 875         retain(false),
 876         nonatomic(false),
 877         dynamic(false),
 878         weak(false),
 879         garbage(false)
 880     {
 881         name = property_getName(property);
 882         const char *attributes(property_getAttributes(property));
 883
 884         for (char *state, *token(apr_strtok(apr_pstrdup(pool_, attributes), ",", &state)); token != NULL; token = apr_strtok(NULL, ",", &state)) {
 885             switch (*token) {
 886                 case 'R': readonly = true; break;
 887                 case 'C': copy = true; break;
 888                 case '&': retain = true; break;
 889                 case 'N': nonatomic = true; break;
 890                 case 'G': getter_ = token + 1; break;
 891                 case 'S': setter_ = token + 1; break;
 892                 case 'V': variable = token + 1; break;
 893             }
 894         }
 895
 896         /*if (variable == NULL) {
 897             variable = property_getName(property);
 898             size_t size(strlen(variable));
 899             char *name(new(pool_) char[size + 2]);
 900             name[0] = '_';
 901             memcpy(name + 1, variable, size);
 902             name[size + 1] = '\0';
 903             variable = name;
 904         }*/
 905     }
 906
 907     const char *Getter() {
 908         if (getter_ == NULL)
 909             getter_ = apr_pstrdup(pool_, name);
 910         return getter_;
 911     }
 912
 913     const char *Setter() {
 914         if (setter_ == NULL && !readonly) {
 915             size_t length(strlen(name));
 916
 917             char *temp(new(pool_) char[length + 5]);
 918             temp[0] = 's';
 919             temp[1] = 'e';
 920             temp[2] = 't';
 921
 922             if (length != 0) {
 923                 temp[3] = toupper(name[0]);
 924                 memcpy(temp + 4, name + 1, length - 1);
 925             }
 926
 927             temp[length + 3] = ':';
 928             temp[length + 4] = '\0';
 929             setter_ = temp;
 930         }
 931
 932         return setter_;
 933     }
 934
 935 };
 936 #endif
 937
 938 #ifdef __APPLE__
 939 NSString *NSCFType$cy$toJSON(id self, SEL sel, NSString *key) {
 940     return [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease];
 941 }
 942 #endif
 943
 944 #ifndef __APPLE__
 945 @interface CYWebUndefined : NSObject {
 946 }
 947
 948 + (CYWebUndefined *) undefined;
 949
 950 @end
 951
 952 @implementation CYWebUndefined
 953
 954 + (CYWebUndefined *) undefined {
 955     static CYWebUndefined *instance_([[CYWebUndefined alloc] init]);
 956     return instance_;
 957 }
 958
 959 @end
 960
 961 #define WebUndefined CYWebUndefined
 962 #endif
 963
 964 /* Bridge: NSArray {{{ */
 965 @implementation NSArray (Cycript)
 966
 967 - (NSString *) cy$toCYON {
 968     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 969     [json appendString:@"["];
 970
 971     bool comma(false);
 972 #ifdef __APPLE__
 973     for (id object in self) {
 974 #else
 975     id object;
 976     for (size_t index(0), count([self count]); index != count; ++index) {
 977         object = [self objectAtIndex:index];
 978 #endif
 979         if (comma)
 980             [json appendString:@","];
 981         else
 982             comma = true;
 983         if (object == nil || [object cy$JSType] != kJSTypeUndefined)
 984             [json appendString:CYPoolNSCYON(NULL, object)];
 985         else {
 986             [json appendString:@","];
 987             comma = false;
 988         }
 989     }
 990
 991     [json appendString:@"]"];
 992     return json;
 993 }
 994
 995 - (bool) cy$hasProperty:(NSString *)name {
 996     if ([name isEqualToString:@"length"])
 997         return true;
 998
 999     size_t index(CYGetIndex(NULL, name));
1000     if (index == _not(size_t) || index >= [self count])
1001         return [super cy$hasProperty:name];
1002     else
1003         return true;
1004 }
1005
1006 - (NSObject *) cy$getProperty:(NSString *)name {
1007     if ([name isEqualToString:@"length"]) {
1008         NSUInteger count([self count]);
1009 #ifdef __APPLE__
1010         return [NSNumber numberWithUnsignedInteger:count];
1011 #else
1012         return [NSNumber numberWithUnsignedInt:count];
1013 #endif
1014     }
1015
1016     size_t index(CYGetIndex(NULL, name));
1017     if (index == _not(size_t) || index >= [self count])
1018         return [super cy$getProperty:name];
1019     else
1020         return [self objectAtIndex:index];
1021 }
1022
1023 @end
1024 /* }}} */
1025 /* Bridge: NSDictionary {{{ */
1026 @implementation NSDictionary (Cycript)
1027
1028 - (NSString *) cy$toCYON {
1029     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
1030     [json appendString:@"{"];
1031
1032     bool comma(false);
1033 #ifdef __APPLE__
1034     for (id key in self) {
1035 #else
1036     NSEnumerator *keys([self keyEnumerator]);
1037     while (id key = [keys nextObject]) {
1038 #endif
1039         if (comma)
1040             [json appendString:@","];
1041         else
1042             comma = true;
1043         [json appendString:[key cy$toKey]];
1044         [json appendString:@":"];
1045         NSObject *object([self objectForKey:key]);
1046         [json appendString:CYPoolNSCYON(NULL, object)];
1047     }
1048
1049     [json appendString:@"}"];
1050     return json;
1051 }
1052
1053 - (bool) cy$hasProperty:(NSString *)name {
1054     return [self objectForKey:name] != nil;
1055 }
1056
1057 - (NSObject *) cy$getProperty:(NSString *)name {
1058     return [self objectForKey:name];
1059 }
1060
1061 @end
1062 /* }}} */
1063 /* Bridge: NSMutableArray {{{ */
1064 @implementation NSMutableArray (Cycript)
1065
1066 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1067     if ([name isEqualToString:@"length"]) {
1068         // XXX: is this not intelligent?
1069         NSNumber *number(reinterpret_cast<NSNumber *>(value));
1070 #ifdef __APPLE__
1071         NSUInteger size([number unsignedIntegerValue]);
1072 #else
1073         NSUInteger size([number unsignedIntValue]);
1074 #endif
1075         NSUInteger count([self count]);
1076         if (size < count)
1077             [self removeObjectsInRange:NSMakeRange(size, count - size)];
1078         else if (size != count) {
1079             WebUndefined *undefined([WebUndefined undefined]);
1080             for (size_t i(count); i != size; ++i)
1081                 [self addObject:undefined];
1082         }
1083         return true;
1084     }
1085
1086     size_t index(CYGetIndex(NULL, name));
1087     if (index == _not(size_t))
1088         return [super cy$setProperty:name to:value];
1089
1090     id object(value ?: [NSNull null]);
1091
1092     size_t count([self count]);
1093     if (index < count)
1094         [self replaceObjectAtIndex:index withObject:object];
1095     else {
1096         if (index != count) {
1097             WebUndefined *undefined([WebUndefined undefined]);
1098             for (size_t i(count); i != index; ++i)
1099                 [self addObject:undefined];
1100         }
1101
1102         [self addObject:object];
1103     }
1104
1105     return true;
1106 }
1107
1108 - (bool) cy$deleteProperty:(NSString *)name {
1109     size_t index(CYGetIndex(NULL, name));
1110     if (index == _not(size_t) || index >= [self count])
1111         return [super cy$deleteProperty:name];
1112     [self replaceObjectAtIndex:index withObject:[WebUndefined undefined]];
1113     return true;
1114 }
1115
1116 @end
1117 /* }}} */
1118 /* Bridge: NSMutableDictionary {{{ */
1119 @implementation NSMutableDictionary (Cycript)
1120
1121 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1122     [self setObject:(value ?: [NSNull null]) forKey:name];
1123     return true;
1124 }
1125
1126 - (bool) cy$deleteProperty:(NSString *)name {
1127     if ([self objectForKey:name] == nil)
1128         return false;
1129     else {
1130         [self removeObjectForKey:name];
1131         return true;
1132     }
1133 }
1134
1135 @end
1136 /* }}} */
1137 /* Bridge: NSNumber {{{ */
1138 @implementation NSNumber (Cycript)
1139
1140 - (JSType) cy$JSType {
1141     // XXX: this just seems stupid
1142     return [self class] == NSCFBoolean_ ? kJSTypeBoolean : kJSTypeNumber;
1143 }
1144
1145 - (NSObject *) cy$toJSON:(NSString *)key {
1146     return self;
1147 }
1148
1149 - (NSString *) cy$toCYON {
1150     return [self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false";
1151 }
1152
1153 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
1154     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, [self boolValue]);
1155 }
1156
1157 @end
1158 /* }}} */
1159 /* Bridge: NSNull {{{ */
1160 @implementation NSNull (Cycript)
1161
1162 - (JSType) cy$JSType {
1163     return kJSTypeNull;
1164 }
1165
1166 - (NSObject *) cy$toJSON:(NSString *)key {
1167     return self;
1168 }
1169
1170 - (NSString *) cy$toCYON {
1171     return @"null";
1172 }
1173
1174 @end
1175 /* }}} */
1176 /* Bridge: NSObject {{{ */
1177 @implementation NSObject (Cycript)
1178
1179 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
1180     return CYMakeInstance(context, self, false);
1181 }
1182
1183 - (JSType) cy$JSType {
1184     return kJSTypeObject;
1185 }
1186
1187 - (NSObject *) cy$toJSON:(NSString *)key {
1188     return [self description];
1189 }
1190
1191 - (NSString *) cy$toCYON {
1192     return [[self cy$toJSON:@""] cy$toCYON];
1193 }
1194
1195 - (NSString *) cy$toKey {
1196     return [self cy$toCYON];
1197 }
1198
1199 - (bool) cy$hasProperty:(NSString *)name {
1200     return false;
1201 }
1202
1203 - (NSObject *) cy$getProperty:(NSString *)name {
1204     return nil;
1205 }
1206
1207 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1208     return false;
1209 }
1210
1211 - (bool) cy$deleteProperty:(NSString *)name {
1212     return false;
1213 }
1214
1215 @end
1216 /* }}} */
1217 /* Bridge: NSProxy {{{ */
1218 @implementation NSProxy (Cycript)
1219
1220 - (NSObject *) cy$toJSON:(NSString *)key {
1221     return [self description];
1222 }
1223
1224 - (NSString *) cy$toCYON {
1225     return [[self cy$toJSON:@""] cy$toCYON];
1226 }
1227
1228 @end
1229 /* }}} */
1230 /* Bridge: NSString {{{ */
1231 @implementation NSString (Cycript)
1232
1233 - (JSType) cy$JSType {
1234     return kJSTypeString;
1235 }
1236
1237 - (NSObject *) cy$toJSON:(NSString *)key {
1238     return self;
1239 }
1240
1241 - (NSString *) cy$toCYON {
1242     // XXX: this should use the better code from Output.cpp
1243     CFMutableStringRef json(CFStringCreateMutableCopy(kCFAllocatorDefault, 0, (CFStringRef) self));
1244
1245     CFStringFindAndReplace(json, CFSTR("\\"), CFSTR("\\\\"), CFRangeMake(0, CFStringGetLength(json)), 0);
1246     CFStringFindAndReplace(json, CFSTR("\""), CFSTR("\\\""), CFRangeMake(0, CFStringGetLength(json)), 0);
1247     CFStringFindAndReplace(json, CFSTR("\t"), CFSTR("\\t"), CFRangeMake(0, CFStringGetLength(json)), 0);
1248     CFStringFindAndReplace(json, CFSTR("\r"), CFSTR("\\r"), CFRangeMake(0, CFStringGetLength(json)), 0);
1249     CFStringFindAndReplace(json, CFSTR("\n"), CFSTR("\\n"), CFRangeMake(0, CFStringGetLength(json)), 0);
1250
1251     CFStringInsert(json, 0, CFSTR("\""));
1252     CFStringAppend(json, CFSTR("\""));
1253
1254     return [reinterpret_cast<const NSString *>(json) autorelease];
1255 }
1256
1257 - (NSString *) cy$toKey {
1258     const char *value([self UTF8String]);
1259     size_t size(strlen(value));
1260
1261     if (size == 0)
1262         goto cyon;
1263
1264     if (DigitRange_[value[0]]) {
1265         size_t index(CYGetIndex(NULL, self));
1266         if (index == _not(size_t))
1267             goto cyon;
1268     } else {
1269         if (!WordStartRange_[value[0]])
1270             goto cyon;
1271         for (size_t i(1); i != size; ++i)
1272             if (!WordEndRange_[value[i]])
1273                 goto cyon;
1274     }
1275
1276     return self;
1277
1278   cyon:
1279     return [self cy$toCYON];
1280 }
1281
1282 - (void *) cy$symbol {
1283     CYPool pool;
1284     return dlsym(RTLD_DEFAULT, CYPoolCString(pool, self));
1285 }
1286
1287 @end
1288 /* }}} */
1289 /* Bridge: WebUndefined {{{ */
1290 @implementation WebUndefined (Cycript)
1291
1292 - (JSType) cy$JSType {
1293     return kJSTypeUndefined;
1294 }
1295
1296 - (NSObject *) cy$toJSON:(NSString *)key {
1297     return self;
1298 }
1299
1300 - (NSString *) cy$toCYON {
1301     return @"undefined";
1302 }
1303
1304 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
1305     return CYJSUndefined(context);
1306 }
1307
1308 @end
1309 /* }}} */
1310
1311 /* Bridge: CYJSObject {{{ */
1312 @interface CYJSObject : NSMutableDictionary {
1313     JSObjectRef object_;
1314     JSContextRef context_;
1315 }
1316
1317 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
1318
1319 - (NSString *) cy$toJSON:(NSString *)key;
1320
1321 - (NSUInteger) count;
1322 - (id) objectForKey:(id)key;
1323 - (NSEnumerator *) keyEnumerator;
1324 - (void) setObject:(id)object forKey:(id)key;
1325 - (void) removeObjectForKey:(id)key;
1326
1327 @end
1328 /* }}} */
1329 /* Bridge: CYJSArray {{{ */
1330 @interface CYJSArray : NSMutableArray {
1331     JSObjectRef object_;
1332     JSContextRef context_;
1333 }
1334
1335 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
1336
1337 - (NSUInteger) count;
1338 - (id) objectAtIndex:(NSUInteger)index;
1339
1340 - (void) addObject:(id)anObject;
1341 - (void) insertObject:(id)anObject atIndex:(NSUInteger)index;
1342 - (void) removeLastObject;
1343 - (void) removeObjectAtIndex:(NSUInteger)index;
1344 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)anObject;
1345
1346 @end
1347 /* }}} */
1348
1349 #define CYTry \
1350     @try
1351 #define CYCatch \
1352     @catch (id error) { \
1353         CYThrow(context, error, exception); \
1354         return NULL; \
1355     }
1356
1357 apr_status_t CYPoolRelease_(void *data) {
1358     id object(reinterpret_cast<id>(data));
1359     [object release];
1360     return APR_SUCCESS;
1361 }
1362
1363 id CYPoolRelease(apr_pool_t *pool, id object) {
1364     if (object == nil)
1365         return nil;
1366     else if (pool == NULL)
1367         return [object autorelease];
1368     else {
1369         apr_pool_cleanup_register(pool, object, &CYPoolRelease_, &apr_pool_cleanup_null);
1370         return object;
1371     }
1372 }
1373
1374 CFTypeRef CYPoolRelease(apr_pool_t *pool, CFTypeRef object) {
1375     return (CFTypeRef) CYPoolRelease(pool, (id) object);
1376 }
1377
1378 id CYCastNSObject_(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
1379     JSValueRef exception(NULL);
1380     bool array(JSValueIsInstanceOfConstructor(context, object, Array_, &exception));
1381     CYThrow(context, exception);
1382     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
1383     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
1384 }
1385
1386 id CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
1387     if (!JSValueIsObjectOfClass(context, object, Instance_))
1388         return CYCastNSObject_(pool, context, object);
1389     else {
1390         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1391         return internal->GetValue();
1392     }
1393 }
1394
1395 double CYCastDouble(const char *value, size_t size) {
1396     char *end;
1397     double number(strtod(value, &end));
1398     if (end != value + size)
1399         return NAN;
1400     return number;
1401 }
1402
1403 double CYCastDouble(const char *value) {
1404     return CYCastDouble(value, strlen(value));
1405 }
1406
1407 double CYCastDouble(JSContextRef context, JSValueRef value) {
1408     JSValueRef exception(NULL);
1409     double number(JSValueToNumber(context, value, &exception));
1410     CYThrow(context, exception);
1411     return number;
1412 }
1413
1414 CFNumberRef CYCopyCFNumber(JSContextRef context, JSValueRef value) {
1415     double number(CYCastDouble(context, value));
1416     return CFNumberCreate(kCFAllocatorDefault, kCFNumberDoubleType, &number);
1417 }
1418
1419 CFStringRef CYCopyCFString(const char *value) {
1420     return CFStringCreateWithCString(kCFAllocatorDefault, value, kCFStringEncodingUTF8);
1421 }
1422
1423 NSString *CYCastNSString(apr_pool_t *pool, const char *value) {
1424     return (NSString *) CYPoolRelease(pool, CYCopyCFString(value));
1425 }
1426
1427 NSString *CYCastNSString(apr_pool_t *pool, JSStringRef value) {
1428     return (NSString *) CYPoolRelease(pool, CYCopyCFString(value));
1429 }
1430
1431 bool CYCastBool(JSContextRef context, JSValueRef value) {
1432     return JSValueToBoolean(context, value);
1433 }
1434
1435 CFTypeRef CYCFType(apr_pool_t *pool, JSContextRef context, JSValueRef value, bool cast) {
1436     CFTypeRef object;
1437     bool copy;
1438
1439     switch (JSType type = JSValueGetType(context, value)) {
1440         case kJSTypeUndefined:
1441             object = [WebUndefined undefined];
1442             copy = false;
1443         break;
1444
1445         case kJSTypeNull:
1446             return NULL;
1447         break;
1448
1449         case kJSTypeBoolean:
1450             object = CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse;
1451             copy = false;
1452         break;
1453
1454         case kJSTypeNumber:
1455             object = CYCopyCFNumber(context, value);
1456             copy = true;
1457         break;
1458
1459         case kJSTypeString:
1460             object = CYCopyCFString(context, value);
1461             copy = true;
1462         break;
1463
1464         case kJSTypeObject:
1465             // XXX: this might could be more efficient
1466             object = (CFTypeRef) CYCastNSObject(pool, context, (JSObjectRef) value);
1467             copy = false;
1468         break;
1469
1470         default:
1471             @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"JSValueGetType() == 0x%x", type] userInfo:nil];
1472         break;
1473     }
1474
1475     if (cast != copy)
1476         return object;
1477     else if (copy)
1478         return CYPoolRelease(pool, object);
1479     else
1480         return CFRetain(object);
1481 }
1482
1483 CFTypeRef CYCastCFType(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1484     return CYCFType(pool, context, value, true);
1485 }
1486
1487 CFTypeRef CYCopyCFType(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1488     return CYCFType(pool, context, value, false);
1489 }
1490
1491 NSArray *CYCastNSArray(JSPropertyNameArrayRef names) {
1492     CYPool pool;
1493     size_t size(JSPropertyNameArrayGetCount(names));
1494     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1495     for (size_t index(0); index != size; ++index)
1496         [array addObject:CYCastNSString(pool, JSPropertyNameArrayGetNameAtIndex(names, index))];
1497     return array;
1498 }
1499
1500 id CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1501     return reinterpret_cast<const NSObject *>(CYCastCFType(pool, context, value));
1502 }
1503
1504 void CYThrow(JSContextRef context, JSValueRef value) {
1505     if (value == NULL)
1506         return;
1507     @throw CYCastNSObject(NULL, context, value);
1508 }
1509
1510 JSValueRef CYJSNull(JSContextRef context) {
1511     return JSValueMakeNull(context);
1512 }
1513
1514 JSValueRef CYCastJSValue(JSContextRef context, JSStringRef value) {
1515     return value == NULL ? CYJSNull(context) : JSValueMakeString(context, value);
1516 }
1517
1518 JSValueRef CYCastJSValue(JSContextRef context, const char *value) {
1519     return CYCastJSValue(context, CYJSString(value));
1520 }
1521
1522 JSValueRef CYCastJSValue(JSContextRef context, id value) {
1523     if (value == nil)
1524         return CYJSNull(context);
1525     else if ([value respondsToSelector:@selector(cy$JSValueInContext:)])
1526         return [value cy$JSValueInContext:context];
1527     else
1528         return CYMakeInstance(context, value, false);
1529 }
1530
1531 JSObjectRef CYCastJSObject(JSContextRef context, JSValueRef value) {
1532     JSValueRef exception(NULL);
1533     JSObjectRef object(JSValueToObject(context, value, &exception));
1534     CYThrow(context, exception);
1535     return object;
1536 }
1537
1538 void CYThrow(JSContextRef context, id error, JSValueRef *exception) {
1539     if (exception == NULL)
1540         throw error;
1541     *exception = CYCastJSValue(context, error);
1542 }
1543
1544 JSValueRef CYCallAsFunction(JSContextRef context, JSObjectRef function, JSObjectRef _this, size_t count, JSValueRef arguments[]) {
1545     JSValueRef exception(NULL);
1546     JSValueRef value(JSObjectCallAsFunction(context, function, _this, count, arguments, &exception));
1547     CYThrow(context, exception);
1548     return value;
1549 }
1550
1551 bool CYIsCallable(JSContextRef context, JSValueRef value) {
1552     // XXX: this isn't actually correct
1553     return value != NULL && JSValueIsObject(context, value);
1554 }
1555
1556 @implementation CYJSObject
1557
1558 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
1559     if ((self = [super init]) != nil) {
1560         object_ = object;
1561         context_ = context;
1562         JSValueProtect(context_, object_);
1563     } return self;
1564 }
1565
1566 - (void) dealloc {
1567     JSValueUnprotect(context_, object_);
1568     [super dealloc];
1569 }
1570
1571 - (NSObject *) cy$toJSON:(NSString *)key {
1572     JSValueRef toJSON(CYGetProperty(context_, object_, toJSON_));
1573     if (!CYIsCallable(context_, toJSON))
1574         return [super cy$toJSON:key];
1575     else {
1576         JSValueRef arguments[1] = {CYCastJSValue(context_, key)};
1577         JSValueRef value(CYCallAsFunction(context_, (JSObjectRef) toJSON, object_, 1, arguments));
1578         // XXX: do I really want an NSNull here?!
1579         return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1580     }
1581 }
1582
1583 - (NSString *) cy$toCYON {
1584     JSValueRef toCYON(CYGetProperty(context_, object_, toCYON_));
1585     if (!CYIsCallable(context_, toCYON)) super:
1586         return [super cy$toCYON];
1587     else if (JSValueRef value = CYCallAsFunction(context_, (JSObjectRef) toCYON, object_, 0, NULL))
1588         return CYCastNSString(NULL, CYJSString(context_, value));
1589     else goto super;
1590 }
1591
1592 - (NSUInteger) count {
1593     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1594     size_t size(JSPropertyNameArrayGetCount(names));
1595     JSPropertyNameArrayRelease(names);
1596     return size;
1597 }
1598
1599 - (id) objectForKey:(id)key {
1600     JSValueRef value(CYGetProperty(context_, object_, CYJSString(key)));
1601     if (JSValueIsUndefined(context_, value))
1602         return nil;
1603     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1604 }
1605
1606 - (NSEnumerator *) keyEnumerator {
1607     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1608     NSEnumerator *enumerator([CYCastNSArray(names) objectEnumerator]);
1609     JSPropertyNameArrayRelease(names);
1610     return enumerator;
1611 }
1612
1613 - (void) setObject:(id)object forKey:(id)key {
1614     CYSetProperty(context_, object_, CYJSString(key), CYCastJSValue(context_, object));
1615 }
1616
1617 - (void) removeObjectForKey:(id)key {
1618     JSValueRef exception(NULL);
1619     (void) JSObjectDeleteProperty(context_, object_, CYJSString(key), &exception);
1620     CYThrow(context_, exception);
1621 }
1622
1623 @end
1624
1625 @implementation CYJSArray
1626
1627 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
1628     if ((self = [super init]) != nil) {
1629         object_ = object;
1630         context_ = context;
1631         JSValueProtect(context_, object_);
1632     } return self;
1633 }
1634
1635 - (void) dealloc {
1636     JSValueUnprotect(context_, object_);
1637     [super dealloc];
1638 }
1639
1640 - (NSUInteger) count {
1641     return CYCastDouble(context_, CYGetProperty(context_, object_, length_));
1642 }
1643
1644 - (id) objectAtIndex:(NSUInteger)index {
1645     size_t bounds([self count]);
1646     if (index >= bounds)
1647         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray objectAtIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1648     JSValueRef exception(NULL);
1649     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
1650     CYThrow(context_, exception);
1651     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1652 }
1653
1654 - (void) addObject:(id)object {
1655     JSValueRef exception(NULL);
1656     JSValueRef arguments[1];
1657     arguments[0] = CYCastJSValue(context_, object);
1658     JSObjectCallAsFunction(context_, Array_push_, object_, 1, arguments, &exception);
1659     CYThrow(context_, exception);
1660 }
1661
1662 - (void) insertObject:(id)object atIndex:(NSUInteger)index {
1663     size_t bounds([self count] + 1);
1664     if (index >= bounds)
1665         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray insertObject:atIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1666     JSValueRef exception(NULL);
1667     JSValueRef arguments[3];
1668     arguments[0] = CYCastJSValue(context_, index);
1669     arguments[1] = CYCastJSValue(context_, 0);
1670     arguments[2] = CYCastJSValue(context_, object);
1671     JSObjectCallAsFunction(context_, Array_splice_, object_, 3, arguments, &exception);
1672     CYThrow(context_, exception);
1673 }
1674
1675 - (void) removeLastObject {
1676     JSValueRef exception(NULL);
1677     JSObjectCallAsFunction(context_, Array_pop_, object_, 0, NULL, &exception);
1678     CYThrow(context_, exception);
1679 }
1680
1681 - (void) removeObjectAtIndex:(NSUInteger)index {
1682     size_t bounds([self count]);
1683     if (index >= bounds)
1684         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray removeObjectAtIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1685     JSValueRef exception(NULL);
1686     JSValueRef arguments[2];
1687     arguments[0] = CYCastJSValue(context_, index);
1688     arguments[1] = CYCastJSValue(context_, 1);
1689     JSObjectCallAsFunction(context_, Array_splice_, object_, 2, arguments, &exception);
1690     CYThrow(context_, exception);
1691 }
1692
1693 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)object {
1694     size_t bounds([self count]);
1695     if (index >= bounds)
1696         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray replaceObjectAtIndex:withObject:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1697     CYSetProperty(context_, object_, index, CYCastJSValue(context_, object));
1698 }
1699
1700 @end
1701
1702 NSString *CYCopyNSCYON(id value) {
1703     NSString *string;
1704
1705     if (value == nil)
1706         string = @"nil";
1707     else {
1708         Class _class(object_getClass(value));
1709         SEL sel(@selector(cy$toCYON));
1710
1711         if (Method toCYON = class_getInstanceMethod(_class, sel))
1712             string = reinterpret_cast<NSString *(*)(id, SEL)>(method_getImplementation(toCYON))(value, sel);
1713         else if (Method methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:))) {
1714             if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
1715                 string = [value cy$toCYON];
1716             else goto fail;
1717         } else fail: {
1718             if (value == NSZombie_)
1719                 string = @"_NSZombie_";
1720             else if (_class == NSZombie_)
1721                 string = [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
1722             // XXX: frowny /in/ the pants
1723             else if (value == NSMessageBuilder_ || value == Object_)
1724                 string = nil;
1725             else
1726                 string = [NSString stringWithFormat:@"%@", value];
1727         }
1728
1729         // XXX: frowny pants
1730         if (string == nil)
1731             string = @"undefined";
1732     }
1733
1734     return [string retain];
1735 }
1736
1737 NSString *CYCopyNSCYON(JSContextRef context, JSValueRef value, JSValueRef *exception) {
1738     if (JSValueIsNull(context, value))
1739         return [@"null" retain];
1740
1741     CYTry {
1742         CYPoolTry {
1743             return CYCopyNSCYON(CYCastNSObject(NULL, context, value));
1744         } CYPoolCatch(NULL)
1745     } CYCatch
1746 }
1747
1748 NSString *CYPoolNSCYON(apr_pool_t *pool, id value) {
1749     return CYPoolRelease(pool, static_cast<id>(CYCopyNSCYON(value)));
1750 }
1751
1752 const char *CYPoolCCYON(apr_pool_t *pool, JSContextRef context, JSValueRef value, JSValueRef *exception) {
1753     if (NSString *json = CYCopyNSCYON(context, value, exception)) {
1754         const char *string(CYPoolCString(pool, json));
1755         [json release];
1756         return string;
1757     } else return NULL;
1758 }
1759
1760 // XXX: use objc_getAssociatedObject and objc_setAssociatedObject on 10.6
1761 struct CYInternal :
1762     CYData
1763 {
1764     JSObjectRef object_;
1765
1766     CYInternal() :
1767         object_(NULL)
1768     {
1769     }
1770
1771     ~CYInternal() {
1772         // XXX: delete object_? ;(
1773     }
1774
1775     static CYInternal *Get(id self) {
1776         CYInternal *internal(NULL);
1777         if (object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal)) == NULL) {
1778             // XXX: do something epic? ;P
1779         }
1780
1781         return internal;
1782     }
1783
1784     static CYInternal *Set(id self) {
1785         CYInternal *internal(NULL);
1786         if (Ivar ivar = object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal))) {
1787             if (internal == NULL) {
1788                 internal = new CYInternal();
1789                 object_setIvar(self, ivar, reinterpret_cast<id>(internal));
1790             }
1791         } else {
1792             // XXX: do something epic? ;P
1793         }
1794
1795         return internal;
1796     }
1797
1798     bool HasProperty(JSContextRef context, JSStringRef name) {
1799         if (object_ == NULL)
1800             return false;
1801         return JSObjectHasProperty(context, object_, name);
1802     }
1803
1804     JSValueRef GetProperty(JSContextRef context, JSStringRef name) {
1805         if (object_ == NULL)
1806             return NULL;
1807         return CYGetProperty(context, object_, name);
1808     }
1809
1810     void SetProperty(JSContextRef context, JSStringRef name, JSValueRef value) {
1811         if (object_ == NULL)
1812             object_ = JSObjectMake(context, NULL, NULL);
1813         CYSetProperty(context, object_, name, value);
1814     }
1815 };
1816
1817 static JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1818     Selector_privateData *internal(new Selector_privateData(sel));
1819     return JSObjectMake(context, Selector_, internal);
1820 }
1821
1822 static JSObjectRef CYMakePointer(JSContextRef context, void *pointer, sig::Type *type, ffi_type *ffi, JSObjectRef owner) {
1823     Pointer *internal(new Pointer(pointer, context, owner, type));
1824     return JSObjectMake(context, Pointer_, internal);
1825 }
1826
1827 static JSObjectRef CYMakeFunctor(JSContextRef context, void (*function)(), const char *type) {
1828     Functor_privateData *internal(new Functor_privateData(type, function));
1829     return JSObjectMake(context, Functor_, internal);
1830 }
1831
1832 static const char *CYPoolCString(apr_pool_t *pool, JSStringRef value) {
1833     if (pool == NULL) {
1834         // XXX: this could be much more efficient
1835         const char *string([CYCastNSString(NULL, value) UTF8String]);
1836         return string;
1837     } else {
1838         size_t size(JSStringGetMaximumUTF8CStringSize(value));
1839         char *string(new(pool) char[size]);
1840         JSStringGetUTF8CString(value, string, size);
1841         return string;
1842     }
1843 }
1844
1845 static const char *CYPoolCString(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1846     return JSValueIsNull(context, value) ? NULL : CYPoolCString(pool, CYJSString(context, value));
1847 }
1848
1849 static bool CYGetOffset(apr_pool_t *pool, JSStringRef value, ssize_t &index) {
1850     return CYGetOffset(CYPoolCString(pool, value), index);
1851 }
1852
1853 // XXX: this macro is unhygenic
1854 #define CYCastCString(context, value) ({ \
1855     char *utf8; \
1856     if (value == NULL) \
1857         utf8 = NULL; \
1858     else if (JSStringRef string = CYCopyJSString(context, value)) { \
1859         size_t size(JSStringGetMaximumUTF8CStringSize(string)); \
1860         utf8 = reinterpret_cast<char *>(alloca(size)); \
1861         JSStringGetUTF8CString(string, utf8, size); \
1862         JSStringRelease(string); \
1863     } else \
1864         utf8 = NULL; \
1865     utf8; \
1866 })
1867
1868 static void *CYCastPointer_(JSContextRef context, JSValueRef value) {
1869     switch (JSValueGetType(context, value)) {
1870         case kJSTypeNull:
1871             return NULL;
1872         /*case kJSTypeString:
1873             return dlsym(RTLD_DEFAULT, CYCastCString(context, value));
1874         case kJSTypeObject:
1875             if (JSValueIsObjectOfClass(context, value, Pointer_)) {
1876                 Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate((JSObjectRef) value)));
1877                 return internal->value_;
1878             }*/
1879         default:
1880             double number(CYCastDouble(context, value));
1881             if (std::isnan(number))
1882                 @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"cannot convert value to pointer" userInfo:nil];
1883             return reinterpret_cast<void *>(static_cast<uintptr_t>(static_cast<long long>(number)));
1884     }
1885 }
1886
1887 template <typename Type_>
1888 static _finline Type_ CYCastPointer(JSContextRef context, JSValueRef value) {
1889     return reinterpret_cast<Type_>(CYCastPointer_(context, value));
1890 }
1891
1892 static SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1893     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1894         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1895         return reinterpret_cast<SEL>(internal->value_);
1896     } else
1897         return CYCastPointer<SEL>(context, value);
1898 }
1899
1900 static void CYPoolFFI(apr_pool_t *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) {
1901     switch (type->primitive) {
1902         case sig::boolean_P:
1903             *reinterpret_cast<bool *>(data) = JSValueToBoolean(context, value);
1904         break;
1905
1906 #define CYPoolFFI_(primitive, native) \
1907         case sig::primitive ## _P: \
1908             *reinterpret_cast<native *>(data) = CYCastDouble(context, value); \
1909         break;
1910
1911         CYPoolFFI_(uchar, unsigned char)
1912         CYPoolFFI_(char, char)
1913         CYPoolFFI_(ushort, unsigned short)
1914         CYPoolFFI_(short, short)
1915         CYPoolFFI_(ulong, unsigned long)
1916         CYPoolFFI_(long, long)
1917         CYPoolFFI_(uint, unsigned int)
1918         CYPoolFFI_(int, int)
1919         CYPoolFFI_(ulonglong, unsigned long long)
1920         CYPoolFFI_(longlong, long long)
1921         CYPoolFFI_(float, float)
1922         CYPoolFFI_(double, double)
1923
1924         case sig::object_P:
1925         case sig::typename_P:
1926             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1927         break;
1928
1929         case sig::selector_P:
1930             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1931         break;
1932
1933         case sig::pointer_P:
1934             *reinterpret_cast<void **>(data) = CYCastPointer<void *>(context, value);
1935         break;
1936
1937         case sig::string_P:
1938             *reinterpret_cast<const char **>(data) = CYPoolCString(pool, context, value);
1939         break;
1940
1941         case sig::struct_P: {
1942             uint8_t *base(reinterpret_cast<uint8_t *>(data));
1943             JSObjectRef aggregate(JSValueIsObject(context, value) ? (JSObjectRef) value : NULL);
1944             for (size_t index(0); index != type->data.signature.count; ++index) {
1945                 sig::Element *element(&type->data.signature.elements[index]);
1946                 ffi_type *field(ffi->elements[index]);
1947
1948                 JSValueRef rhs;
1949                 if (aggregate == NULL)
1950                     rhs = value;
1951                 else {
1952                     rhs = CYGetProperty(context, aggregate, index);
1953                     if (JSValueIsUndefined(context, rhs)) {
1954                         if (element->name != NULL)
1955                             rhs = CYGetProperty(context, aggregate, CYJSString(element->name));
1956                         else
1957                             goto undefined;
1958                         if (JSValueIsUndefined(context, rhs)) undefined:
1959                             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"unable to extract structure value" userInfo:nil];
1960                     }
1961                 }
1962
1963                 CYPoolFFI(pool, context, element->type, field, base, rhs);
1964                 // XXX: alignment?
1965                 base += field->size;
1966             }
1967         } break;
1968
1969         case sig::void_P:
1970         break;
1971
1972         default:
1973             NSLog(@"CYPoolFFI(%c)\n", type->primitive);
1974             _assert(false);
1975     }
1976 }
1977
1978 static JSValueRef CYFromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize = false, JSObjectRef owner = NULL) {
1979     JSValueRef value;
1980
1981     switch (type->primitive) {
1982         case sig::boolean_P:
1983             value = CYCastJSValue(context, *reinterpret_cast<bool *>(data));
1984         break;
1985
1986 #define CYFromFFI_(primitive, native) \
1987         case sig::primitive ## _P: \
1988             value = CYCastJSValue(context, *reinterpret_cast<native *>(data)); \
1989         break;
1990
1991         CYFromFFI_(uchar, unsigned char)
1992         CYFromFFI_(char, char)
1993         CYFromFFI_(ushort, unsigned short)
1994         CYFromFFI_(short, short)
1995         CYFromFFI_(ulong, unsigned long)
1996         CYFromFFI_(long, long)
1997         CYFromFFI_(uint, unsigned int)
1998         CYFromFFI_(int, int)
1999         CYFromFFI_(ulonglong, unsigned long long)
2000         CYFromFFI_(longlong, long long)
2001         CYFromFFI_(float, float)
2002         CYFromFFI_(double, double)
2003
2004         case sig::object_P: {
2005             if (id object = *reinterpret_cast<id *>(data)) {
2006                 value = CYCastJSValue(context, object);
2007                 if (initialize)
2008                     [object release];
2009             } else goto null;
2010         } break;
2011
2012         case sig::typename_P:
2013             value = CYMakeInstance(context, *reinterpret_cast<Class *>(data), true);
2014         break;
2015
2016         case sig::selector_P:
2017             if (SEL sel = *reinterpret_cast<SEL *>(data))
2018                 value = CYMakeSelector(context, sel);
2019             else goto null;
2020         break;
2021
2022         case sig::pointer_P:
2023             if (void *pointer = *reinterpret_cast<void **>(data))
2024                 value = CYMakePointer(context, pointer, type->data.data.type, ffi, owner);
2025             else goto null;
2026         break;
2027
2028         case sig::string_P:
2029             if (char *utf8 = *reinterpret_cast<char **>(data))
2030                 value = CYCastJSValue(context, utf8);
2031             else goto null;
2032         break;
2033
2034         case sig::struct_P:
2035             value = CYMakeStruct(context, data, type, ffi, owner);
2036         break;
2037
2038         case sig::void_P:
2039             value = CYJSUndefined(context);
2040         break;
2041
2042         null:
2043             value = CYJSNull(context);
2044         break;
2045
2046         default:
2047             NSLog(@"CYFromFFI(%c)\n", type->primitive);
2048             _assert(false);
2049     }
2050
2051     return value;
2052 }
2053
2054 static bool CYImplements(id object, Class _class, SEL selector, bool devoid) {
2055     if (Method method = class_getInstanceMethod(_class, selector)) {
2056         if (!devoid)
2057             return true;
2058         char type[16];
2059         method_getReturnType(method, type, sizeof(type));
2060         if (type[0] != 'v')
2061             return true;
2062     }
2063
2064     // XXX: possibly use a more "awesome" check?
2065     return false;
2066 }
2067
2068 static const char *CYPoolTypeEncoding(apr_pool_t *pool, Class _class, SEL sel, Method method) {
2069     if (method != NULL)
2070         return method_getTypeEncoding(method);
2071     else if (NSString *type = [[Bridge_ objectAtIndex:1] objectForKey:CYCastNSString(pool, sel_getName(sel))])
2072         return CYPoolCString(pool, type);
2073     else
2074         return NULL;
2075 }
2076
2077 static void FunctionClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
2078     Closure_privateData *internal(reinterpret_cast<Closure_privateData *>(arg));
2079
2080     JSContextRef context(internal->context_);
2081
2082     size_t count(internal->cif_.nargs);
2083     JSValueRef values[count];
2084
2085     for (size_t index(0); index != count; ++index)
2086         values[index] = CYFromFFI(context, internal->signature_.elements[1 + index].type, internal->cif_.arg_types[index], arguments[index]);
2087
2088     JSValueRef value(CYCallAsFunction(context, internal->function_, NULL, count, values));
2089     CYPoolFFI(NULL, context, internal->signature_.elements[0].type, internal->cif_.rtype, result, value);
2090 }
2091
2092 static void MessageClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
2093     Closure_privateData *internal(reinterpret_cast<Closure_privateData *>(arg));
2094
2095     JSContextRef context(internal->context_);
2096
2097     size_t count(internal->cif_.nargs);
2098     JSValueRef values[count];
2099
2100     for (size_t index(0); index != count; ++index)
2101         values[index] = CYFromFFI(context, internal->signature_.elements[1 + index].type, internal->cif_.arg_types[index], arguments[index]);
2102
2103     JSObjectRef _this(CYCastJSObject(context, values[0]));
2104
2105     JSValueRef value(CYCallAsFunction(context, internal->function_, _this, count - 2, values + 2));
2106     CYPoolFFI(NULL, context, internal->signature_.elements[0].type, internal->cif_.rtype, result, value);
2107 }
2108
2109 static Closure_privateData *CYMakeFunctor_(JSContextRef context, JSObjectRef function, const char *type, void (*callback)(ffi_cif *, void *, void **, void *)) {
2110     // XXX: in case of exceptions this will leak
2111     // XXX: in point of fact, this may /need/ to leak :(
2112     Closure_privateData *internal(new Closure_privateData(CYGetJSContext(), function, type));
2113
2114     ffi_closure *closure((ffi_closure *) _syscall(mmap(
2115         NULL, sizeof(ffi_closure),
2116         PROT_READ | PROT_WRITE, MAP_ANON | MAP_PRIVATE,
2117         -1, 0
2118     )));
2119
2120     ffi_status status(ffi_prep_closure(closure, &internal->cif_, callback, internal));
2121     _assert(status == FFI_OK);
2122
2123     _syscall(mprotect(closure, sizeof(*closure), PROT_READ | PROT_EXEC));
2124
2125     internal->value_ = closure;
2126
2127     return internal;
2128 }
2129
2130 static JSObjectRef CYMakeFunctor(JSContextRef context, JSObjectRef function, const char *type) {
2131     Closure_privateData *internal(CYMakeFunctor_(context, function, type, &FunctionClosure_));
2132     return JSObjectMake(context, Functor_, internal);
2133 }
2134
2135 static JSObjectRef CYMakeFunctor(JSContextRef context, JSValueRef value, const char *type) {
2136     JSValueRef exception(NULL);
2137     bool function(JSValueIsInstanceOfConstructor(context, value, Function_, &exception));
2138     CYThrow(context, exception);
2139
2140     if (function) {
2141         JSObjectRef function(CYCastJSObject(context, value));
2142         return CYMakeFunctor(context, function, type);
2143     } else {
2144         void (*function)()(CYCastPointer<void (*)()>(context, value));
2145         return CYMakeFunctor(context, function, type);
2146     }
2147 }
2148
2149 static JSObjectRef CYMakeMessage(JSContextRef context, SEL sel, IMP imp, const char *type) {
2150     Message_privateData *internal(new Message_privateData(sel, type, imp));
2151     return JSObjectMake(context, Message_, internal);
2152 }
2153
2154 static IMP CYMakeMessage(JSContextRef context, JSValueRef value, const char *type) {
2155     JSObjectRef function(CYCastJSObject(context, value));
2156     Closure_privateData *internal(CYMakeFunctor_(context, function, type, &MessageClosure_));
2157     return reinterpret_cast<IMP>(internal->GetValue());
2158 }
2159
2160 static bool Messages_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
2161     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
2162     Class _class(internal->GetValue());
2163
2164     CYPool pool;
2165     const char *name(CYPoolCString(pool, property));
2166
2167     if (SEL sel = sel_getUid(name))
2168         if (class_getInstanceMethod(_class, sel) != NULL)
2169             return true;
2170
2171     return false;
2172 }
2173
2174 static JSValueRef Messages_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2175     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
2176     Class _class(internal->GetValue());
2177
2178     CYPool pool;
2179     const char *name(CYPoolCString(pool, property));
2180
2181     if (SEL sel = sel_getUid(name))
2182         if (Method method = class_getInstanceMethod(_class, sel))
2183             return CYMakeMessage(context, sel, method_getImplementation(method), method_getTypeEncoding(method));
2184
2185     return NULL;
2186 }
2187
2188 static bool Messages_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2189     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
2190     Class _class(internal->GetValue());
2191
2192     CYPool pool;
2193     const char *name(CYPoolCString(pool, property));
2194
2195     SEL sel(sel_registerName(name));
2196
2197     Method method(class_getInstanceMethod(_class, sel));
2198
2199     const char *type;
2200     IMP imp;
2201
2202     if (JSValueIsObjectOfClass(context, value, Message_)) {
2203         Message_privateData *message(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
2204         type = sig::Unparse(pool, &message->signature_);
2205         imp = reinterpret_cast<IMP>(message->GetValue());
2206     } else {
2207         type = CYPoolTypeEncoding(pool, _class, sel, method);
2208         imp = CYMakeMessage(context, value, type);
2209     }
2210
2211     if (method != NULL)
2212         method_setImplementation(method, imp);
2213     else
2214         class_replaceMethod(_class, sel, imp, type);
2215
2216     return true;
2217 }
2218
2219 #if !__OBJC2__
2220 static bool Messages_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2221     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
2222     Class _class(internal->GetValue());
2223
2224     CYPool pool;
2225     const char *name(CYPoolCString(pool, property));
2226
2227     if (SEL sel = sel_getUid(name))
2228         if (Method method = class_getInstanceMethod(_class, sel)) {
2229             objc_method_list list = {NULL, 1, {method}};
2230             class_removeMethods(_class, &list);
2231             return true;
2232         }
2233
2234     return false;
2235 }
2236 #endif
2237
2238 static void Messages_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2239     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
2240     Class _class(internal->GetValue());
2241
2242     unsigned int size;
2243     Method *data(class_copyMethodList(_class, &size));
2244     for (size_t i(0); i != size; ++i)
2245         JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(data[i]))));
2246     free(data);
2247 }
2248
2249 static bool Instance_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
2250     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2251     id self(internal->GetValue());
2252
2253     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
2254         return true;
2255
2256     CYPool pool;
2257     NSString *name(CYCastNSString(pool, property));
2258
2259     if (CYInternal *internal = CYInternal::Get(self))
2260         if (internal->HasProperty(context, property))
2261             return true;
2262
2263     Class _class(object_getClass(self));
2264
2265     CYPoolTry {
2266         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
2267         if (CYImplements(self, _class, @selector(cy$hasProperty:), false))
2268             if ([self cy$hasProperty:name])
2269                 return true;
2270     } CYPoolCatch(false)
2271
2272     const char *string(CYPoolCString(pool, name));
2273
2274     if (class_getProperty(_class, string) != NULL)
2275         return true;
2276
2277     if (SEL sel = sel_getUid(string))
2278         if (CYImplements(self, _class, sel, true))
2279             return true;
2280
2281     return false;
2282 }
2283
2284 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2285     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2286     id self(internal->GetValue());
2287
2288     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
2289         return Internal::Make(context, self, object);
2290
2291     CYTry {
2292         CYPool pool;
2293         NSString *name(CYCastNSString(pool, property));
2294
2295         if (CYInternal *internal = CYInternal::Get(self))
2296             if (JSValueRef value = internal->GetProperty(context, property))
2297                 return value;
2298
2299         CYPoolTry {
2300             if (NSObject *data = [self cy$getProperty:name])
2301                 return CYCastJSValue(context, data);
2302         } CYPoolCatch(NULL)
2303
2304         const char *string(CYPoolCString(pool, name));
2305         Class _class(object_getClass(self));
2306
2307 #ifdef __APPLE__
2308         if (objc_property_t property = class_getProperty(_class, string)) {
2309             PropertyAttributes attributes(property);
2310             SEL sel(sel_registerName(attributes.Getter()));
2311             return CYSendMessage(pool, context, self, sel, 0, NULL, false, exception);
2312         }
2313 #endif
2314
2315         if (SEL sel = sel_getUid(string))
2316             if (CYImplements(self, _class, sel, true))
2317                 return CYSendMessage(pool, context, self, sel, 0, NULL, false, exception);
2318
2319         return NULL;
2320     } CYCatch
2321 }
2322
2323 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2324     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2325     id self(internal->GetValue());
2326
2327     CYPool pool;
2328
2329     CYTry {
2330         NSString *name(CYCastNSString(pool, property));
2331         NSString *data(CYCastNSObject(pool, context, value));
2332
2333         CYPoolTry {
2334             if ([self cy$setProperty:name to:data])
2335                 return true;
2336         } CYPoolCatch(NULL)
2337
2338         const char *string(CYPoolCString(pool, name));
2339         Class _class(object_getClass(self));
2340
2341 #ifdef __APPLE__
2342         if (objc_property_t property = class_getProperty(_class, string)) {
2343             PropertyAttributes attributes(property);
2344             if (const char *setter = attributes.Setter()) {
2345                 SEL sel(sel_registerName(setter));
2346                 JSValueRef arguments[1] = {value};
2347                 CYSendMessage(pool, context, self, sel, 1, arguments, false, exception);
2348                 return true;
2349             }
2350         }
2351 #endif
2352
2353         size_t length(strlen(string));
2354
2355         char set[length + 5];
2356
2357         set[0] = 's';
2358         set[1] = 'e';
2359         set[2] = 't';
2360
2361         if (string[0] != '\0') {
2362             set[3] = toupper(string[0]);
2363             memcpy(set + 4, string + 1, length - 1);
2364         }
2365
2366         set[length + 3] = ':';
2367         set[length + 4] = '\0';
2368
2369         if (SEL sel = sel_getUid(set))
2370             if (CYImplements(self, _class, sel, false)) {
2371                 JSValueRef arguments[1] = {value};
2372                 CYSendMessage(pool, context, self, sel, 1, arguments, false, exception);
2373             }
2374
2375         if (CYInternal *internal = CYInternal::Set(self)) {
2376             internal->SetProperty(context, property, value);
2377             return true;
2378         }
2379
2380         return false;
2381     } CYCatch
2382 }
2383
2384 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2385     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2386     id self(internal->GetValue());
2387
2388     CYTry {
2389         CYPoolTry {
2390             NSString *name(CYCastNSString(NULL, property));
2391             return [self cy$deleteProperty:name];
2392         } CYPoolCatch(NULL)
2393     } CYCatch
2394 }
2395
2396 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2397     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2398     id self(internal->GetValue());
2399
2400     CYPool pool;
2401     Class _class(object_getClass(self));
2402
2403     {
2404         unsigned int size;
2405         objc_property_t *data(class_copyPropertyList(_class, &size));
2406         for (size_t i(0); i != size; ++i)
2407             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
2408         free(data);
2409     }
2410 }
2411
2412 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2413     CYTry {
2414         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2415         JSObjectRef value(Instance::Make(context, [internal->GetValue() alloc], Instance::Uninitialized));
2416         return value;
2417     } CYCatch
2418 }
2419
2420 static bool CYIsClass(id self) {
2421     // XXX: this is a lame object_isClass
2422     return class_getInstanceMethod(object_getClass(self), @selector(alloc)) != NULL;
2423 }
2424
2425 static bool Instance_hasInstance(JSContextRef context, JSObjectRef constructor, JSValueRef instance, JSValueRef *exception) {
2426     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) constructor)));
2427     Class _class(internal->GetValue());
2428     if (!CYIsClass(_class))
2429         return false;
2430
2431     if (JSValueIsObjectOfClass(context, instance, Instance_)) {
2432         Instance *linternal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) instance)));
2433         // XXX: this isn't always safe
2434         CYTry {
2435             return [linternal->GetValue() isKindOfClass:_class];
2436         } CYCatch
2437     }
2438
2439     return false;
2440 }
2441
2442 static bool Internal_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
2443     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2444     CYPool pool;
2445
2446     id self(internal->GetValue());
2447     const char *name(CYPoolCString(pool, property));
2448
2449     if (object_getInstanceVariable(self, name, NULL) != NULL)
2450         return true;
2451
2452     return false;
2453 }
2454
2455 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2456     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2457     CYPool pool;
2458
2459     CYTry {
2460         id self(internal->GetValue());
2461         const char *name(CYPoolCString(pool, property));
2462
2463         if (Ivar ivar = object_getInstanceVariable(self, name, NULL)) {
2464             Type_privateData type(pool, ivar_getTypeEncoding(ivar));
2465             return CYFromFFI(context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar));
2466         }
2467
2468         return NULL;
2469     } CYCatch
2470 }
2471
2472 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2473     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2474     CYPool pool;
2475
2476     CYTry {
2477         id self(internal->GetValue());
2478         const char *name(CYPoolCString(pool, property));
2479
2480         if (Ivar ivar = object_getInstanceVariable(self, name, NULL)) {
2481             Type_privateData type(pool, ivar_getTypeEncoding(ivar));
2482             CYPoolFFI(pool, context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
2483             return true;
2484         }
2485
2486         return false;
2487     } CYCatch
2488 }
2489
2490 static void Internal_getPropertyNames_(Class _class, JSPropertyNameAccumulatorRef names) {
2491     if (Class super = class_getSuperclass(_class))
2492         Internal_getPropertyNames_(super, names);
2493
2494     unsigned int size;
2495     Ivar *data(class_copyIvarList(_class, &size));
2496     for (size_t i(0); i != size; ++i)
2497         JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
2498     free(data);
2499 }
2500
2501 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2502     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2503     CYPool pool;
2504
2505     id self(internal->GetValue());
2506     Class _class(object_getClass(self));
2507
2508     Internal_getPropertyNames_(_class, names);
2509 }
2510
2511 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2512     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2513     return internal->GetOwner();
2514 }
2515
2516 static bool Index_(apr_pool_t *pool, Struct_privateData *internal, JSStringRef property, ssize_t &index, uint8_t *&base) {
2517     Type_privateData *typical(internal->type_);
2518     sig::Type *type(typical->type_);
2519     if (type == NULL)
2520         return false;
2521
2522     const char *name(CYPoolCString(pool, property));
2523     size_t length(strlen(name));
2524     double number(CYCastDouble(name, length));
2525
2526     size_t count(type->data.signature.count);
2527
2528     if (std::isnan(number)) {
2529         if (property == NULL)
2530             return false;
2531
2532         sig::Element *elements(type->data.signature.elements);
2533
2534         for (size_t local(0); local != count; ++local) {
2535             sig::Element *element(&elements[local]);
2536             if (element->name != NULL && strcmp(name, element->name) == 0) {
2537                 index = local;
2538                 goto base;
2539             }
2540         }
2541
2542         return false;
2543     } else {
2544         index = static_cast<ssize_t>(number);
2545         if (index != number || index < 0 || static_cast<size_t>(index) >= count)
2546             return false;
2547     }
2548
2549   base:
2550     ffi_type **elements(typical->GetFFI()->elements);
2551
2552     base = reinterpret_cast<uint8_t *>(internal->value_);
2553     for (ssize_t local(0); local != index; ++local)
2554         base += elements[local]->size;
2555
2556     return true;
2557 }
2558
2559 static JSValueRef Pointer_getIndex(JSContextRef context, JSObjectRef object, size_t index, JSValueRef *exception) {
2560     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
2561     Type_privateData *typical(internal->type_);
2562
2563     ffi_type *ffi(typical->GetFFI());
2564
2565     uint8_t *base(reinterpret_cast<uint8_t *>(internal->value_));
2566     base += ffi->size * index;
2567
2568     JSObjectRef owner(internal->GetOwner() ?: object);
2569
2570     CYTry {
2571         return CYFromFFI(context, typical->type_, ffi, base, false, owner);
2572     } CYCatch
2573 }
2574
2575 static JSValueRef Pointer_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2576     CYPool pool;
2577     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
2578     Type_privateData *typical(internal->type_);
2579
2580     if (typical->type_ == NULL)
2581         return NULL;
2582
2583     ssize_t offset;
2584     if (!CYGetOffset(pool, property, offset))
2585         return NULL;
2586
2587     return Pointer_getIndex(context, object, offset, exception);
2588 }
2589
2590 static JSValueRef Pointer_getProperty_$cyi(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2591     return Pointer_getIndex(context, object, 0, exception);
2592 }
2593
2594 static bool Pointer_setIndex(JSContextRef context, JSObjectRef object, size_t index, JSValueRef value, JSValueRef *exception) {
2595     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
2596     Type_privateData *typical(internal->type_);
2597
2598     ffi_type *ffi(typical->GetFFI());
2599
2600     uint8_t *base(reinterpret_cast<uint8_t *>(internal->value_));
2601     base += ffi->size * index;
2602
2603     CYTry {
2604         CYPoolFFI(NULL, context, typical->type_, ffi, base, value);
2605         return true;
2606     } CYCatch
2607 }
2608
2609 static bool Pointer_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2610     CYPool pool;
2611     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
2612     Type_privateData *typical(internal->type_);
2613
2614     if (typical->type_ == NULL)
2615         return NULL;
2616
2617     ssize_t offset;
2618     if (!CYGetOffset(pool, property, offset))
2619         return NULL;
2620
2621     return Pointer_setIndex(context, object, offset, value, exception);
2622 }
2623
2624 static bool Pointer_setProperty_$cyi(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2625     return Pointer_setIndex(context, object, 0, value, exception);
2626 }
2627
2628 static JSValueRef Struct_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2629     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(_this)));
2630     Type_privateData *typical(internal->type_);
2631     return CYMakePointer(context, internal->value_, typical->type_, typical->ffi_, _this);
2632 }
2633
2634 static JSValueRef Struct_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2635     CYPool pool;
2636     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(object)));
2637     Type_privateData *typical(internal->type_);
2638
2639     ssize_t index;
2640     uint8_t *base;
2641
2642     if (!Index_(pool, internal, property, index, base))
2643         return NULL;
2644
2645     JSObjectRef owner(internal->GetOwner() ?: object);
2646
2647     CYTry {
2648         return CYFromFFI(context, typical->type_->data.signature.elements[index].type, typical->GetFFI()->elements[index], base, false, owner);
2649     } CYCatch
2650 }
2651
2652 static bool Struct_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2653     CYPool pool;
2654     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(object)));
2655     Type_privateData *typical(internal->type_);
2656
2657     ssize_t index;
2658     uint8_t *base;
2659
2660     if (!Index_(pool, internal, property, index, base))
2661         return false;
2662
2663     CYTry {
2664         CYPoolFFI(NULL, context, typical->type_->data.signature.elements[index].type, typical->GetFFI()->elements[index], base, value);
2665         return true;
2666     } CYCatch
2667 }
2668
2669 static void Struct_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2670     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(object)));
2671     Type_privateData *typical(internal->type_);
2672     sig::Type *type(typical->type_);
2673
2674     if (type == NULL)
2675         return;
2676
2677     size_t count(type->data.signature.count);
2678     sig::Element *elements(type->data.signature.elements);
2679
2680     char number[32];
2681
2682     for (size_t index(0); index != count; ++index) {
2683         const char *name;
2684         name = elements[index].name;
2685
2686         if (name == NULL) {
2687             sprintf(number, "%lu", index);
2688             name = number;
2689         }
2690
2691         JSPropertyNameAccumulatorAddName(names, CYJSString(name));
2692     }
2693 }
2694
2695 JSValueRef CYCallFunction(apr_pool_t *pool, JSContextRef context, size_t setups, void *setup[], size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception, sig::Signature *signature, ffi_cif *cif, void (*function)()) {
2696     CYTry {
2697         if (setups + count != signature->count - 1)
2698             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to ffi function" userInfo:nil];
2699
2700         size_t size(setups + count);
2701         void *values[size];
2702         memcpy(values, setup, sizeof(void *) * setups);
2703
2704         for (size_t index(setups); index != size; ++index) {
2705             sig::Element *element(&signature->elements[index + 1]);
2706             ffi_type *ffi(cif->arg_types[index]);
2707             // XXX: alignment?
2708             values[index] = new(pool) uint8_t[ffi->size];
2709             CYPoolFFI(pool, context, element->type, ffi, values[index], arguments[index - setups]);
2710         }
2711
2712         uint8_t value[cif->rtype->size];
2713         ffi_call(cif, function, value, values);
2714
2715         return CYFromFFI(context, signature->elements[0].type, cif->rtype, value, initialize);
2716     } CYCatch
2717 }
2718
2719 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2720     CYTry {
2721         CYPool pool;
2722         NSString *name(CYCastNSString(pool, property));
2723         if (Class _class = NSClassFromString(name))
2724             return CYMakeInstance(context, _class, true);
2725         return NULL;
2726     } CYCatch
2727 }
2728
2729 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2730     size_t size(objc_getClassList(NULL, 0));
2731     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
2732
2733   get:
2734     size_t writ(objc_getClassList(data, size));
2735     if (size < writ) {
2736         size = writ;
2737         if (Class *copy = reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ))) {
2738             data = copy;
2739             goto get;
2740         } else goto done;
2741     }
2742
2743     for (size_t i(0); i != writ; ++i)
2744         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
2745
2746   done:
2747     free(data);
2748 }
2749
2750 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2751     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2752
2753     CYTry {
2754         CYPool pool;
2755         const char *name(CYPoolCString(pool, property));
2756         unsigned int size;
2757         const char **data(objc_copyClassNamesForImage(internal, &size));
2758         JSValueRef value;
2759         for (size_t i(0); i != size; ++i)
2760             if (strcmp(name, data[i]) == 0) {
2761                 if (Class _class = objc_getClass(name)) {
2762                     value = CYMakeInstance(context, _class, true);
2763                     goto free;
2764                 } else
2765                     break;
2766             }
2767         value = NULL;
2768       free:
2769         free(data);
2770         return value;
2771     } CYCatch
2772 }
2773
2774 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2775     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2776     unsigned int size;
2777     const char **data(objc_copyClassNamesForImage(internal, &size));
2778     for (size_t i(0); i != size; ++i)
2779         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2780     free(data);
2781 }
2782
2783 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2784     CYTry {
2785         CYPool pool;
2786         const char *name(CYPoolCString(pool, property));
2787         unsigned int size;
2788         const char **data(objc_copyImageNames(&size));
2789         for (size_t i(0); i != size; ++i)
2790             if (strcmp(name, data[i]) == 0) {
2791                 name = data[i];
2792                 goto free;
2793             }
2794         name = NULL;
2795       free:
2796         free(data);
2797         if (name == NULL)
2798             return NULL;
2799         JSObjectRef value(JSObjectMake(context, NULL, NULL));
2800         CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
2801         return value;
2802     } CYCatch
2803 }
2804
2805 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2806     unsigned int size;
2807     const char **data(objc_copyImageNames(&size));
2808     for (size_t i(0); i != size; ++i)
2809         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2810     free(data);
2811 }
2812
2813 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2814     CYTry {
2815         CYPool pool;
2816         NSString *name(CYCastNSString(pool, property));
2817         if (Protocol *protocol = NSProtocolFromString(name))
2818             return CYMakeInstance(context, protocol, true);
2819         return NULL;
2820     } CYCatch
2821 }
2822
2823 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2824     unsigned int size;
2825     Protocol **data(objc_copyProtocolList(&size));
2826     for (size_t i(0); i != size; ++i)
2827         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
2828     free(data);
2829 }
2830
2831 static JSObjectRef CYMakeType(JSContextRef context, const char *type) {
2832     Type_privateData *internal(new Type_privateData(NULL, type));
2833     return JSObjectMake(context, Type_privateData::Class_, internal);
2834 }
2835
2836 static JSObjectRef CYMakeType(JSContextRef context, sig::Type *type) {
2837     Type_privateData *internal(new Type_privateData(type));
2838     return JSObjectMake(context, Type_privateData::Class_, internal);
2839 }
2840
2841 static JSValueRef Runtime_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2842     if (JSStringIsEqualToUTF8CString(property, "nil"))
2843         return Instance::Make(context, nil);
2844
2845     CYTry {
2846         CYPool pool;
2847         NSString *name(CYCastNSString(pool, property));
2848         if (Class _class = NSClassFromString(name))
2849             return CYMakeInstance(context, _class, true);
2850         if (NSMutableArray *entry = [[Bridge_ objectAtIndex:0] objectForKey:name])
2851             switch ([[entry objectAtIndex:0] intValue]) {
2852                 case 0:
2853                     return JSEvaluateScript(CYGetJSContext(), CYJSString([entry objectAtIndex:1]), NULL, NULL, 0, NULL);
2854                 case 1:
2855                     return CYMakeFunctor(context, reinterpret_cast<void (*)()>([name cy$symbol]), CYPoolCString(pool, [entry objectAtIndex:1]));
2856                 case 2:
2857                     // XXX: this is horrendously inefficient
2858                     sig::Signature signature;
2859                     sig::Parse(pool, &signature, CYPoolCString(pool, [entry objectAtIndex:1]), &Structor_);
2860                     ffi_cif cif;
2861                     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2862                     return CYFromFFI(context, signature.elements[0].type, cif.rtype, [name cy$symbol]);
2863             }
2864         if (NSMutableArray *entry = [[Bridge_ objectAtIndex:2] objectForKey:name])
2865             switch ([[entry objectAtIndex:0] intValue]) {
2866                 // XXX: implement case 0
2867                 case 1:
2868                     return CYMakeType(context, CYPoolCString(pool, [entry objectAtIndex:1]));
2869             }
2870         return NULL;
2871     } CYCatch
2872 }
2873
2874 static bool stret(ffi_type *ffi_type) {
2875     return ffi_type->type == FFI_TYPE_STRUCT && (
2876         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
2877         struct_forward_array[ffi_type->size] != 0
2878     );
2879 }
2880
2881 extern "C" {
2882     int *_NSGetArgc(void);
2883     char ***_NSGetArgv(void);
2884 }
2885
2886 static JSValueRef System_print(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2887     CYTry {
2888         if (count == 0)
2889             NSLog(@"");
2890         else
2891             NSLog(@"%s", CYCastCString(context, arguments[0]));
2892         return CYJSUndefined(context);
2893     } CYCatch
2894 }
2895
2896 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception) {
2897     const char *type;
2898
2899     Class _class(object_getClass(self));
2900     if (Method method = class_getInstanceMethod(_class, _cmd))
2901         type = method_getTypeEncoding(method);
2902     else {
2903         CYTry {
2904             CYPoolTry {
2905                 NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
2906                 if (method == nil)
2907                     @throw [NSException exceptionWithName:NSInvalidArgumentException reason:[NSString stringWithFormat:@"unrecognized selector %s sent to object %p", sel_getName(_cmd), self] userInfo:nil];
2908                 type = CYPoolCString(pool, [method _typeString]);
2909             } CYPoolCatch(NULL)
2910         } CYCatch
2911     }
2912
2913     void *setup[2];
2914     setup[0] = &self;
2915     setup[1] = &_cmd;
2916
2917     sig::Signature signature;
2918     sig::Parse(pool, &signature, type, &Structor_);
2919
2920     ffi_cif cif;
2921     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2922
2923     void (*function)() = stret(cif.rtype) ? reinterpret_cast<void (*)()>(&objc_msgSend_stret) : reinterpret_cast<void (*)()>(&objc_msgSend);
2924     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, exception, &signature, &cif, function);
2925 }
2926
2927 static size_t Nonce_(0);
2928
2929 static JSValueRef $cyq(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2930     char name[16];
2931     sprintf(name, "%s%zu", CYCastCString(context, arguments[0]), Nonce_++);
2932     return CYCastJSValue(context, name);
2933 }
2934
2935 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2936     CYPool pool;
2937
2938     bool uninitialized;
2939
2940     id self;
2941     SEL _cmd;
2942
2943     CYTry {
2944         if (count < 2)
2945             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"too few arguments to objc_msgSend" userInfo:nil];
2946
2947         if (JSValueIsObjectOfClass(context, arguments[0], Instance_)) {
2948             Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2949             self = internal->GetValue();
2950             uninitialized = internal->IsUninitialized();
2951             if (uninitialized)
2952                 internal->value_ = nil;
2953         } else {
2954             self = CYCastNSObject(pool, context, arguments[0]);
2955             uninitialized = false;
2956         }
2957
2958         if (self == nil)
2959             return CYJSNull(context);
2960
2961         _cmd = CYCastSEL(context, arguments[1]);
2962     } CYCatch
2963
2964     return CYSendMessage(pool, context, self, _cmd, count - 2, arguments + 2, uninitialized, exception);
2965 }
2966
2967 /* Hook: objc_registerClassPair {{{ */
2968 // XXX: replace this with associated objects
2969
2970 MSHook(void, CYDealloc, id self, SEL sel) {
2971     CYInternal *internal;
2972     object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal));
2973     if (internal != NULL)
2974         delete internal;
2975     _CYDealloc(self, sel);
2976 }
2977
2978 MSHook(void, objc_registerClassPair, Class _class) {
2979     Class super(class_getSuperclass(_class));
2980     if (super == NULL || class_getInstanceVariable(super, "cy$internal_") == NULL) {
2981         class_addIvar(_class, "cy$internal_", sizeof(CYInternal *), log2(sizeof(CYInternal *)), "^{CYInternal}");
2982         MSHookMessage(_class, @selector(dealloc), MSHake(CYDealloc));
2983     }
2984
2985     _objc_registerClassPair(_class);
2986 }
2987
2988 static JSValueRef objc_registerClassPair_(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2989     CYTry {
2990         if (count != 1)
2991             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to objc_registerClassPair" userInfo:nil];
2992         CYPool pool;
2993         Class _class(CYCastNSObject(pool, context, arguments[0]));
2994         $objc_registerClassPair(_class);
2995         return CYJSUndefined(context);
2996     } CYCatch
2997 }
2998 /* }}} */
2999
3000 static JSValueRef Cycript_gc_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3001     JSGarbageCollect(context);
3002     return CYJSUndefined(context);
3003 }
3004
3005 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3006     JSValueRef setup[count + 2];
3007     setup[0] = _this;
3008     setup[1] = object;
3009     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
3010     return $objc_msgSend(context, NULL, NULL, count + 2, setup, exception);
3011 }
3012
3013 static JSValueRef Message_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3014     CYPool pool;
3015     Message_privateData *internal(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate(object)));
3016
3017     // XXX: handle Instance::Uninitialized?
3018     id self(CYCastNSObject(pool, context, _this));
3019
3020     void *setup[2];
3021     setup[0] = &self;
3022     setup[1] = &internal->sel_;
3023
3024     return CYCallFunction(pool, context, 2, setup, count, arguments, false, exception, &internal->signature_, &internal->cif_, internal->GetValue());
3025 }
3026
3027 static JSValueRef Functor_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3028     CYPool pool;
3029     Functor_privateData *internal(reinterpret_cast<Functor_privateData *>(JSObjectGetPrivate(object)));
3030     return CYCallFunction(pool, context, 0, NULL, count, arguments, false, exception, &internal->signature_, &internal->cif_, internal->GetValue());
3031 }
3032
3033 static JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3034     CYTry {
3035         if (count != 1)
3036             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Selector constructor" userInfo:nil];
3037         const char *name(CYCastCString(context, arguments[0]));
3038         return CYMakeSelector(context, sel_registerName(name));
3039     } CYCatch
3040 }
3041
3042 static JSObjectRef Pointer_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3043     CYTry {
3044         if (count != 2)
3045             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Functor constructor" userInfo:nil];
3046
3047         void *value(CYCastPointer<void *>(context, arguments[0]));
3048         const char *type(CYCastCString(context, arguments[1]));
3049
3050         CYPool pool;
3051
3052         sig::Signature signature;
3053         sig::Parse(pool, &signature, type, &Structor_);
3054
3055         return CYMakePointer(context, value, signature.elements[0].type, NULL, NULL);
3056     } CYCatch
3057 }
3058
3059 static JSObjectRef Type_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3060     CYTry {
3061         if (count != 1)
3062             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Type constructor" userInfo:nil];
3063         const char *type(CYCastCString(context, arguments[0]));
3064         return CYMakeType(context, type);
3065     } CYCatch
3066 }
3067
3068 static JSValueRef Type_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
3069     Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(object)));
3070
3071     CYTry {
3072         sig::Type type;
3073
3074         if (JSStringIsEqualToUTF8CString(property, "$cyi")) {
3075             type.primitive = sig::pointer_P;
3076             type.data.data.size = 0;
3077         } else {
3078             size_t index(CYGetIndex(NULL, property));
3079             if (index == _not(size_t))
3080                 return NULL;
3081             type.primitive = sig::array_P;
3082             type.data.data.size = index;
3083         }
3084
3085         type.name = NULL;
3086         type.flags = 0;
3087
3088         type.data.data.type = internal->type_;
3089
3090         return CYMakeType(context, &type);
3091     } CYCatch
3092 }
3093
3094 static JSValueRef Type_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3095     Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(object)));
3096
3097     CYTry {
3098         if (count != 1)
3099             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to type cast function" userInfo:nil];
3100         sig::Type *type(internal->type_);
3101         ffi_type *ffi(internal->GetFFI());
3102         // XXX: alignment?
3103         uint8_t value[ffi->size];
3104         CYPool pool;
3105         CYPoolFFI(pool, context, type, ffi, value, arguments[0]);
3106         return CYFromFFI(context, type, ffi, value);
3107     } CYCatch
3108 }
3109
3110 static JSObjectRef Type_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3111     CYTry {
3112         if (count != 0)
3113             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to type cast function" userInfo:nil];
3114         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(object)));
3115
3116         sig::Type *type(internal->type_);
3117         size_t size;
3118
3119         if (type->primitive != sig::array_P)
3120             size = 0;
3121         else {
3122             size = type->data.data.size;
3123             type = type->data.data.type;
3124         }
3125
3126         void *value(malloc(internal->GetFFI()->size));
3127         return CYMakePointer(context, value, type, NULL, NULL);
3128     } CYCatch
3129 }
3130
3131 static JSObjectRef Instance_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3132     CYTry {
3133         if (count > 1)
3134             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Instance constructor" userInfo:nil];
3135         id self(count == 0 ? nil : CYCastPointer<id>(context, arguments[0]));
3136         return Instance::Make(context, self);
3137     } CYCatch
3138 }
3139
3140 static JSObjectRef Functor_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3141     CYTry {
3142         if (count != 2)
3143             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Functor constructor" userInfo:nil];
3144         const char *type(CYCastCString(context, arguments[1]));
3145         return CYMakeFunctor(context, arguments[0], type);
3146     } CYCatch
3147 }
3148
3149 static JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
3150     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
3151     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
3152 }
3153
3154 static JSValueRef CYValue_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3155     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
3156     Type_privateData *typical(internal->GetType());
3157
3158     sig::Type *type;
3159     ffi_type *ffi;
3160
3161     if (typical == NULL) {
3162         type = NULL;
3163         ffi = NULL;
3164     } else {
3165         type = typical->type_;
3166         ffi = typical->ffi_;
3167     }
3168
3169     return CYMakePointer(context, &internal->value_, type, ffi, object);
3170 }
3171
3172 static JSValueRef CYValue_callAsFunction_valueOf(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3173     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
3174
3175     CYTry {
3176         return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
3177     } CYCatch
3178 }
3179
3180 static JSValueRef CYValue_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3181     return CYValue_callAsFunction_valueOf(context, object, _this, count, arguments, exception);
3182 }
3183
3184 static JSValueRef CYValue_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3185     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
3186     char string[32];
3187     sprintf(string, "%p", internal->value_);
3188
3189     CYTry {
3190         return CYCastJSValue(context, string);
3191     } CYCatch
3192 }
3193
3194 static JSValueRef Instance_getProperty_constructor(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
3195     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
3196     return Instance::Make(context, object_getClass(internal->GetValue()));
3197 }
3198
3199 static JSValueRef Instance_getProperty_protocol(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
3200     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
3201     id self(internal->GetValue());
3202     if (!CYIsClass(self))
3203         return CYJSUndefined(context);
3204     CYTry {
3205         return CYGetClassPrototype(context, self);
3206     } CYCatch
3207 }
3208
3209 static JSValueRef Instance_getProperty_messages(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
3210     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
3211     id self(internal->GetValue());
3212     if (class_getInstanceMethod(object_getClass(self), @selector(alloc)) == NULL)
3213         return CYJSUndefined(context);
3214     return Messages::Make(context, self);
3215 }
3216
3217 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3218     if (!JSValueIsObjectOfClass(context, _this, Instance_))
3219         return NULL;
3220
3221     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
3222
3223     CYTry {
3224         CYPoolTry {
3225             return CYCastJSValue(context, CYJSString(CYPoolNSCYON(NULL, internal->GetValue())));
3226         } CYPoolCatch(NULL)
3227     } CYCatch
3228 }
3229
3230 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3231     if (!JSValueIsObjectOfClass(context, _this, Instance_))
3232         return NULL;
3233
3234     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
3235
3236     CYTry {
3237         CYPoolTry {
3238             NSString *key(count == 0 ? nil : CYCastNSString(NULL, CYJSString(context, arguments[0])));
3239             // XXX: check for support of cy$toJSON?
3240             return CYCastJSValue(context, CYJSString([internal->GetValue() cy$toJSON:key]));
3241         } CYPoolCatch(NULL)
3242     } CYCatch
3243 }
3244
3245 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3246     if (!JSValueIsObjectOfClass(context, _this, Instance_))
3247         return NULL;
3248
3249     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
3250
3251     CYTry {
3252         CYPoolTry {
3253             return CYCastJSValue(context, CYJSString([internal->GetValue() description]));
3254         } CYPoolCatch(NULL)
3255     } CYCatch
3256 }
3257
3258 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3259     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
3260
3261     CYTry {
3262         return CYCastJSValue(context, sel_getName(internal->GetValue()));
3263     } CYCatch
3264 }
3265
3266 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3267     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
3268 }
3269
3270 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3271     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
3272     const char *name(sel_getName(internal->GetValue()));
3273
3274     CYTry {
3275         CYPoolTry {
3276             return CYCastJSValue(context, CYJSString([NSString stringWithFormat:@"@selector(%s)", name]));
3277         } CYPoolCatch(NULL)
3278     } CYCatch
3279 }
3280
3281 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3282     CYTry {
3283         if (count != 1)
3284             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Selector.type" userInfo:nil];
3285         CYPool pool;
3286         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
3287         Class _class(CYCastNSObject(pool, context, arguments[0]));
3288         SEL sel(internal->GetValue());
3289         Method method(class_getInstanceMethod(_class, sel));
3290         const char *type(CYPoolTypeEncoding(pool, _class, sel, method));
3291         return type == NULL ? CYJSNull(context) : CYCastJSValue(context, CYJSString(type));
3292     } CYCatch
3293 }
3294
3295 static JSValueRef Type_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3296     CYTry {
3297         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(_this)));
3298         CYPool pool;
3299         const char *type(sig::Unparse(pool, internal->type_));
3300         CYPoolTry {
3301             return CYCastJSValue(context, CYJSString(type));
3302         } CYPoolCatch(NULL)
3303     } CYCatch
3304 }
3305
3306 static JSValueRef Type_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3307     CYTry {
3308         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(_this)));
3309         CYPool pool;
3310         const char *type(sig::Unparse(pool, internal->type_));
3311         CYPoolTry {
3312             return CYCastJSValue(context, CYJSString([NSString stringWithFormat:@"new Type(%@)", [[NSString stringWithUTF8String:type] cy$toCYON]]));
3313         } CYPoolCatch(NULL)
3314     } CYCatch
3315 }
3316
3317 static JSValueRef Type_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
3318     return Type_callAsFunction_toString(context, object, _this, count, arguments, exception);
3319 }
3320
3321 static JSStaticValue CYValue_staticValues[2] = {
3322     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
3323     {NULL, NULL, NULL, 0}
3324 };
3325
3326 static JSStaticValue Pointer_staticValues[2] = {
3327     {"$cyi", &Pointer_getProperty_$cyi, &Pointer_setProperty_$cyi, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3328     {NULL, NULL, NULL, 0}
3329 };
3330
3331 static JSStaticFunction Pointer_staticFunctions[4] = {
3332     {"toCYON", &CYValue_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3333     {"toJSON", &CYValue_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3334     {"valueOf", &CYValue_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3335     {NULL, NULL, 0}
3336 };
3337
3338 static JSStaticFunction Struct_staticFunctions[2] = {
3339     {"$cya", &Struct_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3340     {NULL, NULL, 0}
3341 };
3342
3343 static JSStaticFunction Functor_staticFunctions[4] = {
3344     {"toCYON", &CYValue_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3345     {"toJSON", &CYValue_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3346     {"valueOf", &CYValue_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3347     {NULL, NULL, 0}
3348 };
3349
3350 static JSStaticValue Instance_staticValues[5] = {
3351     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3352     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3353     {"prototype", &Instance_getProperty_protocol, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3354     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3355     {NULL, NULL, NULL, 0}
3356 };
3357
3358 static JSStaticFunction Instance_staticFunctions[5] = {
3359     {"$cya", &CYValue_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3360     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3361     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3362     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3363     {NULL, NULL, 0}
3364 };
3365
3366 static JSStaticFunction Internal_staticFunctions[2] = {
3367     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3368     {NULL, NULL, 0}
3369 };
3370
3371 static JSStaticFunction Selector_staticFunctions[5] = {
3372     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3373     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3374     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3375     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3376     {NULL, NULL, 0}
3377 };
3378
3379 static JSStaticFunction Type_staticFunctions[4] = {
3380     {"toCYON", &Type_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3381     {"toJSON", &Type_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3382     {"toString", &Type_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
3383     {NULL, NULL, 0}
3384 };
3385
3386 void CYSetArgs(int argc, const char *argv[]) {
3387     JSContextRef context(CYGetJSContext());
3388     JSValueRef args[argc];
3389     for (int i(0); i != argc; ++i)
3390         args[i] = CYCastJSValue(context, argv[i]);
3391     JSValueRef exception(NULL);
3392     JSObjectRef array(JSObjectMakeArray(context, argc, args, &exception));
3393     CYThrow(context, exception);
3394     CYSetProperty(context, System_, CYJSString("args"), array);
3395 }
3396
3397 JSObjectRef CYGetGlobalObject(JSContextRef context) {
3398     return JSContextGetGlobalObject(context);
3399 }
3400
3401 const char *CYExecute(apr_pool_t *pool, const char *code) { _pooled
3402     JSContextRef context(CYGetJSContext());
3403     JSValueRef exception(NULL), result;
3404
3405     try {
3406         result = JSEvaluateScript(context, CYJSString(code), NULL, NULL, 0, &exception);
3407     } catch (const char *error) {
3408         return error;
3409     }
3410
3411     if (exception != NULL) { error:
3412         result = exception;
3413         exception = NULL;
3414     }
3415
3416     if (JSValueIsUndefined(context, result))
3417         return NULL;
3418
3419     const char *json;
3420
3421     try {
3422         json = CYPoolCCYON(pool, context, result, &exception);
3423     } catch (const char *error) {
3424         return error;
3425     }
3426
3427     if (exception != NULL)
3428         goto error;
3429
3430     CYSetProperty(context, CYGetGlobalObject(context), Result_, result);
3431     return json;
3432 }
3433
3434 static apr_pool_t *Pool_;
3435
3436 struct CYExecute_ {
3437     apr_pool_t *pool_;
3438     const char * volatile data_;
3439 };
3440
3441 // XXX: this is "tre lame"
3442 @interface CYClient_ : NSObject {
3443 }
3444
3445 - (void) execute:(NSValue *)value;
3446
3447 @end
3448
3449 @implementation CYClient_
3450
3451 - (void) execute:(NSValue *)value {
3452     CYExecute_ *execute(reinterpret_cast<CYExecute_ *>([value pointerValue]));
3453     const char *data(execute->data_);
3454     execute->data_ = NULL;
3455     execute->data_ = CYExecute(execute->pool_, data);
3456 }
3457
3458 @end
3459
3460 struct CYClient :
3461     CYData
3462 {
3463     int socket_;
3464     apr_thread_t *thread_;
3465
3466     CYClient(int socket) :
3467         socket_(socket)
3468     {
3469     }
3470
3471     ~CYClient() {
3472         _syscall(close(socket_));
3473     }
3474
3475     void Handle() { _pooled
3476         CYClient_ *client = [[[CYClient_ alloc] init] autorelease];
3477
3478         for (;;) {
3479             size_t size;
3480             if (!CYRecvAll(socket_, &size, sizeof(size)))
3481                 return;
3482
3483             CYPool pool;
3484             char *data(new(pool) char[size + 1]);
3485             if (!CYRecvAll(socket_, data, size))
3486                 return;
3487             data[size] = '\0';
3488
3489             CYDriver driver("");
3490             cy::parser parser(driver);
3491
3492             driver.data_ = data;
3493             driver.size_ = size;
3494
3495             const char *json;
3496             if (parser.parse() != 0 || !driver.errors_.empty()) {
3497                 json = NULL;
3498                 size = _not(size_t);
3499             } else {
3500                 CYContext context(driver.pool_);
3501                 driver.program_->Replace(context);
3502                 std::ostringstream str;
3503                 CYOutput out(str);
3504                 out << *driver.program_;
3505                 std::string code(str.str());
3506                 CYExecute_ execute = {pool, code.c_str()};
3507                 [client performSelectorOnMainThread:@selector(execute:) withObject:[NSValue valueWithPointer:&execute] waitUntilDone:YES];
3508                 json = execute.data_;
3509                 size = json == NULL ? _not(size_t) : strlen(json);
3510             }
3511
3512             if (!CYSendAll(socket_, &size, sizeof(size)))
3513                 return;
3514             if (json != NULL)
3515                 if (!CYSendAll(socket_, json, size))
3516                     return;
3517         }
3518     }
3519 };
3520
3521 static void * APR_THREAD_FUNC OnClient(apr_thread_t *thread, void *data) {
3522     CYClient *client(reinterpret_cast<CYClient *>(data));
3523     client->Handle();
3524     delete client;
3525     return NULL;
3526 }
3527
3528 extern "C" void CYHandleClient(apr_pool_t *pool, int socket) {
3529     CYClient *client(new(pool) CYClient(socket));
3530     apr_threadattr_t *attr;
3531     _aprcall(apr_threadattr_create(&attr, client->pool_));
3532     _aprcall(apr_thread_create(&client->thread_, attr, &OnClient, client, client->pool_));
3533 }
3534
3535 MSInitialize { _pooled
3536     _aprcall(apr_initialize());
3537     _aprcall(apr_pool_create(&Pool_, NULL));
3538
3539     Type_privateData::Object = new(Pool_) Type_privateData(Pool_, "@");
3540     Type_privateData::Selector = new(Pool_) Type_privateData(Pool_, ":");
3541
3542     Bridge_ = [[NSMutableArray arrayWithContentsOfFile:@"/usr/lib/libcycript.plist"] retain];
3543
3544     NSArray_ = objc_getClass("NSArray");
3545     NSCFBoolean_ = objc_getClass("NSCFBoolean");
3546     NSCFType_ = objc_getClass("NSCFType");
3547     NSDictionary_ = objc_getClass("NSDictonary");
3548     NSMessageBuilder_ = objc_getClass("NSMessageBuilder");
3549     NSZombie_ = objc_getClass("_NSZombie_");
3550     Object_ = objc_getClass("Object");
3551 }
3552
3553 JSGlobalContextRef CYGetJSContext() {
3554     if (Context_ == NULL) {
3555         JSClassDefinition definition;
3556
3557         definition = kJSClassDefinitionEmpty;
3558         definition.className = "Functor";
3559         definition.staticFunctions = Functor_staticFunctions;
3560         definition.callAsFunction = &Functor_callAsFunction;
3561         definition.finalize = &Finalize;
3562         Functor_ = JSClassCreate(&definition);
3563
3564         definition = kJSClassDefinitionEmpty;
3565         definition.className = "Instance";
3566         definition.staticValues = Instance_staticValues;
3567         definition.staticFunctions = Instance_staticFunctions;
3568         definition.hasProperty = &Instance_hasProperty;
3569         definition.getProperty = &Instance_getProperty;
3570         definition.setProperty = &Instance_setProperty;
3571         definition.deleteProperty = &Instance_deleteProperty;
3572         definition.getPropertyNames = &Instance_getPropertyNames;
3573         definition.callAsConstructor = &Instance_callAsConstructor;
3574         definition.hasInstance = &Instance_hasInstance;
3575         definition.finalize = &Finalize;
3576         Instance_ = JSClassCreate(&definition);
3577
3578         definition = kJSClassDefinitionEmpty;
3579         definition.className = "Internal";
3580         definition.staticFunctions = Internal_staticFunctions;
3581         definition.hasProperty = &Internal_hasProperty;
3582         definition.getProperty = &Internal_getProperty;
3583         definition.setProperty = &Internal_setProperty;
3584         definition.getPropertyNames = &Internal_getPropertyNames;
3585         definition.finalize = &Finalize;
3586         Internal_ = JSClassCreate(&definition);
3587
3588         definition = kJSClassDefinitionEmpty;
3589         definition.className = "Message";
3590         definition.staticFunctions = Functor_staticFunctions;
3591         definition.callAsFunction = &Message_callAsFunction;
3592         definition.finalize = &Finalize;
3593         Message_ = JSClassCreate(&definition);
3594
3595         definition = kJSClassDefinitionEmpty;
3596         definition.className = "Messages";
3597         definition.hasProperty = &Messages_hasProperty;
3598         definition.getProperty = &Messages_getProperty;
3599         definition.setProperty = &Messages_setProperty;
3600 #if !__OBJC2__
3601         definition.deleteProperty = &Messages_deleteProperty;
3602 #endif
3603         definition.getPropertyNames = &Messages_getPropertyNames;
3604         definition.finalize = &Finalize;
3605         Messages_ = JSClassCreate(&definition);
3606
3607         definition = kJSClassDefinitionEmpty;
3608         definition.className = "NSArrayPrototype";
3609         //definition.hasProperty = &NSArrayPrototype_hasProperty;
3610         //definition.getProperty = &NSArrayPrototype_getProperty;
3611         //definition.setProperty = &NSArrayPrototype_setProperty;
3612         //definition.deleteProperty = &NSArrayPrototype_deleteProperty;
3613         //definition.getPropertyNames = &NSArrayPrototype_getPropertyNames;
3614         NSArrayPrototype_ = JSClassCreate(&definition);
3615
3616         definition = kJSClassDefinitionEmpty;
3617         definition.className = "Pointer";
3618         definition.staticValues = Pointer_staticValues;
3619         definition.staticFunctions = Pointer_staticFunctions;
3620         definition.getProperty = &Pointer_getProperty;
3621         definition.setProperty = &Pointer_setProperty;
3622         definition.finalize = &Finalize;
3623         Pointer_ = JSClassCreate(&definition);
3624
3625         definition = kJSClassDefinitionEmpty;
3626         definition.className = "Selector";
3627         definition.staticValues = CYValue_staticValues;
3628         definition.staticFunctions = Selector_staticFunctions;
3629         definition.callAsFunction = &Selector_callAsFunction;
3630         definition.finalize = &Finalize;
3631         Selector_ = JSClassCreate(&definition);
3632
3633         definition = kJSClassDefinitionEmpty;
3634         definition.className = "Struct";
3635         definition.staticFunctions = Struct_staticFunctions;
3636         definition.getProperty = &Struct_getProperty;
3637         definition.setProperty = &Struct_setProperty;
3638         definition.getPropertyNames = &Struct_getPropertyNames;
3639         definition.finalize = &Finalize;
3640         Struct_ = JSClassCreate(&definition);
3641
3642         definition = kJSClassDefinitionEmpty;
3643         definition.className = "Type";
3644         definition.staticFunctions = Type_staticFunctions;
3645         definition.getProperty = &Type_getProperty;
3646         definition.callAsFunction = &Type_callAsFunction;
3647         definition.callAsConstructor = &Type_callAsConstructor;
3648         definition.finalize = &Finalize;
3649         Type_privateData::Class_ = JSClassCreate(&definition);
3650
3651         definition = kJSClassDefinitionEmpty;
3652         definition.className = "Runtime";
3653         definition.getProperty = &Runtime_getProperty;
3654         Runtime_ = JSClassCreate(&definition);
3655
3656         definition = kJSClassDefinitionEmpty;
3657         definition.className = "ObjectiveC::Classes";
3658         definition.getProperty = &ObjectiveC_Classes_getProperty;
3659         definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
3660         ObjectiveC_Classes_ = JSClassCreate(&definition);
3661
3662         definition = kJSClassDefinitionEmpty;
3663         definition.className = "ObjectiveC::Images";
3664         definition.getProperty = &ObjectiveC_Images_getProperty;
3665         definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
3666         ObjectiveC_Images_ = JSClassCreate(&definition);
3667
3668         definition = kJSClassDefinitionEmpty;
3669         definition.className = "ObjectiveC::Image::Classes";
3670         definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
3671         definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
3672         ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
3673
3674         definition = kJSClassDefinitionEmpty;
3675         definition.className = "ObjectiveC::Protocols";
3676         definition.getProperty = &ObjectiveC_Protocols_getProperty;
3677         definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
3678         ObjectiveC_Protocols_ = JSClassCreate(&definition);
3679
3680         definition = kJSClassDefinitionEmpty;
3681         //definition.getProperty = &Global_getProperty;
3682         JSClassRef Global(JSClassCreate(&definition));
3683
3684         JSGlobalContextRef context(JSGlobalContextCreate(Global));
3685         Context_ = context;
3686
3687         JSObjectRef global(CYGetGlobalObject(context));
3688
3689         JSObjectSetPrototype(context, global, JSObjectMake(context, Runtime_, NULL));
3690         ObjectiveC_ = JSObjectMake(context, NULL, NULL);
3691         CYSetProperty(context, global, CYJSString("ObjectiveC"), ObjectiveC_);
3692
3693         CYSetProperty(context, ObjectiveC_, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Classes_, NULL));
3694         CYSetProperty(context, ObjectiveC_, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
3695         CYSetProperty(context, ObjectiveC_, CYJSString("protocols"), JSObjectMake(context, ObjectiveC_Protocols_, NULL));
3696
3697         Array_ = CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Array")));
3698         Function_ = CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Function")));
3699         String_ = CYCastJSObject(context, CYGetProperty(context, global, CYJSString("String")));
3700
3701         length_ = JSStringCreateWithUTF8CString("length");
3702         message_ = JSStringCreateWithUTF8CString("message");
3703         name_ = JSStringCreateWithUTF8CString("name");
3704         prototype_ = JSStringCreateWithUTF8CString("prototype");
3705         toCYON_ = JSStringCreateWithUTF8CString("toCYON");
3706         toJSON_ = JSStringCreateWithUTF8CString("toJSON");
3707
3708         JSObjectRef Object(CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Object"))));
3709         Object_prototype_ = CYCastJSObject(context, CYGetProperty(context, Object, prototype_));
3710
3711         Array_prototype_ = CYCastJSObject(context, CYGetProperty(context, Array_, prototype_));
3712         Array_pop_ = CYCastJSObject(context, CYGetProperty(context, Array_prototype_, CYJSString("pop")));
3713         Array_push_ = CYCastJSObject(context, CYGetProperty(context, Array_prototype_, CYJSString("push")));
3714         Array_splice_ = CYCastJSObject(context, CYGetProperty(context, Array_prototype_, CYJSString("splice")));
3715
3716         JSObjectRef Functor(JSObjectMakeConstructor(context, Functor_, &Functor_new));
3717         JSObjectRef Instance(JSObjectMakeConstructor(context, Instance_, &Instance_new));
3718         JSObjectRef Message(JSObjectMakeConstructor(context, Message_, NULL));
3719         JSObjectRef Selector(JSObjectMakeConstructor(context, Selector_, &Selector_new));
3720
3721         Instance_prototype_ = (JSObjectRef) CYGetProperty(context, Instance, prototype_);
3722
3723         JSValueRef function(CYGetProperty(context, Function_, prototype_));
3724         JSObjectSetPrototype(context, (JSObjectRef) CYGetProperty(context, Message, prototype_), function);
3725         JSObjectSetPrototype(context, (JSObjectRef) CYGetProperty(context, Functor, prototype_), function);
3726         JSObjectSetPrototype(context, (JSObjectRef) CYGetProperty(context, Selector, prototype_), function);
3727
3728         CYSetProperty(context, global, CYJSString("Functor"), Functor);
3729         CYSetProperty(context, global, CYJSString("Instance"), Instance);
3730         CYSetProperty(context, global, CYJSString("Pointer"), JSObjectMakeConstructor(context, Pointer_, &Pointer_new));
3731         CYSetProperty(context, global, CYJSString("Selector"), Selector);
3732         CYSetProperty(context, global, CYJSString("Type"), JSObjectMakeConstructor(context, Type_privateData::Class_, &Type_new));
3733
3734         MSHookFunction(&objc_registerClassPair, MSHake(objc_registerClassPair));
3735
3736 #ifdef __APPLE__
3737         class_addMethod(NSCFType_, @selector(cy$toJSON:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON), "@12@0:4@8");
3738 #endif
3739
3740         JSObjectRef cycript(JSObjectMake(context, NULL, NULL));
3741         CYSetProperty(context, global, CYJSString("Cycript"), cycript);
3742         CYSetProperty(context, cycript, CYJSString("gc"), JSObjectMakeFunctionWithCallback(context, CYJSString("gc"), &Cycript_gc_callAsFunction));
3743
3744         CYSetProperty(context, global, CYJSString("objc_registerClassPair"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_registerClassPair"), &objc_registerClassPair_));
3745         CYSetProperty(context, global, CYJSString("objc_msgSend"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_msgSend"), &$objc_msgSend));
3746         CYSetProperty(context, global, CYJSString("$cyq"), JSObjectMakeFunctionWithCallback(context, CYJSString("$cyq"), &$cyq));
3747
3748         System_ = JSObjectMake(context, NULL, NULL);
3749         CYSetProperty(context, global, CYJSString("system"), System_);
3750         CYSetProperty(context, System_, CYJSString("args"), CYJSNull(context));
3751         //CYSetProperty(context, System_, CYJSString("global"), global);
3752
3753         CYSetProperty(context, System_, CYJSString("print"), JSObjectMakeFunctionWithCallback(context, CYJSString("print"), &System_print));
3754
3755         Result_ = JSStringCreateWithUTF8CString("_");
3756
3757         JSValueProtect(context, Array_);
3758         JSValueProtect(context, Function_);
3759         JSValueProtect(context, String_);
3760
3761         JSValueProtect(context, Instance_prototype_);
3762         JSValueProtect(context, Object_prototype_);
3763
3764         JSValueProtect(context, Array_prototype_);
3765         JSValueProtect(context, Array_pop_);
3766         JSValueProtect(context, Array_push_);
3767         JSValueProtect(context, Array_splice_);
3768     }
3769
3770     return Context_;
3771 }