m4/cxx.m4

   1 # -*- Autoconf -*-
   2 # Sanity-test a C++ compiler.
   3 #
   4 # Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301  USA
  20
  21 # Written by Paul Eggert.
  22
  23 AC_DEFUN([BISON_TEST_FOR_WORKING_CXX_COMPILER],
  24 [
  25  AC_CACHE_CHECK([whether $CXX builds executables that work],
  26    bison_cv_cxx_works,
  27    [AC_LANG_PUSH([C++])
  28     AC_RUN_IFELSE(
  29       [AC_LANG_PROGRAM(
  30          [#include <cstdlib>
  31           #include <iostream>
  32           #include <map>
  33           #include <string>
  34           using namespace std;],
  35          [std::cerr << "";
  36           cout << "";
  37           typedef std::pair<unsigned int, int> uipair;
  38           std::map<unsigned int, int> m;
  39           std::map<unsigned int, int>::iterator i;
  40           m.insert (uipair (4, -4));
  41           for (i = m.begin (); i != m.end (); ++i)
  42             if (i->first != 4)
  43               return 1;])],
  44       [bison_cv_cxx_works=yes],
  45       [bison_cv_cxx_works=no],
  46       [bison_cv_cxx_works=cross])
  47     AC_LANG_POP([C++])])
  48
  49  case $bison_cv_cxx_works in
  50  yes)
  51     BISON_CXX_WORKS=':';;
  52  no | cross)
  53     BISON_CXX_WORKS='exit 77';;
  54  esac
  55
  56  AC_SUBST([BISON_CXX_WORKS])
  57  AM_CONDITIONAL(BISON_CXX_WORKS, test $bison_cv_cxx_works = yes)
  58 ])