src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 %option nodefault noyywrap noinput nounput never-interactive debug
  21 %option prefix="skel_" outfile="lex.yy.c"
  22
  23 %{
  24 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  25    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  26 #undef skel_wrap
  27 #define skel_wrap() 1
  28
  29 #define FLEX_PREFIX(Id) skel_ ## Id
  30 #include <src/flex-scanner.h>
  31
  32 #include <dirname.h>
  33 #include <error.h>
  34 #include <quotearg.h>
  35
  36 #include <src/complain.h>
  37 #include <src/getargs.h>
  38 #include <src/files.h>
  39 #include <src/scan-skel.h>
  40
  41 #define YY_DECL static int skel_lex (void)
  42 YY_DECL;
  43
  44 static void at_directive_perform (int argc, char *argv[],
  45                                   char **outnamep, int *out_linenop);
  46 static void fail_for_at_directive_too_many_args (char const *at_directive_name);
  47 static void fail_for_at_directive_too_few_args (char const *at_directive_name);
  48 static void fail_for_invalid_at (char const *at);
  49 %}
  50
  51 %x SC_AT_DIRECTIVE_ARGS
  52 %x SC_AT_DIRECTIVE_SKIP_WS
  53
  54 %%
  55
  56 %{
  57   int out_lineno PACIFY_CC (= 0);
  58   char *outname = NULL;
  59
  60   /* Currently, only the @warn, @complain, @fatal, @warn_at, @complain_at, and
  61      @fatal_at directives take multiple arguments, and the last three already
  62      can't take more than 7.  argv[0] is the directive name.  */
  63   #define ARGC_MAX 8
  64   int argc = 0;
  65   char *argv[ARGC_MAX];
  66 %}
  67
  68 "@@" fputc ('@', yyout);
  69 "@{" fputc ('[', yyout);
  70 "@}" fputc (']', yyout);
  71 "@`" continue;  /* Used by b4_cat in ../data/bison.m4.  */
  72 @\n  continue;
  73
  74 "@oline@"  fprintf (yyout, "%d", out_lineno + 1);
  75 "@ofile@"  fputs (quotearg_style (c_quoting_style, outname), yyout);
  76
  77 @[a-z_]+"(" {
  78   yytext[yyleng-1] = '\0';
  79   obstack_grow (&obstack_for_string, yytext, yyleng);
  80   argv[argc++] = obstack_finish (&obstack_for_string);
  81   BEGIN SC_AT_DIRECTIVE_ARGS;
  82 }
  83
  84   /* This pattern must not match more than the previous @ patterns. */
  85 @[^@{}`(\n]* fail_for_invalid_at (yytext);
  86 \n         out_lineno++; ECHO;
  87 [^@\n]+    ECHO;
  88
  89 <INITIAL><<EOF>> {
  90   if (outname)
  91     {
  92       free (outname);
  93       xfclose (yyout);
  94     }
  95   return EOF;
  96 }
  97
  98 <SC_AT_DIRECTIVE_ARGS>
  99 {
 100   [^@]+  STRING_GROW;
 101
 102   "@@"   obstack_1grow (&obstack_for_string, '@');
 103   "@{"   obstack_1grow (&obstack_for_string, '[');
 104   "@}"   obstack_1grow (&obstack_for_string, ']');
 105   "@`"   continue; /* For starting an argument that begins with whitespace. */
 106   @\n    continue;
 107
 108   @[,)] {
 109     if (argc >= ARGC_MAX)
 110       fail_for_at_directive_too_many_args (argv[0]);
 111
 112     argv[argc++] = obstack_finish0 (&obstack_for_string);
 113
 114     /* Like M4, skip whitespace after a comma.  */
 115     if (yytext[1] == ',')
 116       BEGIN SC_AT_DIRECTIVE_SKIP_WS;
 117     else
 118       {
 119         at_directive_perform (argc, argv, &outname, &out_lineno);
 120         obstack_free (&obstack_for_string, argv[0]);
 121         argc = 0;
 122         BEGIN INITIAL;
 123       }
 124   }
 125
 126   @.?  fail_for_invalid_at (yytext);
 127 }
 128
 129 <SC_AT_DIRECTIVE_SKIP_WS>
 130 {
 131   [ \t\r\n]    continue;
 132   .            yyless (0); BEGIN SC_AT_DIRECTIVE_ARGS;
 133 }
 134
 135 <SC_AT_DIRECTIVE_ARGS,SC_AT_DIRECTIVE_SKIP_WS>
 136 {
 137   <<EOF>>  complain (fatal, _("unclosed %s directive in skeleton"), argv[0]);
 138 }
 139
 140 %%
 141
 142 /*------------------------.
 143 | Scan a Bison skeleton.  |
 144 `------------------------*/
 145
 146 void
 147 scan_skel (FILE *in)
 148 {
 149   static bool initialized = false;
 150   if (!initialized)
 151     {
 152       initialized = true;
 153       obstack_init (&obstack_for_string);
 154     }
 155   skel_in = in;
 156   skel__flex_debug = trace_flag & trace_skeleton;
 157   skel_lex ();
 158 }
 159
 160 void
 161 skel_scanner_free (void)
 162 {
 163   obstack_free (&obstack_for_string, 0);
 164   /* Reclaim Flex's buffers.  */
 165   yylex_destroy ();
 166 }
 167
 168 static inline warnings
 169 flag (const char *arg)
 170 {
 171   switch (arg[1])
 172     {
 173     case 'w': return Wother;
 174     case 'c': return complaint;
 175     case 'f': return fatal;
 176     default: aver (false); break;
 177     }
 178 }
 179
 180 static void
 181 at_directive_perform (int argc, char *argv[], char **outnamep, int *out_linenop)
 182 {
 183   if (STREQ (argv[0], "@basename"))
 184     {
 185       if (argc > 2)
 186         fail_for_at_directive_too_many_args (argv[0]);
 187       fputs (last_component (argv[1]), yyout);
 188     }
 189   else if (STREQ (argv[0], "@warn")
 190            || STREQ (argv[0], "@complain")
 191            || STREQ (argv[0], "@fatal"))
 192     {
 193       warnings w = flag (argv[0]);
 194       switch (argc)
 195         {
 196           case 2:
 197             complain (w, "%s", _(argv[1]));
 198             break;
 199           case 3:
 200             complain (w, _(argv[1]), argv[2]);
 201             break;
 202           case 4:
 203             complain (w, _(argv[1]), argv[2], argv[3]);
 204             break;
 205           case 5:
 206             complain (w, _(argv[1]), argv[2], argv[3], argv[4]);
 207             break;
 208           case 6:
 209             complain (w, _(argv[1]), argv[2], argv[3], argv[4], argv[5]);
 210             break;
 211           default:
 212             fail_for_at_directive_too_many_args (argv[0]);
 213             break;
 214         }
 215     }
 216   else if (STREQ (argv[0], "@warn_at")
 217            || STREQ (argv[0], "@complain_at")
 218            || STREQ (argv[0], "@fatal_at"))
 219     {
 220       warnings w = flag (argv[0]);
 221       location loc;
 222       if (argc < 4)
 223         fail_for_at_directive_too_few_args (argv[0]);
 224       boundary_set_from_string (&loc.start, argv[1]);
 225       boundary_set_from_string (&loc.end, argv[2]);
 226       switch (argc)
 227         {
 228           case 4:
 229             complain_at (loc, w, "%s", _(argv[3]));
 230             break;
 231           case 5:
 232             complain_at (loc, w, _(argv[3]), argv[4]);
 233             break;
 234           case 6:
 235             complain_at (loc, w, _(argv[3]), argv[4], argv[5]);
 236             break;
 237           case 7:
 238             complain_at (loc, w, _(argv[3]), argv[4], argv[5], argv[6]);
 239             break;
 240           case 8:
 241             complain_at (loc, w, _(argv[3]), argv[4], argv[5], argv[6],
 242                          argv[7]);
 243             break;
 244           default:
 245             fail_for_at_directive_too_many_args (argv[0]);
 246             break;
 247         }
 248     }
 249   else if (STREQ (argv[0], "@output"))
 250     {
 251       if (argc > 2)
 252         fail_for_at_directive_too_many_args (argv[0]);
 253       if (*outnamep)
 254         {
 255           free (*outnamep);
 256           xfclose (yyout);
 257         }
 258       *outnamep = xstrdup (argv[1]);
 259       output_file_name_check (outnamep);
 260       yyout = xfopen (*outnamep, "w");
 261       *out_linenop = 1;
 262     }
 263   else
 264     fail_for_invalid_at (argv[0]);
 265 }
 266
 267 static void
 268 fail_for_at_directive_too_few_args (char const *at_directive_name)
 269 {
 270   complain (fatal, _("too few arguments for %s directive in skeleton"),
 271             at_directive_name);
 272 }
 273
 274 static void
 275 fail_for_at_directive_too_many_args (char const *at_directive_name)
 276 {
 277   complain (fatal, _("too many arguments for %s directive in skeleton"),
 278             at_directive_name);
 279 }
 280
 281 static void
 282 fail_for_invalid_at (char const *at)
 283 {
 284   complain (fatal, "invalid @ in skeleton: %s", at);
 285 }