src/parse-gram.y

   1 /* Bison Grammar Parser                             -*- C -*-
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4    This file is part of Bison, the GNU Compiler Compiler.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program; if not, write to the Free Software
  18    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307  USA
  20 */
  21
  22
  23 %debug
  24 %defines
  25 %locations
  26 %pure-parser
  27 // %error-verbose
  28 %defines
  29 %name-prefix="gram_"
  30
  31 %{
  32 #include "system.h"
  33 #include "muscle_tab.h"
  34 #include "files.h"
  35 #include "getargs.h"
  36 #include "output.h"
  37 #include "gram.h"
  38 #include "reader.h"
  39 #include "conflicts.h"
  40
  41 /* Produce verbose parse errors.  */
  42 #define YYERROR_VERBOSE 1
  43
  44 /* Pass the control structure to YYPARSE and YYLEX. */
  45 #define YYPARSE_PARAM gram_control
  46 #define YYLEX_PARAM gram_control
  47 /* YYPARSE receives GRAM_CONTROL as a void *.  Provide a
  48    correctly typed access to it.  */
  49 #define yycontrol ((gram_control_t *) gram_control)
  50
  51 /* Request detailed parse error messages, and pass them to
  52    GRAM_ERROR. */
  53 #undef  yyerror
  54 #define yyerror(Msg) \
  55         gram_error (yycontrol, &yylloc, Msg)
  56
  57 /* When debugging our pure parser, we want to see values and locations
  58    of the tokens.  */
  59 #define YYPRINT(File, Type, Value) \
  60         yyprint (File, &yylloc, Type, &Value)
  61 static void yyprint (FILE *file, const location_t *loc,
  62                      int type, const yystype *value);
  63
  64 symbol_class current_class = unknown_sym;
  65 char *current_type = 0;
  66 symbol_t *current_lhs;
  67 associativity current_assoc;
  68 int current_prec = 0;
  69 %}
  70
  71
  72 /* Only NUMBERS have a value.  */
  73 %union
  74 {
  75   symbol_t *symbol;
  76   int integer;
  77   char *string;
  78   associativity assoc;
  79 };
  80
  81 /* Define the tokens together with there human representation. */
  82 %token GRAM_EOF 0 "end of string"
  83 %token STRING CHARACTER
  84 %token INT
  85
  86 %token PERCENT_TOKEN "%token"
  87 %token PERCENT_NTERM "%nterm"
  88 %token PERCENT_TYPE  "%type"
  89 %token PERCENT_UNION "%union"
  90 %token PERCENT_EXPECT "%expect"
  91 %token PERCENT_START "%start"
  92 %token PERCENT_LEFT  "%left"
  93 %token PERCENT_RIGHT "%right"
  94 %token PERCENT_NONASSOC "%nonassoc"
  95 %token PERCENT_PREC     "%prec"
  96 %token PERCENT_VERBOSE  "%verbose"
  97 %token PERCENT_ERROR_VERBOSE "%error-verbose"
  98
  99 %token PERCENT_OUTPUT "%output"
 100 %token PERCENT_FILE_PREFIX "%file-prefix"
 101 %token PERCENT_NAME_PREFIX "%name-prefix"
 102
 103 %token PERCENT_DEFINE "%define"
 104 %token PERCENT_PURE_PARSER "%pure-parser"
 105
 106 %token PERCENT_DEFINES "%defines"
 107
 108 %token PERCENT_YACC "%yacc"
 109
 110 %token PERCENT_DEBUG "%debug"
 111 %token PERCENT_LOCATIONS "%locations"
 112 %token PERCENT_NO_LINES "%no-lines"
 113 %token PERCENT_SKELETON "%skeleton"
 114 %token PERCENT_TOKEN_TABLE "%token-table"
 115
 116 %token TYPE
 117 %token EQUAL "="
 118 %token SEMICOLON ";"
 119 %token COLON ":"
 120 %token PIPE "|"
 121 %token ID "identifier"
 122 %token PERCENT_PERCENT "%%"
 123 %token PROLOGUE EPILOGUE
 124 %token BRACED_CODE
 125
 126 %type <string> CHARACTER TYPE STRING string_content
 127                BRACED_CODE PROLOGUE EPILOGUE epilogue.opt action
 128 %type <integer> INT
 129 %type <symbol> ID symbol string_as_id
 130 %type <assoc> precedence_declarator
 131
 132 %%
 133
 134 input: { LOCATION_RESET (yylloc); }
 135   declarations "%%" grammar epilogue.opt
 136     {
 137       yycontrol->errcode = 0;
 138       epilogue_set ($5, @5);
 139     }
 140 ;
 141
 142
 143         /*------------------------------------.
 144         | Declarations: before the first %%.  |
 145         `------------------------------------*/
 146
 147 declarations:
 148   /* Nothing */
 149 | declarations declaration
 150 ;
 151
 152 declaration:
 153   grammar_declaration
 154 | PROLOGUE                                 { prologue_augment ($1, @1); }
 155 | "%debug"                                 { debug_flag = 1; }
 156 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 157 | "%defines"                               { defines_flag = 1; }
 158 | "%error-verbose"                         { error_verbose = 1; }
 159 | "%expect" INT                            { expected_conflicts = $2; }
 160 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 161 | "%locations"                             { locations_flag = 1; }
 162 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 163 | "%no-lines"                              { no_lines_flag = 1; }
 164 | "%output" "=" string_content             { spec_outfile = $3; }
 165 | "%pure-parser"                           { pure_parser = 1; }
 166 | "%skeleton" string_content               { skeleton = $2; }
 167 | "%token-table"                           { token_table_flag = 1; }
 168 | "%verbose"                               { report_flag = 1; }
 169 | "%yacc"                                  { yacc_flag = 1; }
 170 ;
 171
 172 grammar_declaration:
 173   precedence_declaration
 174 | symbol_declaration
 175 | "%start" symbol
 176     {
 177       grammar_start_symbol_set ($2);
 178     }
 179 | "%union" BRACED_CODE semi_colon_opt
 180     {
 181       typed = 1;
 182       MUSCLE_INSERT_INT ("stype_line", @2.first_line);
 183       muscle_insert ("stype", $2);
 184     }
 185 ;
 186
 187 symbol_declaration:
 188   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 189     {
 190       current_class = unknown_sym;
 191       current_type = NULL;
 192     }
 193 | "%token" { current_class = token_sym; } symbol_defs.1
 194     {
 195       current_class = unknown_sym;
 196       current_type = NULL;
 197     }
 198 | "%type" TYPE {current_type = $2; } nterms_to_type.1
 199     {
 200       current_type = NULL;
 201     }
 202 ;
 203
 204 precedence_declaration:
 205   precedence_declarator type.opt
 206     { current_assoc = $1; ++current_prec; }
 207   terms_to_prec.1
 208     { current_assoc = non_assoc; current_type = NULL; }
 209 ;
 210
 211 precedence_declarator:
 212   "%left"     { $$ = left_assoc; }
 213 | "%right"    { $$ = right_assoc; }
 214 | "%nonassoc" { $$ = non_assoc; }
 215 ;
 216
 217 type.opt:
 218   /* Nothing. */ { current_type = NULL;}
 219 | TYPE           { current_type = $1; }
 220 ;
 221
 222 /* One or more nonterminals to be %typed. */
 223 nterms_to_type.1:
 224   ID                   { symbol_type_set ($1, current_type); }
 225 | nterms_to_type.1 ID  { symbol_type_set ($2, current_type); }
 226 ;
 227
 228 /* One or more symbols to be given a precedence/associativity.  */
 229 terms_to_prec.1:
 230   symbol
 231     {
 232       symbol_type_set ($1, current_type);
 233       symbol_precedence_set ($1, current_prec, current_assoc);
 234     }
 235 | terms_to_prec.1 symbol
 236     {
 237       symbol_type_set ($2, current_type);
 238       symbol_precedence_set ($2, current_prec, current_assoc);
 239     }
 240 ;
 241
 242 /* One token definition.  */
 243 symbol_def:
 244   TYPE
 245      {
 246        current_type = $1;
 247      }
 248 | ID
 249      {
 250        symbol_class_set ($1, current_class);
 251        symbol_type_set ($1, current_type);
 252      }
 253 | ID INT
 254     {
 255       symbol_class_set ($1, current_class);
 256       symbol_type_set ($1, current_type);
 257       symbol_user_token_number_set ($1, $2);
 258     }
 259 | ID string_as_id
 260     {
 261       symbol_class_set ($1, current_class);
 262       symbol_type_set ($1, current_type);
 263       symbol_make_alias ($1, $2);
 264     }
 265 | ID INT string_as_id
 266     {
 267       symbol_class_set ($1, current_class);
 268       symbol_type_set ($1, current_type);
 269       symbol_user_token_number_set ($1, $2);
 270       symbol_make_alias ($1, $3);
 271     }
 272 ;
 273
 274 /* One or more symbol definitions. */
 275 symbol_defs.1:
 276   symbol_def
 277     {;}
 278 | symbol_defs.1 symbol_def
 279     {;}
 280 ;
 281
 282
 283         /*------------------------------------------.
 284         | The grammar section: between the two %%.  |
 285         `------------------------------------------*/
 286
 287 grammar:
 288   rules
 289 | grammar rules
 290 ;
 291
 292 rules:
 293   ID ":" { current_lhs = $1; } rhses.1 ";"
 294     {;}
 295 ;
 296
 297 rhses.1:
 298   rhs                { grammar_rule_end (); }
 299 | rhses.1 "|" rhs    { grammar_rule_end (); }
 300 ;
 301
 302 rhs:
 303   /* Nothing.  */
 304     { grammar_rule_begin (current_lhs); }
 305 | rhs symbol
 306     { grammar_current_rule_symbol_append ($2); }
 307 | rhs action
 308     { grammar_current_rule_action_append ($2, @2.first_line); }
 309 | rhs "%prec" symbol
 310     { grammar_current_rule_prec_set ($3); }
 311 ;
 312
 313 symbol:
 314   ID              { $$ = $1; }
 315 | string_as_id    { $$ = $1; }
 316 | CHARACTER       { $$ = getsym ($1); }
 317 ;
 318
 319 action:
 320   BRACED_CODE
 321    { $$ = $1; }
 322 ;
 323
 324 /* A string used as an ID: we have to keep the quotes. */
 325 string_as_id:
 326   STRING
 327     {
 328       $$ = getsym ($1);
 329       symbol_class_set ($$, token_sym);
 330     }
 331 ;
 332
 333 /* A string used for its contents.  Strip the quotes. */
 334 string_content:
 335   STRING
 336     {
 337       $$ = $1 + 1;
 338       $$[strlen ($$) - 1] = '\0';
 339     };
 340
 341
 342 epilogue.opt:
 343   /* Nothing.  */
 344     {
 345       $$ = xstrdup ("");
 346     }
 347 | "%%" EPILOGUE
 348     {
 349       $$ = $2;
 350     }
 351 ;
 352
 353 semi_colon_opt:
 354   /* Nothing.  */
 355 | ";"
 356 ;
 357 %%
 358 /*------------------------------------------------------------------.
 359 | When debugging the parser, display tokens' locations and values.  |
 360 `------------------------------------------------------------------*/
 361
 362 static void
 363 yyprint (FILE *file,
 364          const location_t *loc, int type, const yystype *value)
 365 {
 366   fputs (" (", file);
 367   LOCATION_PRINT (file, *loc);
 368   fputs (")", file);
 369   switch (type)
 370     {
 371     case CHARACTER:
 372       fprintf (file, " = '%s'", value->string);
 373       break;
 374
 375     case ID:
 376       fprintf (file, " = %s", value->symbol->tag);
 377       break;
 378
 379     case INT:
 380       fprintf (file, " = %d", value->integer);
 381       break;
 382
 383     case STRING:
 384       fprintf (file, " = \"%s\"", value->string);
 385       break;
 386
 387     case TYPE:
 388       fprintf (file, " = <%s>", value->string);
 389       break;
 390
 391     case BRACED_CODE:
 392     case PROLOGUE:
 393     case EPILOGUE:
 394       fprintf (file, " = {{ %s }}", value->string);
 395       break;
 396     }
 397 }
 398
 399 void
 400 gram_error (gram_control_t *control ATTRIBUTE_UNUSED,
 401             location_t *yylloc, const char *msg)
 402 {
 403   LOCATION_PRINT (stderr, *yylloc);
 404   fprintf (stderr, ": %s\n", msg);
 405 }