configure.in

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  16 # 02111-1307  USA
  17
  18 # We need a recent Autoconf to run a recent Autotest.
  19 AC_PREREQ(2.52g)
  20
  21 AC_INIT([GNU Bison], [1.30e], [bug-bison@gnu.org])
  22 AC_CONFIG_AUX_DIR(config)
  23
  24 AM_INIT_AUTOMAKE([bison], [1.30e])
  25 AM_CONFIG_HEADER(config.h:config.hin)
  26
  27 # Initialize the test suite.
  28 AC_CONFIG_TESTDIR(tests)
  29 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
  30 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
  31 # Needed by tests/atlocal.in.
  32 AC_SUBST([GCC])
  33
  34 # Checks for programs.
  35 AC_PROG_CC
  36 AC_MINIX
  37 AC_ISC_POSIX
  38 AM_PROG_CC_STDC
  39 AC_PROG_RANLIB
  40 AM_MISSING_PROG([AUTOM4TE], [autom4te])
  41
  42 AC_ARG_ENABLE(gcc-warnings,
  43 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  44 [case "${enableval}" in
  45    yes|no) ;;
  46    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  47  esac],
  48               [enableval=no])
  49 if test "${enableval}" = yes; then
  50   BISON_WARNING(-Wall)
  51   BISON_WARNING(-W)
  52   BISON_WARNING(-Wbad-function-cast)
  53   BISON_WARNING(-Wcast-align)
  54   BISON_WARNING(-Wcast-qual)
  55   BISON_WARNING(-Wformat)
  56   BISON_WARNING(-Wmissing-declarations)
  57   BISON_WARNING(-Wmissing-prototypes)
  58   BISON_WARNING(-Wnested-externs)
  59   BISON_WARNING(-Wshadow)
  60   BISON_WARNING(-Wstrict-prototypes)
  61   BISON_WARNING(-Wwrite-strings)
  62   CFLAGS="$CFLAGS $WARNING_CFLAGS"
  63 fi
  64
  65 # Checks for libraries.
  66 AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
  67
  68 # Checks for header files.
  69 AC_HEADER_STDC
  70 AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
  71
  72 # Checks for typedefs.
  73
  74 # Checks for structures.
  75
  76 # Checks for compiler characteristics.
  77 AC_C_CONST
  78 AC_C_INLINE
  79 AM_C_PROTOTYPES
  80
  81 # Checks for library functions.
  82 AC_FUNC_ALLOCA
  83 AC_CHECK_FUNCS(mkstemp setlocale)
  84 AC_CHECK_DECLS([stpcpy, strndup, strnlen, memchr])
  85 AC_REPLACE_FUNCS(stpcpy strndup strnlen strspn memchr)
  86 jm_FUNC_MALLOC
  87 jm_FUNC_REALLOC
  88 jm_PREREQ_QUOTEARG
  89 jm_PREREQ_ERROR
  90 AM_WITH_DMALLOC
  91
  92 ALL_LINGUAS="de es et fr ja nl ru sv tr"
  93 AM_GNU_GETTEXT(, need-ngettext)
  94
  95 # This is necessary so that .o files in LIBOBJS are also built via
  96 # the ANSI2KNR-filtering rules.
  97 LIB@&t@OBJS=`echo $LIB@&t@OBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
  98 AC_SUBST(LIB@&t@OBJS)
  99
 100 AC_OUTPUT([Makefile
 101            config/Makefile
 102            intl/Makefile po/Makefile.in
 103            lib/Makefile src/Makefile doc/Makefile
 104            m4/Makefile])