src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86
  87 %initial-action
  88 {
  89   /* Bison's grammar can initial empty locations, hence a default
  90      location is needed. */
  91   boundary_set (&@$.start, current_file, 1, 1);
  92   boundary_set (&@$.end, current_file, 1, 1);
  93 }
  94
  95 /* Only NUMBERS have a value.  */
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char *chars;
 102   assoc assoc;
 103   uniqstr uniqstr;
 104   unsigned char character;
 105 };
 106
 107 /* Define the tokens together with their human representation.  */
 108 %token GRAM_EOF 0 "end of file"
 109 %token STRING     "string"
 110 %token INT        "integer"
 111
 112 %token PERCENT_TOKEN       "%token"
 113 %token PERCENT_NTERM       "%nterm"
 114
 115 %token PERCENT_TYPE        "%type"
 116 %token PERCENT_DESTRUCTOR  "%destructor"
 117 %token PERCENT_PRINTER     "%printer"
 118
 119 %token PERCENT_LEFT        "%left"
 120 %token PERCENT_RIGHT       "%right"
 121 %token PERCENT_NONASSOC    "%nonassoc"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_AFTER_HEADER    "%after-header"
 134   PERCENT_BEFORE_HEADER   "%before-header"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_END_HEADER      "%end-header"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_REQUIRE         "%require"
 157   PERCENT_SKELETON        "%skeleton"
 158   PERCENT_START           "%start"
 159   PERCENT_START_HEADER    "%start-header"
 160   PERCENT_TOKEN_TABLE     "%token-table"
 161   PERCENT_VERBOSE         "%verbose"
 162   PERCENT_YACC            "%yacc"
 163 ;
 164
 165 %token BRACED_CODE     "{...}"
 166 %token CHAR            "char"
 167 %token EPILOGUE        "epilogue"
 168 %token EQUAL           "="
 169 %token ID              "identifier"
 170 %token ID_COLON        "identifier:"
 171 %token PERCENT_PERCENT "%%"
 172 %token PIPE            "|"
 173 %token PROLOGUE        "%{...%}"
 174 %token SEMICOLON       ";"
 175 %token TYPE            "type"
 176
 177 %type <character> CHAR
 178 %printer { fputs (char_name ($$), stderr); } CHAR
 179
 180 /* braceless is not to be used for rule or symbol actions, as it
 181    calls translate_code. */
 182 %type <chars> STRING "{...}" "%{...%}" EPILOGUE braceless content content.opt
 183 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 184          STRING
 185 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 186          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 187
 188 %type <uniqstr> TYPE ID ID_COLON
 189 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 190 %printer { fputs ($$, stderr); } ID
 191 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 192
 193 %type <integer> INT
 194 %printer { fprintf (stderr, "%d", $$); } INT
 195
 196 %type <symbol> id id_colon symbol string_as_id
 197 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 198 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 199
 200 %type <assoc> precedence_declarator
 201 %type <list>  symbols.1
 202 %%
 203
 204 input:
 205   prologue_declarations "%%" grammar epilogue.opt
 206 ;
 207
 208
 209         /*------------------------------------.
 210         | Declarations: before the first %%.  |
 211         `------------------------------------*/
 212
 213 prologue_declarations:
 214   /* Nothing */
 215 | prologue_declarations prologue_declaration
 216 ;
 217
 218 prologue_declaration:
 219   grammar_declaration
 220 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 221 | "%after-header" braceless        { prologue_augment ($2, @2, true); }
 222 | "%before-header" braceless       { prologue_augment ($2, @2, false); }
 223 | "%debug"                         { debug_flag = true; }
 224 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 225 | "%defines"                       { defines_flag = true; }
 226 | "%end-header" braceless          { muscle_code_grow ("end_header", $2, @2); }
 227 | "%error-verbose"                 { error_verbose = true; }
 228 | "%expect" INT                    { expected_sr_conflicts = $2; }
 229 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 230 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 231 | "%glr-parser"
 232     {
 233       nondeterministic_parser = true;
 234       glr_parser = true;
 235     }
 236 | "%initial-action" "{...}"
 237     {
 238       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 239     }
 240 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 241 | "%locations"                  { locations_flag = true; }
 242 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 243 | "%no-lines"                   { no_lines_flag = true; }
 244 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 245 | "%output" "=" STRING          { spec_outfile = $3; }
 246 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 247 | "%pure-parser"                { pure_parser = true; }
 248 | "%require" STRING             { version_check (&@2, $2); }
 249 | "%skeleton" STRING            { skeleton = $2; }
 250 | "%start-header" braceless     { muscle_code_grow ("start_header", $2, @2); }
 251 | "%token-table"                { token_table_flag = true; }
 252 | "%verbose"                    { report_flag = report_states; }
 253 | "%yacc"                       { yacc_flag = true; }
 254 | /*FIXME: Err?  What is this horror doing here? */ ";"
 255 ;
 256
 257 grammar_declaration:
 258   precedence_declaration
 259 | symbol_declaration
 260 | "%start" symbol
 261     {
 262       grammar_start_symbol_set ($2, @2);
 263     }
 264 | "%destructor" "{...}"
 265     {
 266       default_destructor_set (translate_symbol_action ($2, @2), @2);
 267     }
 268 | "%destructor" "{...}" symbols.1
 269     {
 270       symbol_list *list;
 271       const char *action = translate_symbol_action ($2, @2);
 272       for (list = $3; list; list = list->next)
 273         symbol_destructor_set (list->sym, action, @2);
 274       symbol_list_free ($3);
 275     }
 276 | "%printer" "{...}" symbols.1
 277     {
 278       symbol_list *list;
 279       const char *action = translate_symbol_action ($2, @2);
 280       for (list = $3; list; list = list->next)
 281         symbol_printer_set (list->sym, action, @2);
 282       symbol_list_free ($3);
 283     }
 284 | "%printer" "{...}"
 285     {
 286       default_printer_set (translate_symbol_action ($2, @2), @2);
 287     }
 288 | "%default-prec"
 289     {
 290       default_prec = true;
 291     }
 292 | "%no-default-prec"
 293     {
 294       default_prec = false;
 295     }
 296 ;
 297
 298
 299 /*----------*
 300  | %union.  |
 301  *----------*/
 302
 303 %token PERCENT_UNION "%union";
 304
 305 union_name:
 306   /* Nothing. */ {}
 307 | ID             { muscle_code_grow ("union_name", $1, @1); }
 308 ;
 309
 310 grammar_declaration:
 311   "%union" union_name "{...}"
 312     {
 313       char const *body = $3;
 314
 315       /* Concatenate the %union bodies.  If this is the first %union, make sure
 316          the synchronization line appears after the opening '{' so as not to
 317          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 318          into '\n', and omit the new %union's leading '{'.  */
 319       if (!union_seen)
 320         {
 321           muscle_grow ("stype", "{", "");
 322         }
 323       else
 324         {
 325           char *code = muscle_find ("stype");
 326           code[strlen (code) - 1] = '\n';
 327         }
 328       body++;
 329
 330       union_seen = true;
 331       muscle_code_grow ("stype", body, @3);
 332     }
 333 ;
 334
 335
 336
 337
 338 symbol_declaration:
 339   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 340     {
 341       current_class = unknown_sym;
 342       current_type = NULL;
 343     }
 344 | "%token" { current_class = token_sym; } symbol_defs.1
 345     {
 346       current_class = unknown_sym;
 347       current_type = NULL;
 348     }
 349 | "%type" TYPE symbols.1
 350     {
 351       tag_seen = true;
 352       symbol_list *list;
 353       for (list = $3; list; list = list->next)
 354         symbol_type_set (list->sym, $2, @2);
 355       symbol_list_free ($3);
 356     }
 357 ;
 358
 359 precedence_declaration:
 360   precedence_declarator type.opt symbols.1
 361     {
 362       symbol_list *list;
 363       ++current_prec;
 364       for (list = $3; list; list = list->next)
 365         {
 366           symbol_type_set (list->sym, current_type, @2);
 367           symbol_precedence_set (list->sym, current_prec, $1, @1);
 368         }
 369       symbol_list_free ($3);
 370       current_type = NULL;
 371     }
 372 ;
 373
 374 precedence_declarator:
 375   "%left"     { $$ = left_assoc; }
 376 | "%right"    { $$ = right_assoc; }
 377 | "%nonassoc" { $$ = non_assoc; }
 378 ;
 379
 380 type.opt:
 381   /* Nothing. */ { current_type = NULL; }
 382 | TYPE           { current_type = $1; tag_seen = true; }
 383 ;
 384
 385 /* One or more nonterminals to be %typed. */
 386 symbols.1:
 387   symbol            { $$ = symbol_list_new ($1, @1); }
 388 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 389 ;
 390
 391 /* One token definition.  */
 392 symbol_def:
 393   TYPE
 394      {
 395        current_type = $1;
 396        tag_seen = true;
 397      }
 398 | id
 399      {
 400        symbol_class_set ($1, current_class, @1, true);
 401        symbol_type_set ($1, current_type, @1);
 402      }
 403 | id INT
 404     {
 405       symbol_class_set ($1, current_class, @1, true);
 406       symbol_type_set ($1, current_type, @1);
 407       symbol_user_token_number_set ($1, $2, @2);
 408     }
 409 | id string_as_id
 410     {
 411       symbol_class_set ($1, current_class, @1, true);
 412       symbol_type_set ($1, current_type, @1);
 413       symbol_make_alias ($1, $2, @$);
 414     }
 415 | id INT string_as_id
 416     {
 417       symbol_class_set ($1, current_class, @1, true);
 418       symbol_type_set ($1, current_type, @1);
 419       symbol_user_token_number_set ($1, $2, @2);
 420       symbol_make_alias ($1, $3, @$);
 421     }
 422 ;
 423
 424 /* One or more symbol definitions. */
 425 symbol_defs.1:
 426   symbol_def
 427 | symbol_defs.1 symbol_def
 428 ;
 429
 430
 431         /*------------------------------------------.
 432         | The grammar section: between the two %%.  |
 433         `------------------------------------------*/
 434
 435 grammar:
 436   rules_or_grammar_declaration
 437 | grammar rules_or_grammar_declaration
 438 ;
 439
 440 /* As a Bison extension, one can use the grammar declarations in the
 441    body of the grammar.  */
 442 rules_or_grammar_declaration:
 443   rules
 444 | grammar_declaration ";"
 445 | error ";"
 446     {
 447       yyerrok;
 448     }
 449 ;
 450
 451 rules:
 452   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 453 ;
 454
 455 rhses.1:
 456   rhs                { grammar_current_rule_end (@1); }
 457 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 458 | rhses.1 ";"
 459 ;
 460
 461 rhs:
 462   /* Nothing.  */
 463     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 464 | rhs symbol
 465     { grammar_current_rule_symbol_append ($2, @2); }
 466 | rhs "{...}"
 467     { grammar_current_rule_action_append ($2, @2); }
 468 | rhs "%prec" symbol
 469     { grammar_current_rule_prec_set ($3, @3); }
 470 | rhs "%dprec" INT
 471     { grammar_current_rule_dprec_set ($3, @3); }
 472 | rhs "%merge" TYPE
 473     { grammar_current_rule_merge_set ($3, @3); }
 474 ;
 475
 476
 477 /*-----------*
 478  | content.  |
 479  *-----------*/
 480
 481 content:
 482   STRING
 483 | braceless
 484 ;
 485
 486 /* Some content or "1" by default. */
 487 content.opt:
 488   /* Nothing. */
 489     {
 490       static char one[] = "1";
 491       $$ = one;
 492     }
 493 | content
 494 ;
 495
 496
 497 braceless:
 498   "{...}"
 499     {
 500       $1[strlen ($1) - 1] = '\n';
 501       $$ = translate_code ($1 + 1, @1);
 502     }
 503 ;
 504
 505
 506 /*---------------*
 507  | Identifiers.  |
 508  *---------------*/
 509
 510 /* Identifiers are returned as uniqstr values by the scanner.
 511    Depending on their use, we may need to make them genuine symbols.  */
 512
 513 id:
 514   ID
 515     { $$ = symbol_from_uniqstr ($1, @1); }
 516 | CHAR
 517     {
 518       $$ = symbol_get (char_name ($1), @1);
 519       symbol_class_set ($$, token_sym, @1, false);
 520       symbol_user_token_number_set ($$, $1, @1);
 521     }
 522 ;
 523
 524 id_colon:
 525   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 526 ;
 527
 528
 529 symbol:
 530   id
 531 | string_as_id
 532 ;
 533
 534 /* A string used as an ID: quote it.  */
 535 string_as_id:
 536   STRING
 537     {
 538       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 539       symbol_class_set ($$, token_sym, @1, false);
 540     }
 541 ;
 542
 543 epilogue.opt:
 544   /* Nothing.  */
 545 | "%%" EPILOGUE
 546     {
 547       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 548       gram_scanner_last_string_free ();
 549     }
 550 ;
 551
 552 %%
 553
 554
 555 /* Return the location of the left-hand side of a rule whose
 556    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 557    the right-hand side, and return an empty location equal to the end
 558    boundary of RHS[0] if the right-hand side is empty.  */
 559
 560 static YYLTYPE
 561 lloc_default (YYLTYPE const *rhs, int n)
 562 {
 563   int i;
 564   YYLTYPE loc;
 565
 566   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 567      The bug is fixed in 7.4.2m, but play it safe for now.  */
 568   loc.start = rhs[n].end;
 569   loc.end = rhs[n].end;
 570
 571   /* Ignore empty nonterminals the start of the the right-hand side.
 572      Do not bother to ignore them at the end of the right-hand side,
 573      since empty nonterminals have the same end as their predecessors.  */
 574   for (i = 1; i <= n; i++)
 575     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 576       {
 577         loc.start = rhs[i].start;
 578         break;
 579       }
 580
 581   return loc;
 582 }
 583
 584
 585 /* Add a lex-param or a parse-param (depending on TYPE) with
 586    declaration DECL and location LOC.  */
 587
 588 static void
 589 add_param (char const *type, char *decl, location loc)
 590 {
 591   static char const alphanum[26 + 26 + 1 + 10] =
 592     "abcdefghijklmnopqrstuvwxyz"
 593     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 594     "_"
 595     "0123456789";
 596   char const *name_start = NULL;
 597   char *p;
 598
 599   /* Stop on last actual character.  */
 600   for (p = decl; p[1]; p++)
 601     if ((p == decl
 602          || ! memchr (alphanum, p[-1], sizeof alphanum))
 603         && memchr (alphanum, p[0], sizeof alphanum - 10))
 604       name_start = p;
 605
 606   /* Strip the surrounding '{' and '}', and any blanks just inside
 607      the braces.  */
 608   while (*--p == ' ' || *p == '\t')
 609     continue;
 610   p[1] = '\0';
 611   while (*++decl == ' ' || *decl == '\t')
 612     continue;
 613
 614   if (! name_start)
 615     complain_at (loc, _("missing identifier in parameter declaration"));
 616   else
 617     {
 618       char *name;
 619       size_t name_len;
 620
 621       for (name_len = 1;
 622            memchr (alphanum, name_start[name_len], sizeof alphanum);
 623            name_len++)
 624         continue;
 625
 626       name = xmalloc (name_len + 1);
 627       memcpy (name, name_start, name_len);
 628       name[name_len] = '\0';
 629       muscle_pair_list_grow (type, decl, name);
 630       free (name);
 631     }
 632
 633   gram_scanner_last_string_free ();
 634 }
 635
 636
 637 static void
 638 version_check (location const *loc, char const *version)
 639 {
 640   if (strverscmp (version, PACKAGE_VERSION) > 0)
 641     {
 642       complain_at (*loc, "require bison %s, but have %s",
 643                    version, PACKAGE_VERSION);
 644       exit (63);
 645     }
 646 }
 647
 648 static void
 649 gram_error (location const *loc, char const *msg)
 650 {
 651   complain_at (*loc, "%s", msg);
 652 }
 653
 654 char const *
 655 token_name (int type)
 656 {
 657   return yytname[YYTRANSLATE (type)];
 658 }
 659
 660 static char const *
 661 char_name (char c)
 662 {
 663   if (c == '\'')
 664     return "'\\''";
 665   else
 666     {
 667       char buf[4];
 668       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 669       return quotearg_style (escape_quoting_style, buf);
 670     }
 671 }