[cycript.git] / Cycript.l.in

/* Cycript - Optimizing JavaScript Compiler/Runtime
 * Copyright (C) 2009-2013  Jay Freeman (saurik)
*/

/* GNU General Public License, Version 3 {{{ */
/*
 * Cycript is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published
 * by the Free Software Foundation, either version 3 of the License,
 * or (at your option) any later version.
 *
 * Cycript is distributed in the hope that it will be useful, but
 * WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
**/
/* }}} */

/* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */

%{
#define YYLTYPE cy::location
#include "Cycript.tab.hh"
typedef cy::parser::token tk;

#include "Highlight.hpp"

#define YY_EXTRA_TYPE CYDriver *

// do /not/ fold token to the return: this is a macro and the ordering is dependent
#define F(value, highlight) do { \
    int token(value); \
@begin ObjectiveC
    yyextra->no_.AtImplementation = false; \
@end
    yyextra->no_.Function = false; \
    yyextra->no_.OpenBrace = false; \
    yylval->highlight_ = highlight; \
    return token; \
} while (false)

#define A new($pool)
#define Y $pool.strmemdup(yytext, yyleng)

#define I(type, Type, value, highlight) do { \
    yylval->type ## _ = A CY ## Type; \
    F(value, highlight); \
} while (false)

#define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
#define C T yyextra->state_ = CYClear;
#define R T yyextra->state_ = CYRestricted;

#define N \
    if (yyextra->state_ != CYNewLine) { \
        if (yyextra->state_ != CYRestricted) \
            yyextra->state_ = CYNewLine; \
        else { \
            yyextra->state_ = CYClear; \
            F(tk::NewLine, hi::Nothing); \
        } \
    }

#define V(more) { \
    if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
        unsigned lines(0); \
        size_t left; \
        do { \
            ++lines; \
            left = yyleng - (nl - yytext) - 1; \
            nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
        } while (nl != NULL); \
        yylloc->end.lines(lines); \
        yylloc->end.columns(left); \
        yylloc->step(); \
        more \
    } else L \
}

#define L { \
    yylloc->step(); \
    yylloc->columns(yyleng); \
}

#define M { \
    if (yyextra->commented_) { \
        I(comment, Comment(Y), tk::Comment, hi::Comment); \
    } \
}

int H(char c) {
    if (c >= '0' && c <= '9')
        return c - '0';
    if (c >= 'a' && c <= 'f')
        return c - 'a' + 10;
    if (c >= 'A' && c <= 'F')
        return c - 'A' + 10;
    return -1;
}

#define YY_INPUT(data, value, size) { \
    if (yyextra->data_.eof()) \
        value = YY_NULL; \
    else { \
        yyextra->data_.read(data, size); \
        size_t copy(yyextra->data_.gcount()); \
        value = copy == 0 ? YY_NULL : copy; \
    } \
}

%}

%option prefix="cy"
%option bison-bridge
%option bison-locations
%option noyywrap
%option yylineno
%option nounput
%option interactive
%option reentrant
%option stack

Exponent [eE][+-]?[0-9]+
Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n

IdentifierStart [a-zA-Z$_]
IdentifierPart  [a-zA-Z$_0-9]

NonTerminator [^\n]
BackslashSequence \\{NonTerminator}
RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
RegularExpressionChar [^\n\\/]|{BackslashSequence}
RegularExpressionFlags {IdentifierPart}*
RegularExpressionChars {RegularExpressionChar}*
RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}

@begin E4X
XMLNameStart [a-zA-Z_:]
XMLNamePart [a-zA-Z0-9.-_:]
XMLName {XMLNameStart}{XMLNamePart}*
@end

%s Div
%s RegExp

@begin E4X
%x XMLContent
%x XMLTag
@end

%%

<RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} L C I(literal, RegEx(Y), tk::RegularExpressionLiteral, hi::Constant);

\/\/[^\n]* L M

	/* http://ostermiller.org/findcomment.html */
	/* XXX: unify these two rules using !? */
\/\*!([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V() C I(comment, Comment(Y), tk::Comment, hi::Comment);
\/\*([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V(N) M

@begin E4X
<RegExp>"<>"      L F(tk::LeftRight, hi::Structure);
<XMLContent>"</>" L F(tk::LeftSlashRight, hi::Structure);

<RegExp,XMLContent>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]> V() F(tk::XMLCDATA, hi::Constant);
<RegExp,XMLContent>\<!--(\n|[^-]|-[^-])*--> V() F(tk::XMLComment, hi::Comment);
<RegExp,XMLContent>\<?(\n|[^?]|\?[^>])*?> V() F(tk::XMLPI, hi::Meta);

<XMLTag>"="  L F(tk::Equal, hi::Structure);
<XMLTag>">"  L F(tk::Right, hi::Structure);
<XMLTag>"/>" L F(tk::SlashRight, hi::Structure);
<XMLTag>"{"  L F(tk::OpenBrace, hi::Structure);

<XMLTag>\"(\n|[^"])*\"|'(\n|[^'])*' V() F(tk::XMLAttributeValue, hi::Constant);
<XMLTag>{XMLName} L F(tk::XMLName, hi::Identifier);
<XMLTag>[ \t\r\n] V() F(tk::XMLWhitespace, hi::Nothing);

<XMLContent>"{"  L F(tk::OpenBrace, hi::Structure);
<XMLContent>"<"  L F(tk::Left, hi::Structure);
<XMLContent>"</" L F(tk::LeftSlash, hi::Structure);
@end

"..."  L C F(tk::PeriodPeriodPeriod, hi::Meta);

@begin E4X
"::"   L C F(tk::ColonColon, hi::Operator);
".."   L C F(tk::PeriodPeriod, hi::Operator);
@end

@begin E4X ObjectiveC
"@"    L C F(tk::At, hi::Operator);
"#"    L C F(tk::Pound, hi::Operator);
@end

"&"    L C F(tk::Ampersand, hi::Operator);
"&&"   L C F(tk::AmpersandAmpersand, hi::Operator);
"&="   L C F(tk::AmpersandEqual, hi::Operator);
"^"    L C F(tk::Carrot, hi::Operator);
"^="   L C F(tk::CarrotEqual, hi::Operator);
"="    L C F(tk::Equal, hi::Operator);
"=="   L C F(tk::EqualEqual, hi::Operator);
"==="  L C F(tk::EqualEqualEqual, hi::Operator);
"=>"   L C F(tk::EqualRight, hi::Operator);
"!"    L C F(tk::Exclamation, hi::Operator);
"!="   L C F(tk::ExclamationEqual, hi::Operator);
"!=="  L C F(tk::ExclamationEqualEqual, hi::Operator);
"-"    L C F(tk::Hyphen, hi::Operator);
"-="   L C F(tk::HyphenEqual, hi::Operator);
"--"   L C F(yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen, hi::Operator);
"->"   L C F(tk::HyphenRight, hi::Operator);
"<"    L C F(tk::Left, hi::Operator);
"<="   L C F(tk::LeftEqual, hi::Operator);
"<<"   L C F(tk::LeftLeft, hi::Operator);
"<<="  L C F(tk::LeftLeftEqual, hi::Operator);
"%"    L C F(tk::Percent, hi::Operator);
"%="   L C F(tk::PercentEqual, hi::Operator);
"."    L C F(tk::Period, hi::Operator);
"|"    L C F(tk::Pipe, hi::Operator);
"|="   L C F(tk::PipeEqual, hi::Operator);
"||"   L C F(tk::PipePipe, hi::Operator);
"+"    L C F(tk::Plus, hi::Operator);
"+="   L C F(tk::PlusEqual, hi::Operator);
"++"   L C F(yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus, hi::Operator);
">"    L C F(tk::Right, hi::Operator);
">="   L C F(tk::RightEqual, hi::Operator);
">>"   L C F(tk::RightRight, hi::Operator);
">>="  L C F(tk::RightRightEqual, hi::Operator);
">>>"  L C F(tk::RightRightRight, hi::Operator);
">>>=" L C F(tk::RightRightRightEqual, hi::Operator);
"*"    L C F(tk::Star, hi::Operator);
"*="   L C F(tk::StarEqual, hi::Operator);
"~"    L C F(tk::Tilde, hi::Operator);

<Div>"/"  L C F(tk::Slash, hi::Operator);
<Div>"/=" L C F(tk::SlashEqual, hi::Operator);

":"    L C F(tk::Colon, hi::Structure);
","    L C F(tk::Comma, hi::Structure);
"?"    L C F(tk::Question, hi::Structure);
";"    L C F(tk::SemiColon, hi::Structure);

"("    L C F(tk::OpenParen, hi::Structure);
")"    L C F(tk::CloseParen, hi::Structure);

"{"    L C F(yyextra->no_.OpenBrace ? tk::OpenBrace__ : yylval->newline_ ? tk::OpenBrace_ : tk::OpenBrace, hi::Structure);
"}"    L C F(tk::CloseBrace, hi::Structure);

"["    L C F(tk::OpenBracket, hi::Structure);
"]"    L C F(tk::CloseBracket, hi::Structure);

"@error"          L C F(tk::AtError, hi::Error);

@begin Java
"@class"          L C F(tk::AtClass, hi::Meta);
@end

@begin C
"typedef"         L C I(identifier, Identifier("typedef"), tk::Typedef, hi::Meta);
@end

@begin ObjectiveC
"@encode"         L C F(tk::AtEncode, hi::Meta);
"@end"            L C F(tk::AtEnd, hi::Meta);
"@implementation" L C F(yyextra->no_.AtImplementation ? tk::AtImplementation_ : tk::AtImplementation, hi::Meta);
"@import"         L C F(tk::AtImport, hi::Special);
"@selector"       L C F(tk::AtSelector, hi::Meta);

"NULL"         L C I(identifier, Identifier("NULL"), tk::Identifier_, hi::Constant);
"nil"          L C I(identifier, Identifier("nil"), tk::Identifier_, hi::Constant);
"YES"          L C I(identifier, Identifier("YES"), tk::Yes, hi::Constant);
"NO"           L C I(identifier, Identifier("NO"), tk::No, hi::Constant);

"bool"         L C I(identifier, Identifier("bool"), tk::Identifier_, hi::Type);
"BOOL"         L C I(identifier, Identifier("BOOL"), tk::Identifier_, hi::Type);
"id"           L C I(identifier, Identifier("id"), tk::Identifier_, hi::Type);
"SEL"          L C I(identifier, Identifier("SEL"), tk::Identifier_, hi::Type);
@end

"undefined"    L C I(identifier, Identifier("undefined"), tk::Identifier_, hi::Operator);

"false"        L C I(false, False(), tk::False, hi::Constant);
"null"         L C I(null, Null(), tk::Null, hi::Constant);
"true"         L C I(true, True(), tk::True, hi::Constant);

"auto"         L C I(word, Word("auto"), tk::Auto, hi::Meta);
"break"        L R I(word, Word("break"), tk::Break, hi::Control);
"case"         L C I(word, Word("case"), tk::Case, hi::Control);
"catch"        L C I(word, Word("catch"), tk::Catch, hi::Control);
"continue"     L R I(word, Word("continue"), tk::Continue, hi::Control);
"default"      L C I(word, Word("default"), tk::Default, hi::Control);
"delete"       L C I(word, Word("delete"), tk::Delete, hi::Operator);
"do"           L C I(word, Word("do"), tk::Do, hi::Control);
"else"         L C I(word, Word("else"), tk::Else, hi::Control);
"finally"      L C I(word, Word("finally"), tk::Finally, hi::Control);
"for"          L C I(word, Word("for"), tk::For, hi::Control);
"function"     L C I(word, Word("function"), yyextra->no_.Function ? tk::Function_ : tk::Function, hi::Meta);
"if"           L C I(word, Word("if"), tk::If, hi::Control);
"in"           L C I(word, Word("in"), yyextra->in_.top() ? tk::In_ : tk::In, hi::Operator);
"instanceof"   L C I(word, Word("instanceof"), tk::InstanceOf, hi::Operator);
"new"          L C I(word, Word("new"), tk::New, hi::Operator);
"return"       L R I(word, Word("return"), tk::Return, hi::Control);
"switch"       L C I(word, Word("switch"), tk::Switch, hi::Control);
"this"         L C I(this, This(), tk::This, hi::Constant);
"throw"        L R I(word, Word("throw"), tk::Throw, hi::Control);
"try"          L C I(word, Word("try"), tk::Try, hi::Control);
"typeof"       L C I(word, Word("typeof"), tk::TypeOf, hi::Operator);
"var"          L C I(word, Word("var"), tk::Var, hi::Meta);
"void"         L C I(word, Word("void"), tk::Void, hi::Operator);
"while"        L C I(word, Word("while"), tk::While, hi::Control);
"with"         L C I(word, Word("with"), tk::With, hi::Control);

"debugger"     L C I(word, Word("debugger"), tk::Debugger, hi::Meta);

"const"        L C I(word, Word("const"), tk::Const, hi::Meta);

"class"        L C I(word, Word("class"), tk::Class, hi::Meta);
"enum"         L C I(word, Word("enum"), tk::Enum, hi::Meta);
"export"       L C I(word, Word("export"), tk::Export, hi::Meta);
"extends"      L C I(word, Word("extends"), tk::Extends, hi::Meta);
"import"       L C I(word, Word("import"), tk::Import, hi::Meta);
"super"        L C I(word, Word("super"), tk::Super, hi::Constant);

"implements"   L C I(identifier, Identifier("implements"), tk::Implements, hi::Meta);
"interface"    L C I(identifier, Identifier("interface"), tk::Interface, hi::Meta);
"package"      L C I(identifier, Identifier("package"), tk::Package, hi::Meta);
"private"      L C I(identifier, Identifier("private"), tk::Private, hi::Meta);
"protected"    L C I(identifier, Identifier("protected"), tk::Protected, hi::Meta);
"public"       L C I(identifier, Identifier("public"), tk::Public, hi::Meta);
"static"       L C I(identifier, Identifier("static"), tk::Static, hi::Meta);

"abstract"     L C I(identifier, Identifier("abstract"), tk::Abstract, hi::Meta);
"boolean"      L C I(identifier, Identifier("boolean"), tk::Boolean, hi::Type);
"byte"         L C I(identifier, Identifier("byte"), tk::Byte, hi::Type);
"char"         L C I(identifier, Identifier("char"), tk::Char, hi::Type);
"double"       L C I(identifier, Identifier("double"), tk::Double, hi::Type);
"final"        L C I(identifier, Identifier("final"), tk::Final, hi::Meta);
"float"        L C I(identifier, Identifier("float"), tk::Float, hi::Type);
"goto"         L C I(identifier, Identifier("goto"), tk::Goto, hi::Control);
"int"          L C I(identifier, Identifier("int"), tk::Int, hi::Type);
"long"         L C I(identifier, Identifier("long"), tk::Long, hi::Type);
"native"       L C I(identifier, Identifier("native"), tk::Native, hi::Meta);
"short"        L C I(identifier, Identifier("short"), tk::Short, hi::Type);
"synchronized" L C I(identifier, Identifier("synchronized"), tk::Synchronized, hi::Meta);
"throws"       L C I(identifier, Identifier("throws"), tk::Throws, hi::Meta);
"transient"    L C I(identifier, Identifier("transient"), tk::Transient, hi::Meta);
"volatile"     L C I(identifier, Identifier("volatile"), tk::Volatile, hi::Meta);

"let"          L C I(identifier, Identifier("let"), tk::Let, hi::Meta);
"yield"        L C I(identifier, Identifier("yield"), tk::Yield, hi::Control);

"each"         L C I(identifier, Identifier("each"), tk::Each, hi::Control);
"of"           L C I(identifier, Identifier("of"), tk::Of, hi::Operator);

@begin E4X
"namespace"    L C I(identifier, Identifier("namespace"), tk::Namespace, hi::Meta);
"xml"          L C I(identifier, Identifier("xml"), tk::XML, hi::Meta);
@end

{IdentifierStart}{IdentifierPart}* L C I(identifier, Identifier(Y), tk::Identifier_, hi::Identifier);

(\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? L C I(number, Number(strtod(yytext, NULL)), tk::NumericLiteral, hi::Constant);

0[xX][0-9a-fA-F]+ L C I(number, Number(strtoull(yytext + 2, NULL, 16)), tk::NumericLiteral, hi::Constant);
0[0-7]+ L C I(number, Number(strtoull(yytext + 1, NULL, 8)), tk::NumericLiteral, hi::Constant);
0[bB][0-1]+ L C I(number, Number(strtoull(yytext + 2, NULL, 2)), tk::NumericLiteral, hi::Constant);

\"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
    char *value(A char[yyleng]);
    char *local(value);

    for (yy_size_t i(1), e(yyleng - 1); i != e; ++i) {
        char next(yytext[i]);

        if (yytext[i] == '\\')
            switch (next = yytext[++i]) {
                case '\n': continue;
                case '\\': next = '\\'; break;
                case '\'': next = '\''; break;
                case '"': next = '"'; break;
                case 'b': next = '\b'; break;
                case 'f': next = '\f'; break;
                case 'n': next = '\n'; break;
                case 'r': next = '\r'; break;
                case 't': next = '\t'; break;
                case 'v': next = '\v'; break;
                case '0': next = '\0'; break;

                case 'x':
                    next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
                    i += 2;
                break;
            }

        *local++ = next;
    }

    *local = '\0';
    I(string, String(value, local - value), tk::StringLiteral, hi::Constant);
}

\r?\n|\r|\xe2\x80[\xa8\xa9] yylloc->end.lines(); yylloc->step(); N

[ \t] L

<<EOF>> if (yyextra->auto_) { yyextra->auto_ = false; F(tk::AutoComplete, hi::Nothing); } L yyterminate();

. L {
    CYDriver::Error error;
    error.location_ = *yylloc;
    error.message_ = "syntax error, unknown token";
    yyextra->errors_.push_back(error);
    yyterminate();
}

%%

void CYDriver::ScannerInit() {
    cylex_init(&scanner_);
    cyset_extra(this, scanner_);
}

void CYDriver::ScannerDestroy() {
    cylex_destroy(scanner_);
}

CYDriver::Condition CYDriver::GetCondition() {
    switch (yy_top_state(scanner_)) {
        case RegExp:
            return RegExpCondition;
@begin E4X
        case XMLContent:
            return XMLContentCondition;
        case XMLTag:
            return XMLTagCondition;
@end
        default:
            _assert(false);
    }
}

void CYDriver::SetCondition(Condition condition) {
    struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));

    switch (condition) {
        case RegExpCondition:
            BEGIN(RegExp);
            break;
@begin E4X
        case XMLContentCondition:
            BEGIN(XMLContent);
            break;
        case XMLTagCondition:
            BEGIN(XMLTag);
            break;
@end
        default:
            _assert(false);
    }
}

void CYDriver::PushCondition(Condition condition) {
    switch (condition) {
        case RegExpCondition:
            yy_push_state(RegExp, scanner_);
            break;
@begin E4X
        case XMLContentCondition:
            yy_push_state(XMLContent, scanner_);
            break;
        case XMLTagCondition:
            yy_push_state(XMLTag, scanner_);
            break;
@end
        default:
            _assert(false);
    }
}

void CYDriver::PopCondition() {
    yy_pop_state(scanner_);
}
Commit	Line	Data
b3378a02	1	/* Cycript - Optimizing JavaScript Compiler/Runtime
c15969fd	2	* Copyright (C) 2009-2013 Jay Freeman (saurik)
d15b59f5 JF	3	*/
d15b59f5 JF	4
c15969fd	5	/* GNU General Public License, Version 3 {{{ */
d15b59f5	6	/*
c15969fd JF	7	* Cycript is free software: you can redistribute it and/or modify
	8	* it under the terms of the GNU General Public License as published
	9	* by the Free Software Foundation, either version 3 of the License,
	10	* or (at your option) any later version.
d15b59f5	11	*
c15969fd JF	12	* Cycript is distributed in the hope that it will be useful, but
	13	* WITHOUT ANY WARRANTY; without even the implied warranty of
	14	* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	* GNU General Public License for more details.
d15b59f5	16	*
c15969fd	17	* You should have received a copy of the GNU General Public License
b3378a02 JF	18	* along with Cycript. If not, see <http://www.gnu.org/licenses/>.
b3378a02 JF	19	**/
d15b59f5 JF	20	/* }}} */
d15b59f5 JF	21
2155ab92	22	/* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */
cb02f8ae	23
d15b59f5	24	%{
cac61857	25	#define YYLTYPE cy::location
63b4c5a8 JF	26	#include "Cycript.tab.hh"
63b4c5a8 JF	27	typedef cy::parser::token tk;
693d501b	28
82a02ede JF	29	#include "Highlight.hpp"
82a02ede JF	30
5999c315	31	#define YY_EXTRA_TYPE CYDriver *
db5e2840	32
153c6dec	33	// do /not/ fold token to the return: this is a macro and the ordering is dependent
82a02ede	34	#define F(value, highlight) do { \
153c6dec	35	int token(value); \
39ed6a51	36	@begin ObjectiveC
5602b1ee	37	yyextra->no_.AtImplementation = false; \
39ed6a51	38	@end
5602b1ee JF	39	yyextra->no_.Function = false; \
5602b1ee JF	40	yyextra->no_.OpenBrace = false; \
82a02ede	41	yylval->highlight_ = highlight; \
153c6dec	42	return token; \
3ea7eed0 JF	43	} while (false)
3ea7eed0 JF	44
2eb8215d	45	#define A new($pool)
0cbeddf8	46	#define Y $pool.strmemdup(yytext, yyleng)
2eb8215d	47
82a02ede	48	#define I(type, Type, value, highlight) do { \
2eb8215d	49	yylval->type ## _ = A CY ## Type; \
82a02ede	50	F(value, highlight); \
2eb8215d JF	51	} while (false)
2eb8215d JF	52
697d6fd2	53	#define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
db5e2840 JF	54	#define C T yyextra->state_ = CYClear;
db5e2840 JF	55	#define R T yyextra->state_ = CYRestricted;
5befe15e JF	56
	57	#define N \
	58	if (yyextra->state_ != CYNewLine) { \
2eb8215d JF	59	if (yyextra->state_ != CYRestricted) \
	60	yyextra->state_ = CYNewLine; \
	61	else { \
5befe15e	62	yyextra->state_ = CYClear; \
82a02ede	63	F(tk::NewLine, hi::Nothing); \
2eb8215d	64	} \
5befe15e JF	65	}
5befe15e JF	66
691e4717	67	#define V(more) { \
cb02f8ae JF	68	if (const char nl = reinterpret_cast<const char >(memchr(yytext, '\n', yyleng))) { \
	69	unsigned lines(0); \
	70	size_t left; \
	71	do { \
	72	++lines; \
	73	left = yyleng - (nl - yytext) - 1; \
	74	nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
	75	} while (nl != NULL); \
	76	yylloc->end.lines(lines); \
	77	yylloc->end.columns(left); \
	78	yylloc->step(); \
691e4717	79	more \
cb02f8ae JF	80	} else L \
	81	}
	82
5befe15e JF	83	#define L { \
	84	yylloc->step(); \
	85	yylloc->columns(yyleng); \
	86	}
e7ed5354	87
abc79d6e JF	88	#define M { \
	89	if (yyextra->commented_) { \
	90	I(comment, Comment(Y), tk::Comment, hi::Comment); \
	91	} \
	92	}
	93
931b816a JF	94	int H(char c) {
	95	if (c >= '0' && c <= '9')
	96	return c - '0';
	97	if (c >= 'a' && c <= 'f')
	98	return c - 'a' + 10;
	99	if (c >= 'A' && c <= 'F')
	100	return c - 'A' + 10;
	101	return -1;
	102	}
	103
e7ed5354	104	#define YY_INPUT(data, value, size) { \
d3b63265	105	if (yyextra->data_.eof()) \
e7ed5354 JF	106	value = YY_NULL; \
e7ed5354 JF	107	else { \
d3b63265 JF	108	yyextra->data_.read(data, size); \
	109	size_t copy(yyextra->data_.gcount()); \
	110	value = copy == 0 ? YY_NULL : copy; \
e7ed5354 JF	111	} \
	112	}
	113
e5332278 JF	114	%}
	115
	116	%option prefix="cy"
	117	%option bison-bridge
	118	%option bison-locations
	119	%option noyywrap
	120	%option yylineno
	121	%option nounput
	122	%option interactive
924f67b2	123	%option reentrant
691e4717	124	%option stack
e5332278	125
2bf24581	126	Exponent [eE][+-]?[0-9]+
367eebb1	127	Escape \\[\\'"bfnrtv]\|\\0\|\\x[0-9a-fA-F]{2}\|\\u[0-9a-fA-F]{4}\|\\\n
e5332278	128
63cd45c9 JF	129	IdentifierStart [a-zA-Z$_]
	130	IdentifierPart [a-zA-Z$_0-9]
	131
	132	NonTerminator [^\n]
	133	BackslashSequence \\{NonTerminator}
	134	RegularExpressionFirstChar [^\n*\\/]\|{BackslashSequence}
	135	RegularExpressionChar [^\n\\/]\|{BackslashSequence}
	136	RegularExpressionFlags {IdentifierPart}*
	137	RegularExpressionChars {RegularExpressionChar}*
697d6fd2	138	RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
63cd45c9	139
691e4717 JF	140	@begin E4X
	141	XMLNameStart [a-zA-Z_:]
	142	XMLNamePart [a-zA-Z0-9.-_:]
	143	XMLName {XMLNameStart}{XMLNamePart}*
	144	@end
	145
697d6fd2 JF	146	%s Div
697d6fd2 JF	147	%s RegExp
63cd45c9	148
691e4717 JF	149	@begin E4X
	150	%x XMLContent
	151	%x XMLTag
	152	@end
	153
e5332278 JF	154	%%
e5332278 JF	155
82a02ede	156	<RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} L C I(literal, RegEx(Y), tk::RegularExpressionLiteral, hi::Constant);
63cd45c9	157
abc79d6e	158	\/\/[^\n]* L M
fe123f47 JF	159
	160	/* http://ostermiller.org/findcomment.html */
	161	/* XXX: unify these two rules using !? */
82a02ede	162	\/\!([^]\|[\r\n]\|(\+([^/]\|[\r\n])))\+\/ V() C I(comment, Comment(Y), tk::Comment, hi::Comment);
abc79d6e	163	\/\([^]\|[\r\n]\|(\+([^/]\|[\r\n])))\+\/ V(N) M
66fb559f	164
cb02f8ae	165	@begin E4X
82a02ede JF	166	<RegExp>"<>" L F(tk::LeftRight, hi::Structure);
82a02ede JF	167	<XMLContent>"</>" L F(tk::LeftSlashRight, hi::Structure);
691e4717	168
82a02ede JF	169	<RegExp,XMLContent>\<!\[CDATA\[(\n\|[^[]\|\[[^[]\|\[\[[^>])*]]> V() F(tk::XMLCDATA, hi::Constant);
	170	<RegExp,XMLContent>\<!--(\n\|[^-]\|-[^-])*--> V() F(tk::XMLComment, hi::Comment);
	171	<RegExp,XMLContent>\<?(\n\|[^?]\|\?[^>])*?> V() F(tk::XMLPI, hi::Meta);
691e4717	172
82a02ede JF	173	<XMLTag>"=" L F(tk::Equal, hi::Structure);
	174	<XMLTag>">" L F(tk::Right, hi::Structure);
	175	<XMLTag>"/>" L F(tk::SlashRight, hi::Structure);
	176	<XMLTag>"{" L F(tk::OpenBrace, hi::Structure);
691e4717	177
82a02ede JF	178	<XMLTag>\"(\n\|[^"])\"\|'(\n\|[^'])' V() F(tk::XMLAttributeValue, hi::Constant);
	179	<XMLTag>{XMLName} L F(tk::XMLName, hi::Identifier);
	180	<XMLTag>[ \t\r\n] V() F(tk::XMLWhitespace, hi::Nothing);
db5e2840	181
82a02ede JF	182	<XMLContent>"{" L F(tk::OpenBrace, hi::Structure);
	183	<XMLContent>"<" L F(tk::Left, hi::Structure);
	184	<XMLContent>"</" L F(tk::LeftSlash, hi::Structure);
691e4717 JF	185	@end
691e4717 JF	186
82a02ede	187	"..." L C F(tk::PeriodPeriodPeriod, hi::Meta);
c8a0500b	188
691e4717	189	@begin E4X
82a02ede JF	190	"::" L C F(tk::ColonColon, hi::Operator);
82a02ede JF	191	".." L C F(tk::PeriodPeriod, hi::Operator);
cb02f8ae	192	@end
ac9a5ce1	193
313708a9	194	@begin E4X ObjectiveC
82a02ede	195	"@" L C F(tk::At, hi::Operator);
74dde0f8	196	"#" L C F(tk::Pound, hi::Operator);
313708a9 JF	197	@end
313708a9 JF	198
82a02ede JF	199	"&" L C F(tk::Ampersand, hi::Operator);
	200	"&&" L C F(tk::AmpersandAmpersand, hi::Operator);
	201	"&=" L C F(tk::AmpersandEqual, hi::Operator);
	202	"^" L C F(tk::Carrot, hi::Operator);
	203	"^=" L C F(tk::CarrotEqual, hi::Operator);
	204	"=" L C F(tk::Equal, hi::Operator);
	205	"==" L C F(tk::EqualEqual, hi::Operator);
	206	"===" L C F(tk::EqualEqualEqual, hi::Operator);
	207	"=>" L C F(tk::EqualRight, hi::Operator);
	208	"!" L C F(tk::Exclamation, hi::Operator);
	209	"!=" L C F(tk::ExclamationEqual, hi::Operator);
	210	"!==" L C F(tk::ExclamationEqualEqual, hi::Operator);
	211	"-" L C F(tk::Hyphen, hi::Operator);
	212	"-=" L C F(tk::HyphenEqual, hi::Operator);
	213	"--" L C F(yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen, hi::Operator);
	214	"->" L C F(tk::HyphenRight, hi::Operator);
	215	"<" L C F(tk::Left, hi::Operator);
	216	"<=" L C F(tk::LeftEqual, hi::Operator);
	217	"<<" L C F(tk::LeftLeft, hi::Operator);
	218	"<<=" L C F(tk::LeftLeftEqual, hi::Operator);
	219	"%" L C F(tk::Percent, hi::Operator);
	220	"%=" L C F(tk::PercentEqual, hi::Operator);
	221	"." L C F(tk::Period, hi::Operator);
	222	"\|" L C F(tk::Pipe, hi::Operator);
	223	"\|=" L C F(tk::PipeEqual, hi::Operator);
	224	"\|\|" L C F(tk::PipePipe, hi::Operator);
	225	"+" L C F(tk::Plus, hi::Operator);
	226	"+=" L C F(tk::PlusEqual, hi::Operator);
	227	"++" L C F(yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus, hi::Operator);
	228	">" L C F(tk::Right, hi::Operator);
	229	">=" L C F(tk::RightEqual, hi::Operator);
	230	">>" L C F(tk::RightRight, hi::Operator);
	231	">>=" L C F(tk::RightRightEqual, hi::Operator);
	232	">>>" L C F(tk::RightRightRight, hi::Operator);
	233	">>>=" L C F(tk::RightRightRightEqual, hi::Operator);
	234	"*" L C F(tk::Star, hi::Operator);
	235	"*=" L C F(tk::StarEqual, hi::Operator);
	236	"~" L C F(tk::Tilde, hi::Operator);
	237
	238	<Div>"/" L C F(tk::Slash, hi::Operator);
	239	<Div>"/=" L C F(tk::SlashEqual, hi::Operator);
	240
	241	":" L C F(tk::Colon, hi::Structure);
	242	"," L C F(tk::Comma, hi::Structure);
	243	"?" L C F(tk::Question, hi::Structure);
	244	";" L C F(tk::SemiColon, hi::Structure);
	245
	246	"(" L C F(tk::OpenParen, hi::Structure);
	247	")" L C F(tk::CloseParen, hi::Structure);
	248
	249	"{" L C F(yyextra->no_.OpenBrace ? tk::OpenBrace__ : yylval->newline_ ? tk::OpenBrace_ : tk::OpenBrace, hi::Structure);
	250	"}" L C F(tk::CloseBrace, hi::Structure);
	251
	252	"[" L C F(tk::OpenBracket, hi::Structure);
	253	"]" L C F(tk::CloseBracket, hi::Structure);
5befe15e	254
dc5d7cf4 JF	255	"@error" L C F(tk::AtError, hi::Error);
dc5d7cf4 JF	256
1ba6903e	257	@begin Java
82a02ede	258	"@class" L C F(tk::AtClass, hi::Meta);
1ba6903e JF	259	@end
1ba6903e JF	260
60097023 JF	261	@begin C
	262	"typedef" L C I(identifier, Identifier("typedef"), tk::Typedef, hi::Meta);
	263	@end
	264
cb02f8ae	265	@begin ObjectiveC
46f4f308	266	"@encode" L C F(tk::AtEncode, hi::Meta);
82a02ede JF	267	"@end" L C F(tk::AtEnd, hi::Meta);
82a02ede JF	268	"@implementation" L C F(yyextra->no_.AtImplementation ? tk::AtImplementation_ : tk::AtImplementation, hi::Meta);
73439a14	269	"@import" L C F(tk::AtImport, hi::Special);
82a02ede	270	"@selector" L C F(tk::AtSelector, hi::Meta);
cf19d1c1	271
355cc1eb JF	272	"NULL" L C I(identifier, Identifier("NULL"), tk::Identifier_, hi::Constant);
355cc1eb JF	273	"nil" L C I(identifier, Identifier("nil"), tk::Identifier_, hi::Constant);
60496dd5 JF	274	"YES" L C I(identifier, Identifier("YES"), tk::Yes, hi::Constant);
60496dd5 JF	275	"NO" L C I(identifier, Identifier("NO"), tk::No, hi::Constant);
8b820c00	276
aa82b83b JF	277	"bool" L C I(identifier, Identifier("bool"), tk::Identifier_, hi::Type);
aa82b83b JF	278	"BOOL" L C I(identifier, Identifier("BOOL"), tk::Identifier_, hi::Type);
8b820c00	279	"id" L C I(identifier, Identifier("id"), tk::Identifier_, hi::Type);
aa8f2b2c	280	"SEL" L C I(identifier, Identifier("SEL"), tk::Identifier_, hi::Type);
cb02f8ae	281	@end
d35a3b07	282
355cc1eb JF	283	"undefined" L C I(identifier, Identifier("undefined"), tk::Identifier_, hi::Operator);
355cc1eb JF	284
82a02ede JF	285	"false" L C I(false, False(), tk::False, hi::Constant);
	286	"null" L C I(null, Null(), tk::Null, hi::Constant);
	287	"true" L C I(true, True(), tk::True, hi::Constant);
	288
	289	"auto" L C I(word, Word("auto"), tk::Auto, hi::Meta);
	290	"break" L R I(word, Word("break"), tk::Break, hi::Control);
	291	"case" L C I(word, Word("case"), tk::Case, hi::Control);
	292	"catch" L C I(word, Word("catch"), tk::Catch, hi::Control);
	293	"continue" L R I(word, Word("continue"), tk::Continue, hi::Control);
	294	"default" L C I(word, Word("default"), tk::Default, hi::Control);
	295	"delete" L C I(word, Word("delete"), tk::Delete, hi::Operator);
	296	"do" L C I(word, Word("do"), tk::Do, hi::Control);
	297	"else" L C I(word, Word("else"), tk::Else, hi::Control);
	298	"finally" L C I(word, Word("finally"), tk::Finally, hi::Control);
	299	"for" L C I(word, Word("for"), tk::For, hi::Control);
	300	"function" L C I(word, Word("function"), yyextra->no_.Function ? tk::Function_ : tk::Function, hi::Meta);
	301	"if" L C I(word, Word("if"), tk::If, hi::Control);
	302	"in" L C I(word, Word("in"), yyextra->in_.top() ? tk::In_ : tk::In, hi::Operator);
	303	"instanceof" L C I(word, Word("instanceof"), tk::InstanceOf, hi::Operator);
	304	"new" L C I(word, Word("new"), tk::New, hi::Operator);
	305	"return" L R I(word, Word("return"), tk::Return, hi::Control);
	306	"switch" L C I(word, Word("switch"), tk::Switch, hi::Control);
	307	"this" L C I(this, This(), tk::This, hi::Constant);
	308	"throw" L R I(word, Word("throw"), tk::Throw, hi::Control);
	309	"try" L C I(word, Word("try"), tk::Try, hi::Control);
	310	"typeof" L C I(word, Word("typeof"), tk::TypeOf, hi::Operator);
	311	"var" L C I(word, Word("var"), tk::Var, hi::Meta);
	312	"void" L C I(word, Word("void"), tk::Void, hi::Operator);
	313	"while" L C I(word, Word("while"), tk::While, hi::Control);
	314	"with" L C I(word, Word("with"), tk::With, hi::Control);
	315
	316	"debugger" L C I(word, Word("debugger"), tk::Debugger, hi::Meta);
	317
	318	"const" L C I(word, Word("const"), tk::Const, hi::Meta);
	319
	320	"class" L C I(word, Word("class"), tk::Class, hi::Meta);
	321	"enum" L C I(word, Word("enum"), tk::Enum, hi::Meta);
	322	"export" L C I(word, Word("export"), tk::Export, hi::Meta);
	323	"extends" L C I(word, Word("extends"), tk::Extends, hi::Meta);
	324	"import" L C I(word, Word("import"), tk::Import, hi::Meta);
	325	"super" L C I(word, Word("super"), tk::Super, hi::Constant);
	326
	327	"implements" L C I(identifier, Identifier("implements"), tk::Implements, hi::Meta);
	328	"interface" L C I(identifier, Identifier("interface"), tk::Interface, hi::Meta);
	329	"package" L C I(identifier, Identifier("package"), tk::Package, hi::Meta);
	330	"private" L C I(identifier, Identifier("private"), tk::Private, hi::Meta);
	331	"protected" L C I(identifier, Identifier("protected"), tk::Protected, hi::Meta);
	332	"public" L C I(identifier, Identifier("public"), tk::Public, hi::Meta);
	333	"static" L C I(identifier, Identifier("static"), tk::Static, hi::Meta);
	334
	335	"abstract" L C I(identifier, Identifier("abstract"), tk::Abstract, hi::Meta);
	336	"boolean" L C I(identifier, Identifier("boolean"), tk::Boolean, hi::Type);
	337	"byte" L C I(identifier, Identifier("byte"), tk::Byte, hi::Type);
	338	"char" L C I(identifier, Identifier("char"), tk::Char, hi::Type);
	339	"double" L C I(identifier, Identifier("double"), tk::Double, hi::Type);
	340	"final" L C I(identifier, Identifier("final"), tk::Final, hi::Meta);
	341	"float" L C I(identifier, Identifier("float"), tk::Float, hi::Type);
	342	"goto" L C I(identifier, Identifier("goto"), tk::Goto, hi::Control);
	343	"int" L C I(identifier, Identifier("int"), tk::Int, hi::Type);
	344	"long" L C I(identifier, Identifier("long"), tk::Long, hi::Type);
	345	"native" L C I(identifier, Identifier("native"), tk::Native, hi::Meta);
	346	"short" L C I(identifier, Identifier("short"), tk::Short, hi::Type);
	347	"synchronized" L C I(identifier, Identifier("synchronized"), tk::Synchronized, hi::Meta);
	348	"throws" L C I(identifier, Identifier("throws"), tk::Throws, hi::Meta);
349	"transient" L C I(identifier, Identifier("transient"), tk::Transient, hi::Meta);
350	"volatile" L C I(identifier, Identifier("volatile"), tk::Volatile, hi::Meta);
351
352	"let" L C I(identifier, Identifier("let"), tk::Let, hi::Meta);
353	"yield" L C I(identifier, Identifier("yield"), tk::Yield, hi::Control);
354
355	"each" L C I(identifier, Identifier("each"), tk::Each, hi::Control);
356	"of" L C I(identifier, Identifier("of"), tk::Of, hi::Operator);
5d646fb5	357
691e4717	358	@begin E4X
82a02ede JF	359	"namespace" L C I(identifier, Identifier("namespace"), tk::Namespace, hi::Meta);
82a02ede JF	360	"xml" L C I(identifier, Identifier("xml"), tk::XML, hi::Meta);
691e4717 JF	361	@end
691e4717 JF	362
82a02ede	363	{IdentifierStart}{IdentifierPart}* L C I(identifier, Identifier(Y), tk::Identifier_, hi::Identifier);
5d646fb5	364
82a02ede	365	(\.[0-9]+\|(0\|[1-9][0-9])(\.[0-9])?){Exponent}? L C I(number, Number(strtod(yytext, NULL)), tk::NumericLiteral, hi::Constant);
5d646fb5	366
82a02ede JF	367	0[xX][0-9a-fA-F]+ L C I(number, Number(strtoull(yytext + 2, NULL, 16)), tk::NumericLiteral, hi::Constant);
	368	0[0-7]+ L C I(number, Number(strtoull(yytext + 1, NULL, 8)), tk::NumericLiteral, hi::Constant);
	369	0[bB][0-1]+ L C I(number, Number(strtoull(yytext + 2, NULL, 2)), tk::NumericLiteral, hi::Constant);
5befe15e	370
931b816a	371	\"([^"\\\n]\|{Escape})\"\|'([^'\\\n]\|{Escape})' L C {
2eb8215d	372	char *value(A char[yyleng]);
931b816a JF	373	char *local(value);
931b816a JF	374
66f8d960	375	for (yy_size_t i(1), e(yyleng - 1); i != e; ++i) {
931b816a JF	376	char next(yytext[i]);
	377
	378	if (yytext[i] == '\\')
	379	switch (next = yytext[++i]) {
367eebb1	380	case '\n': continue;
931b816a JF	381	case '\\': next = '\\'; break;
	382	case '\'': next = '\''; break;
	383	case '"': next = '"'; break;
	384	case 'b': next = '\b'; break;
	385	case 'f': next = '\f'; break;
	386	case 'n': next = '\n'; break;
	387	case 'r': next = '\r'; break;
	388	case 't': next = '\t'; break;
	389	case 'v': next = '\v'; break;
	390	case '0': next = '\0'; break;
	391
	392	case 'x':
	393	next = H(yytext[i + 1]) << 4 \| H(yytext[i + 2]);
	394	i += 2;
	395	break;
	396	}
	397
	398	*local++ = next;
	399	}
	400
	401	*local = '\0';
82a02ede	402	I(string, String(value, local - value), tk::StringLiteral, hi::Constant);
931b816a	403	}
5befe15e	404
3ea7eed0	405	\r?\n\|\r\|\xe2\x80[\xa8\xa9] yylloc->end.lines(); yylloc->step(); N
5befe15e JF	406
5befe15e JF	407	[ \t] L
7e5391fd	408
82a02ede	409	<<EOF>> if (yyextra->auto_) { yyextra->auto_ = false; F(tk::AutoComplete, hi::Nothing); } L yyterminate();
94d55b5c	410
48e3be8a	411	. L {
94d55b5c JF	412	CYDriver::Error error;
	413	error.location_ = *yylloc;
	414	error.message_ = "syntax error, unknown token";
	415	yyextra->errors_.push_back(error);
	416	yyterminate();
	417	}
924f67b2 JF	418
	419	%%
	420
5999c315	421	void CYDriver::ScannerInit() {
924f67b2 JF	422	cylex_init(&scanner_);
	423	cyset_extra(this, scanner_);
	424	}
	425
5999c315	426	void CYDriver::ScannerDestroy() {
924f67b2 JF	427	cylex_destroy(scanner_);
924f67b2 JF	428	}
63cd45c9	429
691e4717 JF	430	CYDriver::Condition CYDriver::GetCondition() {
	431	switch (yy_top_state(scanner_)) {
	432	case RegExp:
	433	return RegExpCondition;
	434	@begin E4X
	435	case XMLContent:
	436	return XMLContentCondition;
	437	case XMLTag:
	438	return XMLTagCondition;
	439	@end
	440	default:
	441	_assert(false);
	442	}
	443	}
	444
	445	void CYDriver::SetCondition(Condition condition) {
63cd45c9 JF	446	struct yyguts_t yyg(reinterpret_cast<struct yyguts_t >(scanner_));
	447
	448	switch (condition) {
697d6fd2 JF	449	case RegExpCondition:
697d6fd2 JF	450	BEGIN(RegExp);
63cd45c9	451	break;
691e4717 JF	452	@begin E4X
	453	case XMLContentCondition:
	454	BEGIN(XMLContent);
	455	break;
	456	case XMLTagCondition:
	457	BEGIN(XMLTag);
	458	break;
	459	@end
63cd45c9 JF	460	default:
	461	_assert(false);
	462	}
	463	}
691e4717 JF	464
	465	void CYDriver::PushCondition(Condition condition) {
	466	switch (condition) {
	467	case RegExpCondition:
	468	yy_push_state(RegExp, scanner_);
	469	break;
	470	@begin E4X
	471	case XMLContentCondition:
	472	yy_push_state(XMLContent, scanner_);
	473	break;
	474	case XMLTagCondition:
	475	yy_push_state(XMLTag, scanner_);
	476	break;
	477	@end
	478	default:
	479	_assert(false);
	480	}
	481	}
	482
	483	void CYDriver::PopCondition() {
	484	yy_pop_state(scanner_);
	485	}