src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4    This file is part of Bison, the GNU Compiler Compiler.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program; if not, write to the Free Software
  18    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307  USA
  20 */
  21
  22 %option debug nodefault noyywrap nounput never-interactive stack
  23 %option prefix="gram_" outfile="lex.yy.c"
  24
  25 %{
  26 #include "system.h"
  27 #include "complain.h"
  28 #include "quote.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "reader.h"
  32
  33 /* Each time we match a string, move the end cursor to its end. */
  34 #define YY_USER_INIT                            \
  35 do {                                            \
  36   LOCATION_RESET (*yylloc);                     \
  37    /* This is only to avoid GCC warnings. */    \
  38   if (yycontrol) {;};                           \
  39 } while (0)
  40
  41 #define YY_USER_ACTION  LOCATION_COLUMNS (*yylloc, yyleng)
  42 #define YY_LINES        LOCATION_LINES (*yylloc, yyleng); lineno += yyleng;
  43 #define YY_STEP         LOCATION_STEP (*yylloc)
  44
  45
  46 /* STRING_OBSTACK -- Used to store all the characters that we need to
  47    keep (to construct ID, STRINGS etc.).  Use the following macros to
  48    use it.
  49
  50    Use YY_OBS_GROW to append what has just been matched, and
  51    YY_OBS_FINISH to end the string (it puts the ending 0).
  52    YY_OBS_FINISH also stores this string in LAST_STRING, which can be
  53    used, and which is used by YY_OBS_FREE to free the last string.  */
  54
  55 static struct obstack string_obstack;
  56 char *last_string;
  57
  58 #define YY_OBS_GROW   \
  59   obstack_grow (&string_obstack, yytext, yyleng)
  60
  61 #define YY_OBS_FINISH                                   \
  62   do {                                                  \
  63     obstack_1grow (&string_obstack, '\0');              \
  64     last_string = obstack_finish (&string_obstack);     \
  65   } while (0)
  66
  67 #define YY_OBS_FREE                                             \
  68   do {                                                          \
  69     obstack_free (&string_obstack, last_string);                \
  70   } while (0)
  71
  72 void
  73 scanner_last_string_free (void)
  74 {
  75   YY_OBS_FREE;
  76 }
  77
  78
  79 static int braces_level = 0;
  80 static int percent_percent_count = 0;
  81
  82 static void handle_dollar PARAMS ((braced_code_t code_kind,
  83                                    char *cp, location_t location));
  84 static void handle_at PARAMS ((braced_code_t code_kind,
  85                                char *cp, location_t location));
  86
  87 %}
  88 %x SC_COMMENT
  89 %x SC_STRING SC_CHARACTER
  90 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
  91 %x SC_BRACED_CODE SC_PROLOGUE SC_EPILOGUE
  92
  93 id       [.a-zA-Z][.a-zA-Z_0-9]*
  94 int      [0-9]+
  95 eols     (\n|\r|\n\r|\r\n)+
  96 blanks   [ \t\f]+
  97
  98 %%
  99 %{
 100   /* At each yylex invocation, mark the current position as the
 101      start of the next token.  */
 102 #define TR_POS 0
 103 #if TR_POS
 104   fprintf (stderr, "FOO1: %p: ", yylloc);
 105   LOCATION_PRINT (stderr, *yylloc);
 106   fprintf (stderr, "\n");
 107 #endif
 108   YY_STEP;
 109 #if TR_POS
 110   fprintf (stderr, "BAR1: ");
 111   LOCATION_PRINT (stderr, *yylloc);
 112   fprintf (stderr, "\n");
 113 #endif
 114 %}
 115
 116
 117   /*----------------------------.
 118   | Scanning Bison directives.  |
 119   `----------------------------*/
 120 <INITIAL>
 121 {
 122   "%binary"               return PERCENT_NONASSOC;
 123   "%debug"                return PERCENT_DEBUG;
 124   "%define"               return PERCENT_DEFINE;
 125   "%defines"              return PERCENT_DEFINES;
 126   "%destructor"           return PERCENT_DESTRUCTOR;
 127   "%error"[-_]"verbose"   return PERCENT_ERROR_VERBOSE;
 128   "%expect"               return PERCENT_EXPECT;
 129   "%file-prefix"          return PERCENT_FILE_PREFIX;
 130   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 131   "%left"                 return PERCENT_LEFT;
 132   "%locations"            return PERCENT_LOCATIONS;
 133   "%name"[-_]"prefix"     return PERCENT_NAME_PREFIX;
 134   "%no"[-_]"lines"        return PERCENT_NO_LINES;
 135   "%nonassoc"             return PERCENT_NONASSOC;
 136   "%nterm"                return PERCENT_NTERM;
 137   "%output"               return PERCENT_OUTPUT;
 138   "%prec"                 return PERCENT_PREC;
 139   "%pure"[-_]"parser"     return PERCENT_PURE_PARSER;
 140   "%right"                return PERCENT_RIGHT;
 141   "%skeleton"             return PERCENT_SKELETON;
 142   "%start"                return PERCENT_START;
 143   "%term"                 return PERCENT_TOKEN;
 144   "%token"                return PERCENT_TOKEN;
 145   "%token"[-_]"table"     return PERCENT_TOKEN_TABLE;
 146   "%type"                 return PERCENT_TYPE;
 147   "%union"                return PERCENT_UNION;
 148   "%verbose"              return PERCENT_VERBOSE;
 149   "%yacc"                 return PERCENT_YACC;
 150
 151   "="                     return EQUAL;
 152   ":"                     return COLON;
 153   "|"                     return PIPE;
 154   ";"                     return SEMICOLON;
 155
 156   {eols}      YY_LINES; YY_STEP;
 157   {blanks}    YY_STEP;
 158   {id}        {
 159     yylval->symbol = getsym (yytext, *yylloc);
 160     return ID;
 161   }
 162
 163   {int}       yylval->integer = strtol (yytext, 0, 10); return INT;
 164
 165   /* Characters.  We don't check there is only one.  */
 166   \'          YY_OBS_GROW; yy_push_state (SC_ESCAPED_CHARACTER);
 167
 168   /* Strings. */
 169   \"          YY_OBS_GROW; yy_push_state (SC_ESCAPED_STRING);
 170
 171   /* Comments. */
 172   "/*"        yy_push_state (SC_COMMENT);
 173   "//".*      YY_STEP;
 174
 175   /* Prologue. */
 176   "%{"        yy_push_state (SC_PROLOGUE);
 177
 178   /* Code in between braces.  */
 179   "{"         YY_OBS_GROW; ++braces_level; yy_push_state (SC_BRACED_CODE);
 180
 181   /* A type. */
 182   "<"[^>]+">" {
 183     obstack_grow (&string_obstack, yytext + 1, yyleng - 2);
 184     YY_OBS_FINISH;
 185     yylval->string = last_string;
 186     return TYPE;
 187   }
 188
 189
 190   "%%"   {
 191     if (++percent_percent_count == 2)
 192       yy_push_state (SC_EPILOGUE);
 193     return PERCENT_PERCENT;
 194   }
 195
 196   .           {
 197     LOCATION_PRINT (stderr, *yylloc);
 198     fprintf (stderr, ": invalid character: `%c'\n", *yytext);
 199     YY_STEP;
 200   }
 201 }
 202
 203
 204   /*------------------------------------------------------------.
 205   | Whatever the start condition (but those which correspond to |
 206   | entity `swallowed' by Bison: SC_ESCAPED_STRING and          |
 207   | SC_ESCAPED_CHARACTER), no M4 character must escape as is.   |
 208   `------------------------------------------------------------*/
 209
 210 <SC_COMMENT,SC_STRING,SC_CHARACTER,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 211 {
 212   \[          if (YY_START != SC_COMMENT) obstack_sgrow (&string_obstack, "@<:@");
 213   \]          if (YY_START != SC_COMMENT) obstack_sgrow (&string_obstack, "@:>@");
 214 }
 215
 216
 217
 218   /*-----------------------------------------------------------.
 219   | Scanning a C comment. The initial `/ *' is already eaten.  |
 220   `-----------------------------------------------------------*/
 221
 222 <SC_COMMENT>
 223 {
 224   "*/" { /* End of the comment. */
 225     if (yy_top_state () == INITIAL)
 226       {
 227         YY_STEP;
 228       }
 229     else
 230       {
 231         YY_OBS_GROW;
 232       }
 233     yy_pop_state ();
 234   }
 235
 236   [^\[\]*\n\r]+         if (yy_top_state () != INITIAL) YY_OBS_GROW;
 237   {eols}        if (yy_top_state () != INITIAL) YY_OBS_GROW; YY_LINES;
 238   .             /* Stray `*'. */if (yy_top_state () != INITIAL) YY_OBS_GROW;
 239
 240   <<EOF>> {
 241     LOCATION_PRINT (stderr, *yylloc);
 242     fprintf (stderr, ": unexpected end of file in a comment\n");
 243     yy_pop_state ();
 244   }
 245 }
 246
 247
 248   /*----------------------------------------------------------------.
 249   | Scanning a C string, including its escapes.  The initial `"' is |
 250   | already eaten.                                                  |
 251   `----------------------------------------------------------------*/
 252
 253 <SC_ESCAPED_STRING>
 254 {
 255   \" {
 256     assert (yy_top_state () == INITIAL);
 257     YY_OBS_GROW;
 258     YY_OBS_FINISH;
 259     yylval->string = last_string;
 260     yy_pop_state ();
 261     return STRING;
 262   }
 263
 264   [^\"\n\r\\]+      YY_OBS_GROW;
 265
 266   {eols}    obstack_1grow (&string_obstack, '\n'); YY_LINES;
 267
 268   <<EOF>> {
 269     LOCATION_PRINT (stderr, *yylloc);
 270     fprintf (stderr, ": unexpected end of file in a string\n");
 271     assert (yy_top_state () == INITIAL);
 272     YY_OBS_FINISH;
 273     yylval->string = last_string;
 274     yy_pop_state ();
 275     return STRING;
 276   }
 277 }
 278
 279   /*---------------------------------------------------------------.
 280   | Scanning a C character, decoding its escapes.  The initial "'" |
 281   | is already eaten.                                              |
 282   `---------------------------------------------------------------*/
 283
 284 <SC_ESCAPED_CHARACTER>
 285 {
 286   \' {
 287     YY_OBS_GROW;
 288     assert (yy_top_state () == INITIAL);
 289     {
 290       YY_OBS_FINISH;
 291       yylval->symbol = getsym (last_string, *yylloc);
 292       symbol_class_set (yylval->symbol, token_sym);
 293       symbol_user_token_number_set (yylval->symbol, last_string[1]);
 294       YY_OBS_FREE;
 295       yy_pop_state ();
 296       return ID;
 297     }
 298   }
 299
 300   [^\'\n\r\\]      YY_OBS_GROW;
 301
 302   {eols}    obstack_1grow (&string_obstack, '\n'); YY_LINES;
 303
 304   <<EOF>> {
 305     LOCATION_PRINT (stderr, *yylloc);
 306     fprintf (stderr, ": unexpected end of file in a character\n");
 307     assert (yy_top_state () == INITIAL);
 308     YY_OBS_FINISH;
 309     yylval->string = last_string;
 310     yy_pop_state ();
 311     return CHARACTER;
 312   }
 313 }
 314
 315
 316   /*----------------------------.
 317   | Decode escaped characters.  |
 318   `----------------------------*/
 319
 320 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 321 {
 322   \\[0-7]{3}            {
 323     long c = strtol (yytext + 1, 0, 8);
 324     if (c > 255)
 325       {
 326         LOCATION_PRINT (stderr, *yylloc);
 327         fprintf (stderr, ": invalid escape: %s\n", yytext);
 328         YY_STEP;
 329       }
 330     else
 331       obstack_1grow (&string_obstack, c);
 332   }
 333
 334   \\x[0-9a-fA-F]{2}     {
 335     obstack_1grow (&string_obstack, strtol (yytext + 2, 0, 16));
 336   }
 337
 338   \\a   obstack_1grow (&string_obstack, '\a');
 339   \\b   obstack_1grow (&string_obstack, '\b');
 340   \\f   obstack_1grow (&string_obstack, '\f');
 341   \\n   obstack_1grow (&string_obstack, '\n');
 342   \\r   obstack_1grow (&string_obstack, '\r');
 343   \\t   obstack_1grow (&string_obstack, '\t');
 344   \\v   obstack_1grow (&string_obstack, '\v');
 345   \\[\\""]   obstack_1grow (&string_obstack, yytext[1]);
 346   \\.   {
 347     LOCATION_PRINT (stderr, *yylloc);
 348     fprintf (stderr, ": unrecognized escape: %s\n", yytext);
 349     YY_OBS_GROW;
 350   }
 351 }
 352
 353
 354   /*----------------------------------------------------------.
 355   | Scanning a C character without decoding its escapes.  The |
 356   | initial "'" is already eaten.                             |
 357   `----------------------------------------------------------*/
 358
 359 <SC_CHARACTER>
 360 {
 361   \' {
 362     YY_OBS_GROW;
 363     assert (yy_top_state () != INITIAL);
 364     yy_pop_state ();
 365   }
 366
 367   [^\[\]\'\n\r\\]      YY_OBS_GROW;
 368   \\.                  YY_OBS_GROW;
 369
 370   {eols}               YY_OBS_GROW; YY_LINES;
 371
 372   <<EOF>> {
 373     LOCATION_PRINT (stderr, *yylloc);
 374     fprintf (stderr, ": unexpected end of file in a character\n");
 375     assert (yy_top_state () != INITIAL);
 376     yy_pop_state ();
 377   }
 378 }
 379
 380
 381   /*----------------------------------------------------------------.
 382   | Scanning a C string, without decoding its escapes.  The initial |
 383   | `"' is already eaten.                                           |
 384   `----------------------------------------------------------------*/
 385
 386 <SC_STRING>
 387 {
 388   \" {
 389     assert (yy_top_state () != INITIAL);
 390     YY_OBS_GROW;
 391     yy_pop_state ();
 392   }
 393
 394   [^\[\]\"\n\r\\]+      YY_OBS_GROW;
 395   \\.                   YY_OBS_GROW;
 396
 397   {eols}                YY_OBS_GROW; YY_LINES;
 398
 399   <<EOF>> {
 400     LOCATION_PRINT (stderr, *yylloc);
 401     fprintf (stderr, ": unexpected end of file in a string\n");
 402     assert (yy_top_state () != INITIAL);
 403     yy_pop_state ();
 404   }
 405 }
 406
 407
 408   /*---------------------------------------------------.
 409   | Strings, comments etc. can be found in user code.  |
 410   `---------------------------------------------------*/
 411
 412 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 413 {
 414   /* Characters.  We don't check there is only one.  */
 415   \'          YY_OBS_GROW; yy_push_state (SC_CHARACTER);
 416
 417   /* Strings. */
 418   \"          YY_OBS_GROW; yy_push_state (SC_STRING);
 419
 420   /* Comments. */
 421   "/*"        YY_OBS_GROW; yy_push_state (SC_COMMENT);
 422   "//".*      YY_OBS_GROW;
 423 }
 424
 425
 426   /*---------------------------------------------------------------.
 427   | Scanning some code in braces (%union and actions). The initial |
 428   | "{" is already eaten.                                          |
 429   `---------------------------------------------------------------*/
 430
 431 <SC_BRACED_CODE>
 432 {
 433   "}" {
 434     YY_OBS_GROW;
 435     if (--braces_level == 0)
 436       {
 437         yy_pop_state ();
 438         YY_OBS_FINISH;
 439         yylval->string = last_string;
 440         return BRACED_CODE;
 441       }
 442   }
 443
 444   "{"           YY_OBS_GROW; braces_level++;
 445
 446   "$"("<"[^>]+">")?(-?[0-9]+|"$") { handle_dollar (current_braced_code,
 447                                                    yytext, *yylloc); }
 448   "@"(-?[0-9]+|"$")               { handle_at (current_braced_code,
 449                                                yytext, *yylloc); }
 450
 451   [^$@\[\]/\'\"\{\}\n\r]+ YY_OBS_GROW;
 452   {eols}        YY_OBS_GROW; YY_LINES;
 453
 454   /* A lose $, or /, or etc. */
 455   .             YY_OBS_GROW;
 456
 457   <<EOF>> {
 458     LOCATION_PRINT (stderr, *yylloc);
 459     fprintf (stderr, ": unexpected end of file in a braced code\n");
 460     yy_pop_state ();
 461     YY_OBS_FINISH;
 462     yylval->string = last_string;
 463     return BRACED_CODE;
 464   }
 465
 466 }
 467
 468
 469   /*--------------------------------------------------------------.
 470   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 471   `--------------------------------------------------------------*/
 472
 473 <SC_PROLOGUE>
 474 {
 475   "%}" {
 476     yy_pop_state ();
 477     YY_OBS_FINISH;
 478     yylval->string = last_string;
 479     return PROLOGUE;
 480   }
 481
 482   [^%\[\]/\'\"\n\r]+      YY_OBS_GROW;
 483   "%"+[^%\}\n\r]+ YY_OBS_GROW;
 484   {eols}          YY_OBS_GROW; YY_LINES;
 485
 486   <<EOF>> {
 487     LOCATION_PRINT (stderr, *yylloc);
 488     fprintf (stderr, ": unexpected end of file in a prologue\n");
 489     yy_pop_state ();
 490     YY_OBS_FINISH;
 491     yylval->string = last_string;
 492     return PROLOGUE;
 493   }
 494
 495 }
 496
 497
 498   /*---------------------------------------------------------------.
 499   | Scanning the epilogue (everything after the second "%%", which |
 500   | has already been eaten.                                        |
 501   `---------------------------------------------------------------*/
 502
 503 <SC_EPILOGUE>
 504 {
 505   ([^\[\]]|{eols})+  YY_OBS_GROW;
 506
 507   <<EOF>> {
 508     yy_pop_state ();
 509     YY_OBS_FINISH;
 510     yylval->string = last_string;
 511     return EPILOGUE;
 512   }
 513 }
 514
 515
 516 %%
 517
 518 /*------------------------------------------------------------------.
 519 | CP is pointing to a wannabee semantic value (i.e., a `$').        |
 520 |                                                                   |
 521 | Possible inputs: $[<TYPENAME>]($|integer)                         |
 522 |                                                                   |
 523 | Output to the STRING_OBSTACK a reference to this semantic value.  |
 524 `------------------------------------------------------------------*/
 525
 526 static inline void
 527 handle_action_dollar (char *cp, location_t location)
 528 {
 529   const char *type_name = NULL;
 530
 531   ++cp;
 532
 533   /* Get the type name if explicit. */
 534   if (*cp == '<')
 535     {
 536       type_name = ++cp;
 537       while (*cp != '>')
 538         ++cp;
 539       *cp = '\0';
 540       ++cp;
 541     }
 542
 543   if (*cp == '$')
 544     {
 545       if (!type_name)
 546         type_name = symbol_list_n_type_name_get (current_rule, location, 0);
 547       if (!type_name && typed)
 548         complain_at (location, _("$$ of `%s' has no declared type"),
 549                      current_rule->sym->tag);
 550       if (!type_name)
 551         type_name = "";
 552       obstack_fgrow1 (&string_obstack,
 553                       "]b4_lhs_value([%s])[", type_name);
 554     }
 555   else if (isdigit (*cp) || *cp == '-')
 556     {
 557       /* RULE_LENGTH is the number of values in the current rule so
 558          far, which says where to find `$0' with respect to the top of
 559          the stack.  It is not the same as the rule->length in the
 560          case of mid rule actions.  */
 561       int rule_length = symbol_list_length (current_rule->next);
 562       int n = strtol (cp, &cp, 10);
 563
 564       if (n > rule_length)
 565         complain_at (location, _("invalid value: %s%d"), "$", n);
 566       else
 567         {
 568           if (!type_name && n > 0)
 569             type_name = symbol_list_n_type_name_get (current_rule, location,
 570                                                      n);
 571           if (!type_name && typed)
 572             complain_at (location, _("$%d of `%s' has no declared type"),
 573                       n, current_rule->sym->tag);
 574           if (!type_name)
 575             type_name = "";
 576           obstack_fgrow3 (&string_obstack,
 577                           "]b4_rhs_value([%d], [%d], [%s])[",
 578                           rule_length, n, type_name);
 579         }
 580     }
 581   else
 582     {
 583       char buf[] = "$c";
 584       buf[1] = *cp;
 585       complain_at (location, _("%s is invalid"), quote (buf));
 586     }
 587 }
 588
 589
 590 /*---------------------------------------.
 591 | CP is pointing to $$ in a destructor.  |
 592 `---------------------------------------*/
 593
 594 static inline void
 595 handle_destructor_dollar (char *cp, location_t location)
 596 {
 597   ++cp;
 598   if (*cp == '$')
 599     {
 600       obstack_sgrow (&string_obstack, "]b4_dollar_dollar[");
 601     }
 602   else
 603     {
 604       char buf[] = "$c";
 605       buf[1] = *cp;
 606       complain_at (location, _("%s is invalid"), quote (buf));
 607     }
 608 }
 609
 610
 611 /*-----------------------------------------------------------------.
 612 | Dispatch onto handle_action_dollar, or handle_destructor_dollar, |
 613 | depending upon CODE_KIND.                                        |
 614 `-----------------------------------------------------------------*/
 615
 616 static void
 617 handle_dollar (braced_code_t braced_code_kind,
 618                char *text, location_t location)
 619 {
 620   switch (braced_code_kind)
 621     {
 622     case action_braced_code:
 623       handle_action_dollar (text, location);
 624       break;
 625
 626     case destructor_braced_code:
 627       handle_destructor_dollar (text, location);
 628       break;
 629     }
 630 }
 631
 632
 633 /*------------------------------------------------------.
 634 | TEXT is a location token (i.e., a `@...').  Output to |
 635 | STRING_OBSTACK a reference to this location.          |
 636 `------------------------------------------------------*/
 637
 638 static inline void
 639 handle_action_at (char *text, location_t location)
 640 {
 641   locations_flag = 1;
 642   ++text;
 643
 644   if (*text == '$')
 645     {
 646       obstack_sgrow (&string_obstack, "]b4_lhs_location[");
 647     }
 648   else if (isdigit (*text) || *text == '-')
 649     {
 650       /* RULE_LENGTH is the number of values in the current rule so
 651          far, which says where to find `$0' with respect to the top of
 652          the stack.  It is not the same as the rule->length in the
 653          case of mid rule actions.  */
 654       int rule_length = symbol_list_length (current_rule->next);
 655       int n = strtol (text, &text, 10);
 656
 657       if (n > rule_length)
 658         complain_at (location, _("invalid value: %s%d"), "@", n);
 659       else
 660         obstack_fgrow2 (&string_obstack, "]b4_rhs_location([%d], [%d])[",
 661                         rule_length, n);
 662     }
 663   else
 664     {
 665       char buf[] = "@c";
 666       buf[1] = *text;
 667       complain_at (location, _("%s is invalid"), quote (buf));
 668     }
 669 }
 670
 671
 672 /*--------------------------------------------.
 673 | TEXT is expexted tp be @$ in a destructor.  |
 674 `--------------------------------------------*/
 675
 676 static inline void
 677 handle_destructor_at (char *text, location_t location)
 678 {
 679   ++text;
 680   if (*text == '$')
 681     {
 682       obstack_sgrow (&string_obstack, "]b4_at_dollar[");
 683     }
 684   else
 685     {
 686       char buf[] = "$c";
 687       buf[1] = *text;
 688       complain_at (location, _("%s is invalid"), quote (buf));
 689     }
 690 }
 691
 692
 693 /*-------------------------------------------------------------------.
 694 | Dispatch onto handle_action_at, or handle_destructor_at, depending |
 695 | upon CODE_KIND.                                                    |
 696 `-------------------------------------------------------------------*/
 697
 698 static void
 699 handle_at (braced_code_t braced_code_kind,
 700            char *text, location_t location)
 701 {
 702   switch (braced_code_kind)
 703     {
 704     case action_braced_code:
 705       handle_action_at (text, location);
 706       break;
 707
 708     case destructor_braced_code:
 709       handle_destructor_at (text, location);
 710       break;
 711     }
 712 }
 713
 714
 715 /*-------------------------.
 716 | Initialize the scanner.  |
 717 `-------------------------*/
 718
 719 void
 720 scanner_initialize (void)
 721 {
 722   obstack_init (&string_obstack);
 723 }
 724
 725
 726 /*-----------------------------------------------.
 727 | Free all the memory allocated to the scanner.  |
 728 `-----------------------------------------------*/
 729
 730 void
 731 scanner_free (void)
 732 {
 733   obstack_free (&string_obstack, 0);
 734 }