tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------------------------- ##
  24 ## Macros decoding Bison options.  ##
  25 ## ------------------------------- ##
  26
  27
  28 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  29 # -----------------------------------------
  30 m4_define([AT_BISON_OPTION_PUSHDEFS],
  31 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  32
  33
  34 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  35 # --------------------------------------------------
  36 # This macro works around the impossibility to define macros
  37 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  38 # This sucks hard, GNU M4 should really provide M5 like $$1.
  39 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  40 [m4_if([$1$2], $[1]$[2], [],
  41        [m4_fatal([$0: Invalid arguments: $@])])dnl
  42 m4_pushdef([AT_SKEL_CC_IF],
  43 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  44 m4_pushdef([AT_GLR_IF],
  45 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  46 m4_pushdef([AT_LALR1_CC_IF],
  47 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  48 m4_pushdef([AT_GLR_CC_IF],
  49 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  50 # Using yacc.c?
  51 m4_pushdef([AT_YACC_IF],
  52 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  53 m4_pushdef([AT_LEXPARAM_IF],
  54 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  55 m4_pushdef([AT_PARAM_IF],
  56 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  57 m4_pushdef([AT_LOCATION_IF],
  58 [m4_bmatch([$3], [%locations], [$1], [$2])])
  59 m4_pushdef([AT_PURE_IF],
  60 [m4_bmatch([$3], [%pure-parser], [$1], [$2])])
  61 m4_pushdef([AT_PURE_AND_LOC_IF],
  62 [m4_bmatch([$3], [%locations.*%pure-parser\|%pure-parser.*%locations],
  63            [$1], [$2])])
  64 m4_pushdef([AT_GLR_OR_PARAM_IF],
  65 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  66 m4_pushdef([AT_NAME_PREFIX],
  67 [m4_bmatch([$3], [%name-prefix ".*"],
  68            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  69            [yy])])
  70 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  71 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  72 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  73                     [$2])])
  74 # yyerror always sees the locations (when activated), except if
  75 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  76 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  77 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  78                                         [$1])],
  79                             [$1])],
  80                 [$2])])
  81
  82 # The interface is pure: either because %pure-parser, or because we
  83 # are using the C++ parsers.
  84 m4_pushdef([AT_PURE_LEX_IF],
  85 [AT_PURE_IF([$1],
  86             [AT_SKEL_CC_IF([$1], [$2])])])
  87
  88 AT_PURE_LEX_IF(
  89 [m4_pushdef([AT_LOC], [(*llocp)])
  90  m4_pushdef([AT_VAL], [(*lvalp)])
  91  m4_pushdef([AT_LEX_FORMALS],
  92             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  93  m4_pushdef([AT_LEX_ARGS],
  94             [lvalp[]AT_LOCATION_IF([, llocp])])
  95  m4_pushdef([AT_USE_LEX_ARGS],
  96             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
  97  m4_pushdef([AT_LEX_PRE_FORMALS],
  98             [AT_LEX_FORMALS, ])
  99  m4_pushdef([AT_LEX_PRE_ARGS],
 100             [AT_LEX_ARGS, ])
 101 ],
 102 [m4_pushdef([AT_LOC], [(yylloc)])
 103  m4_pushdef([AT_VAL], [(yylval)])
 104  m4_pushdef([AT_LEX_FORMALS],     [void])
 105  m4_pushdef([AT_LEX_ARGS],        [])
 106  m4_pushdef([AT_USE_LEX_ARGS],    [])
 107  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 108  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 109 ])
 110 ])# _AT_BISON_OPTION_PUSHDEFS
 111
 112
 113 # AT_BISON_OPTION_POPDEFS
 114 # -----------------------
 115 m4_define([AT_BISON_OPTION_POPDEFS],
 116 [m4_popdef([AT_LEX_PRE_ARGS])
 117 m4_popdef([AT_LEX_PRE_FORMALS])
 118 m4_popdef([AT_USE_LEX_ARGS])
 119 m4_popdef([AT_LEX_ARGS])
 120 m4_popdef([AT_LEX_FORMALS])
 121 m4_popdef([AT_VAL])
 122 m4_popdef([AT_LOC])
 123 m4_popdef([AT_PURE_LEX_IF])
 124 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 125 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 126 m4_popdef([AT_NAME_PREFIX])
 127 m4_popdef([AT_GLR_OR_PARAM_IF])
 128 m4_popdef([AT_PURE_AND_LOC_IF])
 129 m4_popdef([AT_LOCATION_IF])
 130 m4_popdef([AT_PARAM_IF])
 131 m4_popdef([AT_LEXPARAM_IF])
 132 m4_popdef([AT_YACC_IF])
 133 m4_popdef([AT_GLR_IF])
 134 m4_popdef([AT_SKEL_CC_IF])
 135 m4_popdef([AT_GLR_CC_IF])
 136 m4_popdef([AT_LALR1_CC_IF])
 137 ])# AT_BISON_OPTION_POPDEFS
 138
 139
 140
 141 ## -------------------------- ##
 142 ## Generating Grammar Files.  ##
 143 ## -------------------------- ##
 144
 145
 146 # AT_DATA_GRAMMAR_PROLOGUE
 147 # ------------------------
 148 # The prologue that should be included in any grammar which parser is
 149 # meant to be compiled.
 150 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 151 [[%{
 152 #include <config.h>
 153 /* We don't need perfect functions for these tests. */
 154 #undef malloc
 155 #undef memcmp
 156 #undef realloc
 157 %}]
 158 ])
 159
 160
 161 # AT_DATA_GRAMMAR(NAME, CONTENT)
 162 # ------------------------------
 163 # Generate the file NAME, which CONTENT is preceded by
 164 # AT_DATA_GRAMMAR_PROLOGUE.
 165 m4_define([AT_DATA_GRAMMAR],
 166 [AT_DATA([$1],
 167 [AT_DATA_GRAMMAR_PROLOGUE
 168 $2])
 169 ])
 170
 171
 172 ## ------------------------ ##
 173 ## Compiling C, C++ Files.  ##
 174 ## ------------------------ ##
 175
 176
 177 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 178 # ----------------------------------------
 179 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 180 # assume that we are linking too; this is a hack.
 181 m4_define([AT_COMPILE],
 182 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 183            0, [ignore], [ignore])])
 184
 185 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 186 # --------------------------------------------
 187 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 188 # assume that we are linking too; this is a hack.
 189 # If the C++ compiler does not work, ignore the test.
 190 m4_define([AT_COMPILE_CXX],
 191 [AT_KEYWORDS(c++)
 192 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 193 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 194          0, [ignore], [ignore])])
 195
 196
 197
 198 ## ---------------------------- ##
 199 ## Running a generated parser.  ##
 200 ## ---------------------------- ##
 201
 202 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 203 # ------------------------------------------------------------
 204 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 205 m4_define([AT_PARSER_CHECK],
 206 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 207
 208
 209
 210
 211 ## ----------------------- ##
 212 ## Launch the test suite.  ##
 213 ## ----------------------- ##
 214
 215 AT_INIT
 216
 217 AT_TESTED([bison])