tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2013 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.  Remove new-lines
  35 # that completely break AT_SETUP.
  36 m4_define([AT_SETUP_STRIP],
  37 [m4_bpatsubsts([$1],
  38       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  39         [\2],
  40       [%define "?\([-A-Za-z0-9_.]+\)"? \("[^\"]+"\|[-A-Za-z0-9_.]+\)],
  41         [\1=\2],
  42       [%define "?\([-A-Za-z0-9_.]+\)"?],
  43         [\1],
  44       [ *
  45 + *],    [ ])dnl
  46 ])
  47
  48
  49 ## ------------- ##
  50 ## Basic tests.  ##
  51 ## ------------- ##
  52
  53 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  54 # ------------------------------------------
  55 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  56 # taken in "slurp" mode, i.e., one can match end-of-lines.
  57 m4_define([AT_MATCHES_CHECK],
  58 [AT_CHECK([$PERL -0777 -ne '
  59 my $count = 0;
  60 s{$2}{ ++$count; "" }gem;
  61 printf "$count\n";' $1], [0], [$3
  62 ])])
  63
  64
  65 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  66 # ------------------------------------------------
  67 # Don't interfere with caller's files.
  68 m4_divert_text([PREPARE_TESTS],
  69 [at_save_special_files ()
  70 {
  71   for at_save_file in stderr experr expout
  72   do
  73     test ! -f at-bison-check-$at_save_file.bak ||
  74       as_fn_error 1 "fatal error: back-up on top of a back-up"
  75     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  76   done
  77 }
  78
  79 at_restore_special_files ()
  80 {
  81   for at_save_file in stderr experr expout
  82   do
  83     test ! -f at-bison-check-$at_save_file.bak ||
  84       mv at-bison-check-$at_save_file.bak $at_save_file
  85   done
  86 }
  87 ])
  88
  89 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  90 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  91
  92
  93
  94 ## ------------------------------- ##
  95 ## Macros decoding Bison options.  ##
  96 ## ------------------------------- ##
  97
  98 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  99 # ----------------------------------------------------------------
 100 # Pushdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 101 m4_define([AT_LOC_PUSHDEF],
 102 [m4_pushdef([AT_FIRST_LINE],  [$1])
 103 m4_pushdef([AT_FIRST_COLUMN], [$2])
 104 m4_pushdef([AT_LAST_LINE],    [$3])
 105 m4_pushdef([AT_LAST_COLUMN],  [$4])
 106 m4_pushdef([AT_LOC_FIRST_LINE],   [AT_LOC.AT_FIRST_LINE])
 107 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.AT_FIRST_COLUMN])
 108 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.AT_LAST_LINE])
 109 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.AT_LAST_COLUMN])])
 110
 111 # AT_LOC_POPDEF
 112 # -------------
 113 # Popdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 114 m4_define([AT_LOC_POPDEF],
 115 [m4_popdef([AT_LOC_FIRST_LINE])
 116 m4_popdef([AT_LOC_FIRST_COLUMN])
 117 m4_popdef([AT_LOC_LAST_LINE])
 118 m4_popdef([AT_LOC_LAST_COLUMN])
 119 m4_popdef([AT_FIRST_LINE])
 120 m4_popdef([AT_FIRST_COLUMN])
 121 m4_popdef([AT_LAST_LINE])
 122 m4_popdef([AT_LAST_COLUMN])
 123 ])
 124
 125
 126
 127 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 128 # -----------------------------------------
 129 m4_define([AT_BISON_OPTION_PUSHDEFS],
 130 [m4_divert_text([KILL],
 131                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 132
 133
 134 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 135 # --------------------------------------------------
 136 # This macro works around the impossibility to define macros
 137 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 138 # This sucks hard, GNU M4 should really provide M5-like $$1.
 139 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 140 [m4_if([$1$2], $[1]$[2], [],
 141        [m4_fatal([$0: Invalid arguments: $@])])dnl
 142 m4_pushdef([AT_DEFINES_IF],
 143 [m4_bmatch([$3], [%defines], [$1], [$2])])
 144 m4_pushdef([AT_DEBUG_IF],
 145 [m4_bmatch([$3], [%debug\|%define parse.trace], [$1], [$2])])
 146 m4_pushdef([AT_SKEL_CC_IF],
 147 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 148 m4_pushdef([AT_SKEL_JAVA_IF],
 149 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 150 # The target language: "c", "c++", or "java".
 151 m4_pushdef([AT_LANG],
 152 [AT_SKEL_JAVA_IF([java],
 153                  [AT_SKEL_CC_IF([c++],
 154                                 [c])])])
 155 m4_pushdef([AT_GLR_IF],
 156 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 157 m4_pushdef([AT_LALR1_CC_IF],
 158 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 159 m4_pushdef([AT_GLR_CC_IF],
 160 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 161 # Using yacc.c?
 162 m4_pushdef([AT_YACC_IF],
 163 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 164 m4_pushdef([AT_LEXPARAM_IF],
 165 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 166 m4_pushdef([AT_LOCATION_IF],
 167 [m4_bmatch([$3], [%locations], [$1], [$2])])
 168 m4_pushdef([AT_LOCATION_TYPE_IF],
 169 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 170 m4_pushdef([AT_PARAM_IF],
 171 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 172 # Comma-terminated list of formals parse-parameters.
 173 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 174 # FIXME: Support grouped parse-param.
 175 m4_pushdef([AT_PARSE_PARAMS])
 176 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 177              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 178
 179 m4_pushdef([AT_PURE_IF],
 180 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 181            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 182            [$2])])
 183 # AT_NAME_PREFIX: also consider api.namespace.
 184 m4_pushdef([AT_NAME_PREFIX],
 185 [m4_bmatch([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) ".*"],
 186            [m4_bregexp([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) "\([^""]*\)"], [\3])],
 187            [yy])])
 188 m4_pushdef([AT_TOKEN_CTOR_IF],
 189 [m4_bmatch([$3], [%define api\.token\.constructor], [$1], [$2])])
 190 m4_pushdef([AT_TOKEN_PREFIX],
 191 [m4_bmatch([$3], [%define api\.token\.prefix ".*"],
 192            [m4_bregexp([$3], [%define api\.token\.prefix "\(.*\)"], [\1])])])
 193 m4_pushdef([AT_VARIANT_IF],
 194 [m4_bmatch([$3], [%define api\.value\.type "?variant"?], [$1], [$2])])
 195 m4_pushdef([AT_API_prefix],
 196 [m4_bmatch([$3], [%define api\.prefix ".*"],
 197            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 198            [yy])])
 199 m4_pushdef([AT_API_PREFIX],
 200 [m4_toupper(AT_API_prefix)])
 201 # yyerror receives the location if %location, and if the parser is pure. For
 202 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 203 # unless an additional "%parse-param" is present, or if the purity is defined
 204 # as "full".
 205 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 206 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 207                                        m4_quote(m4_join([\|],
 208                                                         [%define api\.pure "?full"?],
 209                                                         [%glr-parser],
 210                                                         [%parse-param],
 211                                                         [%skeleton "?glr.c"?])),
 212                                        [$1], [$2])],
 213                             [$2])],
 214                     [$2])])
 215
 216 # yyerror always sees the locations (when activated) if the parser is impure.
 217 # When the parser is pure, yyerror sees the location if it is received as an
 218 # argument.
 219 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 220 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 221                                         [$1])],
 222                             [$1])],
 223                 [$2])])
 224
 225 # The interface is pure: either because %define api.pure, or because we
 226 # are using the C++ parsers.
 227 m4_pushdef([AT_PURE_LEX_IF],
 228 [AT_PURE_IF([$1],
 229             [AT_SKEL_CC_IF([$1], [$2])])])
 230
 231 m4_pushdef([AT_YYSTYPE],
 232 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 233                [AT_API_PREFIX[STYPE]])])
 234 m4_pushdef([AT_YYLTYPE],
 235 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 236                [AT_API_PREFIX[LTYPE]])])
 237
 238
 239 AT_PURE_LEX_IF(
 240 [m4_pushdef([AT_LOC], [(*llocp)])
 241  m4_pushdef([AT_VAL], [(*lvalp)])
 242  m4_pushdef([AT_YYLEX_FORMALS],
 243             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 244  m4_pushdef([AT_YYLEX_ARGS],
 245             [lvalp[]AT_LOCATION_IF([, llocp])])
 246  m4_pushdef([AT_USE_LEX_ARGS],
 247             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 248  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 249             [AT_YYLEX_FORMALS, ])
 250  m4_pushdef([AT_YYLEX_PRE_ARGS],
 251             [AT_YYLEX_ARGS, ])
 252 ],
 253 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 254  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 255  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 256  m4_pushdef([AT_YYLEX_ARGS],        [])
 257  m4_pushdef([AT_USE_LEX_ARGS],    [])
 258  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 259  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 260 ])
 261
 262 # Handle the different types of location components.
 263
 264 AT_SKEL_CC_IF(
 265   [AT_LOCATION_TYPE_IF(
 266     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 267     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 268   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 269
 270
 271 AT_GLR_IF([AT_KEYWORDS([glr])])
 272 ])# _AT_BISON_OPTION_PUSHDEFS
 273
 274
 275 # AT_BISON_OPTION_POPDEFS
 276 # -----------------------
 277 m4_define([AT_BISON_OPTION_POPDEFS],
 278 [m4_divert_text([KILL],
 279 [m4_popdef([AT_YYLEX_PRE_ARGS])
 280 m4_popdef([AT_YYLEX_PRE_FORMALS])
 281 m4_popdef([AT_USE_LEX_ARGS])
 282 m4_popdef([AT_YYLEX_ARGS])
 283 m4_popdef([AT_YYLEX_FORMALS])
 284 m4_popdef([AT_YYLTYPE])
 285 m4_popdef([AT_YYSTYPE])
 286 m4_popdef([AT_VAL])
 287 m4_popdef([AT_LOC])
 288 m4_popdef([AT_PURE_LEX_IF])
 289 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 290 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 291 m4_popdef([AT_API_PREFIX])
 292 m4_popdef([AT_API_prefix])
 293 m4_popdef([AT_VARIANT_IF])
 294 m4_popdef([AT_TOKEN_PREFIX])
 295 m4_popdef([AT_TOKEN_CTOR_IF])
 296 m4_popdef([AT_NAME_PREFIX])
 297 m4_popdef([AT_LOCATION_TYPE_IF])
 298 m4_popdef([AT_LOCATION_IF])
 299 m4_popdef([AT_PARSE_PARAMS])
 300 m4_popdef([AT_PARAM_IF])
 301 m4_popdef([AT_LEXPARAM_IF])
 302 m4_popdef([AT_YACC_IF])
 303 m4_popdef([AT_GLR_IF])
 304 m4_popdef([AT_SKEL_CC_IF])
 305 m4_popdef([AT_LANG])
 306 m4_popdef([AT_SKEL_JAVA_IF])
 307 m4_popdef([AT_GLR_CC_IF])
 308 m4_popdef([AT_LALR1_CC_IF])
 309 m4_popdef([AT_DEFINES_IF])
 310 m4_popdef([AT_DEBUG_IF])
 311 AT_LOC_POPDEF])dnl
 312 ])# AT_BISON_OPTION_POPDEFS
 313
 314
 315
 316 ## -------------------------- ##
 317 ## Generating Grammar Files.  ##
 318 ## -------------------------- ##
 319
 320 # _AT_LANG_DISPATCH(LANG, MACRO, ARGS)
 321 # ------------------------------------
 322 # Call the specialization of MACRO for LANG with ARGS.  Complain if
 323 # unavailable.
 324 m4_define([_AT_LANG_DISPATCH],
 325 [m4_ifdef([$2($1)],
 326        [m4_indir([$2($1)], m4_shift2($@))],
 327        [m4_fatal([$2: unknown language: $1])])])
 328
 329
 330 # AT_LANG_DISPATCH(MACRO, ARGS)
 331 # -----------------------------
 332 # Call the specialization of MACRO for AT_LANG with ARGS.  Complain if
 333 # unavailable.
 334 m4_define([AT_LANG_DISPATCH],
 335 [_AT_LANG_DISPATCH(AT_LANG, $@)])
 336
 337
 338
 339 # AT_DATA_SOURCE_PROLOGUE
 340 # ------------------------
 341 # The prologue that should be included in any source code that is
 342 # meant to be compiled.
 343 m4_define([AT_DATA_SOURCE_PROLOGUE],
 344 [[#include <config.h>
 345 /* We don't need perfect functions for these tests. */
 346 #undef malloc
 347 #undef memcmp
 348 #undef realloc
 349 ]])
 350
 351 # AT_DATA_GRAMMAR_PROLOGUE
 352 # ------------------------
 353 # The prologue that should be included in any grammar which parser is
 354 # meant to be compiled.
 355 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 356 [[%code top {
 357 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 358 [}
 359 ]])
 360
 361 # AT_DATA_SOURCE(NAME, CONTENT)
 362 # -----------------------------
 363 # Generate the file NAME, which CONTENT is preceded by
 364 # AT_DATA_SOURCE_PROLOGUE.
 365 m4_define([AT_DATA_SOURCE],
 366 [AT_DATA([$1],
 367 [AT_DATA_SOURCE_PROLOGUE
 368 $2])
 369 ])
 370
 371 # AT_DATA_GRAMMAR(NAME, CONTENT)
 372 # ------------------------------
 373 # Generate the file NAME, which CONTENT is preceded by
 374 # AT_DATA_GRAMMAR_PROLOGUE.
 375 m4_define([AT_DATA_GRAMMAR],
 376 [AT_DATA([$1],
 377 [AT_DATA_GRAMMAR_PROLOGUE
 378 $2])
 379 ])
 380
 381 # AT_YYLEX_PROTOTYPE
 382 # AT_YYLEX_DECLARE_EXTERN
 383 # AT_YYLEX_DECLARE
 384 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 385 # ----------------------------------
 386 # INPUT can be empty, or in double quotes, or a list (in braces).
 387 # ACTION may compute yylval for instance, using "res" as token type,
 388 # and "toknum" as the number of calls to yylex (starting at 0).
 389 m4_define([AT_YYLEX_PROTOTYPE],
 390 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 391 ])
 392
 393 m4_define([AT_YYLEX_DECLARE_EXTERN],
 394 [AT_YYLEX_PROTOTYPE;dnl
 395 ])
 396
 397 m4_define([AT_YYLEX_DECLARE],
 398 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 399 ])
 400
 401 m4_define([AT_YYLEX_DEFINE],
 402 [[#include <assert.h>
 403 static
 404 ]AT_YYLEX_PROTOTYPE[
 405 {
 406   ]m4_bmatch([$1], [^\(".*"\)?$],
 407              [[static char const input[] = ]m4_default([$1], [""])],
 408              [[static int const input[] = ]$1])[;
 409   static size_t toknum = 0;
 410   int res;
 411   ]AT_USE_LEX_ARGS[;
 412   assert (toknum < sizeof input / sizeof input[0]);
 413   res = input[toknum++];
 414   ]$2[;]AT_LOCATION_IF([[
 415   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 416   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 417   return res;
 418 }]dnl
 419 ])
 420
 421 # AT_YYERROR_FORMALS
 422 # AT_YYERROR_PROTOTYPE
 423 # AT_YYERROR_DECLARE_EXTERN
 424 # AT_YYERROR_DECLARE
 425 # AT_YYERROR_DEFINE
 426 # -------------------------
 427 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 428 m4_define([AT_YYERROR_FORMALS],  [AT_LANG_DISPATCH([$0], $@)])
 429 m4_define([AT_YYERROR_PROTOTYPE],[AT_LANG_DISPATCH([$0], $@)])
 430 m4_define([AT_YYERROR_DECLARE_EXTERN], [AT_LANG_DISPATCH([$0], $@)])
 431 m4_define([AT_YYERROR_DECLARE],  [AT_LANG_DISPATCH([$0], $@)])
 432 m4_define([AT_YYERROR_DEFINE],   [AT_LANG_DISPATCH([$0], $@)])
 433
 434 # AT_MAIN_DEFINE
 435 # --------------
 436 m4_define([AT_MAIN_DEFINE],   [AT_LANG_DISPATCH([$0], $@)])
 437
 438
 439
 440 ## --- ##
 441 ## C.  ##
 442 ## --- ##
 443
 444 m4_define([AT_YYERROR_FORMALS(c)],
 445 [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS [const char *msg]])
 446
 447 m4_define([AT_YYERROR_PROTOTYPE(c)],
 448 [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])
 449
 450 m4_define([AT_YYERROR_DECLARE_EXTERN(c)],
 451 [AT_YYERROR_PROTOTYPE;])
 452
 453 m4_define([AT_YYERROR_DECLARE(c)],
 454 [#include <stdio.h>
 455 ]AT_LOCATION_IF([[
 456 #if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 457 static unsigned location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp);
 458 # ifndef LOCATION_PRINT
 459 #  define LOCATION_PRINT(File, Loc) location_print (File, &(Loc))
 460 # endif
 461 #endif
 462 ]])[
 463 static AT_YYERROR_DECLARE_EXTERN])
 464
 465
 466 m4_define([AT_YYERROR_DEFINE(c)],
 467 [[
 468 ]AT_LOCATION_IF([[
 469 # if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 470 /* Print *YYLOCP on YYO. */
 471 __attribute__((__unused__))
 472 static unsigned
 473 location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp)
 474 {
 475   unsigned res = 0;
 476   int end_col = 0 != yylocp->last_column ? yylocp->last_column - 1 : 0;
 477   if (0 <= yylocp->first_line)
 478     {
 479       res += fprintf (yyo, "%d", yylocp->first_line);
 480       if (0 <= yylocp->first_column)
 481         res += fprintf (yyo, ".%d", yylocp->first_column);
 482     }
 483   if (0 <= yylocp->last_line)
 484     {
 485       if (yylocp->first_line < yylocp->last_line)
 486         {
 487           res += fprintf (yyo, "-%d", yylocp->last_line);
 488           if (0 <= end_col)
 489             res += fprintf (yyo, ".%d", end_col);
 490         }
 491       else if (0 <= end_col && yylocp->first_column < end_col)
 492         res += fprintf (yyo, "-%d", end_col);
 493     }
 494   return res;
 495 }
 496 #endif
 497 ]])[
 498 /* A C error reporting function.  */
 499 static
 500 ]AT_YYERROR_PROTOTYPE[
 501 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 502               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 503   YYUSE(\1);])dnl
 504 AT_YYERROR_SEES_LOC_IF([[
 505   LOCATION_PRINT (stderr, ]AT_LOC[);
 506   fprintf (stderr, ": ");]])[
 507   fprintf (stderr, "%s\n", msg);
 508 }]])
 509
 510
 511 m4_define([AT_MAIN_DEFINE(c)],
 512 [[#include <stdlib.h> /* getenv. */
 513 #include <string.h> /* strcmp. */
 514 int
 515 main (int argc, char const* argv[])
 516 {]AT_DEBUG_IF([[
 517   if (getenv("YYDEBUG")
 518       || (argc == 2
 519           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 520     yydebug |= 1;]], [[
 521   (void) argc;
 522   (void) argv;]])[
 523   return ]AT_NAME_PREFIX[parse ();
 524 }]])
 525
 526
 527 ## ----- ##
 528 ## C++.  ##
 529 ## ----- ##
 530
 531 # No need to declare, it's part of the class interface.
 532 m4_define([AT_YYERROR_DECLARE(c++)],        [])
 533 m4_define([AT_YYERROR_DECLARE_EXTERN(c++)], [])
 534
 535 m4_define([AT_YYERROR_DEFINE(c++)],
 536 [[/* A C++ error reporting function.  */
 537 void
 538 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 539 {
 540   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 541 }]])
 542
 543
 544 m4_define([AT_MAIN_DEFINE(c++)],
 545 [[#include <cstdlib> // getenv.
 546 #include <cstring> // strcmp.
 547 int
 548 main (int argc, char const* argv[])
 549 {
 550   ]AT_NAME_PREFIX[::parser p;]AT_DEBUG_IF([[
 551   if (getenv("YYDEBUG")
 552       || (argc == 2
 553           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 554     p.set_debug_level (true);]], [[
 555   (void) argc;
 556   (void) argv;]])[
 557   return p.parse ();
 558 }]])
 559
 560
 561
 562 ## ------ ##
 563 ## Java.  ##
 564 ## ------ ##
 565
 566 m4_define([AT_YYERROR_DEFINE(java)],
 567 [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 568 {
 569     if (l == null)
 570       System.err.println (s);
 571     else
 572       System.err.println (l + ": " + s);
 573   }
 574 ]], [[
 575   public void yyerror (String s)
 576   {
 577     System.err.println (s);
 578   }
 579 ]])])
 580
 581 m4_define([AT_MAIN_DEFINE(java)],
 582 [[class input
 583 {
 584   public static void main (String args[]) throws IOException
 585   {
 586     YYParser p = new YYParser ();
 587     p.parse ();
 588   }
 589 }]])
 590
 591
 592
 593 ## --------------- ##
 594 ## Running Bison.  ##
 595 ## --------------- ##
 596
 597 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 598 # -------------------------------------------------
 599 # High-level routine that may call bison several times, under different
 600 # conditions.
 601 #
 602 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 603 # shell constructs (such as redirection or pipes) that would prevent
 604 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 605 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 606 #
 607 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 608 # Bison in the test suite.  For now it ensures that:
 609 #
 610 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 611 #      a non-zero exit status since Bison doesn't always try to free all memory
 612 #      in that case.
 613 #
 614 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 615 #      --graph and --report=all output for every working grammar.
 616 #
 617 #   3. If stderr contains a warning, -Werror and --warnings=error
 618 #      convert the warning to an error.
 619 #
 620 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 621 m4_define([AT_BISON_CHECK],
 622 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 623 AT_BISON_CHECK_NO_XML($@)])
 624
 625 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 626 # --------------------------------------------------
 627 # Low-level macro to run bison once.
 628 m4_define([AT_BISON_CHECK_],
 629 [AT_CHECK(AT_QUELL_VALGRIND[[ bison -fno-caret ]]$@)])
 630
 631
 632 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 633 # ----------------------------------------------------------
 634 # Check that warnings (if some are expected) are correctly
 635 # turned into errors with -Werror, etc.
 636 m4_define([AT_BISON_CHECK_WARNINGS],
 637 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 638       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 639
 640 m4_define([AT_BISON_CHECK_WARNINGS_],
 641 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 642 # added after the grammar file name, so skip these checks in that
 643 # case.
 644 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 645           ]AT_SAVE_SPECIAL_FILES[
 646
 647   # To avoid expanding it repeatedly, store specified stdout.
 648   ]AT_DATA([expout], [$3])[
 649
 650   # Run with -Werror.
 651   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 652
 653   # Build expected stderr up to and including the "warnings being
 654   # treated as errors" message.
 655   ]AT_DATA([[experr]], [$4])[
 656   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 657                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 658   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 659
 660   # Now check --warnings=error.
 661   cp stderr experr
 662   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 663
 664   # Now check -Wnone and --warnings=none by making sure that
 665   # -Werror doesn't change the exit status when -Wnone or
 666   # --warnings=none is specified.
 667   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 668   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 669
 670   ]AT_RESTORE_SPECIAL_FILES[
 671 fi]dnl
 672 ])
 673
 674 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 675 # --------------------------------------------------------
 676 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 677 # when a tortured grammar's XML is known to be too large for xsltproc to
 678 # handle.
 679 m4_define([AT_BISON_CHECK_NO_XML],
 680 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison -fno-caret ]]$@)
 681 AT_BISON_CHECK_WARNINGS($@)])
 682
 683 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 684 # -----------------------------------------------------
 685 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 686 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 687 # have a non-zero exit status.
 688 m4_define([AT_BISON_CHECK_XML],
 689 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 690   AT_SAVE_SPECIAL_FILES
 691   [mkdir xml-tests]
 692   m4_pushdef([AT_BISON_ARGS],
 693              [m4_bpatsubsts([[$1]],
 694                             [--report(-file)?=[^][ ]*], [],
 695                             [--graph=[^][ ]*], [],
 696                             [--xml=[^][ ]*], [])])dnl
 697   # Don't combine these Bison invocations since we want to be sure that
 698   # --report=all isn't required to get the full XML file.
 699   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 700              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 701            [[0]], [ignore], [ignore])
 702   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 703            [[0]], [ignore], [ignore])
 704   m4_popdef([AT_BISON_ARGS])dnl
 705   [cp xml-tests/test.output expout]
 706   AT_CHECK([[$XSLTPROC \
 707              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 708              xml-tests/test.xml]], [[0]], [expout])
 709   [sort xml-tests/test.dot > expout]
 710   AT_CHECK([[$XSLTPROC \
 711              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 712              xml-tests/test.xml | sort]], [[0]], [expout])
 713   [rm -rf xml-tests expout]
 714   AT_RESTORE_SPECIAL_FILES
 715 [fi]])
 716
 717 # AT_QUELL_VALGRIND
 718 # -----------------
 719 # Put this before a Bison invocation to keep Valgrind from complaining about
 720 # reachable memory.
 721 #
 722 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 723 # The triple quoting below will cause test cases to fail if you do.  If you do
 724 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 725 # will then fail to shell-escape its contents when attempting to print them.
 726 # The testsuite verbose output, at least, will be incorrect, but nothing may
 727 # fail to make sure you notice.
 728 m4_define([AT_QUELL_VALGRIND],
 729 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 730
 731
 732
 733 ## ------------------------ ##
 734 ## Compiling C, C++ Files.  ##
 735 ## ------------------------ ##
 736
 737
 738 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 739 # ----------------------------------------
 740 # Compile SOURCES into OUTPUT.
 741 #
 742 # If OUTPUT does not contain '.', assume that we are linking too,
 743 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 744 # with trailing .o removed, and ".c" appended.
 745 m4_define([AT_COMPILE],
 746 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 747 AT_CHECK(m4_join([ ],
 748                   [$CC $CFLAGS $CPPFLAGS],
 749                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 750                   [-o $1],
 751                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 752                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 753            0, [ignore], [ignore])])
 754
 755 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 756 # ---------------------------------------------
 757 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 758 # ignore the test.
 759 #
 760 # If OUTPUT does not contain '.', assume that we are linking too,
 761 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 762 # with trailing .o removed, and ".cc" appended.
 763 m4_define([AT_COMPILE_CXX],
 764 [AT_KEYWORDS(c++)
 765 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 766 AT_CHECK(m4_join([ ],
 767                  [$CXX $CXXFLAGS $CPPFLAGS],
 768                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 769                  [-o $1],
 770                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 771                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 772          0, [ignore], [ignore])])
 773
 774
 775 # AT_JAVA_COMPILE(SOURCES)
 776 # ------------------------
 777 # Compile SOURCES into Java class files.  Skip the test if java or javac
 778 # is not installed.
 779 m4_define([AT_JAVA_COMPILE],
 780 [AT_KEYWORDS(java)
 781 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 782 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 783 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 784          [[0]], [ignore], [ignore])])
 785
 786
 787 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 788 # --------------------------------------------
 789 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 790 #
 791 # If OUTPUT does not contain '.', assume that we are linking too,
 792 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 793 # with trailing .o removed, and ".c"/".cc" appended.
 794 m4_define([AT_LANG_COMPILE],  [AT_LANG_DISPATCH([$0], $@)])
 795 m4_define([AT_LANG_COMPILE(c)],    [AT_COMPILE([$1], [$2])])
 796 m4_define([AT_LANG_COMPILE(c++)],  [AT_COMPILE_CXX([$1], [$2])])
 797 m4_define([AT_LANG_COMPILE(java)], [AT_JAVA_COMPILE([$1.java], [$2])])
 798
 799
 800 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 801 # -------------------------------------------
 802 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 803 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 804 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 805 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 806 # AT_SKEL_JAVA_IF.
 807 m4_define([AT_FULL_COMPILE],  [AT_LANG_DISPATCH([$0], $@)])
 808 m4_define([AT_FULL_COMPILE(c)],
 809 [AT_BISON_CHECK([-o $1.c $1.y])
 810  AT_LANG_COMPILE([$1],
 811                  m4_join([ ],
 812                          [$1.c],
 813                          m4_ifval($2, [[$1-$2.c]]),
 814                          m4_ifval($3, [[$1-$3.c]])))])
 815
 816 m4_define([AT_FULL_COMPILE(c++)],
 817 [AT_BISON_CHECK([-o $1.cc $1.y])
 818  AT_LANG_COMPILE([$1],
 819                  m4_join([ ],
 820                          [$1.cc],
 821                          m4_ifval($2, [[$1-$2.cc]]),
 822                          m4_ifval($3, [[$1-$3.cc]])))])
 823
 824 m4_define([AT_FULL_COMPILE(java)],
 825 [AT_BISON_CHECK([-o $1.java $1.y])
 826  AT_LANG_COMPILE([$1],
 827                  m4_join([ ],
 828                          [$1.java],
 829                          m4_ifval($2, [[$1-$2.java]]),
 830                          m4_ifval($3, [[$1-$3.java]])))])
 831
 832
 833
 834
 835 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 836 # --------------------------------
 837 # Check that we can link together C and C++ objects.
 838 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 839 [AT_DATA([c-and-cxx.h],
 840 [[#ifdef __cplusplus
 841 extern "C"
 842 {
 843 #endif
 844   int fortytwo (void);
 845 #ifdef __cplusplus
 846 }
 847 #endif
 848 ]])
 849 AT_DATA([c-only.c],
 850 [[#include "c-and-cxx.h"
 851 int
 852 main (void)
 853 {
 854   return fortytwo () == 42 ? 0 : 1;
 855 }
 856 ]])
 857 AT_DATA([cxx-only.cc],
 858 [[#include "c-and-cxx.h"
 859 int fortytwo ()
 860 {
 861   return 42;
 862 }
 863 ]])
 864 AT_COMPILE([c-only.o], [c-only.c])
 865 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 866 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 867           exit 77], [ignore], [ignore])
 868 AT_PARSER_CHECK([./c-and-cxx])
 869 ])
 870
 871
 872 ## ---------------------------- ##
 873 ## Running a generated parser.  ##
 874 ## ---------------------------- ##
 875
 876
 877 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 878 # ------------------------------------------------------------
 879 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 880 #
 881 # Get rid of spurious messages when compiled with --coverage:
 882 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 883 m4_define([AT_PARSER_CHECK],
 884 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 885 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 886          [0], [], [$4])
 887 ])
 888
 889
 890 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 891 # -----------------------------------------------------------------
 892 m4_define([AT_JAVA_PARSER_CHECK],
 893 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 894
 895
 896 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 897 #                          DECLS, GRAMMAR, INPUT,
 898 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 899 #                          [OTHER-CHECKS],
 900 #                          [PARSER-EXIT-VALUE],
 901 #                          [PARSER-STDOUT], [PARSER-STDERR])
 902 # -------------------------------------------------------------
 903 # Using TITLE as the test group title, check the generated parser tables
 904 # and parser for a specified grammar file under a condition labeled by
 905 # COND-VALUE.
 906 #
 907 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 908 # recognized attribute is described below where it is relevant.
 909 #
 910 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 911 # the grammar file.  Insert basic yyerror, yylex, and main function
 912 # definitions as well.  Hardcode yylex to return the (possibly empty)
 913 # comma-delimited series of tokens in INPUT followed by token 0.
 914 #
 915 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 916 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 917 # On the bison command-line, specify `--report=all --defines'.  Check
 918 # that Bison exits with value 0, has no stdout, and has stderr
 919 # BISON-STDERR.
 920 #
 921 # If TEST-SPEC contains the attribute `last-state', check that the value
 922 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 923 # the grammar; in other words, check the number of states (minus one).
 924 # Otherwise, check that everything in the `.output' file starting with
 925 # the definition of state 0 is the same as the entire value of
 926 # TABLES-OR-LAST-STATE.
 927 #
 928 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 929 # `.output' file, which is named `input.output', and/or grammar file,
 930 # which is named `input.y'.
 931 #
 932 # Finally, compile the generated parser and then run it using
 933 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 934 # PARSER-STDERR as the 2nd-4th arguments.
 935 #
 936 # As a precondition, you must properly double-quote all arguments that
 937 # are to be interpreted as strings.
 938 #
 939 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 940 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 941 # first argument.  This is useful, for example, when wrapping multiple
 942 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 943 # condition, in another macro.
 944 #
 945 # For example:
 946 #
 947 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 948 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 949 #   # ---------------------------------------------------------------------
 950 #   m4_define([AT_TEST_SYNTAX_ERROR],
 951 #   [
 952 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 953 #                              [[last-state]],
 954 #                              [[%error-verbose ]$2], [$3], [$4],
 955 #                              [[]], [$5], [], [$6], [$7], [$8])
 956 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 957 #                              [[last-state]],
 958 #                              [$2], [$3], [$4],
 959 #                              [[]], [$5], [], [$6], [$7], [$8])
 960 #   ])
 961 #
 962 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 963 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 964 #                        [[3]],
 965 #                        [[1]], [[]],
 966 #                        [AT_COND_CASE([[no verbose]],
 967 #                                      [[syntax error
 968 #   ]],
 969 #                                      [[syntax error, unexpected 'b', expecting $end
 970 #   ]])])
 971 m4_define([AT_TEST_TABLES_AND_PARSE],
 972 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 973
 974 AT_SETUP([$1])
 975 AT_BISON_OPTION_PUSHDEFS([$4])
 976 AT_DATA_GRAMMAR([[input.y]],
 977 [[%code {
 978   ]AT_YYERROR_DECLARE[
 979   ]AT_YYLEX_DECLARE[
 980 }
 981
 982 ]$4[
 983
 984 %%
 985
 986 ]$5[
 987
 988 %%
 989 ]AT_YYERROR_DEFINE[
 990 static int
 991 yylex (void)
 992 {
 993   static int const input[] = {
 994     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 995   };
 996   static int const *inputp = input;
 997   return *inputp++;
 998 }
 999
1000 ]AT_MAIN_DEFINE[
1001 ]])
1002
1003 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
1004 # expanding macros, so it corrupts some special characters in the
1005 # macros.  To avoid this, expand now and pass it the result with proper
1006 # string quotation.  Assume args 7 through 12 expand to properly quoted
1007 # strings.
1008
1009 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
1010       [AT_BISON_CHECK],
1011       [AT_BISON_CHECK_NO_XML])([[-Wall --report=all --defines -o input.c input.y]],
1012                                [0], [], m4_dquote($7))
1013
1014 m4_if(m4_index(m4_quote($3), [last-state]), -1,
1015       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
1016                 m4_dquote($8))],
1017       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
1018                 m4_dquote($8)[[
1019 ]])])
1020
1021 $9
1022
1023 # Canonical LR generates very large tables, resulting in very long
1024 # files with #line directives that may overflow what the standards
1025 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
1026 # will issue an error.
1027 #
1028 # There is no "" around `wc` since some indent the result.
1029 m4_bmatch([$4], [%define lr.type canonical-lr],
1030 [if test 32767 -lt `wc -l < input.c`; then
1031   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic / /'`
1032   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic / /'`
1033 fi])
1034 AT_COMPILE([[input]])
1035
1036 AT_PARSER_CHECK([[./input]],
1037                 m4_ifval([$10], [m4_dquote($10)]),
1038                 m4_ifval([$11], [m4_dquote($11)]),
1039                 m4_ifval([$12], [m4_dquote($12)]))
1040
1041 AT_BISON_OPTION_POPDEFS
1042 AT_CLEANUP
1043
1044 m4_popdef([AT_COND_CASE])])
1045
1046
1047
1048
1049 ## ----------------------- ##
1050 ## Launch the test suite.  ##
1051 ## ----------------------- ##
1052
1053 AT_INIT
1054
1055 # AT_SETUP([TITLE])
1056 # -----------------
1057 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
1058 m4_copy_force([AT_SETUP], [B4_SETUP])
1059 m4_define([AT_SETUP],
1060 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
1061
1062 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
1063 # options are processed, so we don't know the value of CXX and
1064 # CXXFLAGS yet.
1065 #
1066 # Note that it also means that command line values for CXX and
1067 # CXXFLAGS will not be propagated to CC and CFLAGS.
1068 AT_ARG_OPTION([compile-c-with-cxx],
1069               [compile C parsers with the C++ compiler])
1070
1071 AT_COLOR_TESTS
1072
1073 AT_TESTED([bison])