src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_CODE_TOP        "%code-top"
 136   PERCENT_DEBUG           "%debug"
 137   PERCENT_DEFAULT_PREC    "%default-prec"
 138   PERCENT_DEFINE          "%define"
 139   PERCENT_DEFINES         "%defines"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LANGUAGE        "%language"
 147   PERCENT_LEX_PARAM       "%lex-param"
 148   PERCENT_LOCATIONS       "%locations"
 149   PERCENT_NAME_PREFIX     "%name-prefix"
 150   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 151   PERCENT_NO_LINES        "%no-lines"
 152   PERCENT_NONDETERMINISTIC_PARSER
 153                           "%nondeterministic-parser"
 154   PERCENT_OUTPUT          "%output"
 155   PERCENT_PARSE_PARAM     "%parse-param"
 156   PERCENT_PROVIDES        "%provides"
 157   PERCENT_PURE_PARSER     "%pure-parser"
 158   PERCENT_PUSH_PARSER     "%push-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_REQUIRES        "%requires"
 161   PERCENT_SKELETON        "%skeleton"
 162   PERCENT_START           "%start"
 163   PERCENT_TOKEN_TABLE     "%token-table"
 164   PERCENT_VERBOSE         "%verbose"
 165   PERCENT_YACC            "%yacc"
 166 ;
 167
 168 %token BRACED_CODE     "{...}"
 169 %token CHAR            "char"
 170 %token EPILOGUE        "epilogue"
 171 %token EQUAL           "="
 172 %token ID              "identifier"
 173 %token ID_COLON        "identifier:"
 174 %token PERCENT_PERCENT "%%"
 175 %token PIPE            "|"
 176 %token PROLOGUE        "%{...%}"
 177 %token SEMICOLON       ";"
 178 %token TYPE            "type"
 179 %token TYPE_TAG_ANY    "<*>"
 180 %token TYPE_TAG_NONE   "<>"
 181
 182 %type <character> CHAR
 183 %printer { fputs (char_name ($$), stderr); } CHAR
 184
 185 /* braceless is not to be used for rule or symbol actions, as it
 186    calls translate_code. */
 187 %type <chars> STRING "%{...%}" EPILOGUE braceless content content.opt
 188 %type <code> "{...}"
 189 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 190          STRING
 191 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 192          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 193
 194 %type <uniqstr> TYPE ID ID_COLON
 195 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 196 %printer { fputs ($$, stderr); } ID
 197 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 198
 199 %type <integer> INT
 200 %printer { fprintf (stderr, "%d", $$); } INT
 201
 202 %type <symbol> id id_colon symbol string_as_id
 203 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 204 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 205
 206 %type <assoc> precedence_declarator
 207 %type <list>  symbols.1 generic_symlist generic_symlist_item
 208 %%
 209
 210 input:
 211   prologue_declarations "%%" grammar epilogue.opt
 212 ;
 213
 214
 215         /*------------------------------------.
 216         | Declarations: before the first %%.  |
 217         `------------------------------------*/
 218
 219 prologue_declarations:
 220   /* Nothing */
 221 | prologue_declarations prologue_declaration
 222 ;
 223
 224 prologue_declaration:
 225   grammar_declaration
 226 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 227 | "%debug"                         { debug_flag = true; }
 228 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 229 | "%defines"                       { defines_flag = true; }
 230 | "%defines" STRING
 231     {
 232       defines_flag = true;
 233       spec_defines_file = xstrdup ($2);
 234     }
 235 | "%error-verbose"                 { error_verbose = true; }
 236 | "%expect" INT                    { expected_sr_conflicts = $2; }
 237 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 238 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 239 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 240 | "%glr-parser"
 241     {
 242       nondeterministic_parser = true;
 243       glr_parser = true;
 244     }
 245 | "%initial-action" "{...}"
 246     {
 247       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 248     }
 249 | "%language" STRING            { language_argmatch ($2, 1, &@1); }
 250 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 251 | "%locations"                  { locations_flag = true; }
 252 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 253 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 254 | "%no-lines"                   { no_lines_flag = true; }
 255 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 256 | "%output" STRING              { spec_outfile = $2; }
 257 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 258 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 259 | "%pure-parser"                { pure_parser = true; }
 260 | "%push-parser"                { push_parser = true; pure_parser = true; }
 261 | "%require" STRING             { version_check (&@2, $2); }
 262 | "%skeleton" STRING            { skeleton_arg ($2, 1, &@1); }
 263 | "%token-table"                { token_table_flag = true; }
 264 | "%verbose"                    { report_flag = report_states; }
 265 | "%yacc"                       { yacc_flag = true; }
 266 | /*FIXME: Err?  What is this horror doing here? */ ";"
 267 ;
 268
 269 grammar_declaration:
 270   precedence_declaration
 271 | symbol_declaration
 272 | "%start" symbol
 273     {
 274       grammar_start_symbol_set ($2, @2);
 275     }
 276 | "%destructor" "{...}" generic_symlist
 277     {
 278       symbol_list *list;
 279       const char *action = translate_symbol_action ($2, @2);
 280       for (list = $3; list; list = list->next)
 281         symbol_list_destructor_set (list, action, @2);
 282       symbol_list_free ($3);
 283     }
 284 | "%printer" "{...}" generic_symlist
 285     {
 286       symbol_list *list;
 287       const char *action = translate_symbol_action ($2, @2);
 288       for (list = $3; list; list = list->next)
 289         symbol_list_printer_set (list, action, @2);
 290       symbol_list_free ($3);
 291     }
 292 | "%default-prec"
 293     {
 294       default_prec = true;
 295     }
 296 | "%no-default-prec"
 297     {
 298       default_prec = false;
 299     }
 300 | "%code" braceless      { prologue_augment ($2, @2, true); }
 301 | "%code-top" braceless  { prologue_augment ($2, @2, false); }
 302 | "%provides" braceless  { muscle_code_grow ("provides", $2, @2); }
 303 | "%requires" braceless  { muscle_code_grow ("requires", $2, @2); }
 304 ;
 305
 306
 307 /*----------*
 308  | %union.  |
 309  *----------*/
 310
 311 %token PERCENT_UNION "%union";
 312
 313 union_name:
 314   /* Nothing. */ {}
 315 | ID             { muscle_code_grow ("union_name", $1, @1); }
 316 ;
 317
 318 grammar_declaration:
 319   "%union" union_name "{...}"
 320     {
 321       char const *body = $3;
 322
 323       /* Concatenate the %union bodies.  If this is the first %union, make sure
 324          the synchronization line appears after the opening '{' so as not to
 325          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 326          into '\n', and omit the new %union's leading '{'.  */
 327       if (!union_seen)
 328         {
 329           muscle_grow ("stype", "{", "");
 330         }
 331       else
 332         {
 333           char *code = muscle_find ("stype");
 334           code[strlen (code) - 1] = '\n';
 335         }
 336       body++;
 337
 338       union_seen = true;
 339       muscle_code_grow ("stype", body, @3);
 340     }
 341 ;
 342
 343
 344
 345
 346 symbol_declaration:
 347   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 348     {
 349       current_class = unknown_sym;
 350       current_type = NULL;
 351     }
 352 | "%token" { current_class = token_sym; } symbol_defs.1
 353     {
 354       current_class = unknown_sym;
 355       current_type = NULL;
 356     }
 357 | "%type" TYPE symbols.1
 358     {
 359       symbol_list *list;
 360       tag_seen = true;
 361       for (list = $3; list; list = list->next)
 362         symbol_type_set (list->content.sym, $2, @2);
 363       symbol_list_free ($3);
 364     }
 365 ;
 366
 367 precedence_declaration:
 368   precedence_declarator type.opt symbols.1
 369     {
 370       symbol_list *list;
 371       ++current_prec;
 372       for (list = $3; list; list = list->next)
 373         {
 374           symbol_type_set (list->content.sym, current_type, @2);
 375           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 376         }
 377       symbol_list_free ($3);
 378       current_type = NULL;
 379     }
 380 ;
 381
 382 precedence_declarator:
 383   "%left"     { $$ = left_assoc; }
 384 | "%right"    { $$ = right_assoc; }
 385 | "%nonassoc" { $$ = non_assoc; }
 386 ;
 387
 388 type.opt:
 389   /* Nothing. */ { current_type = NULL; }
 390 | TYPE           { current_type = $1; tag_seen = true; }
 391 ;
 392
 393 /* One or more symbols to be %typed. */
 394 symbols.1:
 395   symbol
 396     { $$ = symbol_list_sym_new ($1, @1); }
 397 | symbols.1 symbol
 398     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 399 ;
 400
 401 generic_symlist:
 402   generic_symlist_item { $$ = $1; }
 403 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 404 ;
 405
 406 generic_symlist_item:
 407   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 408 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 409 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 410 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 411 ;
 412
 413 /* One token definition.  */
 414 symbol_def:
 415   TYPE
 416      {
 417        current_type = $1;
 418        tag_seen = true;
 419      }
 420 | id
 421      {
 422        symbol_class_set ($1, current_class, @1, true);
 423        symbol_type_set ($1, current_type, @1);
 424      }
 425 | id INT
 426     {
 427       symbol_class_set ($1, current_class, @1, true);
 428       symbol_type_set ($1, current_type, @1);
 429       symbol_user_token_number_set ($1, $2, @2);
 430     }
 431 | id string_as_id
 432     {
 433       symbol_class_set ($1, current_class, @1, true);
 434       symbol_type_set ($1, current_type, @1);
 435       symbol_make_alias ($1, $2, @$);
 436     }
 437 | id INT string_as_id
 438     {
 439       symbol_class_set ($1, current_class, @1, true);
 440       symbol_type_set ($1, current_type, @1);
 441       symbol_user_token_number_set ($1, $2, @2);
 442       symbol_make_alias ($1, $3, @$);
 443     }
 444 ;
 445
 446 /* One or more symbol definitions. */
 447 symbol_defs.1:
 448   symbol_def
 449 | symbol_defs.1 symbol_def
 450 ;
 451
 452
 453         /*------------------------------------------.
 454         | The grammar section: between the two %%.  |
 455         `------------------------------------------*/
 456
 457 grammar:
 458   rules_or_grammar_declaration
 459 | grammar rules_or_grammar_declaration
 460 ;
 461
 462 /* As a Bison extension, one can use the grammar declarations in the
 463    body of the grammar.  */
 464 rules_or_grammar_declaration:
 465   rules
 466 | grammar_declaration ";"
 467 | error ";"
 468     {
 469       yyerrok;
 470     }
 471 ;
 472
 473 rules:
 474   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 475 ;
 476
 477 rhses.1:
 478   rhs                { grammar_current_rule_end (@1); }
 479 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 480 | rhses.1 ";"
 481 ;
 482
 483 rhs:
 484   /* Nothing.  */
 485     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 486 | rhs symbol
 487     { grammar_current_rule_symbol_append ($2, @2); }
 488 | rhs "{...}"
 489     { grammar_current_rule_action_append ($2, @2); }
 490 | rhs "%prec" symbol
 491     { grammar_current_rule_prec_set ($3, @3); }
 492 | rhs "%dprec" INT
 493     { grammar_current_rule_dprec_set ($3, @3); }
 494 | rhs "%merge" TYPE
 495     { grammar_current_rule_merge_set ($3, @3); }
 496 ;
 497
 498
 499 /*-----------*
 500  | content.  |
 501  *-----------*/
 502
 503 content:
 504   STRING
 505 | braceless
 506 ;
 507
 508 /* Some content or "1" by default. */
 509 content.opt:
 510   /* Nothing. */
 511     {
 512       static char one[] = "1";
 513       $$ = one;
 514     }
 515 | content
 516 ;
 517
 518
 519 braceless:
 520   "{...}"
 521     {
 522       $1[strlen ($1) - 1] = '\n';
 523       $$ = translate_code ($1 + 1, @1);
 524     }
 525 ;
 526
 527
 528 /*---------------*
 529  | Identifiers.  |
 530  *---------------*/
 531
 532 /* Identifiers are returned as uniqstr values by the scanner.
 533    Depending on their use, we may need to make them genuine symbols.  */
 534
 535 id:
 536   ID
 537     { $$ = symbol_from_uniqstr ($1, @1); }
 538 | CHAR
 539     {
 540       $$ = symbol_get (char_name ($1), @1);
 541       symbol_class_set ($$, token_sym, @1, false);
 542       symbol_user_token_number_set ($$, $1, @1);
 543     }
 544 ;
 545
 546 id_colon:
 547   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 548 ;
 549
 550
 551 symbol:
 552   id
 553 | string_as_id
 554 ;
 555
 556 /* A string used as an ID: quote it.  */
 557 string_as_id:
 558   STRING
 559     {
 560       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 561       symbol_class_set ($$, token_sym, @1, false);
 562     }
 563 ;
 564
 565 epilogue.opt:
 566   /* Nothing.  */
 567 | "%%" EPILOGUE
 568     {
 569       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 570       gram_scanner_last_string_free ();
 571     }
 572 ;
 573
 574 %%
 575
 576
 577 /* Return the location of the left-hand side of a rule whose
 578    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 579    the right-hand side, and return an empty location equal to the end
 580    boundary of RHS[0] if the right-hand side is empty.  */
 581
 582 static YYLTYPE
 583 lloc_default (YYLTYPE const *rhs, int n)
 584 {
 585   int i;
 586   YYLTYPE loc;
 587
 588   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 589      The bug is fixed in 7.4.2m, but play it safe for now.  */
 590   loc.start = rhs[n].end;
 591   loc.end = rhs[n].end;
 592
 593   /* Ignore empty nonterminals the start of the the right-hand side.
 594      Do not bother to ignore them at the end of the right-hand side,
 595      since empty nonterminals have the same end as their predecessors.  */
 596   for (i = 1; i <= n; i++)
 597     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 598       {
 599         loc.start = rhs[i].start;
 600         break;
 601       }
 602
 603   return loc;
 604 }
 605
 606
 607 /* Add a lex-param or a parse-param (depending on TYPE) with
 608    declaration DECL and location LOC.  */
 609
 610 static void
 611 add_param (char const *type, char *decl, location loc)
 612 {
 613   static char const alphanum[26 + 26 + 1 + 10] =
 614     "abcdefghijklmnopqrstuvwxyz"
 615     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 616     "_"
 617     "0123456789";
 618   char const *name_start = NULL;
 619   char *p;
 620
 621   /* Stop on last actual character.  */
 622   for (p = decl; p[1]; p++)
 623     if ((p == decl
 624          || ! memchr (alphanum, p[-1], sizeof alphanum))
 625         && memchr (alphanum, p[0], sizeof alphanum - 10))
 626       name_start = p;
 627
 628   /* Strip the surrounding '{' and '}', and any blanks just inside
 629      the braces.  */
 630   while (*--p == ' ' || *p == '\t')
 631     continue;
 632   p[1] = '\0';
 633   while (*++decl == ' ' || *decl == '\t')
 634     continue;
 635
 636   if (! name_start)
 637     complain_at (loc, _("missing identifier in parameter declaration"));
 638   else
 639     {
 640       char *name;
 641       size_t name_len;
 642
 643       for (name_len = 1;
 644            memchr (alphanum, name_start[name_len], sizeof alphanum);
 645            name_len++)
 646         continue;
 647
 648       name = xmalloc (name_len + 1);
 649       memcpy (name, name_start, name_len);
 650       name[name_len] = '\0';
 651       muscle_pair_list_grow (type, decl, name);
 652       free (name);
 653     }
 654
 655   gram_scanner_last_string_free ();
 656 }
 657
 658
 659 static void
 660 version_check (location const *loc, char const *version)
 661 {
 662   if (strverscmp (version, PACKAGE_VERSION) > 0)
 663     {
 664       complain_at (*loc, "require bison %s, but have %s",
 665                    version, PACKAGE_VERSION);
 666       exit (63);
 667     }
 668 }
 669
 670 static void
 671 gram_error (location const *loc, char const *msg)
 672 {
 673   complain_at (*loc, "%s", msg);
 674 }
 675
 676 char const *
 677 token_name (int type)
 678 {
 679   return yytname[YYTRANSLATE (type)];
 680 }
 681
 682 static char const *
 683 char_name (char c)
 684 {
 685   if (c == '\'')
 686     return "'\\''";
 687   else
 688     {
 689       char buf[4];
 690       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 691       return quotearg_style (escape_quoting_style, buf);
 692     }
 693 }