tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2011 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  45 # ----------------------------------------------------------------
  46 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  47 m4_define([AT_LOC_PUSHDEF],
  48 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  49 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  50 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  51 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  52
  53 # AT_LOC_POPDEF
  54 # -------------
  55 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  56 m4_define([AT_LOC_POPDEF],
  57 [m4_popdef([AT_LOC_FIRST_LINE])
  58 m4_popdef([AT_LOC_FIRST_COLUMN])
  59 m4_popdef([AT_LOC_LAST_LINE])
  60 m4_popdef([AT_LOC_LAST_COLUMN])])
  61
  62
  63
  64 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  65 # -----------------------------------------
  66 m4_define([AT_BISON_OPTION_PUSHDEFS],
  67 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  68
  69
  70 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  71 # --------------------------------------------------
  72 # This macro works around the impossibility to define macros
  73 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  74 # This sucks hard, GNU M4 should really provide M5 like $$1.
  75 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  76 [m4_if([$1$2], $[1]$[2], [],
  77        [m4_fatal([$0: Invalid arguments: $@])])dnl
  78 m4_pushdef([AT_DEFINES_IF],
  79 [m4_bmatch([$3], [%defines], [$1], [$2])])
  80 m4_pushdef([AT_SKEL_CC_IF],
  81 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  82 m4_pushdef([AT_SKEL_JAVA_IF],
  83 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  84 m4_pushdef([AT_GLR_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  86 m4_pushdef([AT_LALR1_CC_IF],
  87 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  88 m4_pushdef([AT_GLR_CC_IF],
  89 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  90 # Using yacc.c?
  91 m4_pushdef([AT_YACC_IF],
  92 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  93 m4_pushdef([AT_LEXPARAM_IF],
  94 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  95 m4_pushdef([AT_LOCATION_IF],
  96 [m4_bmatch([$3], [%locations], [$1], [$2])])
  97 m4_pushdef([AT_LOCATION_TYPE_IF],
  98 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  99 m4_pushdef([AT_PARAM_IF],
 100 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 101 m4_pushdef([AT_PURE_IF],
 102 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 103            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 104            [$2])])
 105 m4_pushdef([AT_PURE_AND_LOC_IF],
 106 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 107 m4_pushdef([AT_GLR_OR_PARAM_IF],
 108 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 109 m4_pushdef([AT_NAME_PREFIX],
 110 [m4_bmatch([$3], [%name-prefix ".*"],
 111            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 112            [yy])])
 113 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 114 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 115 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 116                     [$2])])
 117 # yyerror always sees the locations (when activated), except if
 118 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 119 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 120 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 121                                         [$1])],
 122                             [$1])],
 123                 [$2])])
 124
 125 # The interface is pure: either because %define api.pure, or because we
 126 # are using the C++ parsers.
 127 m4_pushdef([AT_PURE_LEX_IF],
 128 [AT_PURE_IF([$1],
 129             [AT_SKEL_CC_IF([$1], [$2])])])
 130
 131 AT_PURE_LEX_IF(
 132 [m4_pushdef([AT_LOC], [(*llocp)])
 133  m4_pushdef([AT_VAL], [(*lvalp)])
 134  m4_pushdef([AT_LEX_FORMALS],
 135             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 136  m4_pushdef([AT_LEX_ARGS],
 137             [lvalp[]AT_LOCATION_IF([, llocp])])
 138  m4_pushdef([AT_USE_LEX_ARGS],
 139             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 140  m4_pushdef([AT_LEX_PRE_FORMALS],
 141             [AT_LEX_FORMALS, ])
 142  m4_pushdef([AT_LEX_PRE_ARGS],
 143             [AT_LEX_ARGS, ])
 144 ],
 145 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 146  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 147  m4_pushdef([AT_LEX_FORMALS],     [void])
 148  m4_pushdef([AT_LEX_ARGS],        [])
 149  m4_pushdef([AT_USE_LEX_ARGS],    [])
 150  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 151  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 152 ])
 153
 154 # Handle the different types of location components.
 155
 156 AT_SKEL_CC_IF(
 157   [AT_LOCATION_TYPE_IF(
 158     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 159     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 160   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 161
 162 ])# _AT_BISON_OPTION_PUSHDEFS
 163
 164
 165 # AT_BISON_OPTION_POPDEFS
 166 # -----------------------
 167 m4_define([AT_BISON_OPTION_POPDEFS],
 168 [m4_popdef([AT_LEX_PRE_ARGS])
 169 m4_popdef([AT_LEX_PRE_FORMALS])
 170 m4_popdef([AT_USE_LEX_ARGS])
 171 m4_popdef([AT_LEX_ARGS])
 172 m4_popdef([AT_LEX_FORMALS])
 173 m4_popdef([AT_VAL])
 174 m4_popdef([AT_LOC])
 175 m4_popdef([AT_PURE_LEX_IF])
 176 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 177 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 178 m4_popdef([AT_NAME_PREFIX])
 179 m4_popdef([AT_GLR_OR_PARAM_IF])
 180 m4_popdef([AT_PURE_AND_LOC_IF])
 181 m4_popdef([AT_LOCATION_TYPE_IF])
 182 m4_popdef([AT_LOCATION_IF])
 183 m4_popdef([AT_PARAM_IF])
 184 m4_popdef([AT_LEXPARAM_IF])
 185 m4_popdef([AT_YACC_IF])
 186 m4_popdef([AT_GLR_IF])
 187 m4_popdef([AT_SKEL_CC_IF])
 188 m4_popdef([AT_SKEL_JAVA_IF])
 189 m4_popdef([AT_GLR_CC_IF])
 190 m4_popdef([AT_LALR1_CC_IF])
 191 m4_popdef([AT_DEFINES_IF])
 192 AT_LOC_POPDEF
 193 ])# AT_BISON_OPTION_POPDEFS
 194
 195
 196
 197 ## -------------------------- ##
 198 ## Generating Grammar Files.  ##
 199 ## -------------------------- ##
 200
 201 # AT_DATA_SOURCE_PROLOGUE
 202 # ------------------------
 203 # The prologue that should be included in any source code that is
 204 # meant to be compiled.
 205 m4_define([AT_DATA_SOURCE_PROLOGUE],
 206 [[#include <config.h>
 207 /* We don't need perfect functions for these tests. */
 208 #undef malloc
 209 #undef memcmp
 210 #undef realloc
 211 ]])
 212
 213 # AT_DATA_GRAMMAR_PROLOGUE
 214 # ------------------------
 215 # The prologue that should be included in any grammar which parser is
 216 # meant to be compiled.
 217 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 218 [[%code top {
 219 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 220 [}
 221 ]])
 222
 223 # AT_DATA_SOURCE(NAME, CONTENT)
 224 # -----------------------------
 225 # Generate the file NAME, which CONTENT is preceded by
 226 # AT_DATA_SOURCE_PROLOGUE.
 227 m4_define([AT_DATA_SOURCE],
 228 [AT_DATA([$1],
 229 [AT_DATA_SOURCE_PROLOGUE
 230 $2])
 231 ])
 232
 233 # AT_DATA_GRAMMAR(NAME, CONTENT)
 234 # ------------------------------
 235 # Generate the file NAME, which CONTENT is preceded by
 236 # AT_DATA_GRAMMAR_PROLOGUE.
 237 m4_define([AT_DATA_GRAMMAR],
 238 [AT_DATA([$1],
 239 [AT_DATA_GRAMMAR_PROLOGUE
 240 $2])
 241 ])
 242
 243 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 244 # -------------------------------------------------
 245 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 246 # shell constructs (such as redirection or pipes) that would prevent
 247 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 248 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 249 #
 250 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 251 # Bison in the test suite.  For now it ensures that:
 252 #
 253 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 254 #      a non-zero exit status since Bison doesn't always try to free all memory
 255 #      in that case.
 256 #
 257 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 258 #      --graph and --report=all output for every working grammar.
 259 #
 260 #   3. If stderr contains a warning, -Werror and --warnings=error
 261 #      convert the warning to an error.
 262 #
 263 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 264 m4_define([AT_BISON_CHECK],
 265 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 266        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 267 AT_BISON_CHECK_NO_XML($@)])
 268
 269 m4_define([AT_BISON_WERROR_MSG],
 270           [[bison: warnings being treated as errors]])
 271
 272 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 273 # --------------------------------------------------------
 274 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 275 # when a tortured grammar's XML is known to be too large for xsltproc to
 276 # handle.
 277 m4_define([AT_BISON_CHECK_NO_XML],
 278 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 279                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 280 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 281       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 282         # POSIXLY_CORRECT=1 causes bison to complain if options are added
 283         # after the grammar file name, so skip these checks in that case.
 284         if test x"$POSIXLY_CORRECT" != x1; then
 285           # Don't interfere with caller's files.
 286           if test -f stderr; then mv stderr at-bison-check-stderr.bak; fi
 287           if test -f experr; then mv experr at-bison-check-experr.bak; fi
 288           if test -f expout; then mv expout at-bison-check-expout.bak; fi
 289
 290           # To avoid expanding it repeatedly, store specified stdout.
 291           ]AT_DATA([expout], [$3])[
 292
 293           # Run with -Werror.
 294           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 295                     [[1]], [expout], [stderr])[
 296
 297           # Build expected stderr up to and including the "warnings being
 298           # treated as errors" message.
 299           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 300           at_bison_check_first="` \
 301             sed -n '/: warning: /=' at-bison-check-warnings \
 302             | sed -n 1p \
 303           `"
 304           if test $at_bison_check_first -gt 1; then
 305             sed -n "1,`expr $at_bison_check_first - 1`"p \
 306               at-bison-check-warnings > experr
 307           fi
 308           echo ']AT_BISON_WERROR_MSG[' >> experr
 309
 310           # Finish building expected stderr and check.  Unlike warnings,
 311           # complaints cause bison to exit early.  Thus, with -Werror, bison
 312           # does not necessarily report all warnings that it does without
 313           # -Werror, but it at least reports one.
 314           at_bison_check_last="`sed -n '$=' stderr`"
 315           if test x"$at_bison_check_last" = x; then
 316             at_bison_check_last=1
 317           fi
 318           at_bison_check_last="`expr $at_bison_check_last - 1`"
 319           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 320             at-bison-check-warnings >> experr
 321           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 322                       stderr 1>&2]], [[0]], [[]], [experr])[
 323
 324           # Now check --warnings=error.
 325           cp stderr experr
 326           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 327                     [[1]], [expout], [experr])[
 328
 329           # Now check -Wnone and --warnings=none by making sure that
 330           # -Werror doesn't change the exit status when -Wnone or
 331           # --warnings=none is specified.
 332           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 333                     [[0]], [expout], [ignore])[
 334           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 335                     -Werror]], [[0]], [expout], [ignore])[
 336
 337           # Restore caller's files.
 338           if test -f at-bison-check-expout.bak; then
 339             mv at-bison-check-expout.bak expout
 340           fi
 341           if test -f at-bison-check-experr.bak; then
 342             mv at-bison-check-experr.bak experr
 343           fi
 344           if test -f at-bison-check-stderr.bak; then
 345             mv at-bison-check-stderr.bak stderr
 346           fi
 347         fi
 348       ]])
 349 ])
 350
 351 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 352 # -----------------------------------------------------
 353 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 354 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 355 # have a non-zero exit status.
 356 m4_define([AT_BISON_CHECK_XML],
 357 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 358   mkdir xml-tests]
 359   m4_pushdef([AT_BISON_ARGS],
 360              [m4_bpatsubsts([[$1]],
 361                             [--report(-file)?=[^][ ]*], [],
 362                             [--graph=[^][ ]*], [],
 363                             [--xml=[^][ ]*], [])])dnl
 364   # Don't combine these Bison invocations since we want to be sure that
 365   # --report=all isn't required to get the full XML file.
 366   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 367              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 368            [[0]], [ignore], [ignore])
 369   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 370            [[0]], [ignore], [ignore])
 371   m4_popdef([AT_BISON_ARGS])dnl
 372   [cp xml-tests/test.output expout]
 373   AT_CHECK([[$XSLTPROC \
 374              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 375              xml-tests/test.xml]], [[0]], [expout])
 376   [cp xml-tests/test.dot expout]
 377   AT_CHECK([[$XSLTPROC \
 378              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 379              xml-tests/test.xml]], [[0]], [expout])
 380   [rm -rf xml-tests expout
 381 fi]])
 382
 383 # AT_QUELL_VALGRIND
 384 # -----------------
 385 # Put this before a Bison invocation to keep Valgrind from complaining about
 386 # reachable memory.
 387 #
 388 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 389 # The triple quoting below will cause test cases to fail if you do.  If you do
 390 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 391 # will then fail to shell-escape its contents when attempting to print them.
 392 # The testsuite verbose output, at least, will be incorrect, but nothing may
 393 # fail to make sure you notice.
 394 m4_define([AT_QUELL_VALGRIND],
 395 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 396
 397 ## ------------------------ ##
 398 ## Compiling C, C++ Files.  ##
 399 ## ------------------------ ##
 400
 401
 402 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 403 # ----------------------------------------
 404 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 405 # assume that we are linking too; this is a hack.
 406 m4_define([AT_COMPILE],
 407 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 408            0, [ignore], [ignore])])
 409
 410 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 411 # --------------------------------------------
 412 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 413 # assume that we are linking too; this is a hack.
 414 # If the C++ compiler does not work, ignore the test.
 415 m4_define([AT_COMPILE_CXX],
 416 [AT_KEYWORDS(c++)
 417 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 418 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 419          0, [ignore], [ignore])])
 420
 421 # AT_JAVA_COMPILE(SOURCES)
 422 # ------------------------
 423 # Compile SOURCES into Java class files.  Skip the test if java or javac
 424 # is not installed.
 425 m4_define([AT_JAVA_COMPILE],
 426 [AT_KEYWORDS(java)
 427 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 428            test -n "$CONF_JAVAC" || exit 77]])
 429 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 430          [[0]], [ignore], [ignore])])
 431
 432 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 433 # --------------------------------
 434 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 435 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 436 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 437 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 438 # AT_SKEL_JAVA_IF.
 439 m4_define([AT_FULL_COMPILE], [
 440   AT_SKEL_JAVA_IF([
 441     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 442     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 443                                         [[$1[.java ]$1[-]$2[.java]]]))
 444   ], [
 445     AT_SKEL_CC_IF([
 446       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 447       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 448     ], [
 449       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 450       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 451     ])
 452   ])
 453 ])
 454
 455
 456 ## ---------------------------- ##
 457 ## Running a generated parser.  ##
 458 ## ---------------------------- ##
 459
 460 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 461 # ------------------------------------------------------------
 462 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 463 m4_define([AT_PARSER_CHECK],
 464 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 465
 466 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 467 # -----------------------------------------------------------------
 468 m4_define([AT_JAVA_PARSER_CHECK],
 469 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 470
 471 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 472 #                          DECLS, GRAMMAR, INPUT,
 473 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 474 #                          [OTHER-CHECKS],
 475 #                          [PARSER-EXIT-VALUE],
 476 #                          [PARSER-STDOUT], [PARSER-STDERR])
 477 # -------------------------------------------------------------
 478 # Using TITLE as the test group title, check the generated parser tables
 479 # and parser for a specified grammar file under a condition labeled by
 480 # COND-VALUE.
 481 #
 482 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 483 # recognized attribute is described below where it is relevant.
 484 #
 485 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 486 # the grammar file.  Insert basic yyerror, yylex, and main function
 487 # definitions as well.  Hardcode yylex to return the (possibly empty)
 488 # comma-delimited series of tokens in INPUT followed by token 0.
 489 #
 490 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 491 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 492 # On the bison command-line, specify `--report=all --defines'.  Check
 493 # that Bison exits with value 0, has no stdout, and has stderr
 494 # BISON-STDERR.
 495 #
 496 # If TEST-SPEC contains the attribute `last-state', check that the value
 497 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 498 # the grammar; in other words, check the number of states (minus one).
 499 # Otherwise, check that everything in the `.output' file starting with
 500 # the definition of state 0 is the same as the entire value of
 501 # TABLES-OR-LAST-STATE.
 502 #
 503 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 504 # `.output' file, which is named `input.output', and/or grammar file,
 505 # which is named `input.y'.
 506 #
 507 # Finally, compile the generated parser and then run it using
 508 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 509 # PARSER-STDERR as the 2nd-4th arguments.
 510 #
 511 # As a precondition, you must properly double-quote all arguments that
 512 # are to be interpreted as strings.
 513 #
 514 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 515 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 516 # first argument.  This is useful, for example, when wrapping multiple
 517 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 518 # condition, in another macro.
 519 #
 520 # For example:
 521 #
 522 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 523 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 524 #   # ---------------------------------------------------------------------
 525 #   m4_define([AT_TEST_SYNTAX_ERROR],
 526 #   [
 527 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 528 #                              [[last-state]],
 529 #                              [[%error-verbose ]$2], [$3], [$4],
 530 #                              [[]], [$5], [], [$6], [$7], [$8])
 531 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 532 #                              [[last-state]],
 533 #                              [$2], [$3], [$4],
 534 #                              [[]], [$5], [], [$6], [$7], [$8])
 535 #   ])
 536 #
 537 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 538 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 539 #                        [[3]],
 540 #                        [[1]], [[]],
 541 #                        [AT_COND_CASE([[no verbose]],
 542 #                                      [[syntax error
 543 #   ]],
 544 #                                      [[syntax error, unexpected 'b', expecting $end
 545 #   ]])])
 546 m4_define([AT_TEST_TABLES_AND_PARSE],
 547 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 548
 549 AT_SETUP([$1])
 550
 551 AT_DATA_GRAMMAR([[input.y]],
 552 [[%code {
 553   #include <stdio.h>
 554   static void yyerror (char const *msg);
 555   static int yylex (void);
 556 }
 557
 558 ]$4[
 559
 560 %%
 561
 562 ]$5[
 563
 564 %%
 565
 566 static void
 567 yyerror (char const *msg)
 568 {
 569   fprintf (stderr, "%s\n", msg);
 570 }
 571
 572 static int
 573 yylex (void)
 574 {
 575   static int const input[] = {
 576     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 577   };
 578   static int const *inputp = input;
 579   return *inputp++;
 580 }
 581
 582 int
 583 main (void)
 584 {
 585   return yyparse ();
 586 }
 587 ]])
 588
 589 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 590 # expanding macros, so it corrupts some special characters in the
 591 # macros.  To avoid this, expand now and pass it the result with proper
 592 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 593 # strings.
 594
 595 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 596       [AT_BISON_CHECK],
 597       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 598                                [0], [], m4_dquote($7))
 599
 600 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 601       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 602                 m4_dquote($8))],
 603       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 604                 m4_dquote($8)[[
 605 ]])])
 606
 607 $9
 608
 609 AT_COMPILE([[input]])
 610
 611 AT_PARSER_CHECK([[./input]],
 612                 m4_ifval([$10], [m4_dquote($10)]),
 613                 m4_ifval([$11], [m4_dquote($11)]),
 614                 m4_ifval([$12], [m4_dquote($12)]))
 615
 616 AT_CLEANUP
 617
 618 m4_popdef([AT_COND_CASE])])
 619
 620
 621
 622 ## ----------------------- ##
 623 ## Launch the test suite.  ##
 624 ## ----------------------- ##
 625
 626 AT_INIT
 627
 628 AT_TESTED([bison])