configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301  USA
  20
  21 # We use macros like AC_CHECK_HEADERS_ONCE, so we need Autoconf 2.60 or better.
  22 AC_PREREQ(2.60)
  23
  24 AC_INIT([GNU Bison], [2.3+], [bug-bison@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  29 AM_INIT_AUTOMAKE([1.8 check-news readme-alpha dist-bzip2])
  30 AC_CONFIG_HEADERS([config.h:config.hin])
  31
  32 gl_USE_SYSTEM_EXTENSIONS
  33
  34 # Checks for the compiler.
  35 AC_PROG_CC
  36 AM_PROG_CC_STDC
  37 AC_ARG_ENABLE(gcc-warnings,
  38 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  39 [case "${enableval}" in
  40    yes|no) ;;
  41    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  42  esac],
  43               [enableval=no])
  44 if test "${enableval}" = yes; then
  45   gl_WARNING_CFLAGS([-Werror])
  46   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  47   WARNING_CFLAGS=
  48   gl_WARNING_CFLAGS([-W])
  49   gl_WARNING_CFLAGS([-Wall])
  50   gl_WARNING_CFLAGS([-Wcast-align])
  51   gl_WARNING_CFLAGS([-Wcast-qual])
  52   gl_WARNING_CFLAGS([-Wformat])
  53   gl_WARNING_CFLAGS([-Wwrite-strings])
  54   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  55   # The following warnings are not suitable for C++.
  56   gl_WARNING_CFLAGS([-Wbad-function-cast])
  57   gl_WARNING_CFLAGS([-Wmissing-declarations])
  58   gl_WARNING_CFLAGS([-Wmissing-prototypes])
  59   gl_WARNING_CFLAGS([-Wshadow])
  60   gl_WARNING_CFLAGS([-Wstrict-prototypes])
  61   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  62 fi
  63
  64 BISON_TEST_FOR_WORKING_C_COMPILER
  65
  66 AC_ARG_ENABLE([yacc],
  67   [AC_HELP_STRING([--disable-yacc],
  68      [do not build a yacc command or an -ly library])],
  69   , [enable_yacc=yes])
  70 case $enable_yacc in
  71 yes)
  72   YACC_SCRIPT=yacc
  73   YACC_LIBRARY=liby.a;;
  74 *)
  75   YACC_SCRIPT=
  76   YACC_LIBRARY=;;
  77 esac
  78 AC_SUBST([YACC_SCRIPT])
  79 AC_SUBST([YACC_LIBRARY])
  80
  81 # Checks for programs.
  82 AC_PROG_LEX
  83 AC_PROG_YACC
  84 AC_PROG_RANLIB
  85 BISON_PROG_GNU_M4
  86 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  87   AC_MSG_ERROR([GNU M4 1.4 is required])
  88 fi
  89 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  90
  91 # Checks for header files.
  92 AC_CHECK_HEADERS_ONCE([locale.h])
  93 AM_STDBOOL_H
  94
  95 # Checks for compiler characteristics.
  96 AC_C_INLINE
  97
  98 # Checks for library functions.
  99 AC_CHECK_FUNCS_ONCE([setlocale])
 100 AM_WITH_DMALLOC
 101 BISON_PREREQ_SUBPIPE
 102 BISON_PREREQ_TIMEVAR
 103
 104 # gnulib and gettext.
 105 GNULIB_AUTOCONF_SNIPPET
 106 # We've never tested with gettext versions before 0.15, so play it safe.
 107 AM_GNU_GETTEXT_VERSION([0.15])
 108 BISON_I18N
 109
 110 # Internationalized parsers.
 111 AC_CONFIG_FILES([runtime-po/Makefile.in])
 112 # Autoconf macros for packages using internationalized parsers.
 113 aclocaldir='${datadir}/aclocal'
 114 AC_SUBST([aclocaldir])
 115
 116 # Initialize the test suite.
 117 AC_CONFIG_TESTDIR(tests)
 118 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 119 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 120 AC_CHECK_PROGS([VALGRIND], [valgrind])
 121 AC_PROG_CXX
 122 BISON_TEST_FOR_WORKING_CXX_COMPILER
 123 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 124 # Needed by tests/atlocal.in.
 125 AC_SUBST([GCC])
 126 O0CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]] *//'`
 127 AC_SUBST([O0CFLAGS])
 128 O0CXXFLAGS=`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`
 129 AC_SUBST([O0CXXFLAGS])
 130
 131 AC_CONFIG_FILES([Makefile
 132                  build-aux/Makefile
 133                  po/Makefile.in
 134                  data/Makefile
 135                  examples/Makefile
 136                     examples/calc++/Makefile
 137                  lib/Makefile src/Makefile doc/Makefile])
 138 AC_OUTPUT