[cycript.git] / Cycript.l.in

/* Cycript - Optimizing JavaScript Compiler/Runtime
 * Copyright (C) 2009-2015  Jay Freeman (saurik)
*/

/* GNU Affero General Public License, Version 3 {{{ */
/*
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.

 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.

 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
**/
/* }}} */

/* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */

%{

#if defined(__clang__)
#pragma clang diagnostic push
#pragma clang diagnostic ignored "-Wunknown-pragmas"
#pragma clang diagnostic ignored "-Wdeprecated-register"
#endif

#define YYLTYPE CYLocation
#include "Cycript.tab.hh"
typedef cy::parser::token tk;

#include "Highlight.hpp"

#define YY_EXTRA_TYPE CYDriver *

// do /not/ fold token to the return: this is a macro and the ordering is dependent
#define F(value, highlight) do { \
    int token(value); \
@begin ObjectiveC
    yyextra->no_.AtImplementation = false; \
@end
    yyextra->no_.Function = false; \
    yyextra->no_.OpenBrace = false; \
    yylval->highlight_ = highlight; \
    return token; \
} while (false)

#define A new($pool)
#define Y $pool.strmemdup(yytext, yyleng)

#define I(type, Type, value, highlight) do { \
    yylval->type ## _ = A CY ## Type; \
    F(value, highlight); \
} while (false)

#define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
#define C T yyextra->state_ = CYClear;
#define R T yyextra->state_ = CYRestricted;

#define N \
    if (yyextra->state_ != CYNewLine) { \
        if (yyextra->state_ != CYRestricted) \
            yyextra->state_ = CYNewLine; \
        else { \
            yyextra->state_ = CYClear; \
            F(tk::NewLine, hi::Nothing); \
        } \
    }

#define V(more) { \
    if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
        unsigned lines(0); \
        size_t left; \
        do { \
            ++lines; \
            left = yyleng - (nl - yytext) - 1; \
            nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
        } while (nl != NULL); \
        yylloc->step(); \
        yylloc->end.lines(lines); \
        yylloc->end.columns(left); \
        more \
    } else L \
}

#define L { \
    yylloc->step(); \
    yylloc->end.columns(yyleng); \
}

#define M { \
    if (yyextra->commented_) { \
        I(comment, Comment(Y), tk::Comment, hi::Comment); \
    } \
}

#define E(message) { \
    CYDriver::Error error; \
    error.location_ = *yylloc; \
    error.message_ = "syntax error, " message; \
    yyextra->errors_.push_back(error); \
    yyterminate(); \
}

int H(char c) {
    if (c >= '0' && c <= '9')
        return c - '0';
    if (c >= 'a' && c <= 'f')
        return c - 'a' + 10;
    if (c >= 'A' && c <= 'F')
        return c - 'A' + 10;
    return -1;
}

#define YY_INPUT(data, value, size) { \
    if (yyextra->data_.eof()) \
        value = YY_NULL; \
    else { \
        yyextra->data_.read(data, size); \
        size_t copy(yyextra->data_.gcount()); \
        value = copy == 0 ? YY_NULL : copy; \
    } \
}

%}

%option prefix="cy"
%option bison-bridge
%option bison-locations
%option nodefault
%option noyywrap
%option noyylineno
%option nounput
%option nounistd
%option 8bit
%option backup
%option batch
%option full
%option never-interactive
%option pointer
%option reentrant
%option stack

Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n

IdentifierStart [a-zA-Z$_]
IdentifierPart  [a-zA-Z$_0-9]

NonTerminator [^\n]
BackslashSequence \\{NonTerminator}
RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
RegularExpressionChar [^\n\\/]|{BackslashSequence}
RegularExpressionFlags {IdentifierPart}*
RegularExpressionChars {RegularExpressionChar}*
RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}

@begin E4X
XMLNameStart [a-zA-Z_:]
XMLNamePart [a-zA-Z0-9.-_:]
XMLName {XMLNameStart}{XMLNamePart}*
@end

%s Div
%s RegExp

@begin E4X
%x XMLContent
%x XMLTag
@end

%%

<RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} L C I(literal, RegEx(Y), tk::RegularExpressionLiteral, hi::Constant);
<RegExp>\/{RegularExpressionBody}?\\? L E("unterminated regex")

#![^\n]* L M

\/\/[^\n]* L M

	/* http://ostermiller.org/findcomment.html */
	/* XXX: unify these two rules using !? */
\/\*!([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V() C I(comment, Comment(Y), tk::Comment, hi::Comment);
\/\*([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V(N) M
\/\*([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\** V() E("invalid comment")

@begin E4X
<RegExp>"<>"      L F(tk::LeftRight, hi::Structure);
<XMLContent>"</>" L F(tk::LeftSlashRight, hi::Structure);

<RegExp,XMLContent>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]> V() F(tk::XMLCDATA, hi::Constant);
<RegExp,XMLContent>\<!--(\n|[^-]|-[^-])*--> V() F(tk::XMLComment, hi::Comment);
<RegExp,XMLContent>\<?(\n|[^?]|\?[^>])*?> V() F(tk::XMLPI, hi::Meta);

<XMLTag>"="  L F(tk::Equal, hi::Structure);
<XMLTag>">"  L F(tk::Right, hi::Structure);
<XMLTag>"/>" L F(tk::SlashRight, hi::Structure);
<XMLTag>"{"  L F(tk::OpenBrace, hi::Structure);

<XMLTag>\"(\n|[^"])*\"|'(\n|[^'])*' V() F(tk::XMLAttributeValue, hi::Constant);
<XMLTag>{XMLName} L F(tk::XMLName, hi::Identifier);
<XMLTag>[ \t\r\n] V() F(tk::XMLWhitespace, hi::Nothing);

<XMLContent>"{"  L F(tk::OpenBrace, hi::Structure);
<XMLContent>"<"  L F(tk::Left, hi::Structure);
<XMLContent>"</" L F(tk::LeftSlash, hi::Structure);
@end

"..."  L C F(tk::PeriodPeriodPeriod, hi::Meta);
".."   L E("invalid operator")

@begin E4X
"::"   L C F(tk::ColonColon, hi::Operator);
".."   L C F(tk::PeriodPeriod, hi::Operator);
@end

@begin E4X ObjectiveC
"@"    L C F(tk::At, hi::Operator);
"#"    L C F(tk::Pound, hi::Operator);
@end

"&"    L C F(tk::Ampersand, hi::Operator);
"&&"   L C F(tk::AmpersandAmpersand, hi::Operator);
"&="   L C F(tk::AmpersandEqual, hi::Operator);
"^"    L C F(tk::Carrot, hi::Operator);
"^="   L C F(tk::CarrotEqual, hi::Operator);
"="    L C F(tk::Equal, hi::Operator);
"=="   L C F(tk::EqualEqual, hi::Operator);
"==="  L C F(tk::EqualEqualEqual, hi::Operator);
"=>"   L C F(tk::EqualRight, hi::Operator);
"!"    L C F(tk::Exclamation, hi::Operator);
"!="   L C F(tk::ExclamationEqual, hi::Operator);
"!=="  L C F(tk::ExclamationEqualEqual, hi::Operator);
"-"    L C F(tk::Hyphen, hi::Operator);
"-="   L C F(tk::HyphenEqual, hi::Operator);
"--"   L C F(yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen, hi::Operator);
"->"   L C F(tk::HyphenRight, hi::Operator);
"<"    L C F(tk::Left, hi::Operator);
"<="   L C F(tk::LeftEqual, hi::Operator);
"<<"   L C F(tk::LeftLeft, hi::Operator);
"<<="  L C F(tk::LeftLeftEqual, hi::Operator);
"%"    L C F(tk::Percent, hi::Operator);
"%="   L C F(tk::PercentEqual, hi::Operator);
"."    L C F(tk::Period, hi::Operator);
"|"    L C F(tk::Pipe, hi::Operator);
"|="   L C F(tk::PipeEqual, hi::Operator);
"||"   L C F(tk::PipePipe, hi::Operator);
"+"    L C F(tk::Plus, hi::Operator);
"+="   L C F(tk::PlusEqual, hi::Operator);
"++"   L C F(yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus, hi::Operator);
">"    L C F(tk::Right, hi::Operator);
">="   L C F(tk::RightEqual, hi::Operator);
">>"   L C F(tk::RightRight, hi::Operator);
">>="  L C F(tk::RightRightEqual, hi::Operator);
">>>"  L C F(tk::RightRightRight, hi::Operator);
">>>=" L C F(tk::RightRightRightEqual, hi::Operator);
"*"    L C F(tk::Star, hi::Operator);
"*="   L C F(tk::StarEqual, hi::Operator);
"~"    L C F(tk::Tilde, hi::Operator);

<Div>"/"  L C F(tk::Slash, hi::Operator);
<Div>"/=" L C F(tk::SlashEqual, hi::Operator);

":"    L C F(tk::Colon, hi::Structure);
","    L C F(tk::Comma, hi::Structure);
"?"    L C F(tk::Question, hi::Structure);
";"    L C F(tk::SemiColon, hi::Structure);

"("    L C F(tk::OpenParen, hi::Structure);
")"    L C F(tk::CloseParen, hi::Structure);

"{"    L C F(yyextra->no_.OpenBrace ? tk::OpenBrace__ : yylval->newline_ ? tk::OpenBrace_ : tk::OpenBrace, hi::Structure);
"}"    L C F(tk::CloseBrace, hi::Structure);

"["    L C F(tk::OpenBracket, hi::Structure);
"]"    L C F(tk::CloseBracket, hi::Structure);

"@error"          L C F(tk::AtError, hi::Error);

@begin Java
"@class"          L C F(tk::AtClass, hi::Meta);
@end

@begin C
"typedef"         L C I(identifier, Identifier("typedef"), tk::Typedef, hi::Meta);
"unsigned"        L C I(identifier, Identifier("unsigned"), tk::Unsigned, hi::Type);
"signed"          L C I(identifier, Identifier("signed"), tk::Signed, hi::Type);
"extern"          L C I(identifier, Identifier("extern"), tk::Extern, hi::Type);
@end

@begin C
"@encode"         L C F(tk::AtEncode, hi::Meta);
@end

@begin ObjectiveC
"@end"            L C F(tk::AtEnd, hi::Meta);
"@implementation" L C F(yyextra->no_.AtImplementation ? tk::AtImplementation_ : tk::AtImplementation, hi::Meta);
"@import"         L C F(tk::AtImport, hi::Special);
"@selector"       L C F(tk::AtSelector, hi::Meta);

"NULL"         L C I(identifier, Identifier("NULL"), tk::Identifier_, hi::Constant);
"nil"          L C I(identifier, Identifier("nil"), tk::Identifier_, hi::Constant);
"YES"          L C I(identifier, Identifier("YES"), tk::Yes, hi::Constant);
"NO"           L C I(identifier, Identifier("NO"), tk::No, hi::Constant);

"bool"         L C I(identifier, Identifier("bool"), tk::Identifier_, hi::Type);
"BOOL"         L C I(identifier, Identifier("BOOL"), tk::Identifier_, hi::Type);
"id"           L C I(identifier, Identifier("id"), tk::Identifier_, hi::Type);
"SEL"          L C I(identifier, Identifier("SEL"), tk::Identifier_, hi::Type);
@end

"undefined"    L C I(identifier, Identifier("undefined"), tk::Identifier_, hi::Operator);

"false"        L C I(false, False(), tk::False, hi::Constant);
"null"         L C I(null, Null(), tk::Null, hi::Constant);
"true"         L C I(true, True(), tk::True, hi::Constant);

"auto"         L C I(word, Word("auto"), tk::Auto, hi::Meta);
"break"        L R I(word, Word("break"), tk::Break, hi::Control);
"case"         L C I(word, Word("case"), tk::Case, hi::Control);
"catch"        L C I(word, Word("catch"), tk::Catch, hi::Control);
"continue"     L R I(word, Word("continue"), tk::Continue, hi::Control);
"default"      L C I(word, Word("default"), tk::Default, hi::Control);
"delete"       L C I(word, Word("delete"), tk::Delete, hi::Operator);
"do"           L C I(word, Word("do"), tk::Do, hi::Control);
"else"         L C I(word, Word("else"), tk::Else, hi::Control);
"finally"      L C I(word, Word("finally"), tk::Finally, hi::Control);
"for"          L C I(word, Word("for"), tk::For, hi::Control);
"function"     L C I(word, Word("function"), yyextra->no_.Function ? tk::Function_ : tk::Function, hi::Meta);
"if"           L C I(word, Word("if"), tk::If, hi::Control);
"in"           L C I(word, Word("in"), yyextra->in_.top() ? tk::In_ : tk::In, hi::Operator);
"instanceof"   L C I(word, Word("instanceof"), tk::InstanceOf, hi::Operator);
"new"          L C I(word, Word("new"), tk::New, hi::Operator);
"return"       L R I(word, Word("return"), tk::Return, hi::Control);
"switch"       L C I(word, Word("switch"), tk::Switch, hi::Control);
"this"         L C I(this, This(), tk::This, hi::Constant);
"throw"        L R I(word, Word("throw"), tk::Throw, hi::Control);
"try"          L C I(word, Word("try"), tk::Try, hi::Control);
"typeof"       L C I(word, Word("typeof"), tk::TypeOf, hi::Operator);
"var"          L C I(word, Word("var"), tk::Var, hi::Meta);
"void"         L C I(word, Word("void"), tk::Void, hi::Operator);
"while"        L C I(word, Word("while"), tk::While, hi::Control);
"with"         L C I(word, Word("with"), tk::With, hi::Control);

"debugger"     L C I(word, Word("debugger"), tk::Debugger, hi::Meta);

"const"        L C I(word, Word("const"), tk::Const, hi::Meta);

"class"        L C I(word, Word("class"), tk::Class, hi::Meta);
"enum"         L C I(word, Word("enum"), tk::Enum, hi::Meta);
"export"       L C I(word, Word("export"), tk::Export, hi::Meta);
"extends"      L C I(word, Word("extends"), tk::Extends, hi::Meta);
"import"       L C I(word, Word("import"), tk::Import, hi::Meta);
"super"        L C I(word, Word("super"), tk::Super, hi::Constant);

"implements"   L C I(identifier, Identifier("implements"), tk::Implements, hi::Meta);
"interface"    L C I(identifier, Identifier("interface"), tk::Interface, hi::Meta);
"package"      L C I(identifier, Identifier("package"), tk::Package, hi::Meta);
"private"      L C I(identifier, Identifier("private"), tk::Private, hi::Meta);
"protected"    L C I(identifier, Identifier("protected"), tk::Protected, hi::Meta);
"public"       L C I(identifier, Identifier("public"), tk::Public, hi::Meta);
"static"       L C I(identifier, Identifier("static"), tk::Static, hi::Meta);

"abstract"     L C I(identifier, Identifier("abstract"), tk::Abstract, hi::Meta);
"boolean"      L C I(identifier, Identifier("boolean"), tk::Boolean, hi::Type);
"byte"         L C I(identifier, Identifier("byte"), tk::Byte, hi::Type);
"char"         L C I(identifier, Identifier("char"), tk::Char, hi::Type);
"double"       L C I(identifier, Identifier("double"), tk::Double, hi::Type);
"final"        L C I(identifier, Identifier("final"), tk::Final, hi::Meta);
"float"        L C I(identifier, Identifier("float"), tk::Float, hi::Type);
"goto"         L C I(identifier, Identifier("goto"), tk::Goto, hi::Control);
"int"          L C I(identifier, Identifier("int"), tk::Int, hi::Type);
"long"         L C I(identifier, Identifier("long"), tk::Long, hi::Type);
"native"       L C I(identifier, Identifier("native"), tk::Native, hi::Meta);
"short"        L C I(identifier, Identifier("short"), tk::Short, hi::Type);
"synchronized" L C I(identifier, Identifier("synchronized"), tk::Synchronized, hi::Meta);
"throws"       L C I(identifier, Identifier("throws"), tk::Throws, hi::Meta);
"transient"    L C I(identifier, Identifier("transient"), tk::Transient, hi::Meta);
"volatile"     L C I(identifier, Identifier("volatile"), tk::Volatile, hi::Meta);

"let"          L C I(identifier, Identifier("let"), tk::Let, hi::Meta);
"yield"        L C I(identifier, Identifier("yield"), tk::Yield, hi::Control);

"each"         L C I(identifier, Identifier("each"), tk::Each, hi::Control);
"of"           L C I(identifier, Identifier("of"), tk::Of, hi::Operator);

@begin E4X
"namespace"    L C I(identifier, Identifier("namespace"), tk::Namespace, hi::Meta);
"xml"          L C I(identifier, Identifier("xml"), tk::XML, hi::Meta);
@end

{IdentifierStart}{IdentifierPart}* L C I(identifier, Identifier(Y), tk::Identifier_, hi::Identifier);


0[xX][0-9a-fA-F]+ L C I(number, Number(strtoull(yytext + 2, NULL, 16)), tk::NumericLiteral, hi::Constant);
0[0-7]+ L C I(number, Number(strtoull(yytext + 1, NULL, 8)), tk::NumericLiteral, hi::Constant);
0[bB][0-1]+ L C I(number, Number(strtoull(yytext + 2, NULL, 2)), tk::NumericLiteral, hi::Constant);

(\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?)([eE][+-]?[0-9]+)? L C I(number, Number(strtod(yytext, NULL)), tk::NumericLiteral, hi::Constant);
(\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?)[eE][+-]?{IdentifierPart}* L E("invalid exponent")
(\.?[0-9]|(0|[1-9][0-9]*)?\.){IdentifierPart}* L E("invalid number")

\"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
    char *value(A char[yyleng]);
    char *local(value);

    for (yy_size_t i(1), e(yyleng - 1); i != e; ++i) {
        char next(yytext[i]);

        if (yytext[i] == '\\')
            switch (next = yytext[++i]) {
                case '\n': continue;
                case '\\': next = '\\'; break;
                case '\'': next = '\''; break;
                case '"': next = '"'; break;
                case 'b': next = '\b'; break;
                case 'f': next = '\f'; break;
                case 'n': next = '\n'; break;
                case 'r': next = '\r'; break;
                case 't': next = '\t'; break;
                case 'v': next = '\v'; break;
                case '0': next = '\0'; break;

                case 'x':
                    next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
                    i += 2;
                break;
            }

        *local++ = next;
    }

    *local = '\0';
    I(string, String(value, local - value), tk::StringLiteral, hi::Constant);
}

(\"([^"\\\n]|{Escape})*|'([^'\\\n]|{Escape})*)(\\(x.{0,2}|u.{0,4})?)? L E("invalid escape")

\r?\n|\r|\xe2\x80[\xa8\xa9] yylloc->step(); yylloc->end.lines(); N

[ \t] L

<<EOF>> if (yyextra->auto_) { yyextra->auto_ = false; F(tk::AutoComplete, hi::Nothing); } L yyterminate();

@{IdentifierPart}+|\xe2.|. L E("unknown token")

%%

void CYDriver::ScannerInit() {
    cylex_init(&scanner_);
    cyset_extra(this, scanner_);
}

void CYDriver::ScannerDestroy() {
    cylex_destroy(scanner_);
}

CYDriver::Condition CYDriver::GetCondition() {
    switch (yy_top_state(scanner_)) {
        case RegExp:
            return RegExpCondition;
@begin E4X
        case XMLContent:
            return XMLContentCondition;
        case XMLTag:
            return XMLTagCondition;
@end
        default:
            _assert(false);
    }
}

void CYDriver::SetCondition(Condition condition) {
    struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));

    switch (condition) {
        case RegExpCondition:
            BEGIN(RegExp);
            break;
@begin E4X
        case XMLContentCondition:
            BEGIN(XMLContent);
            break;
        case XMLTagCondition:
            BEGIN(XMLTag);
            break;
@end
        default:
            _assert(false);
    }
}

void CYDriver::PushCondition(Condition condition) {
    switch (condition) {
        case RegExpCondition:
            yy_push_state(RegExp, scanner_);
            break;
@begin E4X
        case XMLContentCondition:
            yy_push_state(XMLContent, scanner_);
            break;
        case XMLTagCondition:
            yy_push_state(XMLTag, scanner_);
            break;
@end
        default:
            _assert(false);
    }
}

void CYDriver::PopCondition() {
    yy_pop_state(scanner_);
}

#if defined(__clang__)
#pragma clang diagnostic pop
#endif
Commit	Line	Data
b3378a02	1	/* Cycript - Optimizing JavaScript Compiler/Runtime
c1d3e52e	2	* Copyright (C) 2009-2015 Jay Freeman (saurik)
d15b59f5 JF	3	*/
d15b59f5 JF	4
f95d2598	5	/* GNU Affero General Public License, Version 3 {{{ */
d15b59f5	6	/*
f95d2598 JF	7	* This program is free software: you can redistribute it and/or modify
	8	* it under the terms of the GNU Affero General Public License as published by
	9	* the Free Software Foundation, either version 3 of the License, or
	10	* (at your option) any later version.
	11
	12	* This program is distributed in the hope that it will be useful,
	13	* but WITHOUT ANY WARRANTY; without even the implied warranty of
c15969fd	14	* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
f95d2598 JF	15	* GNU Affero General Public License for more details.
	16
	17	* You should have received a copy of the GNU Affero General Public License
	18	* along with this program. If not, see <http://www.gnu.org/licenses/>.
b3378a02	19	**/
d15b59f5 JF	20	/* }}} */
d15b59f5 JF	21
2155ab92	22	/* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */
cb02f8ae	23
d15b59f5	24	%{
1771224f JF	25
	26	#if defined(__clang__)
	27	#pragma clang diagnostic push
	28	#pragma clang diagnostic ignored "-Wunknown-pragmas"
	29	#pragma clang diagnostic ignored "-Wdeprecated-register"
	30	#endif
	31
58afc6aa	32	#define YYLTYPE CYLocation
63b4c5a8 JF	33	#include "Cycript.tab.hh"
63b4c5a8 JF	34	typedef cy::parser::token tk;
693d501b	35
82a02ede JF	36	#include "Highlight.hpp"
82a02ede JF	37
5999c315	38	#define YY_EXTRA_TYPE CYDriver *
db5e2840	39
153c6dec	40	// do /not/ fold token to the return: this is a macro and the ordering is dependent
82a02ede	41	#define F(value, highlight) do { \
153c6dec	42	int token(value); \
39ed6a51	43	@begin ObjectiveC
5602b1ee	44	yyextra->no_.AtImplementation = false; \
39ed6a51	45	@end
5602b1ee JF	46	yyextra->no_.Function = false; \
5602b1ee JF	47	yyextra->no_.OpenBrace = false; \
82a02ede	48	yylval->highlight_ = highlight; \
153c6dec	49	return token; \
3ea7eed0 JF	50	} while (false)
3ea7eed0 JF	51
2eb8215d	52	#define A new($pool)
0cbeddf8	53	#define Y $pool.strmemdup(yytext, yyleng)
2eb8215d	54
82a02ede	55	#define I(type, Type, value, highlight) do { \
2eb8215d	56	yylval->type ## _ = A CY ## Type; \
82a02ede	57	F(value, highlight); \
2eb8215d JF	58	} while (false)
2eb8215d JF	59
697d6fd2	60	#define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
db5e2840 JF	61	#define C T yyextra->state_ = CYClear;
db5e2840 JF	62	#define R T yyextra->state_ = CYRestricted;
5befe15e JF	63
	64	#define N \
	65	if (yyextra->state_ != CYNewLine) { \
2eb8215d JF	66	if (yyextra->state_ != CYRestricted) \
	67	yyextra->state_ = CYNewLine; \
	68	else { \
5befe15e	69	yyextra->state_ = CYClear; \
82a02ede	70	F(tk::NewLine, hi::Nothing); \
2eb8215d	71	} \
5befe15e JF	72	}
5befe15e JF	73
691e4717	74	#define V(more) { \
cb02f8ae JF	75	if (const char nl = reinterpret_cast<const char >(memchr(yytext, '\n', yyleng))) { \
	76	unsigned lines(0); \
	77	size_t left; \
	78	do { \
	79	++lines; \
	80	left = yyleng - (nl - yytext) - 1; \
	81	nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
	82	} while (nl != NULL); \
f89aaa11	83	yylloc->step(); \
cb02f8ae JF	84	yylloc->end.lines(lines); \
cb02f8ae JF	85	yylloc->end.columns(left); \
691e4717	86	more \
cb02f8ae JF	87	} else L \
	88	}
	89
5befe15e JF	90	#define L { \
5befe15e JF	91	yylloc->step(); \
58afc6aa	92	yylloc->end.columns(yyleng); \
5befe15e	93	}
e7ed5354	94
abc79d6e JF	95	#define M { \
	96	if (yyextra->commented_) { \
	97	I(comment, Comment(Y), tk::Comment, hi::Comment); \
	98	} \
	99	}
	100
e31ea496 JF	101	#define E(message) { \
	102	CYDriver::Error error; \
	103	error.location_ = *yylloc; \
	104	error.message_ = "syntax error, " message; \
	105	yyextra->errors_.push_back(error); \
	106	yyterminate(); \
	107	}
	108
931b816a JF	109	int H(char c) {
	110	if (c >= '0' && c <= '9')
	111	return c - '0';
	112	if (c >= 'a' && c <= 'f')
	113	return c - 'a' + 10;
	114	if (c >= 'A' && c <= 'F')
	115	return c - 'A' + 10;
	116	return -1;
	117	}
	118
e7ed5354	119	#define YY_INPUT(data, value, size) { \
d3b63265	120	if (yyextra->data_.eof()) \
e7ed5354 JF	121	value = YY_NULL; \
e7ed5354 JF	122	else { \
d3b63265 JF	123	yyextra->data_.read(data, size); \
	124	size_t copy(yyextra->data_.gcount()); \
	125	value = copy == 0 ? YY_NULL : copy; \
e7ed5354 JF	126	} \
	127	}
	128
e5332278 JF	129	%}
	130
	131	%option prefix="cy"
	132	%option bison-bridge
	133	%option bison-locations
af340def	134	%option nodefault
e5332278	135	%option noyywrap
7b869615	136	%option noyylineno
e5332278	137	%option nounput
af340def JF	138	%option nounistd
	139	%option 8bit
	140	%option backup
6c962f8b	141	%option batch
e31ea496	142	%option full
6c962f8b	143	%option never-interactive
af340def	144	%option pointer
924f67b2	145	%option reentrant
691e4717	146	%option stack
e5332278	147
367eebb1	148	Escape \\[\\'"bfnrtv]\|\\0\|\\x[0-9a-fA-F]{2}\|\\u[0-9a-fA-F]{4}\|\\\n
e5332278	149
63cd45c9 JF	150	IdentifierStart [a-zA-Z$_]
	151	IdentifierPart [a-zA-Z$_0-9]
	152
	153	NonTerminator [^\n]
	154	BackslashSequence \\{NonTerminator}
	155	RegularExpressionFirstChar [^\n*\\/]\|{BackslashSequence}
	156	RegularExpressionChar [^\n\\/]\|{BackslashSequence}
	157	RegularExpressionFlags {IdentifierPart}*
	158	RegularExpressionChars {RegularExpressionChar}*
697d6fd2	159	RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
63cd45c9	160
691e4717 JF	161	@begin E4X
	162	XMLNameStart [a-zA-Z_:]
	163	XMLNamePart [a-zA-Z0-9.-_:]
	164	XMLName {XMLNameStart}{XMLNamePart}*
	165	@end
	166
697d6fd2 JF	167	%s Div
697d6fd2 JF	168	%s RegExp
63cd45c9	169
691e4717 JF	170	@begin E4X
	171	%x XMLContent
	172	%x XMLTag
	173	@end
	174
e5332278 JF	175	%%
e5332278 JF	176
82a02ede	177	<RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} L C I(literal, RegEx(Y), tk::RegularExpressionLiteral, hi::Constant);
e31ea496	178	<RegExp>\/{RegularExpressionBody}?\\? L E("unterminated regex")
63cd45c9	179
fc44232b JF	180	#![^\n]* L M
fc44232b JF	181
abc79d6e	182	\/\/[^\n]* L M
fe123f47 JF	183
	184	/* http://ostermiller.org/findcomment.html */
	185	/* XXX: unify these two rules using !? */
82a02ede	186	\/\!([^]\|[\r\n]\|(\+([^/]\|[\r\n])))\+\/ V() C I(comment, Comment(Y), tk::Comment, hi::Comment);
abc79d6e	187	\/\([^]\|[\r\n]\|(\+([^/]\|[\r\n])))\+\/ V(N) M
e31ea496	188	\/\([^]\|[\r\n]\|(\+([^/]\|[\r\n])))\* V() E("invalid comment")
66fb559f	189
cb02f8ae	190	@begin E4X
82a02ede JF	191	<RegExp>"<>" L F(tk::LeftRight, hi::Structure);
82a02ede JF	192	<XMLContent>"</>" L F(tk::LeftSlashRight, hi::Structure);
691e4717	193
82a02ede JF	194	<RegExp,XMLContent>\<!\[CDATA\[(\n\|[^[]\|\[[^[]\|\[\[[^>])*]]> V() F(tk::XMLCDATA, hi::Constant);
	195	<RegExp,XMLContent>\<!--(\n\|[^-]\|-[^-])*--> V() F(tk::XMLComment, hi::Comment);
	196	<RegExp,XMLContent>\<?(\n\|[^?]\|\?[^>])*?> V() F(tk::XMLPI, hi::Meta);
691e4717	197
82a02ede JF	198	<XMLTag>"=" L F(tk::Equal, hi::Structure);
	199	<XMLTag>">" L F(tk::Right, hi::Structure);
	200	<XMLTag>"/>" L F(tk::SlashRight, hi::Structure);
	201	<XMLTag>"{" L F(tk::OpenBrace, hi::Structure);
691e4717	202
82a02ede JF	203	<XMLTag>\"(\n\|[^"])\"\|'(\n\|[^'])' V() F(tk::XMLAttributeValue, hi::Constant);
	204	<XMLTag>{XMLName} L F(tk::XMLName, hi::Identifier);
	205	<XMLTag>[ \t\r\n] V() F(tk::XMLWhitespace, hi::Nothing);
db5e2840	206
82a02ede JF	207	<XMLContent>"{" L F(tk::OpenBrace, hi::Structure);
	208	<XMLContent>"<" L F(tk::Left, hi::Structure);
	209	<XMLContent>"</" L F(tk::LeftSlash, hi::Structure);
691e4717 JF	210	@end
691e4717 JF	211
82a02ede	212	"..." L C F(tk::PeriodPeriodPeriod, hi::Meta);
e31ea496	213	".." L E("invalid operator")
c8a0500b	214
691e4717	215	@begin E4X
82a02ede JF	216	"::" L C F(tk::ColonColon, hi::Operator);
82a02ede JF	217	".." L C F(tk::PeriodPeriod, hi::Operator);
cb02f8ae	218	@end
ac9a5ce1	219
313708a9	220	@begin E4X ObjectiveC
82a02ede	221	"@" L C F(tk::At, hi::Operator);
ac9d4181	222	"#" L C F(tk::Pound, hi::Operator);
313708a9 JF	223	@end
313708a9 JF	224
82a02ede JF	225	"&" L C F(tk::Ampersand, hi::Operator);
	226	"&&" L C F(tk::AmpersandAmpersand, hi::Operator);
	227	"&=" L C F(tk::AmpersandEqual, hi::Operator);
	228	"^" L C F(tk::Carrot, hi::Operator);
	229	"^=" L C F(tk::CarrotEqual, hi::Operator);
	230	"=" L C F(tk::Equal, hi::Operator);
	231	"==" L C F(tk::EqualEqual, hi::Operator);
	232	"===" L C F(tk::EqualEqualEqual, hi::Operator);
	233	"=>" L C F(tk::EqualRight, hi::Operator);
	234	"!" L C F(tk::Exclamation, hi::Operator);
	235	"!=" L C F(tk::ExclamationEqual, hi::Operator);
	236	"!==" L C F(tk::ExclamationEqualEqual, hi::Operator);
	237	"-" L C F(tk::Hyphen, hi::Operator);
	238	"-=" L C F(tk::HyphenEqual, hi::Operator);
	239	"--" L C F(yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen, hi::Operator);
	240	"->" L C F(tk::HyphenRight, hi::Operator);
	241	"<" L C F(tk::Left, hi::Operator);
	242	"<=" L C F(tk::LeftEqual, hi::Operator);
	243	"<<" L C F(tk::LeftLeft, hi::Operator);
	244	"<<=" L C F(tk::LeftLeftEqual, hi::Operator);
	245	"%" L C F(tk::Percent, hi::Operator);
	246	"%=" L C F(tk::PercentEqual, hi::Operator);
	247	"." L C F(tk::Period, hi::Operator);
	248	"\|" L C F(tk::Pipe, hi::Operator);
	249	"\|=" L C F(tk::PipeEqual, hi::Operator);
	250	"\|\|" L C F(tk::PipePipe, hi::Operator);
	251	"+" L C F(tk::Plus, hi::Operator);
	252	"+=" L C F(tk::PlusEqual, hi::Operator);
	253	"++" L C F(yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus, hi::Operator);
	254	">" L C F(tk::Right, hi::Operator);
	255	">=" L C F(tk::RightEqual, hi::Operator);
	256	">>" L C F(tk::RightRight, hi::Operator);
	257	">>=" L C F(tk::RightRightEqual, hi::Operator);
	258	">>>" L C F(tk::RightRightRight, hi::Operator);
	259	">>>=" L C F(tk::RightRightRightEqual, hi::Operator);
	260	"*" L C F(tk::Star, hi::Operator);
	261	"*=" L C F(tk::StarEqual, hi::Operator);
	262	"~" L C F(tk::Tilde, hi::Operator);
	263
	264	<Div>"/" L C F(tk::Slash, hi::Operator);
	265	<Div>"/=" L C F(tk::SlashEqual, hi::Operator);
	266
	267	":" L C F(tk::Colon, hi::Structure);
	268	"," L C F(tk::Comma, hi::Structure);
	269	"?" L C F(tk::Question, hi::Structure);
	270	";" L C F(tk::SemiColon, hi::Structure);
	271
	272	"(" L C F(tk::OpenParen, hi::Structure);
	273	")" L C F(tk::CloseParen, hi::Structure);
	274
	275	"{" L C F(yyextra->no_.OpenBrace ? tk::OpenBrace__ : yylval->newline_ ? tk::OpenBrace_ : tk::OpenBrace, hi::Structure);
	276	"}" L C F(tk::CloseBrace, hi::Structure);
	277
	278	"[" L C F(tk::OpenBracket, hi::Structure);
	279	"]" L C F(tk::CloseBracket, hi::Structure);
5befe15e	280
dc5d7cf4 JF	281	"@error" L C F(tk::AtError, hi::Error);
dc5d7cf4 JF	282
1ba6903e	283	@begin Java
82a02ede	284	"@class" L C F(tk::AtClass, hi::Meta);
1ba6903e JF	285	@end
1ba6903e JF	286
60097023 JF	287	@begin C
60097023 JF	288	"typedef" L C I(identifier, Identifier("typedef"), tk::Typedef, hi::Meta);
8aebacfe JF	289	"unsigned" L C I(identifier, Identifier("unsigned"), tk::Unsigned, hi::Type);
8aebacfe JF	290	"signed" L C I(identifier, Identifier("signed"), tk::Signed, hi::Type);
c5587ed7	291	"extern" L C I(identifier, Identifier("extern"), tk::Extern, hi::Type);
60097023 JF	292	@end
60097023 JF	293
8a2eb1be	294	@begin C
46f4f308	295	"@encode" L C F(tk::AtEncode, hi::Meta);
8a2eb1be JF	296	@end
	297
	298	@begin ObjectiveC
82a02ede JF	299	"@end" L C F(tk::AtEnd, hi::Meta);
82a02ede JF	300	"@implementation" L C F(yyextra->no_.AtImplementation ? tk::AtImplementation_ : tk::AtImplementation, hi::Meta);
73439a14	301	"@import" L C F(tk::AtImport, hi::Special);
82a02ede	302	"@selector" L C F(tk::AtSelector, hi::Meta);
cf19d1c1	303
355cc1eb JF	304	"NULL" L C I(identifier, Identifier("NULL"), tk::Identifier_, hi::Constant);
355cc1eb JF	305	"nil" L C I(identifier, Identifier("nil"), tk::Identifier_, hi::Constant);
60496dd5 JF	306	"YES" L C I(identifier, Identifier("YES"), tk::Yes, hi::Constant);
60496dd5 JF	307	"NO" L C I(identifier, Identifier("NO"), tk::No, hi::Constant);
8b820c00	308
aa82b83b JF	309	"bool" L C I(identifier, Identifier("bool"), tk::Identifier_, hi::Type);
aa82b83b JF	310	"BOOL" L C I(identifier, Identifier("BOOL"), tk::Identifier_, hi::Type);
8b820c00	311	"id" L C I(identifier, Identifier("id"), tk::Identifier_, hi::Type);
aa8f2b2c	312	"SEL" L C I(identifier, Identifier("SEL"), tk::Identifier_, hi::Type);
cb02f8ae	313	@end
d35a3b07	314
355cc1eb JF	315	"undefined" L C I(identifier, Identifier("undefined"), tk::Identifier_, hi::Operator);
355cc1eb JF	316
82a02ede JF	317	"false" L C I(false, False(), tk::False, hi::Constant);
	318	"null" L C I(null, Null(), tk::Null, hi::Constant);
	319	"true" L C I(true, True(), tk::True, hi::Constant);
	320
	321	"auto" L C I(word, Word("auto"), tk::Auto, hi::Meta);
	322	"break" L R I(word, Word("break"), tk::Break, hi::Control);
	323	"case" L C I(word, Word("case"), tk::Case, hi::Control);
	324	"catch" L C I(word, Word("catch"), tk::Catch, hi::Control);
	325	"continue" L R I(word, Word("continue"), tk::Continue, hi::Control);
	326	"default" L C I(word, Word("default"), tk::Default, hi::Control);
	327	"delete" L C I(word, Word("delete"), tk::Delete, hi::Operator);
	328	"do" L C I(word, Word("do"), tk::Do, hi::Control);
	329	"else" L C I(word, Word("else"), tk::Else, hi::Control);
	330	"finally" L C I(word, Word("finally"), tk::Finally, hi::Control);
	331	"for" L C I(word, Word("for"), tk::For, hi::Control);
	332	"function" L C I(word, Word("function"), yyextra->no_.Function ? tk::Function_ : tk::Function, hi::Meta);
	333	"if" L C I(word, Word("if"), tk::If, hi::Control);
	334	"in" L C I(word, Word("in"), yyextra->in_.top() ? tk::In_ : tk::In, hi::Operator);
	335	"instanceof" L C I(word, Word("instanceof"), tk::InstanceOf, hi::Operator);
	336	"new" L C I(word, Word("new"), tk::New, hi::Operator);
	337	"return" L R I(word, Word("return"), tk::Return, hi::Control);
	338	"switch" L C I(word, Word("switch"), tk::Switch, hi::Control);
	339	"this" L C I(this, This(), tk::This, hi::Constant);
	340	"throw" L R I(word, Word("throw"), tk::Throw, hi::Control);
	341	"try" L C I(word, Word("try"), tk::Try, hi::Control);
	342	"typeof" L C I(word, Word("typeof"), tk::TypeOf, hi::Operator);
	343	"var" L C I(word, Word("var"), tk::Var, hi::Meta);
	344	"void" L C I(word, Word("void"), tk::Void, hi::Operator);
	345	"while" L C I(word, Word("while"), tk::While, hi::Control);
	346	"with" L C I(word, Word("with"), tk::With, hi::Control);
	347
	348	"debugger" L C I(word, Word("debugger"), tk::Debugger, hi::Meta);
	349
	350	"const" L C I(word, Word("const"), tk::Const, hi::Meta);
	351
	352	"class" L C I(word, Word("class"), tk::Class, hi::Meta);
	353	"enum" L C I(word, Word("enum"), tk::Enum, hi::Meta);
	354	"export" L C I(word, Word("export"), tk::Export, hi::Meta);
	355	"extends" L C I(word, Word("extends"), tk::Extends, hi::Meta);
	356	"import" L C I(word, Word("import"), tk::Import, hi::Meta);
	357	"super" L C I(word, Word("super"), tk::Super, hi::Constant);
	358
	359	"implements" L C I(identifier, Identifier("implements"), tk::Implements, hi::Meta);
	360	"interface" L C I(identifier, Identifier("interface"), tk::Interface, hi::Meta);
	361	"package" L C I(identifier, Identifier("package"), tk::Package, hi::Meta);
	362	"private" L C I(identifier, Identifier("private"), tk::Private, hi::Meta);
	363	"protected" L C I(identifier, Identifier("protected"), tk::Protected, hi::Meta);
	364	"public" L C I(identifier, Identifier("public"), tk::Public, hi::Meta);
	365	"static" L C I(identifier, Identifier("static"), tk::Static, hi::Meta);
	366
	367	"abstract" L C I(identifier, Identifier("abstract"), tk::Abstract, hi::Meta);
	368	"boolean" L C I(identifier, Identifier("boolean"), tk::Boolean, hi::Type);
	369	"byte" L C I(identifier, Identifier("byte"), tk::Byte, hi::Type);
	370	"char" L C I(identifier, Identifier("char"), tk::Char, hi::Type);
	371	"double" L C I(identifier, Identifier("double"), tk::Double, hi::Type);
	372	"final" L C I(identifier, Identifier("final"), tk::Final, hi::Meta);
	373	"float" L C I(identifier, Identifier("float"), tk::Float, hi::Type);
	374	"goto" L C I(identifier, Identifier("goto"), tk::Goto, hi::Control);
	375	"int" L C I(identifier, Identifier("int"), tk::Int, hi::Type);
	376	"long" L C I(identifier, Identifier("long"), tk::Long, hi::Type);
	377	"native" L C I(identifier, Identifier("native"), tk::Native, hi::Meta);
	378	"short" L C I(identifier, Identifier("short"), tk::Short, hi::Type);
	379	"synchronized" L C I(identifier, Identifier("synchronized"), tk::Synchronized, hi::Meta);
	380	"throws" L C I(identifier, Identifier("throws"), tk::Throws, hi::Meta);
381	"transient" L C I(identifier, Identifier("transient"), tk::Transient, hi::Meta);
382	"volatile" L C I(identifier, Identifier("volatile"), tk::Volatile, hi::Meta);
383
384	"let" L C I(identifier, Identifier("let"), tk::Let, hi::Meta);
385	"yield" L C I(identifier, Identifier("yield"), tk::Yield, hi::Control);
386
387	"each" L C I(identifier, Identifier("each"), tk::Each, hi::Control);
388	"of" L C I(identifier, Identifier("of"), tk::Of, hi::Operator);
5d646fb5	389
691e4717	390	@begin E4X
82a02ede JF	391	"namespace" L C I(identifier, Identifier("namespace"), tk::Namespace, hi::Meta);
82a02ede JF	392	"xml" L C I(identifier, Identifier("xml"), tk::XML, hi::Meta);
691e4717 JF	393	@end
691e4717 JF	394
82a02ede	395	{IdentifierStart}{IdentifierPart}* L C I(identifier, Identifier(Y), tk::Identifier_, hi::Identifier);
5d646fb5	396
5d646fb5	397
82a02ede JF	398	0[xX][0-9a-fA-F]+ L C I(number, Number(strtoull(yytext + 2, NULL, 16)), tk::NumericLiteral, hi::Constant);
	399	0[0-7]+ L C I(number, Number(strtoull(yytext + 1, NULL, 8)), tk::NumericLiteral, hi::Constant);
	400	0[bB][0-1]+ L C I(number, Number(strtoull(yytext + 2, NULL, 2)), tk::NumericLiteral, hi::Constant);
5befe15e	401
e31ea496 JF	402	(\.[0-9]+\|(0\|[1-9][0-9])(\.[0-9])?)([eE][+-]?[0-9]+)? L C I(number, Number(strtod(yytext, NULL)), tk::NumericLiteral, hi::Constant);
	403	(\.[0-9]+\|(0\|[1-9][0-9])(\.[0-9])?)[eE][+-]?{IdentifierPart}* L E("invalid exponent")
	404	(\.?[0-9]\|(0\|[1-9][0-9])?\.){IdentifierPart} L E("invalid number")
	405
931b816a	406	\"([^"\\\n]\|{Escape})\"\|'([^'\\\n]\|{Escape})' L C {
2eb8215d	407	char *value(A char[yyleng]);
931b816a JF	408	char *local(value);
931b816a JF	409
66f8d960	410	for (yy_size_t i(1), e(yyleng - 1); i != e; ++i) {
931b816a JF	411	char next(yytext[i]);
	412
	413	if (yytext[i] == '\\')
	414	switch (next = yytext[++i]) {
367eebb1	415	case '\n': continue;
931b816a JF	416	case '\\': next = '\\'; break;
	417	case '\'': next = '\''; break;
	418	case '"': next = '"'; break;
	419	case 'b': next = '\b'; break;
	420	case 'f': next = '\f'; break;
	421	case 'n': next = '\n'; break;
	422	case 'r': next = '\r'; break;
	423	case 't': next = '\t'; break;
	424	case 'v': next = '\v'; break;
	425	case '0': next = '\0'; break;
	426
	427	case 'x':
	428	next = H(yytext[i + 1]) << 4 \| H(yytext[i + 2]);
	429	i += 2;
	430	break;
	431	}
	432
	433	*local++ = next;
	434	}
	435
	436	*local = '\0';
82a02ede	437	I(string, String(value, local - value), tk::StringLiteral, hi::Constant);
931b816a	438	}
5befe15e	439
e31ea496 JF	440	(\"([^"\\\n]\|{Escape})\|'([^'\\\n]\|{Escape}))(\\(x.{0,2}\|u.{0,4})?)? L E("invalid escape")
e31ea496 JF	441
f89aaa11	442	\r?\n\|\r\|\xe2\x80[\xa8\xa9] yylloc->step(); yylloc->end.lines(); N
5befe15e JF	443
5befe15e JF	444	[ \t] L
7e5391fd	445
82a02ede	446	<<EOF>> if (yyextra->auto_) { yyextra->auto_ = false; F(tk::AutoComplete, hi::Nothing); } L yyterminate();
94d55b5c	447
e31ea496	448	@{IdentifierPart}+\|\xe2.\|. L E("unknown token")
924f67b2 JF	449
	450	%%
	451
5999c315	452	void CYDriver::ScannerInit() {
924f67b2 JF	453	cylex_init(&scanner_);
	454	cyset_extra(this, scanner_);
	455	}
	456
5999c315	457	void CYDriver::ScannerDestroy() {
924f67b2 JF	458	cylex_destroy(scanner_);
924f67b2 JF	459	}
63cd45c9	460
691e4717 JF	461	CYDriver::Condition CYDriver::GetCondition() {
	462	switch (yy_top_state(scanner_)) {
	463	case RegExp:
	464	return RegExpCondition;
	465	@begin E4X
	466	case XMLContent:
	467	return XMLContentCondition;
	468	case XMLTag:
	469	return XMLTagCondition;
	470	@end
	471	default:
	472	_assert(false);
	473	}
	474	}
	475
	476	void CYDriver::SetCondition(Condition condition) {
63cd45c9 JF	477	struct yyguts_t yyg(reinterpret_cast<struct yyguts_t >(scanner_));
	478
	479	switch (condition) {
697d6fd2 JF	480	case RegExpCondition:
697d6fd2 JF	481	BEGIN(RegExp);
63cd45c9	482	break;
691e4717 JF	483	@begin E4X
	484	case XMLContentCondition:
	485	BEGIN(XMLContent);
	486	break;
	487	case XMLTagCondition:
	488	BEGIN(XMLTag);
	489	break;
	490	@end
63cd45c9 JF	491	default:
	492	_assert(false);
	493	}
	494	}
691e4717 JF	495
	496	void CYDriver::PushCondition(Condition condition) {
	497	switch (condition) {
	498	case RegExpCondition:
	499	yy_push_state(RegExp, scanner_);
	500	break;
	501	@begin E4X
	502	case XMLContentCondition:
	503	yy_push_state(XMLContent, scanner_);
	504	break;
	505	case XMLTagCondition:
	506	yy_push_state(XMLTag, scanner_);
	507	break;
	508	@end
	509	default:
	510	_assert(false);
	511	}
	512	}
	513
	514	void CYDriver::PopCondition() {
	515	yy_pop_state(scanner_);
	516	}
1771224f JF	517
	518	#if defined(__clang__)
	519	#pragma clang diagnostic pop
	520	#endif