Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 typedef struct {
  43     bool newline_;
  44
  45     union {
  46         bool bool_;
  47
  48         CYDriver::Condition condition_;
  49
  50         CYArgument *argument_;
  51         CYAssignment *assignment_;
  52         CYBoolean *boolean_;
  53         CYClause *clause_;
  54         cy::Syntax::Catch *catch_;
  55         CYComment *comment_;
  56         CYComprehension *comprehension_;
  57         CYCompound *compound_;
  58         CYDeclaration *declaration_;
  59         CYDeclarations *declarations_;
  60         CYElement *element_;
  61         CYExpression *expression_;
  62         CYFalse *false_;
  63         CYFinally *finally_;
  64         CYForInitialiser *for_;
  65         CYForInInitialiser *forin_;
  66         CYFunctionParameter *functionParameter_;
  67         CYIdentifier *identifier_;
  68         CYInfix *infix_;
  69         CYLiteral *literal_;
  70         CYMember *member_;
  71         CYNull *null_;
  72         CYNumber *number_;
  73         CYProgram *program_;
  74         CYProperty *property_;
  75         CYPropertyName *propertyName_;
  76         CYRubyProc *rubyProc_;
  77         CYStatement *statement_;
  78         CYString *string_;
  79         CYThis *this_;
  80         CYTrue *true_;
  81         CYWord *word_;
  82
  83 @begin ObjectiveC
  84         CYClassName *className_;
  85         CYField *field_;
  86         CYMessage *message_;
  87         CYMessageParameter *messageParameter_;
  88         CYProtocol *protocol_;
  89         CYSelectorPart *selector_;
  90 @end
  91
  92 @begin E4X
  93         CYAttribute *attribute_;
  94         CYPropertyIdentifier *propertyIdentifier_;
  95         CYSelector *selector_;
  96 @end
  97     };
  98 } YYSTYPE;
  99
 100 #define YYSTYPE YYSTYPE
 101 @if Bison24 }
 102
 103 @if Bison24 %code provides {
 104 int cylex(YYSTYPE *, cy::location *, void *);
 105 @if Bison24 }
 106
 107 @if Bison23 %}
 108
 109 %name-prefix="cy"
 110
 111 @if Bison23 %skeleton "lalr1.cc"
 112 @if Bison24 %language "C++"
 113
 114 %initial-action {
 115     @$.begin.filename = @$.end.filename = &driver.filename_;
 116 };
 117
 118 %locations
 119 %defines
 120
 121 //%glr-parser
 122 //%expect 1
 123
 124 %error-verbose
 125
 126 %parse-param { CYDriver &driver }
 127 %lex-param { void *cyscanner }
 128
 129 @begin E4X
 130 %token XMLCDATA
 131 %token XMLComment
 132 %token XMLPI
 133
 134 %token XMLAttributeValue
 135 %token XMLName
 136 %token XMLTagCharacters
 137 %token XMLText
 138 %token XMLWhitespace
 139 @end
 140
 141 @begin E4X
 142 %token LeftRight "<>"
 143 %token LeftSlashRight "</>"
 144
 145 %token SlashRight "/>"
 146 %token LeftSlash "</"
 147
 148 %token ColonColon "::"
 149 %token PeriodPeriod ".."
 150 @end
 151
 152 @begin E4X ObjectiveC
 153 %token At "@"
 154 @end
 155
 156 %token Ampersand "&"
 157 %token AmpersandAmpersand "&&"
 158 %token AmpersandEqual "&="
 159 %token Carrot "^"
 160 %token CarrotEqual "^="
 161 %token Equal "="
 162 %token EqualEqual "=="
 163 %token EqualEqualEqual "==="
 164 %token Exclamation "!"
 165 %token ExclamationEqual "!="
 166 %token ExclamationEqualEqual "!=="
 167 %token Hyphen "-"
 168 %token HyphenEqual "-="
 169 %token HyphenHyphen "--"
 170 %token HyphenHyphen_ "\n--"
 171 %token HyphenRight "->"
 172 %token Left "<"
 173 %token LeftEqual "<="
 174 %token LeftLeft "<<"
 175 %token LeftLeftEqual "<<="
 176 %token Percent "%"
 177 %token PercentEqual "%="
 178 %token Period "."
 179 %token PeriodPeriodPeriod "..."
 180 %token Pipe "|"
 181 %token PipeEqual "|="
 182 %token PipePipe "||"
 183 %token Plus "+"
 184 %token PlusEqual "+="
 185 %token PlusPlus "++"
 186 %token PlusPlus_ "\n++"
 187 %token Right ">"
 188 %token RightEqual ">="
 189 %token RightRight ">>"
 190 %token RightRightEqual ">>="
 191 %token RightRightRight ">>>"
 192 %token RightRightRightEqual ">>>="
 193 %token Slash "/"
 194 %token SlashEqual "/="
 195 %token Star "*"
 196 %token StarEqual "*="
 197 %token Tilde "~"
 198
 199 %token Colon ":"
 200 %token Comma ","
 201 %token Question "?"
 202 %token SemiColon ";"
 203 %token NewLine "\n"
 204
 205 %token <comment_> Comment
 206
 207 %token OpenParen "("
 208 %token CloseParen ")"
 209
 210 %token OpenBrace "{"
 211 %token OpenBrace_ "\n{"
 212 %token OpenBrace__ ";{"
 213 %token CloseBrace "}"
 214
 215 %token OpenBracket "["
 216 %token CloseBracket "]"
 217
 218 @begin Java
 219 %token AtClass "@class"
 220 @end
 221
 222 @begin ObjectiveC
 223 %token AtImplementation "@implementation"
 224 %token AtImplementation_ ";@implementation"
 225 %token AtImport "@import"
 226 %token AtEnd "@end"
 227 %token AtSelector "@selector"
 228 @end
 229
 230 %token <false_> False "false"
 231 %token <null_> Null "null"
 232 %token <true_> True "true"
 233
 234 // ES3/ES5/WIE/JSC Reserved
 235 %token <word_> Break "break"
 236 %token <word_> Case "case"
 237 %token <word_> Catch "catch"
 238 %token <word_> Continue "continue"
 239 %token <word_> Default "default"
 240 %token <word_> Delete "delete"
 241 %token <word_> Do "do"
 242 %token <word_> Else "else"
 243 %token <word_> Finally "finally"
 244 %token <word_> For "for"
 245 %token <word_> Function "function"
 246 %token <word_> Function_ ";function"
 247 %token <word_> If "if"
 248 %token <word_> In "in"
 249 %token <word_> In_ "!in"
 250 %token <word_> InstanceOf "instanceof"
 251 %token <word_> New "new"
 252 %token <word_> Return "return"
 253 %token <word_> Switch "switch"
 254 %token <this_> This "this"
 255 %token <word_> Throw "throw"
 256 %token <word_> Try "try"
 257 %token <word_> TypeOf "typeof"
 258 %token <word_> Var "var"
 259 %token <word_> Void "void"
 260 %token <word_> While "while"
 261 %token <word_> With "with"
 262
 263 // ES3/IE6 Future, ES5/JSC Reserved
 264 %token <word_> Debugger "debugger"
 265
 266 // ES3/ES5/IE6 Future, JSC Reserved
 267 %token <word_> Const "const"
 268
 269 // ES3/ES5/IE6/JSC Future
 270 %token <word_> Class "class"
 271 %token <word_> Enum "enum"
 272 %token <word_> Export "export"
 273 %token <word_> Extends "extends"
 274 %token <word_> Import "import"
 275 %token <word_> Super "super"
 276
 277 // ES3 Future, ES5 Strict Future
 278 %token <identifier_> Implements "implements"
 279 %token <identifier_> Interface "interface"
 280 %token <identifier_> Package "package"
 281 %token <identifier_> Private "private"
 282 %token <identifier_> Protected "protected"
 283 %token <identifier_> Public "public"
 284 %token <identifier_> Static "static"
 285
 286 // ES3 Future
 287 %token <identifier_> Abstract "abstract"
 288 %token <identifier_> Boolean "boolean"
 289 %token <identifier_> Byte "byte"
 290 %token <identifier_> Char "char"
 291 %token <identifier_> Double "double"
 292 %token <identifier_> Final "final"
 293 %token <identifier_> Float "float"
 294 %token <identifier_> Goto "goto"
 295 %token <identifier_> Int "int"
 296 %token <identifier_> Long "long"
 297 %token <identifier_> Native "native"
 298 %token <identifier_> Short "short"
 299 %token <identifier_> Synchronized "synchronized"
 300 %token <identifier_> Throws "throws"
 301 %token <identifier_> Transient "transient"
 302 %token <identifier_> Volatile "volatile"
 303
 304 // ES5 Strict
 305 %token <identifier_> Let "let"
 306 %token <identifier_> Yield "yield"
 307
 308 // Woah?!
 309 %token <identifier_> Each "each"
 310
 311 @begin E4X
 312 // E4X Conditional
 313 %token <identifier_> Namespace "namespace"
 314 %token <identifier_> XML "xml"
 315 @end
 316
 317 %token AutoComplete
 318
 319 %token <identifier_> Identifier_
 320 %token <number_> NumericLiteral
 321 %token <string_> StringLiteral
 322 %token <literal_> RegularExpressionLiteral
 323
 324 %type <expression_> AdditiveExpression
 325 %type <argument_> ArgumentList_
 326 %type <argument_> ArgumentList
 327 %type <argument_> ArgumentListOpt
 328 %type <argument_> Arguments
 329 %type <literal_> ArrayLiteral
 330 %type <expression_> AssignmentExpression
 331 %type <identifier_> BindingIdentifier
 332 %type <expression_> BitwiseANDExpression
 333 %type <statement_> Block_
 334 %type <statement_> Block
 335 %type <boolean_> BooleanLiteral
 336 %type <declaration_> BindingElement
 337 %type <expression_> BitwiseORExpression
 338 %type <expression_> BitwiseXORExpression
 339 %type <statement_> BreakStatement
 340 %type <statement_> BreakableStatement
 341 %type <expression_> CallExpression_
 342 %type <expression_> CallExpression
 343 %type <clause_> CaseBlock
 344 %type <clause_> CaseClause
 345 %type <clause_> CaseClausesOpt
 346 %type <catch_> CatchOpt
 347 %type <comprehension_> ComprehensionList
 348 %type <comprehension_> ComprehensionListOpt
 349 %type <expression_> ConditionalExpression
 350 %type <statement_> ContinueStatement
 351 %type <statement_> DebuggerStatement
 352 %type <statement_> Declaration__
 353 %type <statement_> Declaration_
 354 %type <statement_> Declaration
 355 %type <clause_> DefaultClause
 356 %type <statement_> DoWhileStatement
 357 %type <expression_> Element
 358 %type <expression_> ElementOpt
 359 %type <element_> ElementList
 360 %type <element_> ElementListOpt
 361 %type <statement_> ElseStatementOpt
 362 %type <statement_> EmptyStatement
 363 %type <expression_> EqualityExpression
 364 %type <compound_> Expression_
 365 %type <expression_> Expression
 366 %type <expression_> ExpressionOpt
 367 %type <statement_> ExpressionStatement
 368 %type <finally_> FinallyOpt
 369 %type <comprehension_> ForComprehension
 370 %type <statement_> ForStatement
 371 %type <for_> ForStatementInitialiser
 372 %type <statement_> ForInStatement
 373 %type <forin_> ForInStatementInitialiser
 374 %type <declaration_> FormalParameter
 375 %type <functionParameter_> FormalParameterList_
 376 %type <functionParameter_> FormalParameterList
 377 %type <functionParameter_> FormalParameterListOpt
 378 %type <statement_> FunctionBody
 379 %type <statement_> FunctionDeclaration
 380 %type <expression_> FunctionExpression
 381 %type <identifier_> Identifier
 382 %type <identifier_> IdentifierOpt
 383 %type <comprehension_> IfComprehension
 384 %type <statement_> IfStatement
 385 %type <expression_> Initialiser
 386 %type <expression_> InitialiserOpt
 387 %type <statement_> IterationStatement
 388 %type <statement_> LabelledStatement
 389 %type <expression_> LeftHandSideExpression
 390 %type <statement_> LetStatement
 391 %type <statement_> LexicalDeclaration
 392 %type <literal_> Literal
 393 %type <literal_> LiteralNoRE
 394 %type <expression_> LogicalANDExpression
 395 %type <expression_> LogicalORExpression
 396 %type <member_> MemberAccess
 397 %type <expression_> MemberExpression_
 398 %type <expression_> MemberExpression
 399 %type <expression_> MultiplicativeExpression
 400 %type <expression_> NewExpression
 401 %type <null_> NullLiteral
 402 %type <literal_> ObjectLiteral
 403 %type <expression_> Parenthetical
 404 %type <expression_> PostfixExpression
 405 %type <expression_> PrimaryExpression
 406 %type <statement_> Program
 407 %type <statement_> ProgramBody
 408 %type <statement_> ProgramBodyOpt
 409 %type <propertyName_> PropertyName_
 410 %type <propertyName_> PropertyName
 411 %type <property_> PropertyNameAndValueList_
 412 %type <property_> PropertyNameAndValueList
 413 %type <property_> PropertyNameAndValueListOpt
 414 %type <expression_> RelationalExpression
 415 %type <statement_> ReturnStatement
 416 %type <rubyProc_> RubyProcExpression
 417 %type <functionParameter_> RubyProcParameterList_
 418 %type <functionParameter_> RubyProcParameterList
 419 %type <functionParameter_> RubyProcParameters
 420 %type <functionParameter_> RubyProcParametersOpt
 421 %type <expression_> ShiftExpression
 422 %type <declaration_> SingleNameBinding
 423 %type <statement_> Statement__
 424 %type <statement_> Statement_
 425 %type <statement_> Statement
 426 %type <statement_> StatementList
 427 %type <statement_> StatementListOpt
 428 %type <statement_> StatementListItem
 429 %type <statement_> SwitchStatement
 430 %type <statement_> ThrowStatement
 431 %type <statement_> TryStatement
 432 %type <expression_> UnaryExpression_
 433 %type <expression_> UnaryExpression
 434 %type <declaration_> VariableDeclaration
 435 %type <declarations_> VariableDeclarationList_
 436 %type <declarations_> VariableDeclarationList
 437 %type <statement_> VariableStatement
 438 %type <statement_> WhileStatement
 439 %type <statement_> WithStatement
 440
 441 @begin ObjectiveC
 442 %type <statement_> CategoryStatement
 443 %type <expression_> ClassExpression
 444 %type <statement_> ClassStatement
 445 %type <expression_> ClassSuperOpt
 446 %type <field_> ClassFieldList
 447 %type <message_> ClassMessageDeclaration
 448 %type <message_> ClassMessageDeclarationListOpt
 449 %type <className_> ClassName
 450 %type <className_> ClassNameOpt
 451 %type <protocol_> ClassProtocolListOpt
 452 %type <protocol_> ClassProtocols
 453 %type <protocol_> ClassProtocolsOpt
 454 %type <expression_> MessageExpression
 455 %type <messageParameter_> MessageParameter
 456 %type <messageParameter_> MessageParameters
 457 %type <messageParameter_> MessageParameterList
 458 %type <messageParameter_> MessageParameterListOpt
 459 %type <bool_> MessageScope
 460 %type <argument_> SelectorCall_
 461 %type <argument_> SelectorCall
 462 %type <selector_> SelectorExpression_
 463 %type <selector_> SelectorExpression
 464 %type <selector_> SelectorExpressionOpt
 465 %type <argument_> SelectorList
 466 %type <word_> SelectorWordOpt
 467 %type <expression_> TypeOpt
 468 %type <argument_> VariadicCall
 469 %type <word_> Word
 470 %type <word_> WordOpt
 471 @end
 472
 473 @begin E4X
 474 %type <propertyIdentifier_> PropertyIdentifier_
 475 %type <selector_> PropertySelector_
 476 %type <selector_> PropertySelector
 477 %type <identifier_> QualifiedIdentifier_
 478 %type <identifier_> QualifiedIdentifier
 479 %type <identifier_> WildcardIdentifier
 480 %type <identifier_> XMLComment
 481 %type <identifier_> XMLCDATA
 482 %type <identifier_> XMLElement
 483 %type <identifier_> XMLElementContent
 484 %type <identifier_> XMLMarkup
 485 %type <identifier_> XMLPI
 486
 487 %type <attribute_> AttributeIdentifier
 488 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 489 %type <expression_> PropertyIdentifier
 490 %type <expression_> XMLListInitialiser
 491 %type <expression_> XMLInitialiser
 492 @end
 493
 494 %nonassoc ""
 495 %left "++" "--"
 496
 497 %nonassoc "if"
 498 %nonassoc "else"
 499
 500 %start Program
 501
 502 %%
 503
 504 /* Lexer State {{{ */
 505 LexPushInOn
 506     : { driver.in_.push(true); }
 507     ;
 508
 509 LexPushInOff
 510     : { driver.in_.push(false); }
 511     ;
 512
 513 LexPopIn
 514     : { driver.in_.pop(); }
 515     ;
 516
 517 LexSetRegExp
 518     : { driver.SetCondition(CYDriver::RegExpCondition); }
 519     ;
 520
 521 LexSetStatement
 522     : { switch (yychar) {
 523         case token::Function:
 524             yychar = token::Function_;
 525         break;
 526
 527         case token::OpenBrace:
 528         case token::OpenBrace_:
 529             yychar = token::OpenBrace__;
 530         break;
 531     } }
 532     ;
 533 /* }}} */
 534
 535 BRACE
 536     : "{"
 537     | "\n{"
 538     ;
 539
 540 StrictSemi
 541     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 542     ;
 543
 544 Terminator_
 545     : ";"
 546     | "\n" StrictSemi
 547     ;
 548
 549 Terminator
 550     : Terminator_
 551     | error { if (yychar != 0 && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 552     ;
 553
 554 TerminatorOpt
 555     : Terminator_
 556     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 557     ;
 558
 559 /*CommaOpt
 560     : ","
 561     |
 562     ;*/
 563
 564 @begin ObjectiveC
 565 NewLineOpt
 566     : "\n"
 567     |
 568     ;
 569
 570 Word
 571     : Identifier { $$ = $1; }
 572     | "break" NewLineOpt { $$ = $1; }
 573     | "case" { $$ = $1; }
 574     | "catch" { $$ = $1; }
 575     | "class" { $$ = $1; }
 576     | "const" { $$ = $1; }
 577     | "continue" NewLineOpt { $$ = $1; }
 578     | "debugger" { $$ = $1; }
 579     | "default" { $$ = $1; }
 580     | "delete" { $$ = $1; }
 581     | "do" { $$ = $1; }
 582     | "else" { $$ = $1; }
 583     | "enum" { $$ = $1; }
 584     | "export" { $$ = $1; }
 585     | "extends" { $$ = $1; }
 586     | "false" { $$ = $1; }
 587     | "finally" { $$ = $1; }
 588     /* XXX: | "for" { $$ = $1; } */
 589     | "function" { $$ = $1; }
 590     | "if" { $$ = $1; }
 591     | "import" { $$ = $1; }
 592     /* XXX: | "in" { $$ = $1; } */
 593     /* XXX: | "instanceof" { $$ = $1; } */
 594     | "new" { $$ = $1; }
 595     | "null" { $$ = $1; }
 596     | "return" NewLineOpt { $$ = $1; }
 597     | "super" { $$ = $1; }
 598     | "switch" { $$ = $1; }
 599     | "this" { $$ = $1; }
 600     | "throw" NewLineOpt { $$ = $1; }
 601     | "true" { $$ = $1; }
 602     | "try" { $$ = $1; }
 603     | "typeof" { $$ = $1; }
 604     | "var" { $$ = $1; }
 605     | "void" { $$ = $1; }
 606     | "while" { $$ = $1; }
 607     | "with" { $$ = $1; }
 608     ;
 609
 610 WordOpt
 611     : Word { $$ = $1; }
 612     | { $$ = NULL; }
 613     ;
 614
 615 PrimaryExpression
 616     : "@" LiteralNoRE { $$ = CYNew CYBox($2); }
 617     | "@" ArrayLiteral { $$ = CYNew CYBox($2); }
 618     | "@" ObjectLiteral { $$ = CYNew CYBox($2); }
 619     | "@" Parenthetical { $$ = CYNew CYBox($2); }
 620     ;
 621 @end
 622
 623 Identifier
 624     : Identifier_ { $$ = $1; }
 625
 626     | "implements" { $$ = $1; }
 627     | "interface" { $$ = $1; }
 628     | "package" { $$ = $1; }
 629     | "private" { $$ = $1; }
 630     | "protected" { $$ = $1; }
 631     | "public" { $$ = $1; }
 632     | "static" { $$ = $1; }
 633
 634     | "abstract" { $$ = $1; }
 635     | "boolean" { $$ = $1; }
 636     | "byte" { $$ = $1; }
 637     | "char" { $$ = $1; }
 638     | "double" { $$ = $1; }
 639     | "final" { $$ = $1; }
 640     | "float" { $$ = $1; }
 641     | "goto" { $$ = $1; }
 642     | "int" { $$ = $1; }
 643     | "long" { $$ = $1; }
 644     | "native" { $$ = $1; }
 645     | "short" { $$ = $1; }
 646     | "synchronized" { $$ = $1; }
 647     | "throws" { $$ = $1; }
 648     | "transient" { $$ = $1; }
 649     | "volatile" { $$ = $1; }
 650
 651     // XXX: is this allowed?! | "let" { $$ = $1; }
 652     | "yield" { $$ = $1; }
 653
 654     | "each" { $$ = $1; }
 655     ;
 656
 657 IdentifierOpt
 658     : Identifier { $$ = $1; }
 659     | { $$ = NULL; }
 660     ;
 661
 662 LiteralNoRE
 663     : NullLiteral { $$ = $1; }
 664     | BooleanLiteral { $$ = $1; }
 665     | NumericLiteral { $$ = $1; }
 666     | StringLiteral { $$ = $1; }
 667     ;
 668
 669 Literal
 670     : LiteralNoRE { $$ = $1; }
 671     | RegularExpressionLiteral { $$ = $1; }
 672     ;
 673
 674 NullLiteral
 675     : "null" { $$ = $1; }
 676     ;
 677
 678 BooleanLiteral
 679     : "true" { $$ = $1; }
 680     | "false" { $$ = $1; }
 681     ;
 682
 683 /* 11.1 Primary Expressions {{{ */
 684 Parenthetical
 685     : "(" LexPushInOff Expression LexPopIn ")" { $$ = $3; }
 686     ;
 687
 688 PrimaryExpression
 689     : "this" { $$ = $1; }
 690     | Identifier { $$ = CYNew CYVariable($1); }
 691     | Literal { $$ = $1; }
 692     | ArrayLiteral { $$ = $1; }
 693     | ObjectLiteral { $$ = $1; }
 694     | FunctionExpression { $$ = $1; }
 695     | Parenthetical { $$ = $1; }
 696     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 697     ;
 698 /* }}} */
 699 /* 11.1.4.1 Array Initialiser {{{ */
 700 ArrayLiteral
 701     : "[" LexPushInOff ElementListOpt LexPopIn "]" { $$ = CYNew CYArray($3); }
 702     ;
 703
 704 Element
 705     : AssignmentExpression { $$ = $1; }
 706     ;
 707
 708 ElementOpt
 709     : Element { $$ = $1; }
 710     | LexSetRegExp { $$ = NULL; }
 711     ;
 712
 713 ElementList
 714     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 715     | Element { $$ = CYNew CYElement($1, NULL); }
 716     ;
 717
 718 ElementListOpt
 719     : ElementList { $$ = $1; }
 720     | LexSetRegExp { $$ = NULL; }
 721     ;
 722 /* }}} */
 723 /* 11.1.5 Object Initialiser {{{ */
 724 ObjectLiteral
 725     : BRACE LexPushInOff PropertyNameAndValueListOpt LexPopIn "}" { $$ = CYNew CYObject($3); }
 726     ;
 727
 728 PropertyNameAndValueList_
 729     : "," PropertyNameAndValueList { $$ = $2; }
 730     | { $$ = NULL; }
 731     ;
 732
 733 PropertyNameAndValueList
 734     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = CYNew CYProperty($1, $3, $4); }
 735     ;
 736
 737 PropertyNameAndValueListOpt
 738     : PropertyNameAndValueList { $$ = $1; }
 739     | { $$ = NULL; }
 740     ;
 741
 742 PropertyName_
 743     : Identifier { $$ = $1; }
 744     | StringLiteral { $$ = $1; }
 745     | NumericLiteral { $$ = $1; }
 746     ;
 747
 748 PropertyName
 749     : LexSetRegExp PropertyName_ { $$ = $2; }
 750     ;
 751 /* }}} */
 752
 753 /* 11.2 Left-Hand-Side Expressions {{{ */
 754 MemberAccess
 755     : "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYDirectMember(NULL, $3); }
 756     | "." Identifier { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 757     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 758     ;
 759
 760 MemberExpression_
 761     : MemberExpression { $$ = $1; }
 762     //| "super" { $$ = $1; }
 763     ;
 764
 765 MemberExpression
 766     : LexSetRegExp PrimaryExpression { $$ = $2; }
 767     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 768     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 769     ;
 770
 771 NewExpression
 772     : MemberExpression { $$ = $1; }
 773     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 774     ;
 775
 776 CallExpression_
 777     : MemberExpression_
 778     | CallExpression
 779     ;
 780
 781 CallExpression
 782     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 783     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 784     ;
 785
 786 Arguments
 787     : "(" LexPushInOff ArgumentListOpt LexPopIn ")" { $$ = $3; }
 788     ;
 789
 790 ArgumentList_
 791     : "," ArgumentList { $$ = $2; }
 792     | { $$ = NULL; }
 793     ;
 794
 795 ArgumentList
 796     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 797     ;
 798
 799 ArgumentListOpt
 800     : ArgumentList { $$ = $1; }
 801     | LexSetRegExp { $$ = NULL; }
 802     ;
 803
 804 LeftHandSideExpression
 805     : NewExpression { $$ = $1; }
 806     | CallExpression { $$ = $1; }
 807     ;
 808 /* }}} */
 809 /* 11.3 Postfix Expressions {{{ */
 810 PostfixExpression
 811     : %prec "" LeftHandSideExpression { $$ = $1; }
 812     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 813     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 814     ;
 815 /* }}} */
 816 /* 11.4 Unary Operators {{{ */
 817 UnaryExpression_
 818     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 819     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 820     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 821     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 822     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 823     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 824     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 825     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 826     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 827     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 828     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 829     ;
 830
 831 UnaryExpression
 832     : PostfixExpression { $$ = $1; }
 833     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 834     ;
 835 /* }}} */
 836 /* 11.5 Multiplicative Operators {{{ */
 837 MultiplicativeExpression
 838     : UnaryExpression { $$ = $1; }
 839     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 840     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 841     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 842     ;
 843 /* }}} */
 844 /* 11.6 Additive Operators {{{ */
 845 AdditiveExpression
 846     : MultiplicativeExpression { $$ = $1; }
 847     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 848     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 849     ;
 850 /* }}} */
 851 /* 11.7 Bitwise Shift Operators {{{ */
 852 ShiftExpression
 853     : AdditiveExpression { $$ = $1; }
 854     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 855     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 856     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 857     ;
 858 /* }}} */
 859 /* 11.8 Relational Operators {{{ */
 860 RelationalExpression
 861     : ShiftExpression { $$ = $1; }
 862     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 863     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 864     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 865     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 866     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 867     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 868     ;
 869 /* }}} */
 870 /* 11.9 Equality Operators {{{ */
 871 EqualityExpression
 872     : RelationalExpression { $$ = $1; }
 873     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 874     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 875     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 876     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 877     ;
 878 /* }}} */
 879 /* 11.10 Binary Bitwise Operators {{{ */
 880 BitwiseANDExpression
 881     : EqualityExpression { $$ = $1; }
 882     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 883     ;
 884
 885 BitwiseXORExpression
 886     : BitwiseANDExpression { $$ = $1; }
 887     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 888     ;
 889
 890 BitwiseORExpression
 891     : BitwiseXORExpression { $$ = $1; }
 892     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 893     ;
 894 /* }}} */
 895 /* 11.11 Binary Logical Operators {{{ */
 896 LogicalANDExpression
 897     : BitwiseORExpression { $$ = $1; }
 898     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 899     ;
 900
 901 LogicalORExpression
 902     : LogicalANDExpression { $$ = $1; }
 903     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
 904     ;
 905 /* }}} */
 906 /* 11.12 Conditional Operator ( ? : ) {{{ */
 907 ConditionalExpression
 908     : LogicalORExpression { $$ = $1; }
 909     | LogicalORExpression "?" LexPushInOff AssignmentExpression LexPopIn ":" AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
 910     ;
 911 /* }}} */
 912 /* 11.13 Assignment Operators {{{ */
 913 AssignmentExpression
 914     : ConditionalExpression { $$ = $1; }
 915     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
 916     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
 917     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
 918     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
 919     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
 920     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
 921     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
 922     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
 923     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
 924     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
 925     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
 926     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
 927     ;
 928 /* }}} */
 929 /* 11.14 Comma Operator {{{ */
 930 Expression_
 931     : "," Expression { $$ = CYNew CYCompound($2); }
 932     | { $$ = NULL; }
 933     ;
 934
 935 Expression
 936     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 937     ;
 938
 939 ExpressionOpt
 940     : Expression { $$ = $1; }
 941     | LexSetRegExp { $$ = NULL; }
 942     ;
 943 /* }}} */
 944
 945 /* 12 Statements {{{ */
 946 Statement__
 947     : Block { $$ = $1; }
 948     | VariableStatement { $$ = $1; }
 949     | EmptyStatement { $$ = $1; }
 950     | IfStatement { $$ = $1; }
 951     | BreakableStatement { $$ = $1; }
 952     | ContinueStatement { $$ = $1; }
 953     | BreakStatement { $$ = $1; }
 954     | ReturnStatement { $$ = $1; }
 955     | WithStatement { $$ = $1; }
 956     | LabelledStatement { $$ = $1; }
 957     | ThrowStatement { $$ = $1; }
 958     | TryStatement { $$ = $1; }
 959     | DebuggerStatement { $$ = $1; }
 960     ;
 961
 962 Statement_
 963     : LexSetRegExp Statement__ { $$ = $2; }
 964     | ExpressionStatement { $$ = $1; }
 965     ;
 966
 967 Statement
 968     : LexSetStatement Statement_ { $$ = $2; }
 969     ;
 970
 971 Declaration__
 972     : FunctionDeclaration { $$ = $1; }
 973     | LexicalDeclaration { $$ = $1; }
 974     ;
 975
 976 Declaration_
 977     : LexSetRegExp Declaration__ { $$ = $2; }
 978     ;
 979
 980 Declaration
 981     : LexSetStatement Declaration_ { $$ = $2; }
 982     ;
 983
 984 BreakableStatement
 985     : IterationStatement { $$ = $1; }
 986     | SwitchStatement { $$ = $1; }
 987     ;
 988 /* }}} */
 989 /* 12.1 Block {{{ */
 990 Block_
 991     : BRACE StatementListOpt "}" { $$ = $2; }
 992     ;
 993
 994 Block
 995     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
 996     ;
 997
 998 StatementList
 999     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1000     ;
1001
1002 StatementListOpt
1003     : StatementList { $$ = $1; }
1004     | LexSetRegExp { $$ = NULL; }
1005     ;
1006
1007 StatementListItem
1008     : Statement { $$ = $1; }
1009     | Declaration { $$ = $1; }
1010     ;
1011 /* }}} */
1012 /* 12.2 Declarations {{{ */
1013 BindingIdentifier
1014     : Identifier { $$ = $1; }
1015     ;
1016
1017 // XXX: BindingPattern
1018 /* }}} */
1019 /* 12.2.1 Let and Const Declarations {{{ */
1020 LexicalDeclaration
1021     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1022     ;
1023
1024 LetOrConst
1025     : "let"
1026     | "const"
1027     ;
1028 /* }}} */
1029 /* 12.2.2 Variable Statement {{{ */
1030 VariableStatement
1031     : "var" VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1032     ;
1033
1034 VariableDeclarationList_
1035     : "," VariableDeclarationList { $$ = $2; }
1036     | { $$ = NULL; }
1037     ;
1038
1039 VariableDeclarationList
1040     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1041     ;
1042
1043 VariableDeclaration
1044     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1045     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1046     ;
1047
1048 Initialiser
1049     : "=" AssignmentExpression { $$ = $2; }
1050     ;
1051
1052 InitialiserOpt
1053     : Initialiser { $$ = $1; }
1054     | { $$ = NULL; }
1055     ;
1056 /* }}} */
1057 /* 12.2.4 Destructuring Binding Patterns {{{ */
1058 // XXX: *
1059
1060 BindingElement
1061     : SingleNameBinding { $$ = $1; }
1062     ;
1063
1064 SingleNameBinding
1065     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1066     ;
1067 /* }}} */
1068 /* 12.3 Empty Statement {{{ */
1069 EmptyStatement
1070     : ";" { $$ = CYNew CYEmpty(); }
1071     ;
1072 /* }}} */
1073 /* 12.4 Expression Statement {{{ */
1074 ExpressionStatement
1075     : Expression Terminator { $$ = CYNew CYExpress($1); }
1076     ;
1077 /* }}} */
1078 /* 12.5 The if Statement {{{ */
1079 ElseStatementOpt
1080     : "else" Statement { $$ = $2; }
1081     | %prec "if" { $$ = NULL; }
1082     ;
1083
1084 IfStatement
1085     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1086     ;
1087 /* }}} */
1088
1089 /* 12.6 Iteration Statements {{{ */
1090 IterationStatement
1091     : DoWhileStatement { $$ = $1; }
1092     | WhileStatement { $$ = $1; }
1093     | ForStatement { $$ = $1; }
1094     | ForInStatement { $$ = $1; }
1095     ;
1096 /* }}} */
1097 /* 12.6.1 The do-while Statement {{{ */
1098 DoWhileStatement
1099     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1100     ;
1101 /* }}} */
1102 /* 12.6.2 The while Statement {{{ */
1103 WhileStatement
1104     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1105     ;
1106 /* }}} */
1107 /* 12.6.3 The for Statement {{{ */
1108 ForStatement
1109     : "for" "(" LexPushInOn ForStatementInitialiser LexPopIn ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1110     ;
1111
1112 ForStatementInitialiser
1113     : ExpressionOpt { $$ = $1; }
1114     | LexSetRegExp "var" VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1115     ;
1116 /* }}} */
1117 /* 12.6.4 The for-in Statement {{{ */
1118 ForInStatement
1119     : "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1120     ;
1121
1122 ForInStatementInitialiser
1123     : LeftHandSideExpression { $$ = $1; }
1124     | LexSetRegExp "var" VariableDeclaration { $$ = $3; }
1125     ;
1126 /* }}} */
1127
1128 /* 12.7 The continue Statement {{{ */
1129 ContinueStatement
1130     : "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1131     ;
1132 /* }}} */
1133 /* 12.8 The break Statement {{{ */
1134 BreakStatement
1135     : "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1136     ;
1137 /* }}} */
1138 /* 12.9 The return Statement {{{ */
1139 ReturnStatement
1140     : "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1141     ;
1142 /* }}} */
1143 /* 12.10 The with Statement {{{ */
1144 WithStatement
1145     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1146     ;
1147 /* }}} */
1148
1149 /* 12.11 The switch Statement {{{ */
1150 SwitchStatement
1151     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1152     ;
1153
1154 CaseBlock
1155     : BRACE CaseClausesOpt "}" { $$ = $2; }
1156     ;
1157
1158 CaseClause
1159     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1160     ;
1161
1162 CaseClausesOpt
1163     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1164     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1165     | { $$ = NULL; }
1166     ;
1167
1168 DefaultClause
1169     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1170     ;
1171 /* }}} */
1172 /* 12.12 Labelled Statements {{{ */
1173 LabelledStatement
1174     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1175     ;
1176 /* }}} */
1177 /* 12.13 The throw Statement {{{ */
1178 ThrowStatement
1179     : "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1180     ;
1181 /* }}} */
1182 /* 12.14 The try Statement {{{ */
1183 TryStatement
1184     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1185     ;
1186
1187 CatchOpt
1188     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1189     | { $$ = NULL; }
1190     ;
1191
1192 FinallyOpt
1193     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1194     | { $$ = NULL; }
1195     ;
1196 /* }}} */
1197 /* 12.14 The debugger Statement {{{ */
1198 DebuggerStatement
1199     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1200     ;
1201 /* }}} */
1202
1203 /* 13 Function Definition {{{ */
1204 FunctionDeclaration
1205     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1206     ;
1207
1208 FunctionExpression
1209     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt LexPopIn ")" BRACE LexPushInOff FunctionBody LexPopIn "}" { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1210     ;
1211
1212 FormalParameterList_
1213     : "," FormalParameterList { $$ = $2; }
1214     | { $$ = NULL; }
1215     ;
1216
1217 FormalParameterList
1218     // XXX: : FunctionRestParameter { $$ = $1; }
1219     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1220     ;
1221
1222 FormalParameterListOpt
1223     : FormalParameterList
1224     | { $$ = NULL; }
1225     ;
1226
1227 /* XXX: FunctionRestParameter
1228     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1229     ;*/
1230
1231 FormalParameter
1232     : BindingElement { $$ = $1; }
1233     ;
1234
1235 FunctionBody
1236     : StatementListOpt { $$ = $1; }
1237     ;
1238 /* }}} */
1239 /* 14 Program {{{ */
1240 Program
1241     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1242     ;
1243
1244 ProgramBody
1245     : StatementList { $$ = $1; }
1246     ;
1247
1248 ProgramBodyOpt
1249     : ProgramBody { $$ = $1; }
1250     | { $$ = NULL; }
1251     ;
1252 /* }}} */
1253
1254 @begin ObjectiveC
1255 /* Cycript (Objective-C): @class Declaration {{{ */
1256 ClassSuperOpt
1257     /* XXX: why the hell did I choose MemberExpression? */
1258     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1259     | { $$ = NULL; }
1260     ;
1261
1262 ClassField
1263     : Expression Identifier ";"
1264     ;
1265
1266 ClassFieldList
1267     : BRACE ClassFieldListOpt "}" { $$ = NULL; }
1268     ;
1269
1270 ClassFieldListOpt
1271     : ClassFieldListOpt ClassField
1272     |
1273     ;
1274
1275 MessageScope
1276     : "+" { $$ = false; }
1277     | "-" { $$ = true; }
1278     ;
1279
1280 TypeOpt
1281     : "(" Expression ")" { $$ = $2; }
1282     | "(" LexSetRegExp "void" ")" { $$ = NULL; }
1283     | { $$ = NULL; }
1284     ;
1285
1286 MessageParameter
1287     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1288     ;
1289
1290 MessageParameterList
1291     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1292     ;
1293
1294 MessageParameterListOpt
1295     : MessageParameterList { $$ = $1; }
1296     | { $$ = NULL; }
1297     ;
1298
1299 MessageParameters
1300     : MessageParameterList { $$ = $1; }
1301     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1302     ;
1303
1304 ClassMessageDeclaration
1305     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1306     ;
1307
1308 ClassMessageDeclarationListOpt
1309     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1310     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1311     | { $$ = NULL; }
1312     ;
1313
1314 ClassName
1315     : Identifier { $$ = $1; }
1316     | "(" AssignmentExpression ")" { $$ = $2; }
1317     ;
1318
1319 ClassNameOpt
1320     : ClassName { $$ = $1; }
1321     | { $$ = NULL; }
1322     ;
1323
1324 // XXX: this should be AssignmentExpressionNoRight
1325 ClassProtocols
1326     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1327     ;
1328
1329 ClassProtocolsOpt
1330     : "," ClassProtocols { $$ = $2; }
1331     | { $$ = NULL; }
1332     ;
1333
1334 ClassProtocolListOpt
1335     : "<" ClassProtocols ">" { $$ = $2; }
1336     | { $$ = NULL; }
1337     ;
1338
1339 ClassExpression
1340     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt LexPopIn "@end" { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1341     ;
1342
1343 ClassStatement
1344     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1345     ;
1346
1347 CategoryName
1348     : "(" WordOpt ")"
1349     ;
1350
1351 CategoryStatement
1352     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1353     ;
1354
1355 PrimaryExpression
1356     : ClassExpression { $$ = $1; }
1357     ;
1358
1359 Statement__
1360     : ClassStatement { $$ = $1; }
1361     | CategoryStatement { $$ = $1; }
1362     ;
1363 /* }}} */
1364 /* Cycript (Objective-C): Send Message {{{ */
1365 VariadicCall
1366     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1367     | { $$ = NULL; }
1368     ;
1369
1370 SelectorWordOpt
1371     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1372     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1373     ;
1374
1375 SelectorCall_
1376     : SelectorCall { $$ = $1; }
1377     | VariadicCall { $$ = $1; }
1378     ;
1379
1380 SelectorCall
1381     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1382     ;
1383
1384 SelectorList
1385     : SelectorCall { $$ = $1; }
1386     | Word { $$ = CYNew CYArgument($1, NULL); }
1387     ;
1388
1389 MessageExpression
1390     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList LexPopIn "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1391     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList LexPopIn "]" { $$ = CYNew CYSendSuper($6); }
1392     ;
1393
1394 SelectorExpression_
1395     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1396     ;
1397
1398 SelectorExpression
1399     : SelectorExpression_ { $$ = $1; }
1400     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1401     ;
1402
1403 SelectorExpressionOpt
1404     : SelectorExpression_ { $$ = $1; }
1405     | { $$ = NULL; }
1406     ;
1407
1408 PrimaryExpression
1409     : MessageExpression { $$ = $1; }
1410     | "@selector" "(" LexPushInOff SelectorExpression LexPopIn ")" { $$ = CYNew CYSelector($4); }
1411     ;
1412 /* }}} */
1413 /* Cycript (Objective-C): @import Directive {{{ */
1414 PathName
1415     : "/" PathName
1416     | "." PathName
1417     | Word PathName
1418     |
1419     ;
1420
1421 ImportPath
1422     : "<" PathName ">"
1423     | StringLiteral
1424     ;
1425
1426 StatementListItem
1427     : "@import" ImportPath { $$ = CYNew CYImport(); }
1428     ;
1429 /* }}} */
1430 @end
1431
1432 @begin C
1433 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1434 LeftHandSideExpression
1435     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1436     ;
1437
1438 UnaryExpression_
1439     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1440     ;
1441
1442 MemberAccess
1443     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1444     | "->" Identifier { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1445     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1446     ;
1447 /* }}} */
1448 @end
1449
1450 /* YUI: Documentation Comments {{{ */
1451 Statement__
1452     : Comment { $$ = $1; }
1453     ;
1454 /* }}} */
1455
1456 @begin E4X
1457 /* Lexer State {{{ */
1458 LexPushRegExp
1459     : { driver.PushCondition(CYDriver::RegExpCondition); }
1460     ;
1461
1462 LexPushXMLContent
1463     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1464     ;
1465
1466 LexPushXMLTag
1467     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1468     ;
1469
1470 LexPop
1471     : { driver.PopCondition(); }
1472     ;
1473
1474 LexSetXMLContent
1475     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1476     ;
1477
1478 LexSetXMLTag
1479     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1480     ;
1481 /* }}} */
1482
1483 XMLWhitespaceOpt
1484     : XMLWhitespace
1485     |
1486     ;
1487
1488 /* 8.1 Context Keywords {{{ */
1489 Identifier
1490     : "namespace" { $$ = $1; }
1491     | "xml" { $$ = $1; }
1492     ;
1493 /* }}} */
1494 /* 8.3 XML Initialiser Input Elements {{{ */
1495 XMLMarkup
1496     : XMLComment { $$ = $1; }
1497     | XMLCDATA { $$ = $1; }
1498     | XMLPI { $$ = $1; }
1499     ;
1500 /* }}} */
1501 /* 11.1 Primary Expressions {{{ */
1502 PrimaryExpression
1503     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1504     | XMLInitialiser { $$ = $1; }
1505     | XMLListInitialiser { $$ = $1; }
1506     ;
1507
1508 PropertyIdentifier
1509     : AttributeIdentifier { $$ = $1; }
1510     | QualifiedIdentifier { $$ = $1; }
1511     | WildcardIdentifier { $$ = $1; }
1512     ;
1513 /* }}} */
1514 /* 11.1.1 Attribute Identifiers {{{ */
1515 AttributeIdentifier
1516     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1517     ;
1518
1519 PropertySelector_
1520     : PropertySelector { $$ = $1; }
1521     | "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYSelector($3); }
1522     ;
1523
1524 PropertySelector
1525     : Identifier { $$ = CYNew CYSelector($1); }
1526     | WildcardIdentifier { $$ = $1; }
1527     ;
1528 /* }}} */
1529 /* 11.1.2 Qualified Identifiers {{{ */
1530 QualifiedIdentifier_
1531     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1532     | QualifiedIdentifier { $$ = $1; }
1533     ;
1534
1535 QualifiedIdentifier
1536     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1537     ;
1538 /* }}} */
1539 /* 11.1.3 Wildcard Identifiers {{{ */
1540 WildcardIdentifier
1541     : "*" { $$ = CYNew CYWildcard(); }
1542     ;
1543 /* }}} */
1544 /* 11.1.4 XML Initialiser {{{ */
1545 XMLInitialiser
1546     : XMLMarkup { $$ = $1; }
1547     | XMLElement { $$ = $1; }
1548     ;
1549
1550 XMLElement
1551     : "<" LexPushInOff XMLTagContent LexPop LexPopIn "/>"
1552     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop LexPopIn ">"
1553     ;
1554
1555 XMLTagContent
1556     : LexPushXMLTag XMLTagName XMLAttributes
1557     ;
1558
1559 XMLExpression
1560     : BRACE LexPushRegExp Expression LexPop "}"
1561     ;
1562
1563 XMLTagName
1564     : XMLExpression
1565     | XMLName
1566     ;
1567
1568 XMLAttributes_
1569     : XMLAttributes_ XMLAttribute
1570     |
1571     ;
1572
1573 XMLAttributes
1574     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1575     | XMLAttributes_ XMLWhitespaceOpt
1576     ;
1577
1578 XMLAttributeValue_
1579     : XMLExpression
1580     | XMLAttributeValue
1581     ;
1582
1583 XMLAttribute
1584     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1585     ;
1586
1587 XMLElementContent
1588     : XMLExpression XMLElementContentOpt
1589     | XMLMarkup XMLElementContentOpt
1590     | XMLText XMLElementContentOpt
1591     | XMLElement XMLElementContentOpt
1592     ;
1593
1594 XMLElementContentOpt
1595     : XMLElementContent
1596     |
1597     ;
1598 /* }}} */
1599 /* 11.1.5 XMLList Initialiser {{{ */
1600 XMLListInitialiser
1601     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop LexPopIn "</>" { $$ = CYNew CYXMLList($4); }
1602     ;
1603 /* }}} */
1604 /* 11.2 Left-Hand-Side Expressions {{{ */
1605 PropertyIdentifier_
1606     : Identifier { $$ = $1; }
1607     | PropertyIdentifier { $$ = $1; }
1608     ;
1609
1610 MemberAccess
1611     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1612     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1613     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1614     ;
1615 /* }}} */
1616 /* 12.1 The default xml namespace Statement {{{ */
1617 /* XXX: DefaultXMLNamespaceStatement
1618     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1619     ;
1620
1621 Statement__
1622     : DefaultXMLNamespaceStatement { $$ = $1; }
1623     ; */
1624 /* }}} */
1625 @end
1626
1627 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1628 PropertyNameAndValueList_
1629     : "," { $$ = NULL; }
1630     ;
1631 /* }}} */
1632
1633 /* JavaScript 1.7: Array Comprehensions {{{ */
1634 IfComprehension
1635     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1636     ;
1637
1638 ForComprehension
1639     : "for" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
1640     | "for" "each" "(" LexPushInOn Identifier LexPopIn "!in" Expression ")" { $$ = CYNew CYForEachInComprehension($5, $8); }
1641     ;
1642
1643 ComprehensionList
1644     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1645     ;
1646
1647 ComprehensionListOpt
1648     : ComprehensionList { $$ = $1; }
1649     | IfComprehension { $$ = $1; }
1650     | { $$ = NULL; }
1651     ;
1652
1653 PrimaryExpression
1654     : "[" LexPushInOff AssignmentExpression ComprehensionList LexPopIn "]" { $$ = CYNew CYArrayComprehension($3, $4); }
1655     ;
1656 /* }}} */
1657 /* JavaScript 1.7: for each {{{ */
1658 ForInStatement
1659     : "for" "each" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForEachIn($5, $8, $10); }
1660     ;
1661 /* }}} */
1662 /* JavaScript 1.7: let Statements {{{ */
1663 LetStatement
1664     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1665     ;
1666
1667 Statement__
1668     : LetStatement
1669     ;
1670 /* }}} */
1671
1672 /* JavaScript FTW: Ruby Blocks {{{ */
1673 RubyProcParameterList_
1674     : "," RubyProcParameterList { $$ = $2; }
1675     | { $$ = NULL; }
1676     ;
1677
1678 RubyProcParameterList
1679     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1680     | { $$ = NULL; }
1681     ;
1682
1683 RubyProcParameters
1684     : "|" RubyProcParameterList "|" { $$ = $2; }
1685     | "||" { $$ = NULL; }
1686     ;
1687
1688 RubyProcParametersOpt
1689     : RubyProcParameters
1690     | { $$ = NULL; }
1691     ;
1692
1693 RubyProcExpression
1694     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1695     ;
1696
1697 PrimaryExpression
1698     : "{" LexPushInOff RubyProcParameters StatementListOpt LexPopIn "}" { $$ = CYNew CYRubyProc($3, $4); }
1699     ;
1700
1701 CallExpression
1702     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1703     ;
1704 /* }}} */
1705
1706 %%