src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002-2013 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software: you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation, either version 3 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  19
  20 #include <config.h>
  21 #include "system.h"
  22
  23 #include "c-ctype.h"
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "named-ref.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "symtab.h"
  34 #include "scan-gram.h"
  35 #include "scan-code.h"
  36 #include "xmemdup0.h"
  37
  38 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  39 static YYLTYPE lloc_default (YYLTYPE const *, int);
  40
  41 #define YY_LOCATION_PRINT(File, Loc) \
  42           location_print (Loc, File)
  43
  44 static void version_check (location const *loc, char const *version);
  45
  46 static void gram_error (location const *, char const *);
  47
  48 /* A string that describes a char (e.g., 'a' -> "'a'").  */
  49 static char const *char_name (char);
  50 %}
  51
  52 %code
  53 {
  54   static int current_prec = 0;
  55   static location current_lhs_location;
  56   static named_ref *current_lhs_named_ref;
  57   static symbol *current_lhs_symbol;
  58   static symbol_class current_class = unknown_sym;
  59   static uniqstr current_type = NULL;
  60
  61   /** Set the new current left-hand side symbol, possibly common
  62    * to several right-hand side parts of rule.
  63    */
  64   static
  65   void
  66   current_lhs (symbol *sym, location loc, named_ref *ref)
  67   {
  68     current_lhs_symbol = sym;
  69     current_lhs_location = loc;
  70     /* In order to simplify memory management, named references for lhs
  71        are always assigned by deep copy into the current symbol_list
  72        node.  This is because a single named-ref in the grammar may
  73        result in several uses when the user factors lhs between several
  74        rules using "|".  Therefore free the parser's original copy.  */
  75     free (current_lhs_named_ref);
  76     current_lhs_named_ref = ref;
  77   }
  78
  79   #define YYTYPE_INT16 int_fast16_t
  80   #define YYTYPE_INT8 int_fast8_t
  81   #define YYTYPE_UINT16 uint_fast16_t
  82   #define YYTYPE_UINT8 uint_fast8_t
  83 }
  84
  85 %define api.prefix "gram_"
  86 %define api.pure full
  87 %define locations
  88 %define parse.error verbose
  89 %define parse.lac full
  90 %define parse.trace
  91 %defines
  92 %expect 0
  93 %verbose
  94
  95 %initial-action
  96 {
  97   /* Bison's grammar can initial empty locations, hence a default
  98      location is needed. */
  99   boundary_set (&@$.start, current_file, 1, 1);
 100   boundary_set (&@$.end, current_file, 1, 1);
 101 }
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106
 107 %token PERCENT_TOKEN       "%token"
 108 %token PERCENT_NTERM       "%nterm"
 109
 110 %token PERCENT_TYPE        "%type"
 111 %token PERCENT_DESTRUCTOR  "%destructor"
 112 %token PERCENT_PRINTER     "%printer"
 113
 114 %token PERCENT_LEFT        "%left"
 115 %token PERCENT_RIGHT       "%right"
 116 %token PERCENT_NONASSOC    "%nonassoc"
 117 %token PERCENT_PRECEDENCE  "%precedence"
 118
 119 %token PERCENT_PREC          "%prec"
 120 %token PERCENT_DPREC         "%dprec"
 121 %token PERCENT_MERGE         "%merge"
 122
 123 /*----------------------.
 124 | Global Declarations.  |
 125 `----------------------*/
 126
 127 %token
 128   PERCENT_CODE            "%code"
 129   PERCENT_DEFAULT_PREC    "%default-prec"
 130   PERCENT_DEFINE          "%define"
 131   PERCENT_DEFINES         "%defines"
 132   PERCENT_ERROR_VERBOSE   "%error-verbose"
 133   PERCENT_EXPECT          "%expect"
 134   PERCENT_EXPECT_RR       "%expect-rr"
 135   PERCENT_FLAG            "%<flag>"
 136   PERCENT_FILE_PREFIX     "%file-prefix"
 137   PERCENT_GLR_PARSER      "%glr-parser"
 138   PERCENT_INITIAL_ACTION  "%initial-action"
 139   PERCENT_LANGUAGE        "%language"
 140   PERCENT_NAME_PREFIX     "%name-prefix"
 141   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 142   PERCENT_NO_LINES        "%no-lines"
 143   PERCENT_NONDETERMINISTIC_PARSER
 144                           "%nondeterministic-parser"
 145   PERCENT_OUTPUT          "%output"
 146   PERCENT_REQUIRE         "%require"
 147   PERCENT_SKELETON        "%skeleton"
 148   PERCENT_START           "%start"
 149   PERCENT_TOKEN_TABLE     "%token-table"
 150   PERCENT_VERBOSE         "%verbose"
 151   PERCENT_YACC            "%yacc"
 152 ;
 153
 154 %token BRACED_CODE     "{...}"
 155 %token BRACED_PREDICATE "%?{...}"
 156 %token BRACKETED_ID    "[identifier]"
 157 %token CHAR            "char"
 158 %token EPILOGUE        "epilogue"
 159 %token EQUAL           "="
 160 %token ID              "identifier"
 161 %token ID_COLON        "identifier:"
 162 %token PERCENT_PERCENT "%%"
 163 %token PIPE            "|"
 164 %token PROLOGUE        "%{...%}"
 165 %token SEMICOLON       ";"
 166 %token TAG             "<tag>"
 167 %token TAG_ANY         "<*>"
 168 %token TAG_NONE        "<>"
 169
 170 %union {unsigned char character;}
 171 %type <character> CHAR
 172 %printer { fputs (char_name ($$), yyo); } CHAR
 173
 174 /* braceless is not to be used for rule or symbol actions, as it
 175    calls code_props_plain_init.  */
 176 %union
 177 {
 178   char *code;
 179   char const *chars;
 180 };
 181 %type <chars> STRING "%{...%}" EPILOGUE braceless
 182 %type <code> "{...}" "%?{...}"
 183 %printer { fputs (quotearg_style (c_quoting_style, $$), yyo); }
 184          STRING
 185 %printer { fprintf (yyo, "{\n%s\n}", $$); }
 186          braceless "{...}" "%{...%}" EPILOGUE
 187
 188 %union {uniqstr uniqstr;}
 189 %type <uniqstr> BRACKETED_ID ID ID_COLON PERCENT_FLAG TAG tag variable
 190 %printer { fputs ($$, yyo); } <uniqstr>
 191 %printer { fprintf (yyo, "[%s]", $$); } BRACKETED_ID
 192 %printer { fprintf (yyo, "%s:", $$); } ID_COLON
 193 %printer { fprintf (yyo, "%%%s", $$); } PERCENT_FLAG
 194 %printer { fprintf (yyo, "<%s>", $$); } TAG tag
 195
 196 %union {int integer;};
 197 %token <integer> INT "integer"
 198 %printer { fprintf (yyo, "%d", $$); } <integer>
 199
 200 %union {symbol *symbol;}
 201 %type <symbol> id id_colon string_as_id symbol symbol.prec
 202 %printer { fprintf (yyo, "%s", $$->tag); } <symbol>
 203 %printer { fprintf (yyo, "%s:", $$->tag); } id_colon
 204
 205 %union {assoc assoc;};
 206 %type <assoc> precedence_declarator
 207
 208 %union {symbol_list *list;}
 209 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 210
 211 %union {named_ref *named_ref;}
 212 %type <named_ref> named_ref.opt
 213
 214 /*---------.
 215 | %param.  |
 216 `---------*/
 217 %code requires
 218 {
 219   typedef enum
 220   {
 221     param_none   = 0,
 222     param_lex    = 1 << 0,
 223     param_parse  = 1 << 1,
 224     param_both   = param_lex | param_parse
 225   } param_type;
 226 };
 227 %code
 228 {
 229   /** Add a lex-param and/or a parse-param.
 230    *
 231    * \param type  where to push this formal argument.
 232    * \param decl  the formal argument.  Destroyed.
 233    * \param loc   the location in the source.
 234    */
 235   static void add_param (param_type type, char *decl, location loc);
 236   static param_type current_param = param_none;
 237 };
 238 %union {param_type param;}
 239 %token <param> PERCENT_PARAM "%param";
 240 %printer
 241 {
 242   switch ($$)
 243     {
 244 #define CASE(In, Out)                                           \
 245       case param_ ## In: fputs ("%" #Out, yyo); break
 246       CASE (lex,   lex-param);
 247       CASE (parse, parse-param);
 248       CASE (both,  param);
 249 #undef CASE
 250       case param_none: aver (false); break;
 251     }
 252 } <param>;
 253
 254
 255                      /*==========\
 256                      | Grammar.  |
 257                      \==========*/
 258 %%
 259
 260 input:
 261   prologue_declarations "%%" grammar epilogue.opt
 262 ;
 263
 264
 265         /*------------------------------------.
 266         | Declarations: before the first %%.  |
 267         `------------------------------------*/
 268
 269 prologue_declarations:
 270   %empty
 271 | prologue_declarations prologue_declaration
 272 ;
 273
 274 prologue_declaration:
 275   grammar_declaration
 276 | "%{...%}"
 277     {
 278       code_props plain_code;
 279       code_props_plain_init (&plain_code, $1, @1);
 280       code_props_translate_code (&plain_code);
 281       gram_scanner_last_string_free ();
 282       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 283                         plain_code.code, @1);
 284       code_scanner_last_string_free ();
 285     }
 286 | "%<flag>"
 287     {
 288       muscle_percent_define_ensure ($1, @1, true);
 289     }
 290 | "%define" variable value
 291     {
 292       muscle_percent_define_insert ($2, @2, $3.kind, $3.chars,
 293                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 294     }
 295 | "%defines"                       { defines_flag = true; }
 296 | "%defines" STRING
 297     {
 298       defines_flag = true;
 299       spec_defines_file = xstrdup ($2);
 300     }
 301 | "%error-verbose"
 302     {
 303       muscle_percent_define_insert ("parse.error", @1, muscle_keyword,
 304                                     "verbose",
 305                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 306     }
 307 | "%expect" INT                    { expected_sr_conflicts = $2; }
 308 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 309 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 310 | "%glr-parser"
 311     {
 312       nondeterministic_parser = true;
 313       glr_parser = true;
 314     }
 315 | "%initial-action" "{...}"
 316     {
 317       code_props action;
 318       code_props_symbol_action_init (&action, $2, @2);
 319       code_props_translate_code (&action);
 320       gram_scanner_last_string_free ();
 321       muscle_code_grow ("initial_action", action.code, @2);
 322       code_scanner_last_string_free ();
 323     }
 324 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 325 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 326 | "%no-lines"                   { no_lines_flag = true; }
 327 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 328 | "%output" STRING              { spec_outfile = $2; }
 329 | "%param" { current_param = $1; } params { current_param = param_none; }
 330 | "%require" STRING             { version_check (&@2, $2); }
 331 | "%skeleton" STRING
 332     {
 333       char const *skeleton_user = $2;
 334       if (strchr (skeleton_user, '/'))
 335         {
 336           size_t dir_length = strlen (current_file);
 337           char *skeleton_build;
 338           while (dir_length && current_file[dir_length - 1] != '/')
 339             --dir_length;
 340           while (dir_length && current_file[dir_length - 1] == '/')
 341             --dir_length;
 342           skeleton_build =
 343             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 344           if (dir_length > 0)
 345             {
 346               memcpy (skeleton_build, current_file, dir_length);
 347               skeleton_build[dir_length++] = '/';
 348             }
 349           strcpy (skeleton_build + dir_length, skeleton_user);
 350           skeleton_user = uniqstr_new (skeleton_build);
 351           free (skeleton_build);
 352         }
 353       skeleton_arg (skeleton_user, grammar_prio, @1);
 354     }
 355 | "%token-table"                { token_table_flag = true; }
 356 | "%verbose"                    { report_flag |= report_states; }
 357 | "%yacc"                       { yacc_flag = true; }
 358 | /*FIXME: Err?  What is this horror doing here? */ ";"
 359 ;
 360
 361 params:
 362    params "{...}"  { add_param (current_param, $2, @2); }
 363 | "{...}"          { add_param (current_param, $1, @1); }
 364 ;
 365
 366
 367 /*----------------------.
 368 | grammar_declaration.  |
 369 `----------------------*/
 370
 371 grammar_declaration:
 372   precedence_declaration
 373 | symbol_declaration
 374 | "%start" symbol
 375     {
 376       grammar_start_symbol_set ($2, @2);
 377     }
 378 | code_props_type "{...}" generic_symlist
 379     {
 380       code_props code;
 381       code_props_symbol_action_init (&code, $2, @2);
 382       code_props_translate_code (&code);
 383       {
 384         symbol_list *list;
 385         for (list = $3; list; list = list->next)
 386           symbol_list_code_props_set (list, $1, &code);
 387         symbol_list_free ($3);
 388       }
 389     }
 390 | "%default-prec"
 391     {
 392       default_prec = true;
 393     }
 394 | "%no-default-prec"
 395     {
 396       default_prec = false;
 397     }
 398 | "%code" braceless
 399     {
 400       /* Do not invoke muscle_percent_code_grow here since it invokes
 401          muscle_user_name_list_grow.  */
 402       muscle_code_grow ("percent_code()", $2, @2);
 403       code_scanner_last_string_free ();
 404     }
 405 | "%code" ID braceless
 406     {
 407       muscle_percent_code_grow ($2, @2, $3, @3);
 408       code_scanner_last_string_free ();
 409     }
 410 ;
 411
 412 %type <code_type> code_props_type;
 413 %union {code_props_type code_type;};
 414 %printer { fprintf (yyo, "%s", code_props_type_string ($$)); } <code_type>;
 415 code_props_type:
 416   "%destructor"  { $$ = destructor; }
 417 | "%printer"     { $$ = printer; }
 418 ;
 419
 420 /*---------.
 421 | %union.  |
 422 `---------*/
 423
 424 %token PERCENT_UNION "%union";
 425
 426 union_name:
 427   %empty {}
 428 | ID     { muscle_code_grow ("union_name", $1, @1); }
 429 ;
 430
 431 grammar_declaration:
 432   "%union" union_name braceless
 433     {
 434       union_seen = true;
 435       muscle_code_grow ("union_members", $3, @3);
 436       code_scanner_last_string_free ();
 437     }
 438 ;
 439
 440
 441
 442
 443 symbol_declaration:
 444   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 445     {
 446       current_class = unknown_sym;
 447       current_type = NULL;
 448     }
 449 | "%token" { current_class = token_sym; } symbol_defs.1
 450     {
 451       current_class = unknown_sym;
 452       current_type = NULL;
 453     }
 454 | "%type" TAG symbols.1
 455     {
 456       symbol_list *list;
 457       tag_seen = true;
 458       for (list = $3; list; list = list->next)
 459         symbol_type_set (list->content.sym, $2, @2);
 460       symbol_list_free ($3);
 461     }
 462 ;
 463
 464 precedence_declaration:
 465   precedence_declarator tag.opt symbols.prec
 466     {
 467       symbol_list *list;
 468       ++current_prec;
 469       for (list = $3; list; list = list->next)
 470         {
 471           symbol_type_set (list->content.sym, current_type, @2);
 472           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 473         }
 474       symbol_list_free ($3);
 475       current_type = NULL;
 476     }
 477 ;
 478
 479 precedence_declarator:
 480   "%left"       { $$ = left_assoc; }
 481 | "%right"      { $$ = right_assoc; }
 482 | "%nonassoc"   { $$ = non_assoc; }
 483 | "%precedence" { $$ = precedence_assoc; }
 484 ;
 485
 486 tag.opt:
 487   %empty { current_type = NULL; }
 488 | TAG    { current_type = $1; tag_seen = true; }
 489 ;
 490
 491 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 492 symbols.prec:
 493   symbol.prec
 494     { $$ = symbol_list_sym_new ($1, @1); }
 495 | symbols.prec symbol.prec
 496     { $$ = symbol_list_append ($1, symbol_list_sym_new ($2, @2)); }
 497 ;
 498
 499 symbol.prec:
 500   symbol
 501     {
 502       $$ = $1;
 503       symbol_class_set ($1, token_sym, @1, false);
 504     }
 505 | symbol INT
 506     {
 507       $$ = $1;
 508       symbol_user_token_number_set ($1, $2, @2);
 509       symbol_class_set ($1, token_sym, @1, false);
 510     }
 511 ;
 512
 513 /* One or more symbols to be %typed. */
 514 symbols.1:
 515   symbol
 516     { $$ = symbol_list_sym_new ($1, @1); }
 517 | symbols.1 symbol
 518     { $$ = symbol_list_append ($1, symbol_list_sym_new ($2, @2)); }
 519 ;
 520
 521 generic_symlist:
 522   generic_symlist_item { $$ = $1; }
 523 | generic_symlist generic_symlist_item { $$ = symbol_list_append ($1, $2); }
 524 ;
 525
 526 generic_symlist_item:
 527   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 528 | tag       { $$ = symbol_list_type_new ($1, @1); }
 529 ;
 530
 531 tag:
 532   TAG
 533 | "<*>" { $$ = uniqstr_new ("*"); }
 534 | "<>"  { $$ = uniqstr_new (""); }
 535 ;
 536
 537 /* One token definition.  */
 538 symbol_def:
 539   TAG
 540     {
 541       current_type = $1;
 542       tag_seen = true;
 543     }
 544 | id
 545     {
 546       symbol_class_set ($1, current_class, @1, true);
 547       symbol_type_set ($1, current_type, @1);
 548     }
 549 | id INT
 550     {
 551       symbol_class_set ($1, current_class, @1, true);
 552       symbol_type_set ($1, current_type, @1);
 553       symbol_user_token_number_set ($1, $2, @2);
 554     }
 555 | id string_as_id
 556     {
 557       symbol_class_set ($1, current_class, @1, true);
 558       symbol_type_set ($1, current_type, @1);
 559       symbol_make_alias ($1, $2, @$);
 560     }
 561 | id INT string_as_id
 562     {
 563       symbol_class_set ($1, current_class, @1, true);
 564       symbol_type_set ($1, current_type, @1);
 565       symbol_user_token_number_set ($1, $2, @2);
 566       symbol_make_alias ($1, $3, @$);
 567     }
 568 ;
 569
 570 /* One or more symbol definitions. */
 571 symbol_defs.1:
 572   symbol_def
 573 | symbol_defs.1 symbol_def
 574 ;
 575
 576
 577         /*------------------------------------------.
 578         | The grammar section: between the two %%.  |
 579         `------------------------------------------*/
 580
 581 grammar:
 582   rules_or_grammar_declaration
 583 | grammar rules_or_grammar_declaration
 584 ;
 585
 586 /* As a Bison extension, one can use the grammar declarations in the
 587    body of the grammar.  */
 588 rules_or_grammar_declaration:
 589   rules
 590 | grammar_declaration ";"
 591 | error ";"
 592     {
 593       yyerrok;
 594     }
 595 ;
 596
 597 rules:
 598   id_colon named_ref.opt { current_lhs ($1, @1, $2); } rhses.1
 599   {
 600     /* Free the current lhs. */
 601     current_lhs (0, @1, 0);
 602   }
 603 ;
 604
 605 rhses.1:
 606   rhs                { grammar_current_rule_end (@1); }
 607 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 608 | rhses.1 ";"
 609 ;
 610
 611 %token PERCENT_EMPTY "%empty";
 612 rhs:
 613   %empty
 614     { grammar_current_rule_begin (current_lhs_symbol, current_lhs_location,
 615                                   current_lhs_named_ref); }
 616 | rhs symbol named_ref.opt
 617     { grammar_current_rule_symbol_append ($2, @2, $3); }
 618 | rhs "{...}" named_ref.opt
 619     { grammar_current_rule_action_append ($2, @2, $3, false); }
 620 | rhs "%?{...}"
 621     { grammar_current_rule_action_append ($2, @2, NULL, true); }
 622 | rhs "%empty"
 623     { grammar_current_rule_empty_set (@2); }
 624 | rhs "%prec" symbol
 625     { grammar_current_rule_prec_set ($3, @3); }
 626 | rhs "%dprec" INT
 627     { grammar_current_rule_dprec_set ($3, @3); }
 628 | rhs "%merge" TAG
 629     { grammar_current_rule_merge_set ($3, @3); }
 630 ;
 631
 632 named_ref.opt:
 633   %empty         { $$ = 0; }
 634 | BRACKETED_ID   { $$ = named_ref_new($1, @1); }
 635 ;
 636
 637 /*---------------------.
 638 | variable and value.  |
 639 `---------------------*/
 640
 641 /* The STRING form of variable is deprecated and is not M4-friendly.
 642    For example, M4 fails for '%define "[" "value"'.  */
 643 variable:
 644   ID
 645 | STRING { $$ = uniqstr_new ($1); }
 646 ;
 647
 648 /* Some content or empty by default. */
 649 %code requires {#include "muscle-tab.h"};
 650 %union
 651 {
 652   struct
 653   {
 654     char const *chars;
 655     muscle_kind kind;
 656   } value;
 657 };
 658 %type <value> value;
 659 %printer
 660 {
 661   switch ($$.kind)
 662     {
 663     case muscle_code:    fprintf (yyo,  "{%s}",  $$.chars); break;
 664     case muscle_keyword: fprintf (yyo,   "%s",   $$.chars); break;
 665     case muscle_string:  fprintf (yyo, "\"%s\"", $$.chars); break;
 666     }
 667 } <value>;
 668
 669 value:
 670   %empty    { $$.kind = muscle_keyword; $$.chars = ""; }
 671 | ID        { $$.kind = muscle_keyword; $$.chars = $1; }
 672 | STRING    { $$.kind = muscle_string;  $$.chars = $1; }
 673 | braceless { $$.kind = muscle_code;    $$.chars = $1; }
 674 ;
 675
 676
 677 /*------------.
 678 | braceless.  |
 679 `------------*/
 680
 681 braceless:
 682   "{...}"
 683     {
 684       code_props plain_code;
 685       $1[strlen ($1) - 1] = '\0';
 686       code_props_plain_init (&plain_code, $1+1, @1);
 687       code_props_translate_code (&plain_code);
 688       gram_scanner_last_string_free ();
 689       $$ = plain_code.code;
 690     }
 691 ;
 692
 693
 694 /*--------------.
 695 | Identifiers.  |
 696 `--------------*/
 697
 698 /* Identifiers are returned as uniqstr values by the scanner.
 699    Depending on their use, we may need to make them genuine symbols.  */
 700
 701 id:
 702   ID
 703     { $$ = symbol_from_uniqstr ($1, @1); }
 704 | CHAR
 705     {
 706       $$ = symbol_get (char_name ($1), @1);
 707       symbol_class_set ($$, token_sym, @1, false);
 708       symbol_user_token_number_set ($$, $1, @1);
 709     }
 710 ;
 711
 712 id_colon:
 713   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 714 ;
 715
 716
 717 symbol:
 718   id
 719 | string_as_id
 720 ;
 721
 722 /* A string used as an ID: quote it.  */
 723 string_as_id:
 724   STRING
 725     {
 726       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 727       symbol_class_set ($$, token_sym, @1, false);
 728     }
 729 ;
 730
 731 epilogue.opt:
 732   %empty
 733 | "%%" EPILOGUE
 734     {
 735       code_props plain_code;
 736       code_props_plain_init (&plain_code, $2, @2);
 737       code_props_translate_code (&plain_code);
 738       gram_scanner_last_string_free ();
 739       muscle_code_grow ("epilogue", plain_code.code, @2);
 740       code_scanner_last_string_free ();
 741     }
 742 ;
 743
 744 %%
 745
 746 /* Return the location of the left-hand side of a rule whose
 747    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 748    the right-hand side, and return an empty location equal to the end
 749    boundary of RHS[0] if the right-hand side is empty.  */
 750
 751 static YYLTYPE
 752 lloc_default (YYLTYPE const *rhs, int n)
 753 {
 754   int i;
 755   YYLTYPE loc;
 756
 757   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 758      The bug is fixed in 7.4.2m, but play it safe for now.  */
 759   loc.start = rhs[n].end;
 760   loc.end = rhs[n].end;
 761
 762   /* Ignore empty nonterminals the start of the right-hand side.
 763      Do not bother to ignore them at the end of the right-hand side,
 764      since empty nonterminals have the same end as their predecessors.  */
 765   for (i = 1; i <= n; i++)
 766     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 767       {
 768         loc.start = rhs[i].start;
 769         break;
 770       }
 771
 772   return loc;
 773 }
 774
 775
 776 static void
 777 add_param (param_type type, char *decl, location loc)
 778 {
 779   static char const alphanum[26 + 26 + 1 + 10] =
 780     "abcdefghijklmnopqrstuvwxyz"
 781     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 782     "_"
 783     "0123456789";
 784
 785   char const *name_start = NULL;
 786   {
 787     char *p;
 788     /* Stop on last actual character.  */
 789     for (p = decl; p[1]; p++)
 790       if ((p == decl
 791            || ! memchr (alphanum, p[-1], sizeof alphanum))
 792           && memchr (alphanum, p[0], sizeof alphanum - 10))
 793         name_start = p;
 794
 795     /* Strip the surrounding '{' and '}', and any blanks just inside
 796        the braces.  */
 797     --p;
 798   while (c_isspace ((unsigned char) *p))
 799       --p;
 800     p[1] = '\0';
 801     ++decl;
 802   while (c_isspace ((unsigned char) *decl))
 803       ++decl;
 804   }
 805
 806   if (! name_start)
 807     complain (&loc, complaint, _("missing identifier in parameter declaration"));
 808   else
 809     {
 810       char *name = xmemdup0 (name_start, strspn (name_start, alphanum));
 811       if (type & param_lex)
 812         muscle_pair_list_grow ("lex_param", decl, name);
 813       if (type & param_parse)
 814         muscle_pair_list_grow ("parse_param", decl, name);
 815       free (name);
 816     }
 817
 818   gram_scanner_last_string_free ();
 819 }
 820
 821
 822 static void
 823 version_check (location const *loc, char const *version)
 824 {
 825   if (strverscmp (version, PACKAGE_VERSION) > 0)
 826     {
 827       complain (loc, complaint, "require bison %s, but have %s",
 828                 version, PACKAGE_VERSION);
 829       exit (EX_MISMATCH);
 830     }
 831 }
 832
 833 static void
 834 gram_error (location const *loc, char const *msg)
 835 {
 836   complain (loc, complaint, "%s", msg);
 837 }
 838
 839 char const *
 840 token_name (int type)
 841 {
 842   return yytname[YYTRANSLATE (type)];
 843 }
 844
 845 static char const *
 846 char_name (char c)
 847 {
 848   if (c == '\'')
 849     return "'\\''";
 850   else
 851     {
 852       char buf[4];
 853       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 854       return quotearg_style (escape_quoting_style, buf);
 855     }
 856 }