tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  45 # ----------------------------------------------------------------
  46 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  47 m4_define([AT_LOC_PUSHDEF],
  48 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  49 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  50 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  51 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  52
  53 # AT_LOC_POPDEF
  54 # -------------
  55 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  56 m4_define([AT_LOC_POPDEF],
  57 [m4_popdef([AT_LOC_FIRST_LINE])
  58 m4_popdef([AT_LOC_FIRST_COLUMN])
  59 m4_popdef([AT_LOC_LAST_LINE])
  60 m4_popdef([AT_LOC_LAST_COLUMN])])
  61
  62
  63
  64 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  65 # -----------------------------------------
  66 m4_define([AT_BISON_OPTION_PUSHDEFS],
  67 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  68
  69
  70 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  71 # --------------------------------------------------
  72 # This macro works around the impossibility to define macros
  73 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  74 # This sucks hard, GNU M4 should really provide M5-like $$1.
  75 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  76 [m4_if([$1$2], $[1]$[2], [],
  77        [m4_fatal([$0: Invalid arguments: $@])])dnl
  78 m4_pushdef([AT_DEFINES_IF],
  79 [m4_bmatch([$3], [%defines], [$1], [$2])])
  80 m4_pushdef([AT_SKEL_CC_IF],
  81 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  82 m4_pushdef([AT_SKEL_JAVA_IF],
  83 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  84 m4_pushdef([AT_GLR_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  86 m4_pushdef([AT_LALR1_CC_IF],
  87 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  88 m4_pushdef([AT_GLR_CC_IF],
  89 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  90 # Using yacc.c?
  91 m4_pushdef([AT_YACC_IF],
  92 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  93 m4_pushdef([AT_LEXPARAM_IF],
  94 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  95 m4_pushdef([AT_LOCATION_IF],
  96 [m4_bmatch([$3], [%locations], [$1], [$2])])
  97 m4_pushdef([AT_LOCATION_TYPE_IF],
  98 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  99 m4_pushdef([AT_PARAM_IF],
 100 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 101 m4_pushdef([AT_PURE_IF],
 102 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 103            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 104            [$2])])
 105 m4_pushdef([AT_PURE_AND_LOC_IF],
 106 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 107 m4_pushdef([AT_GLR_OR_PARAM_IF],
 108 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 109 m4_pushdef([AT_NAME_PREFIX],
 110 [m4_bmatch([$3], [%name-prefix ".*"],
 111            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 112            [yy])])
 113 m4_pushdef([AT_TOKEN_PREFIX],
 114 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 115            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 116 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 117 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 118 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 119                     [$2])])
 120 # yyerror always sees the locations (when activated), except if
 121 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 122 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 123 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 124                                         [$1])],
 125                             [$1])],
 126                 [$2])])
 127
 128 # The interface is pure: either because %define api.pure, or because we
 129 # are using the C++ parsers.
 130 m4_pushdef([AT_PURE_LEX_IF],
 131 [AT_PURE_IF([$1],
 132             [AT_SKEL_CC_IF([$1], [$2])])])
 133
 134 AT_PURE_LEX_IF(
 135 [m4_pushdef([AT_LOC], [(*llocp)])
 136  m4_pushdef([AT_VAL], [(*lvalp)])
 137  m4_pushdef([AT_LEX_FORMALS],
 138             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 139  m4_pushdef([AT_LEX_ARGS],
 140             [lvalp[]AT_LOCATION_IF([, llocp])])
 141  m4_pushdef([AT_USE_LEX_ARGS],
 142             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 143  m4_pushdef([AT_LEX_PRE_FORMALS],
 144             [AT_LEX_FORMALS, ])
 145  m4_pushdef([AT_LEX_PRE_ARGS],
 146             [AT_LEX_ARGS, ])
 147 ],
 148 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 149  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 150  m4_pushdef([AT_LEX_FORMALS],     [void])
 151  m4_pushdef([AT_LEX_ARGS],        [])
 152  m4_pushdef([AT_USE_LEX_ARGS],    [])
 153  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 154  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 155 ])
 156
 157 # Handle the different types of location components.
 158
 159 AT_SKEL_CC_IF(
 160   [AT_LOCATION_TYPE_IF(
 161     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 162     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 163   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 164
 165
 166 AT_GLR_IF([AT_KEYWORDS([glr])])
 167 ])# _AT_BISON_OPTION_PUSHDEFS
 168
 169
 170 # AT_BISON_OPTION_POPDEFS
 171 # -----------------------
 172 m4_define([AT_BISON_OPTION_POPDEFS],
 173 [m4_popdef([AT_LEX_PRE_ARGS])
 174 m4_popdef([AT_LEX_PRE_FORMALS])
 175 m4_popdef([AT_USE_LEX_ARGS])
 176 m4_popdef([AT_LEX_ARGS])
 177 m4_popdef([AT_LEX_FORMALS])
 178 m4_popdef([AT_VAL])
 179 m4_popdef([AT_LOC])
 180 m4_popdef([AT_PURE_LEX_IF])
 181 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 182 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 183 m4_popdef([AT_NAME_PREFIX])
 184 m4_popdef([AT_GLR_OR_PARAM_IF])
 185 m4_popdef([AT_PURE_AND_LOC_IF])
 186 m4_popdef([AT_LOCATION_TYPE_IF])
 187 m4_popdef([AT_LOCATION_IF])
 188 m4_popdef([AT_PARAM_IF])
 189 m4_popdef([AT_LEXPARAM_IF])
 190 m4_popdef([AT_YACC_IF])
 191 m4_popdef([AT_GLR_IF])
 192 m4_popdef([AT_SKEL_CC_IF])
 193 m4_popdef([AT_SKEL_JAVA_IF])
 194 m4_popdef([AT_GLR_CC_IF])
 195 m4_popdef([AT_LALR1_CC_IF])
 196 m4_popdef([AT_DEFINES_IF])
 197 AT_LOC_POPDEF
 198 ])# AT_BISON_OPTION_POPDEFS
 199
 200
 201
 202 ## -------------------------- ##
 203 ## Generating Grammar Files.  ##
 204 ## -------------------------- ##
 205
 206 # AT_DATA_SOURCE_PROLOGUE
 207 # ------------------------
 208 # The prologue that should be included in any source code that is
 209 # meant to be compiled.
 210 m4_define([AT_DATA_SOURCE_PROLOGUE],
 211 [[#include <config.h>
 212 /* We don't need perfect functions for these tests. */
 213 #undef malloc
 214 #undef memcmp
 215 #undef realloc
 216 ]])
 217
 218 # AT_DATA_GRAMMAR_PROLOGUE
 219 # ------------------------
 220 # The prologue that should be included in any grammar which parser is
 221 # meant to be compiled.
 222 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 223 [[%code top {
 224 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 225 [}
 226 ]])
 227
 228 # AT_DATA_SOURCE(NAME, CONTENT)
 229 # -----------------------------
 230 # Generate the file NAME, which CONTENT is preceded by
 231 # AT_DATA_SOURCE_PROLOGUE.
 232 m4_define([AT_DATA_SOURCE],
 233 [AT_DATA([$1],
 234 [AT_DATA_SOURCE_PROLOGUE
 235 $2])
 236 ])
 237
 238 # AT_DATA_GRAMMAR(NAME, CONTENT)
 239 # ------------------------------
 240 # Generate the file NAME, which CONTENT is preceded by
 241 # AT_DATA_GRAMMAR_PROLOGUE.
 242 m4_define([AT_DATA_GRAMMAR],
 243 [AT_DATA([$1],
 244 [AT_DATA_GRAMMAR_PROLOGUE
 245 $2])
 246 ])
 247
 248 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 249 # -------------------------------------------------
 250 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 251 # shell constructs (such as redirection or pipes) that would prevent
 252 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 253 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 254 #
 255 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 256 # Bison in the test suite.  For now it ensures that:
 257 #
 258 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 259 #      a non-zero exit status since Bison doesn't always try to free all memory
 260 #      in that case.
 261 #
 262 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 263 #      --graph and --report=all output for every working grammar.
 264 #
 265 #   3. If stderr contains a warning, -Werror and --warnings=error
 266 #      convert the warning to an error.
 267 #
 268 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 269 m4_define([AT_BISON_CHECK],
 270 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 271        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 272 AT_BISON_CHECK_NO_XML($@)])
 273
 274 m4_define([AT_BISON_WERROR_MSG],
 275           [[bison: warnings being treated as errors]])
 276
 277 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 278 # --------------------------------------------------------
 279 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 280 # when a tortured grammar's XML is known to be too large for xsltproc to
 281 # handle.
 282 m4_define([AT_BISON_CHECK_NO_XML],
 283 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 284                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 285 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 286       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 287         # Defining POSIXLY_CORRECT causes bison to complain if options
 288         # are added after the grammar file name, so skip these checks
 289         # in that case.
 290         if test -z "${POSIXLY_CORRECT+set}"; then
 291           # Don't interfere with caller's files.
 292           if test -f stderr; then mv stderr at-bison-check-stderr.bak; fi
 293           if test -f experr; then mv experr at-bison-check-experr.bak; fi
 294           if test -f expout; then mv expout at-bison-check-expout.bak; fi
 295
 296           # To avoid expanding it repeatedly, store specified stdout.
 297           ]AT_DATA([expout], [$3])[
 298
 299           # Run with -Werror.
 300           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 301                     [[1]], [expout], [stderr])[
 302
 303           # Build expected stderr up to and including the "warnings being
 304           # treated as errors" message.
 305           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 306           at_bison_check_first=`sed -n \
 307             '/: warning: /{=;q;}' at-bison-check-warnings`
 308           : ${at_bison_check_first:=1}
 309           at_bison_check_first_tmp=`sed -n \
 310             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 311           : ${at_bison_check_first_tmp:=1}
 312           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 313             at_bison_check_first=$at_bison_check_first_tmp
 314           fi
 315           if test $at_bison_check_first -gt 1; then
 316             sed -n "1,`expr $at_bison_check_first - 1`"p \
 317               at-bison-check-warnings > experr
 318           fi
 319           echo ']AT_BISON_WERROR_MSG[' >> experr
 320
 321           # Finish building expected stderr and check.  Unlike warnings,
 322           # complaints cause bison to exit early.  Thus, with -Werror, bison
 323           # does not necessarily report all warnings that it does without
 324           # -Werror, but it at least reports one.
 325           at_bison_check_last=`sed -n '$=' stderr`
 326           : ${at_bison_check_last:=1}
 327           at_bison_check_last=`expr $at_bison_check_last - 1`
 328           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 329             at-bison-check-warnings >> experr
 330           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 331                       stderr 1>&2]], [[0]], [[]], [experr])[
 332
 333           # Now check --warnings=error.
 334           cp stderr experr
 335           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 336                     [[1]], [expout], [experr])[
 337
 338           # Now check -Wnone and --warnings=none by making sure that
 339           # -Werror doesn't change the exit status when -Wnone or
 340           # --warnings=none is specified.
 341           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 342                     [[0]], [expout])[
 343           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 344                     -Werror]], [[0]], [expout])[
 345
 346           # Restore caller's files.
 347           if test -f at-bison-check-expout.bak; then
 348             mv at-bison-check-expout.bak expout
 349           fi
 350           if test -f at-bison-check-experr.bak; then
 351             mv at-bison-check-experr.bak experr
 352           fi
 353           if test -f at-bison-check-stderr.bak; then
 354             mv at-bison-check-stderr.bak stderr
 355           fi
 356         fi
 357       ]])
 358 ])
 359
 360 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 361 # -----------------------------------------------------
 362 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 363 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 364 # have a non-zero exit status.
 365 m4_define([AT_BISON_CHECK_XML],
 366 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 367   mkdir xml-tests]
 368   m4_pushdef([AT_BISON_ARGS],
 369              [m4_bpatsubsts([[$1]],
 370                             [--report(-file)?=[^][ ]*], [],
 371                             [--graph=[^][ ]*], [],
 372                             [--xml=[^][ ]*], [])])dnl
 373   # Don't combine these Bison invocations since we want to be sure that
 374   # --report=all isn't required to get the full XML file.
 375   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 376              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 377            [[0]], [ignore], [ignore])
 378   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 379            [[0]], [ignore], [ignore])
 380   m4_popdef([AT_BISON_ARGS])dnl
 381   [cp xml-tests/test.output expout]
 382   AT_CHECK([[$XSLTPROC \
 383              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 384              xml-tests/test.xml]], [[0]], [expout])
 385   [cp xml-tests/test.dot expout]
 386   AT_CHECK([[$XSLTPROC \
 387              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 388              xml-tests/test.xml]], [[0]], [expout])
 389   [rm -rf xml-tests expout
 390 fi]])
 391
 392 # AT_QUELL_VALGRIND
 393 # -----------------
 394 # Put this before a Bison invocation to keep Valgrind from complaining about
 395 # reachable memory.
 396 #
 397 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 398 # The triple quoting below will cause test cases to fail if you do.  If you do
 399 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 400 # will then fail to shell-escape its contents when attempting to print them.
 401 # The testsuite verbose output, at least, will be incorrect, but nothing may
 402 # fail to make sure you notice.
 403 m4_define([AT_QUELL_VALGRIND],
 404 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 405
 406 ## ------------------------ ##
 407 ## Compiling C, C++ Files.  ##
 408 ## ------------------------ ##
 409
 410
 411 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 412 # ----------------------------------------
 413 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 414 # assume that we are linking too; this is a hack.
 415 m4_define([AT_COMPILE],
 416 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 417            0, [ignore], [ignore])])
 418
 419 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 420 # --------------------------------------------
 421 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 422 # assume that we are linking too; this is a hack.
 423 # If the C++ compiler does not work, ignore the test.
 424 m4_define([AT_COMPILE_CXX],
 425 [AT_KEYWORDS(c++)
 426 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 427 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 428          0, [ignore], [ignore])])
 429
 430 # AT_JAVA_COMPILE(SOURCES)
 431 # ------------------------
 432 # Compile SOURCES into Java class files.  Skip the test if java or javac
 433 # is not installed.
 434 m4_define([AT_JAVA_COMPILE],
 435 [AT_KEYWORDS(java)
 436 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 437            test -n "$CONF_JAVAC" || exit 77]])
 438 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 439          [[0]], [ignore], [ignore])])
 440
 441 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 442 # --------------------------------
 443 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 444 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 445 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 446 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 447 # AT_SKEL_JAVA_IF.
 448 m4_define([AT_FULL_COMPILE], [
 449   AT_SKEL_JAVA_IF([
 450     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 451     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 452                                         [[$1[.java ]$1[-]$2[.java]]]))
 453   ], [
 454     AT_SKEL_CC_IF([
 455       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 456       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 457     ], [
 458       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 459       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 460     ])
 461   ])
 462 ])
 463
 464
 465 ## ---------------------------- ##
 466 ## Running a generated parser.  ##
 467 ## ---------------------------- ##
 468
 469 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 470 # ------------------------------------------------------------
 471 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 472 m4_define([AT_PARSER_CHECK],
 473 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 474
 475 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 476 # -----------------------------------------------------------------
 477 m4_define([AT_JAVA_PARSER_CHECK],
 478 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 479
 480 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 481 #                          DECLS, GRAMMAR, INPUT,
 482 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 483 #                          [OTHER-CHECKS],
 484 #                          [PARSER-EXIT-VALUE],
 485 #                          [PARSER-STDOUT], [PARSER-STDERR])
 486 # -------------------------------------------------------------
 487 # Using TITLE as the test group title, check the generated parser tables
 488 # and parser for a specified grammar file under a condition labeled by
 489 # COND-VALUE.
 490 #
 491 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 492 # recognized attribute is described below where it is relevant.
 493 #
 494 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 495 # the grammar file.  Insert basic yyerror, yylex, and main function
 496 # definitions as well.  Hardcode yylex to return the (possibly empty)
 497 # comma-delimited series of tokens in INPUT followed by token 0.
 498 #
 499 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 500 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 501 # On the bison command-line, specify `--report=all --defines'.  Check
 502 # that Bison exits with value 0, has no stdout, and has stderr
 503 # BISON-STDERR.
 504 #
 505 # If TEST-SPEC contains the attribute `last-state', check that the value
 506 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 507 # the grammar; in other words, check the number of states (minus one).
 508 # Otherwise, check that everything in the `.output' file starting with
 509 # the definition of state 0 is the same as the entire value of
 510 # TABLES-OR-LAST-STATE.
 511 #
 512 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 513 # `.output' file, which is named `input.output', and/or grammar file,
 514 # which is named `input.y'.
 515 #
 516 # Finally, compile the generated parser and then run it using
 517 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 518 # PARSER-STDERR as the 2nd-4th arguments.
 519 #
 520 # As a precondition, you must properly double-quote all arguments that
 521 # are to be interpreted as strings.
 522 #
 523 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 524 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 525 # first argument.  This is useful, for example, when wrapping multiple
 526 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 527 # condition, in another macro.
 528 #
 529 # For example:
 530 #
 531 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 532 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 533 #   # ---------------------------------------------------------------------
 534 #   m4_define([AT_TEST_SYNTAX_ERROR],
 535 #   [
 536 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 537 #                              [[last-state]],
 538 #                              [[%error-verbose ]$2], [$3], [$4],
 539 #                              [[]], [$5], [], [$6], [$7], [$8])
 540 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 541 #                              [[last-state]],
 542 #                              [$2], [$3], [$4],
 543 #                              [[]], [$5], [], [$6], [$7], [$8])
 544 #   ])
 545 #
 546 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 547 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 548 #                        [[3]],
 549 #                        [[1]], [[]],
 550 #                        [AT_COND_CASE([[no verbose]],
 551 #                                      [[syntax error
 552 #   ]],
 553 #                                      [[syntax error, unexpected 'b', expecting $end
 554 #   ]])])
 555 m4_define([AT_TEST_TABLES_AND_PARSE],
 556 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 557
 558 AT_SETUP([$1])
 559
 560 AT_DATA_GRAMMAR([[input.y]],
 561 [[%code {
 562   #include <stdio.h>
 563   static void yyerror (char const *msg);
 564   static int yylex (void);
 565 }
 566
 567 ]$4[
 568
 569 %%
 570
 571 ]$5[
 572
 573 %%
 574
 575 static void
 576 yyerror (char const *msg)
 577 {
 578   fprintf (stderr, "%s\n", msg);
 579 }
 580
 581 static int
 582 yylex (void)
 583 {
 584   static int const input[] = {
 585     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 586   };
 587   static int const *inputp = input;
 588   return *inputp++;
 589 }
 590
 591 int
 592 main (void)
 593 {
 594   return yyparse ();
 595 }
 596 ]])
 597
 598 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 599 # expanding macros, so it corrupts some special characters in the
 600 # macros.  To avoid this, expand now and pass it the result with proper
 601 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 602 # strings.
 603
 604 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 605       [AT_BISON_CHECK],
 606       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 607                                [0], [], m4_dquote($7))
 608
 609 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 610       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 611                 m4_dquote($8))],
 612       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 613                 m4_dquote($8)[[
 614 ]])])
 615
 616 $9
 617
 618 AT_COMPILE([[input]])
 619
 620 AT_PARSER_CHECK([[./input]],
 621                 m4_ifval([$10], [m4_dquote($10)]),
 622                 m4_ifval([$11], [m4_dquote($11)]),
 623                 m4_ifval([$12], [m4_dquote($12)]))
 624
 625 AT_CLEANUP
 626
 627 m4_popdef([AT_COND_CASE])])
 628
 629
 630
 631 ## ----------------------- ##
 632 ## Launch the test suite.  ##
 633 ## ----------------------- ##
 634
 635 AT_INIT
 636
 637 AT_TESTED([bison])