src/parse-gram.y

   1 /* Bison Grammar Parser                             -*- C -*-
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4    This file is part of Bison, the GNU Compiler Compiler.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program; if not, write to the Free Software
  18    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307  USA
  20 */
  21
  22
  23 %debug
  24 %defines
  25 %locations
  26 %pure-parser
  27 // %error-verbose
  28 %defines
  29 %name-prefix="gram_"
  30
  31 %{
  32 #include "system.h"
  33 #include "complain.h"
  34 #include "muscle_tab.h"
  35 #include "files.h"
  36 #include "getargs.h"
  37 #include "output.h"
  38 #include "symlist.h"
  39 #include "gram.h"
  40 #include "reader.h"
  41 #include "conflicts.h"
  42
  43 /* Produce verbose parse errors.  */
  44 #define YYERROR_VERBOSE 1
  45 #define YYLLOC_DEFAULT(Current, Rhs, N)                 \
  46 do {                                                    \
  47   if (N)                                                \
  48   {                                                     \
  49     Current.first_column  = Rhs[1].first_column;        \
  50     Current.first_line    = Rhs[1].first_line;          \
  51     Current.last_column   = Rhs[N].last_column;         \
  52     Current.last_line     = Rhs[N].last_line;           \
  53   }                                                     \
  54   else                                                  \
  55   {                                                     \
  56     Current = Rhs[0];                                   \
  57   }                                                     \
  58 } while (0)
  59
  60 /* Pass the control structure to YYPARSE and YYLEX. */
  61 #define YYPARSE_PARAM gram_control
  62 #define YYLEX_PARAM gram_control
  63 /* YYPARSE receives GRAM_CONTROL as a void *.  Provide a
  64    correctly typed access to it.  */
  65 #define yycontrol ((gram_control_t *) gram_control)
  66
  67 /* Request detailed parse error messages, and pass them to GRAM_ERROR.
  68    FIXME: depends on the undocumented availability of YYLLOC.t */
  69 #undef  yyerror
  70 #define yyerror(Msg) \
  71         gram_error (&yylloc, Msg)
  72
  73 #define YYPRINT(File, Type, Value) \
  74         yyprint (File, Type, &Value)
  75 static void yyprint (FILE *file, int type, const yystype *value);
  76
  77 symbol_class current_class = unknown_sym;
  78 char *current_type = 0;
  79 symbol_t *current_lhs;
  80 location_t current_lhs_location;
  81 assoc_t current_assoc;
  82 int current_prec = 0;
  83 braced_code_t current_braced_code = action_braced_code;
  84 %}
  85
  86
  87 /* Only NUMBERS have a value.  */
  88 %union
  89 {
  90   symbol_t *symbol;
  91   symbol_list_t *list;
  92   int integer;
  93   char *string;
  94   assoc_t assoc;
  95 };
  96
  97 /* Define the tokens together with their human representation.  */
  98 %token GRAM_EOF 0 "end of file"
  99 %token STRING     "string"
 100 %token CHARACTER  "character"
 101 %token INT        "integer"
 102
 103 %token PERCENT_TOKEN       "%token"
 104 %token PERCENT_NTERM       "%nterm"
 105
 106 %token PERCENT_TYPE        "%type"
 107 %token PERCENT_DESTRUCTOR  "%destructor"
 108 %token PERCENT_PRINTER     "%printer"
 109
 110 %token PERCENT_UNION       "%union"
 111
 112 %token PERCENT_LEFT        "%left"
 113 %token PERCENT_RIGHT       "%right"
 114 %token PERCENT_NONASSOC    "%nonassoc"
 115
 116 %token PERCENT_EXPECT        "%expect"
 117 %token PERCENT_START         "%start"
 118 %token PERCENT_PREC          "%prec"
 119 %token PERCENT_DPREC         "%dprec"
 120 %token PERCENT_MERGE         "%merge"
 121 %token PERCENT_VERBOSE       "%verbose"
 122 %token PERCENT_ERROR_VERBOSE "%error-verbose"
 123
 124 %token PERCENT_OUTPUT      "%output"
 125 %token PERCENT_FILE_PREFIX "%file-prefix"
 126 %token PERCENT_NAME_PREFIX "%name-prefix"
 127
 128 %token PERCENT_DEFINE      "%define"
 129 %token PERCENT_PURE_PARSER "%pure-parser"
 130 %token PERCENT_GLR_PARSER  "%glr-parser"
 131
 132 %token PERCENT_DEFINES "%defines"
 133
 134 %token PERCENT_YACC "%yacc"
 135
 136 %token PERCENT_DEBUG       "%debug"
 137 %token PERCENT_LOCATIONS   "%locations"
 138 %token PERCENT_NO_LINES    "%no-lines"
 139 %token PERCENT_SKELETON    "%skeleton"
 140 %token PERCENT_TOKEN_TABLE "%token-table"
 141
 142 %token TYPE            "type"
 143 %token EQUAL           "="
 144 %token SEMICOLON       ";"
 145 %token COLON           ":"
 146 %token PIPE            "|"
 147 %token ID              "identifier"
 148 %token PERCENT_PERCENT "%%"
 149 %token PROLOGUE        "%{...%}"
 150 %token EPILOGUE        "epilogue"
 151 %token BRACED_CODE     "{...}"
 152
 153
 154 %type <string> CHARACTER TYPE STRING string_content
 155                BRACED_CODE PROLOGUE EPILOGUE epilogue.opt action
 156 %type <integer> INT
 157 %type <symbol> ID symbol string_as_id
 158 %type <assoc> precedence_declarator
 159 %type <list>  symbols.1
 160 %%
 161
 162 input:
 163   declarations "%%" grammar epilogue.opt
 164     {
 165       yycontrol->errcode = 0;
 166       epilogue_set ($4, @4);
 167     }
 168 ;
 169
 170
 171         /*------------------------------------.
 172         | Declarations: before the first %%.  |
 173         `------------------------------------*/
 174
 175 declarations:
 176   /* Nothing */
 177 | declarations declaration semi_colon.opt
 178 ;
 179
 180 declaration:
 181   grammar_declaration
 182 | PROLOGUE                                 { prologue_augment ($1, @1); }
 183 | "%debug"                                 { debug_flag = 1; }
 184 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 185 | "%defines"                               { defines_flag = 1; }
 186 | "%error-verbose"                         { error_verbose = 1; }
 187 | "%expect" INT                            { expected_conflicts = $2; }
 188 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 189 | "%locations"                             { locations_flag = 1; }
 190 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 191 | "%no-lines"                              { no_lines_flag = 1; }
 192 | "%output" "=" string_content             { spec_outfile = $3; }
 193 | "%pure-parser"                           { pure_parser = 1; }
 194 | "%glr-parser"                            { glr_parser = 1; }
 195 | "%skeleton" string_content               { skeleton = $2; }
 196 | "%token-table"                           { token_table_flag = 1; }
 197 | "%verbose"                               { report_flag = 1; }
 198 | "%yacc"                                  { yacc_flag = 1; }
 199 ;
 200
 201 grammar_declaration:
 202   precedence_declaration
 203 | symbol_declaration
 204 | "%start" symbol
 205     {
 206       grammar_start_symbol_set ($2, @2);
 207     }
 208 | "%union" BRACED_CODE
 209     {
 210       typed = 1;
 211       MUSCLE_INSERT_INT ("stype_line", @2.first_line);
 212       muscle_insert ("stype", $2);
 213     }
 214 | "%destructor"
 215     { current_braced_code = destructor_braced_code; }
 216   BRACED_CODE symbols.1
 217     {
 218       symbol_list_t *list;
 219       for (list = $4; list; list = list->next)
 220         symbol_destructor_set (list->sym, $3, @3);
 221       symbol_list_free ($4);
 222       current_braced_code = action_braced_code;
 223     }
 224 | "%printer"
 225     { current_braced_code = printer_braced_code; }
 226   BRACED_CODE symbols.1
 227     {
 228       symbol_list_t *list;
 229       for (list = $4; list; list = list->next)
 230         symbol_printer_set (list->sym, $3, list->location);
 231       symbol_list_free ($4);
 232       current_braced_code = action_braced_code;
 233     }
 234 ;
 235
 236 symbol_declaration:
 237   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 238     {
 239       current_class = unknown_sym;
 240       current_type = NULL;
 241     }
 242 | "%token" { current_class = token_sym; } symbol_defs.1
 243     {
 244       current_class = unknown_sym;
 245       current_type = NULL;
 246     }
 247 | "%type" TYPE symbols.1
 248     {
 249       symbol_list_t *list;
 250       for (list = $3; list; list = list->next)
 251         symbol_type_set (list->sym, $2, @2);
 252       symbol_list_free ($3);
 253     }
 254 ;
 255
 256 precedence_declaration:
 257   precedence_declarator type.opt symbols.1
 258     {
 259       symbol_list_t *list;
 260       ++current_prec;
 261       for (list = $3; list; list = list->next)
 262         {
 263           symbol_type_set (list->sym, current_type, @2);
 264           symbol_precedence_set (list->sym, current_prec, $1, @1);
 265         }
 266       symbol_list_free ($3);
 267       current_type = NULL;
 268     }
 269 ;
 270
 271 precedence_declarator:
 272   "%left"     { $$ = left_assoc; }
 273 | "%right"    { $$ = right_assoc; }
 274 | "%nonassoc" { $$ = non_assoc; }
 275 ;
 276
 277 type.opt:
 278   /* Nothing. */ { current_type = NULL;}
 279 | TYPE           { current_type = $1; }
 280 ;
 281
 282 /* One or more nonterminals to be %typed. */
 283
 284 symbols.1:
 285   symbol            { $$ = symbol_list_new ($1, @1); }
 286 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 287 ;
 288
 289 /* One token definition.  */
 290 symbol_def:
 291   TYPE
 292      {
 293        current_type = $1;
 294      }
 295 | ID
 296      {
 297        symbol_class_set ($1, current_class, @1);
 298        symbol_type_set ($1, current_type, @1);
 299      }
 300 | ID INT
 301     {
 302       symbol_class_set ($1, current_class, @1);
 303       symbol_type_set ($1, current_type, @1);
 304       symbol_user_token_number_set ($1, $2, @2);
 305     }
 306 | ID string_as_id
 307     {
 308       symbol_class_set ($1, current_class, @1);
 309       symbol_type_set ($1, current_type, @1);
 310       symbol_make_alias ($1, $2, @$);
 311     }
 312 | ID INT string_as_id
 313     {
 314       symbol_class_set ($1, current_class, @1);
 315       symbol_type_set ($1, current_type, @1);
 316       symbol_user_token_number_set ($1, $2, @2);
 317       symbol_make_alias ($1, $3, @$);
 318     }
 319 ;
 320
 321 /* One or more symbol definitions. */
 322 symbol_defs.1:
 323   symbol_def
 324     {;}
 325 | symbol_defs.1 symbol_def
 326     {;}
 327 ;
 328
 329
 330         /*------------------------------------------.
 331         | The grammar section: between the two %%.  |
 332         `------------------------------------------*/
 333
 334 grammar:
 335   rules_or_grammar_declaration
 336 | grammar rules_or_grammar_declaration
 337 ;
 338
 339 /* As a Bison extension, one can use the grammar declarations in the
 340    body of the grammar.  But to remain LALR(1), they must be ended
 341    with a semi-colon.  */
 342 rules_or_grammar_declaration:
 343   rules
 344 | grammar_declaration ";"
 345     {
 346       if (yacc_flag)
 347         complain_at (@$, _("POSIX forbids declarations in the grammar"));
 348     }
 349 | error ";"
 350     {
 351       yyerrok;
 352     }
 353 ;
 354
 355 rules:
 356   ID ":" { current_lhs = $1; current_lhs_location = @1; } rhses.1 ";"
 357     {;}
 358 ;
 359
 360 rhses.1:
 361   rhs                { grammar_rule_end (@1); }
 362 | rhses.1 "|" rhs    { grammar_rule_end (@3); }
 363 ;
 364
 365 rhs:
 366   /* Nothing.  */
 367     { grammar_rule_begin (current_lhs, current_lhs_location); }
 368 | rhs symbol
 369     { grammar_current_rule_symbol_append ($2, @2); }
 370 | rhs action
 371     { grammar_current_rule_action_append ($2, @2); }
 372 | rhs "%prec" symbol
 373     { grammar_current_rule_prec_set ($3, @3); }
 374 | rhs "%dprec" INT
 375     { grammar_current_rule_dprec_set ($3, @3); }
 376 | rhs "%merge" TYPE
 377     { grammar_current_rule_merge_set ($3, @3); }
 378 ;
 379
 380 symbol:
 381   ID              { $$ = $1; }
 382 | string_as_id    { $$ = $1; }
 383 | CHARACTER       { $$ = symbol_get ($1, @1); }
 384 ;
 385
 386 action:
 387   BRACED_CODE
 388    { $$ = $1; }
 389 ;
 390
 391 /* A string used as an ID: we have to keep the quotes. */
 392 string_as_id:
 393   STRING
 394     {
 395       $$ = symbol_get ($1, @1);
 396       symbol_class_set ($$, token_sym, @1);
 397     }
 398 ;
 399
 400 /* A string used for its contents.  Strip the quotes. */
 401 string_content:
 402   STRING
 403     {
 404       $$ = $1 + 1;
 405       $$[strlen ($$) - 1] = '\0';
 406     };
 407
 408
 409 epilogue.opt:
 410   /* Nothing.  */
 411     {
 412       $$ = xstrdup ("");
 413     }
 414 | "%%" EPILOGUE
 415     {
 416       $$ = $2;
 417     }
 418 ;
 419
 420 semi_colon.opt:
 421   /* Nothing.  */
 422 | ";"
 423 ;
 424 %%
 425 /*------------------------------------------------------------------.
 426 | When debugging the parser, display tokens' locations and values.  |
 427 `------------------------------------------------------------------*/
 428
 429 static void
 430 yyprint (FILE *file,
 431          int type, const yystype *value)
 432 {
 433   fputc (' ', file);
 434   switch (type)
 435     {
 436     case CHARACTER:
 437       fprintf (file, " = '%s'", value->string);
 438       break;
 439
 440     case ID:
 441       fprintf (file, " = %s", value->symbol->tag);
 442       break;
 443
 444     case INT:
 445       fprintf (file, " = %d", value->integer);
 446       break;
 447
 448     case STRING:
 449       fprintf (file, " = \"%s\"", value->string);
 450       break;
 451
 452     case TYPE:
 453       fprintf (file, " = <%s>", value->string);
 454       break;
 455
 456     case BRACED_CODE:
 457     case PROLOGUE:
 458     case EPILOGUE:
 459       fprintf (file, " = {{ %s }}", value->string);
 460       break;
 461     }
 462 }
 463
 464 void
 465 gram_error (location_t *yylloc, const char *msg)
 466 {
 467   complain_at (*yylloc, "%s", msg);
 468 }