[cycript.git] / configure.ac

dnl Cycript - Optimizing JavaScript Compiler/Runtime
dnl Copyright (C) 2009-2013  Jay Freeman (saurik)

dnl GNU General Public License, Version 3 {{{
dnl
dnl Cycript is free software: you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published
dnl by the Free Software Foundation, either version 3 of the License,
dnl or (at your option) any later version.
dnl
dnl Cycript is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
dnl }}}

AC_PREREQ([2.65])
AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])

AC_CONFIG_SRCDIR([Console.cpp])
AC_CONFIG_AUX_DIR([.])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_HEADERS([config.h])

AM_INIT_AUTOMAKE([-Wall -Werror foreign])
AM_MAINTAINER_MODE([disable])

dnl XXX: do this only on Mac OS X
am_cv_CC_dependencies_compiler_type=none
am_cv_CXX_dependencies_compiler_type=none
am_cv_OBJCXX_dependencies_compiler_type=none

AC_PROG_CC
AC_PROG_CXX
AC_PROG_OBJCXX

AM_PROG_AR
AC_PROG_INSTALL

LT_INIT([disable-static])

AC_LANG([C++])

PKG_PROG_PKG_CONFIG([0.22])

AC_PATH_PROG([GIT], [git])
AC_PATH_PROG([TIME], [time])

dnl CY_CHECK_PROGS_VERSION {{{
AC_DEFUN([CY_CHECK_PROGS_VERSION], [
    AC_ARG_VAR(]$1[, ]$3[)

    AC_MSG_CHECKING(for ]$2[ >= ]$5[)
    AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
        AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
        AS_VAR_IF(version, [], ,
            AS_VERSION_COMPARE($version, ]$5[, ,
                ac_cv_path_]$1[=$ac_path_]$1[,
                ac_cv_path_]$1[=$ac_path_]$1[))
    , AC_MSG_RESULT(no))

    AS_IF([true], [
        AC_SUBST(]$1[, $ac_cv_path_]$1[)
        AC_MSG_RESULT($]$1[)
    ], AS_IF([true], [
        AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
    ], [
        AC_SUBST(]$1[, [:])
        AC_MSG_RESULT([no])
    ]))
]) dnl }}}

CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
    [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
    [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
    [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
    [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])

AC_MSG_CHECKING([bison for %code{}])
echo '%code{}%%_:' >conftest.y
if $BISON conftest.y -o/dev/null 2>/dev/null; then
    AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
    AC_MSG_RESULT([yes])
else
    AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
    AC_MSG_RESULT([no])
fi

rm -f conftest.y
AC_SUBST([CY_FILTERS])

dnl CY_TRY {{{
AC_DEFUN([CY_SUCCESS], [cy_good=1])
AC_DEFUN([CY_FAILURE], [cy_good=0])

AC_DEFUN([CY_TRY], [
    cy_save=$]$1[
        AC_LIB_APPENDTOVAR(]$1[, ]$2[)
        ]$3[
    ]$1[=$cy_save
    AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
]) dnl }}}

AC_DEFUN([CY_TEST_FLAG_], [
    AC_LANG_PUSH(]$2[)
    AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
    CY_TRY(]$3[, $1, [
        AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
            [CY_SUCCESS], [CY_FAILURE])
    ], [
        AC_MSG_RESULT([yes])
        AC_LIB_APPENDTOVAR(]$3[, ]$1[)
    ], [AC_MSG_RESULT([no])])
    AC_LANG_POP(]$2[)
])

AC_DEFUN([CY_TEST_FLAG], [
    CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
    CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
    CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
])

AX_CFLAGS_WARN_ALL
AX_CXXFLAGS_WARN_ALL
AX_FLAGS_WARN_ALL

CY_TEST_FLAG([-Werror])

dnl XXX: this is used to support GNU Objective-C struct objc_method
CY_TEST_FLAG([-Wno-deprecated-declarations])

CY_TEST_FLAG([-Wno-dangling-else])
CY_TEST_FLAG([-Wno-overloaded-virtual])
CY_TEST_FLAG([-Wno-parentheses])
CY_TEST_FLAG([-Wno-unneeded-internal-declaration])

AC_DEFUN([CY_LT_LIB], [
    cy_save=$LIBS
    LIBS=
    ]$2[
    ]$1[=$LIBS
    LIBS=$cy_save
    AC_SUBST(]$1[)
])

dnl --enable-javascript {{{
AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
    CY_LT_LIB([LTJAVASCRIPTCORE], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
        #include <JavaScriptCore/JSBase.h>
    ], [
        JSEvaluateScript(0, 0, 0, 0, 0, 0);
    ], [
        AC_SUBST([CY_EXECUTE], [1])
    ], [
        for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
            PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
                AC_SUBST([CY_EXECUTE], [1])
                AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
                AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
            ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
        done
    ])])
])

AC_DEFUN([CY_CHECK_JAVASCRIPT], [
    CY_CHECK_JAVASCRIPTCORE])

AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
    [--enable-javascript@<:@=ENGINE@:>@],
    [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
)], [
    AS_CASE([$enableval],
        [yes], [
            CY_CHECK_JAVASCRIPT],
        [no], [
            AC_SUBST([CY_EXECUTE], [0])],
        [JavaScriptCore], [
            CY_CHECK_JAVASCRIPTCORE],
        [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
], [CY_CHECK_JAVASCRIPT])
dnl }}}

AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])

AM_COND_IF([CY_CONSOLE], [
dnl APR_FIND_APR {{{
AS_IF([test "x$LTLIBAPR" != x], [
    AC_SUBST([LTLIBAPR])
], [
    APR_FIND_APR([], [], [1], [1])
AS_CASE([$apr_found], [yes], [
    AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
    AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
    AC_SUBST([LTLIBAPR])
], [
    AC_MSG_ERROR([missing "libapr"])
])])
dnl }}}
])

AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
    PKG_CHECK_MODULES([LIBFFI], [libffi], [
        AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
        AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
    ], [AC_MSG_ERROR([missing "libffi"])])])

AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])

AS_CASE([$CY_EXECUTE], [1], [
    AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])

    CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
        CY_CHECK_PKG_CONFIG_LIBFFI
    ], [
        AC_SEARCH_LIBS([ffi_call], [ffi])
        AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
    ]))

    AC_LANG_PUSH([Objective C++])

    AC_MSG_CHECKING([if we really have Objective C++])
    AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
        CY_OBJECTIVEC=1
        AC_MSG_RESULT([yes])
    ], [AC_MSG_RESULT([no])])

    AS_IF([test "x$CY_OBJECTIVEC" = x1], [
        CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
            #include <CoreFoundation/CFBase.h>
        ], [CFAllocatorGetDefault();], [
            AC_SUBST([CY_OBJECTIVEC])

            AC_CHECK_FRAMEWORK([Foundation], [
                #include <Foundation/NSObject.h>
            ], [[[[NSObject alloc] init];]])
        ], [
            AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
            AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])

            AS_IF([test "x$GNUSTEP_CONFIG" != x], [
                AC_SUBST([CY_OBJECTIVEC])
                AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
                AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
            ], [AC_SUBST([CY_OBJECTIVEC], [0])])
        ])])
    ])

    AC_LANG_POP([Objective C++])
])

AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])

CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])

CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])

AC_SUBST([LTFLAGS])
AC_SUBST([SO], [$acl_shlibext])

AS_IF([test "x$CY_EXECUTE" = x1], [
    AC_CHECK_HEADER([mach/mach.h], [
        AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
        AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
        AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
        AC_SUBST([CY_ATTACH_GROUP], [procmod])
        AC_SUBST([CY_MACH], [1])])])
AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])

AC_CONFIG_FILES([Makefile])
AC_OUTPUT
Commit	Line	Data
c15969fd JF	1	dnl Cycript - Optimizing JavaScript Compiler/Runtime
	2	dnl Copyright (C) 2009-2013 Jay Freeman (saurik)
	3
	4	dnl GNU General Public License, Version 3 {{{
	5	dnl
	6	dnl Cycript is free software: you can redistribute it and/or modify
	7	dnl it under the terms of the GNU General Public License as published
	8	dnl by the Free Software Foundation, either version 3 of the License,
	9	dnl or (at your option) any later version.
	10	dnl
	11	dnl Cycript is distributed in the hope that it will be useful, but
	12	dnl WITHOUT ANY WARRANTY; without even the implied warranty of
	13	dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	dnl GNU General Public License for more details.
	15	dnl
	16	dnl You should have received a copy of the GNU General Public License
	17	dnl along with Cycript. If not, see <http://www.gnu.org/licenses/>.
	18	dnl }}}
	19
9c60689e	20	AC_PREREQ([2.65])
c7aa54aa	21	AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
66170b30 JF	22	AC_COPYRIGHT([Copyright (C) 2009-2012 Jay Freeman (saurik)])
66170b30 JF	23
35fa52c0	24	AC_CONFIG_SRCDIR([Console.cpp])
6b66678a	25	AC_CONFIG_AUX_DIR([.])
66170b30	26	AC_CONFIG_MACRO_DIR([m4])
e2852502	27	AC_CONFIG_HEADERS([config.h])
66170b30	28
9228a43a	29	AM_INIT_AUTOMAKE([-Wall -Werror foreign])
b2895b4c	30	AM_MAINTAINER_MODE([disable])
a243b558	31
bfde1b76 JF	32	dnl XXX: do this only on Mac OS X
	33	am_cv_CC_dependencies_compiler_type=none
	34	am_cv_CXX_dependencies_compiler_type=none
	35	am_cv_OBJCXX_dependencies_compiler_type=none
	36
7caa62e6	37	AC_PROG_CC
a243b558 JF	38	AC_PROG_CXX
a243b558 JF	39	AC_PROG_OBJCXX
bfde1b76	40
a243b558 JF	41	AM_PROG_AR
	42	AC_PROG_INSTALL
	43
549f29b5	44	LT_INIT([disable-static])
66170b30 JF	45
	46	AC_LANG([C++])
	47
3fd51f51	48	PKG_PROG_PKG_CONFIG([0.22])
66170b30	49
66170b30 JF	50	AC_PATH_PROG([GIT], [git])
	51	AC_PATH_PROG([TIME], [time])
	52
	53	dnl CY_CHECK_PROGS_VERSION {{{
e9c9a47c	54	AC_DEFUN([CY_CHECK_PROGS_VERSION], [
66170b30 JF	55	AC_ARG_VAR(]$1[, ]$3[)
	56
	57	AC_MSG_CHECKING(for ]$2[ >= ]$5[)
	58	AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
	59	AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
	60	AS_VAR_IF(version, [], ,
	61	AS_VERSION_COMPARE($version, ]$5[, ,
	62	ac_cv_path_]$1[=$ac_path_]$1[,
	63	ac_cv_path_]$1[=$ac_path_]$1[))
	64	, AC_MSG_RESULT(no))
	65
	66	AS_IF([true], [
	67	AC_SUBST(]$1[, $ac_cv_path_]$1[)
	68	AC_MSG_RESULT($]$1[)
	69	], AS_IF([true], [
	70	AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
	71	], [
	72	AC_SUBST(]$1[, [:])
	73	AC_MSG_RESULT([no])
	74	]))
	75	]) dnl }}}
	76
	77	CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
	78	[-V \| $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
	79	CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
	80	[--version \| $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@\).$/\1/p;d'], [2.5.33])
	81	CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
	82	[--version \| $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
	83	CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
	84	[--version \| $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
	85
9228a43a JF	86	AC_MSG_CHECKING([bison for %code{}])
	87	echo '%code{}%%_:' >conftest.y
	88	if $BISON conftest.y -o/dev/null 2>/dev/null; then
	89	AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
	90	AC_MSG_RESULT([yes])
	91	else
	92	AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
	93	AC_MSG_RESULT([no])
	94	fi
	95
	96	rm -f conftest.y
	97	AC_SUBST([CY_FILTERS])
	98
66170b30 JF	99	dnl CY_TRY {{{
	100	AC_DEFUN([CY_SUCCESS], [cy_good=1])
	101	AC_DEFUN([CY_FAILURE], [cy_good=0])
	102
	103	AC_DEFUN([CY_TRY], [
	104	cy_save=$]$1[
	105	AC_LIB_APPENDTOVAR(]$1[, ]$2[)
	106	]$3[
	107	]$1[=$cy_save
	108	AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
	109	]) dnl }}}
	110
ff6daad2 JF	111	AC_DEFUN([CY_TEST_FLAG_], [
	112	AC_LANG_PUSH(]$2[)
	113	AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
	114	CY_TRY(]$3[, $1, [
66170b30 JF	115	AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
	116	[CY_SUCCESS], [CY_FAILURE])
	117	], [
	118	AC_MSG_RESULT([yes])
ff6daad2	119	AC_LIB_APPENDTOVAR(]$3[, ]$1[)
66170b30	120	], [AC_MSG_RESULT([no])])
ff6daad2 JF	121	AC_LANG_POP(]$2[)
	122	])
	123
	124	AC_DEFUN([CY_TEST_FLAG], [
	125	CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
	126	CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
5a288ada	127	CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
66170b30 JF	128	])
	129
	130	AX_CFLAGS_WARN_ALL
	131	AX_CXXFLAGS_WARN_ALL
90b4fa6b	132	AX_FLAGS_WARN_ALL
66170b30	133
4fc6e20e JF	134	CY_TEST_FLAG([-Werror])
4fc6e20e JF	135
a69dc826 JF	136	dnl XXX: this is used to support GNU Objective-C struct objc_method
	137	CY_TEST_FLAG([-Wno-deprecated-declarations])
	138
0cfdb323	139	CY_TEST_FLAG([-Wno-dangling-else])
66170b30 JF	140	CY_TEST_FLAG([-Wno-overloaded-virtual])
	141	CY_TEST_FLAG([-Wno-parentheses])
	142	CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
	143
e71ad079 JF	144	AC_DEFUN([CY_LT_LIB], [
	145	cy_save=$LIBS
	146	LIBS=
	147	]$2[
	148	]$1[=$LIBS
	149	LIBS=$cy_save
	150	AC_SUBST(]$1[)
	151	])
	152
66170b30	153	dnl --enable-javascript {{{
b66977f1	154	AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
604ed881	155	CY_LT_LIB([LTJAVASCRIPTCORE], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
4a762893 JF	156	#include <JavaScriptCore/JSBase.h>
	157	], [
	158	JSEvaluateScript(0, 0, 0, 0, 0, 0);
	159	], [
66170b30	160	AC_SUBST([CY_EXECUTE], [1])
66170b30	161	], [
4a762893 JF	162	for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
4a762893 JF	163	PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
66170b30	164	AC_SUBST([CY_EXECUTE], [1])
d70419f1	165	AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
4a762893 JF	166	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
	167	], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
	168	done
604ed881	169	])])
35fa52c0	170	])
66170b30	171
b66977f1	172	AC_DEFUN([CY_CHECK_JAVASCRIPT], [
66170b30 JF	173	CY_CHECK_JAVASCRIPTCORE])
66170b30 JF	174
b66977f1	175	AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
66170b30 JF	176	[--enable-javascript@<:@=ENGINE@:>@],
66170b30 JF	177	[use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
b66977f1	178	)], [
66170b30 JF	179	AS_CASE([$enableval],
	180	[yes], [
	181	CY_CHECK_JAVASCRIPT],
	182	[no], [
	183	AC_SUBST([CY_EXECUTE], [0])],
	184	[JavaScriptCore], [
	185	CY_CHECK_JAVASCRIPTCORE],
	186	[AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
b66977f1	187	], [CY_CHECK_JAVASCRIPT])
66170b30 JF	188	dnl }}}
66170b30 JF	189
002ca3d9 JF	190	AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
	191	AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])
	192
	193	AM_COND_IF([CY_CONSOLE], [
66170b30	194	dnl APR_FIND_APR {{{
d4705d6b JF	195	AS_IF([test "x$LTLIBAPR" != x], [
	196	AC_SUBST([LTLIBAPR])
	197	], [
	198	APR_FIND_APR([], [], [1], [1])
66170b30 JF	199	AS_CASE([$apr_found], [yes], [
66170b30 JF	200	AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
812bb90b JF	201	AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
812bb90b JF	202	AC_SUBST([LTLIBAPR])
d4705d6b JF	203	], [
	204	AC_MSG_ERROR([missing "libapr"])
	205	])])
66170b30	206	dnl }}}
002ca3d9	207	])
66170b30	208
e5cca37d	209	AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
66170b30	210	PKG_CHECK_MODULES([LIBFFI], [libffi], [
d70419f1	211	AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
66170b30 JF	212	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
	213	], [AC_MSG_ERROR([missing "libffi"])])])
	214
a243b558 JF	215	AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
a243b558 JF	216
e5cca37d	217	AS_CASE([$CY_EXECUTE], [1], [
66170b30	218	AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
e71ad079 JF	219
e71ad079 JF	220	CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
66170b30 JF	221	CY_CHECK_PKG_CONFIG_LIBFFI
	222	], [
	223	AC_SEARCH_LIBS([ffi_call], [ffi])
	224	AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
e71ad079	225	]))
66170b30 JF	226
	227	AC_LANG_PUSH([Objective C++])
	228
	229	AC_MSG_CHECKING([if we really have Objective C++])
	230	AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
	231	CY_OBJECTIVEC=1
	232	AC_MSG_RESULT([yes])
	233	], [AC_MSG_RESULT([no])])
	234
	235	AS_IF([test "x$CY_OBJECTIVEC" = x1], [
604ed881	236	CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
66170b30 JF	237	#include <CoreFoundation/CFBase.h>
	238	], [CFAllocatorGetDefault();], [
	239	AC_SUBST([CY_OBJECTIVEC])
	240
	241	AC_CHECK_FRAMEWORK([Foundation], [
	242	#include <Foundation/NSObject.h>
	243	], [[[[NSObject alloc] init];]])
66170b30 JF	244	], [
	245	AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
	246	AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
	247
	248	AS_IF([test "x$GNUSTEP_CONFIG" != x], [
	249	AC_SUBST([CY_OBJECTIVEC])
	250	AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
	251	AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
	252	], [AC_SUBST([CY_OBJECTIVEC], [0])])
604ed881	253	])])
66170b30 JF	254	])
	255
	256	AC_LANG_POP([Objective C++])
3fd51f51	257	])
66170b30	258
a243b558 JF	259	AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
a243b558 JF	260
6f9aea2b JF	261	CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
6f9aea2b JF	262	AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
66170b30	263
b5437404	264	CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
a243b558	265
66170b30	266	AC_SUBST([LTFLAGS])
9777bd50	267	AC_SUBST([SO], [$acl_shlibext])
66170b30	268
1f11d1b4 JF	269	AS_IF([test "x$CY_EXECUTE" = x1], [
	270	AC_CHECK_HEADER([mach/mach.h], [
	271	AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
	272	AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
	273	AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
	274	AC_SUBST([CY_ATTACH_GROUP], [procmod])
	275	AC_SUBST([CY_MACH], [1])])])
a243b558	276	AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
66170b30	277
a243b558	278	AC_CONFIG_FILES([Makefile])
9c60689e	279	AC_OUTPUT