data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ## ---------------- ##
  21 ## Identification.  ##
  22 ## ---------------- ##
  23
  24 # b4_copyright(TITLE, YEARS)
  25 # --------------------------
  26 m4_define([b4_copyright],
  27 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  28
  29 b4_comment([$1
  30
  31 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  32
  33 This program is free software: you can redistribute it and/or modify
  34 it under the terms of the GNU General Public License as published by
  35 the Free Software Foundation, either version 3 of the License, or
  36 (at your option) any later version.
  37
  38 This program is distributed in the hope that it will be useful,
  39 but WITHOUT ANY WARRANTY; without even the implied warranty of
  40 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  41 GNU General Public License for more details.
  42
  43 You should have received a copy of the GNU General Public License
  44 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  45
  46 b4_comment([As a special exception, you may create a larger work that contains
  47 part or all of the Bison parser skeleton and distribute that work
  48 under terms of your choice, so long as that work isn't itself a
  49 parser generator using the skeleton or a modified version thereof
  50 as a parser skeleton.  Alternatively, if you modify or redistribute
  51 the parser skeleton itself, you may (at your option) remove this
  52 special exception, which will cause the skeleton and the resulting
  53 Bison output files to be licensed under the GNU General Public
  54 License without this special exception.
  55
  56 This special exception was added by the Free Software Foundation in
  57 version 2.2 of Bison.])])
  58
  59
  60 ## ---------------- ##
  61 ## Error handling.  ##
  62 ## ---------------- ##
  63
  64 # The following error handling macros print error directives that should not
  65 # become arguments of other macro invocations since they would likely then be
  66 # mangled.  Thus, they print to stdout directly.
  67
  68 # b4_cat(TEXT)
  69 # ------------
  70 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  71 # escaped.  For example:
  72 #
  73 #   b4_cat([[@complain(invalid input@)]])
  74 m4_define([b4_cat],
  75 [m4_syscmd([cat <<'_m4eof'
  76 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  77 _m4eof])dnl
  78 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  79
  80 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  81 # -------------------------------------------
  82 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  83 #
  84 # For example:
  85 #
  86 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  87 m4_define([b4_error],
  88 [b4_cat([[@]$1[(]$2[]]dnl
  89 [m4_if([$#], [2], [],
  90        [m4_foreach([b4_arg],
  91                    m4_dquote(m4_shift(m4_shift($@))),
  92                    [[@,]b4_arg])])[@)]])])
  93
  94 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  95 # ----------------------------------------------------------
  96 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
  97 #
  98 # For example:
  99 #
 100 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 101 #               [[invalid %s]], [[foo]])
 102 m4_define([b4_error_at],
 103 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 104 [m4_if([$#], [4], [],
 105        [m4_foreach([b4_arg],
 106                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 107                    [[@,]b4_arg])])[@)]])])
 108
 109 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 110 # ------------------------------------
 111 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 112 #
 113 # For example:
 114 #
 115 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 116 #
 117 # As a simple test suite, this:
 118 #
 119 #   m4_divert(-1)
 120 #   m4_define([asdf], [ASDF])
 121 #   m4_define([fsa], [FSA])
 122 #   m4_define([fdsa], [FDSA])
 123 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 124 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 125 #   b4_warn()
 126 #   b4_warn(1)
 127 #   b4_warn(1, 2)
 128 #
 129 # Should produce this without newlines:
 130 #
 131 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 132 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 133 #   @warn(@)
 134 #   @warn(1@)
 135 #   @warn(1@,2@)
 136 m4_define([b4_warn],
 137 [b4_error([[warn]], $@)])
 138
 139 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 140 # ---------------------------------------------------
 141 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 142 #
 143 # For example:
 144 #
 145 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 146 m4_define([b4_warn_at],
 147 [b4_error_at([[warn]], $@)])
 148
 149 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 150 # ----------------------------------------
 151 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 152 #
 153 # See b4_warn example.
 154 m4_define([b4_complain],
 155 [b4_error([[complain]], $@)])
 156
 157 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 158 # -------------------------------------------------------
 159 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 160 #
 161 # See b4_warn_at example.
 162 m4_define([b4_complain_at],
 163 [b4_error_at([[complain]], $@)])
 164
 165 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 166 # -------------------------------------
 167 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 168 #
 169 # See b4_warn example.
 170 m4_define([b4_fatal],
 171 [b4_error([[fatal]], $@)dnl
 172 m4_exit(1)])
 173
 174 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 175 # ----------------------------------------------------
 176 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 177 #
 178 # See b4_warn_at example.
 179 m4_define([b4_fatal_at],
 180 [b4_error_at([[fatal]], $@)dnl
 181 m4_exit(1)])
 182
 183
 184 ## ---------------- ##
 185 ## Default values.  ##
 186 ## ---------------- ##
 187
 188 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 189 m4_define_default([b4_pre_prologue], [])
 190 m4_define_default([b4_post_prologue], [])
 191 m4_define_default([b4_epilogue], [])
 192 m4_define_default([b4_parse_param], [])
 193
 194 # The initial column and line.
 195 m4_define_default([b4_location_initial_column], [1])
 196 m4_define_default([b4_location_initial_line],   [1])
 197
 198
 199 ## ------------ ##
 200 ## Data Types.  ##
 201 ## ------------ ##
 202
 203 # b4_ints_in(INT1, INT2, LOW, HIGH)
 204 # ---------------------------------
 205 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 206 m4_define([b4_ints_in],
 207 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 208
 209
 210
 211 ## ------------------ ##
 212 ## Decoding options.  ##
 213 ## ------------------ ##
 214
 215 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 216 # -----------------------------------
 217 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 218 m4_define([b4_flag_if],
 219 [m4_case(b4_$1_flag,
 220          [0], [$3],
 221          [1], [$2],
 222          [m4_fatal([invalid $1 value: ]$1)])])
 223
 224
 225 # b4_define_flag_if(FLAG)
 226 # -----------------------
 227 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 228 # value of the Boolean FLAG.
 229 m4_define([b4_define_flag_if],
 230 [_b4_define_flag_if($[1], $[2], [$1])])
 231
 232 # _b4_define_flag_if($1, $2, FLAG)
 233 # --------------------------------
 234 # This macro works around the impossibility to define macros
 235 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 236 # This sucks hard, GNU M4 should really provide M5 like $$1.
 237 m4_define([_b4_define_flag_if],
 238 [m4_if([$1$2], $[1]$[2], [],
 239        [m4_fatal([$0: Invalid arguments: $@])])dnl
 240 m4_define([b4_$3_if],
 241           [b4_flag_if([$3], [$1], [$2])])])
 242
 243
 244 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 245 # -----------------------------
 246 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 247 b4_define_flag_if([defines])            # Whether headers are requested.
 248 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 249 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 250 b4_define_flag_if([locations])          # Whether locations are tracked.
 251 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 252 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 253
 254
 255 ## ------------------------- ##
 256 ## Assigning token numbers.  ##
 257 ## ------------------------- ##
 258
 259
 260 ## ----------- ##
 261 ## Synclines.  ##
 262 ## ----------- ##
 263
 264 # b4_basename(NAME)
 265 # -----------------
 266 # Similar to POSIX basename; the differences don't matter here.
 267 # Beware that NAME is not evaluated.
 268 m4_define([b4_basename],
 269 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 270
 271
 272 # b4_syncline(LINE, FILE)
 273 # -----------------------
 274 m4_define([b4_syncline],
 275 [b4_flag_if([synclines], [
 276 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 277 b4_sync_start([$1], [$2])])])
 278
 279 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 280 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 281
 282 # b4_user_code(USER-CODE)
 283 # -----------------------
 284 # Emit code from the user, ending it with synclines.
 285 m4_define([b4_user_code],
 286 [$1
 287 b4_syncline([@oline@], [@ofile@])])
 288
 289
 290 # b4_define_user_code(MACRO)
 291 # --------------------------
 292 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 293 m4_define([b4_define_user_code],
 294 [m4_define([b4_user_$1],
 295 [b4_user_code([b4_$1])])])
 296
 297
 298 # b4_user_actions
 299 # b4_user_initial_action
 300 # b4_user_post_prologue
 301 # b4_user_pre_prologue
 302 # b4_user_stype
 303 # ----------------------
 304 # Macros that issue user code, ending with synclines.
 305 b4_define_user_code([actions])
 306 b4_define_user_code([initial_action])
 307 b4_define_user_code([post_prologue])
 308 b4_define_user_code([pre_prologue])
 309 b4_define_user_code([stype])
 310
 311
 312 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 313 # --------------------------------------------------------
 314 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 315 # but is not used by Bison (as recorded by macros in the namespace
 316 # BISON-NAMESPACE).
 317 #
 318 # USER-LIST must expand to a list specifying all grammar occurrences of all
 319 # names of type WHAT.   Each item in the list must be a triplet specifying one
 320 # occurrence: name, start boundary, and end boundary.  Empty string names are
 321 # fine.  An empty list is fine.
 322 #
 323 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 324 # name occurrences and with correct quoting:
 325 #
 326 #   m4_define([b4_foo_user_names],
 327 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 328 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 329 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 330 #
 331 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 332 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 333 # are fine, but it would be ugly for Bison to actually use one.
 334 #
 335 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 336 # the names bar and baz are used by Bison:
 337 #
 338 #   m4_define([b4_foo_bison_names(bar)])
 339 #   m4_define([b4_foo_bison_names(baz)])
 340 #
 341 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 342 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 343 # quoting:
 344 #
 345 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 346 #                       [[b4_foo_bison_names]])
 347 m4_define([b4_check_user_names],
 348 [m4_foreach([b4_occurrence], $2,
 349 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 350 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 351 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 352 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 353 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 354           [b4_warn_at([b4_start], [b4_end],
 355                       [[%s `%s' is not used]],
 356                       [$1], [b4_user_name])])[]dnl
 357 m4_popdef([b4_occurrence])dnl
 358 m4_popdef([b4_user_name])dnl
 359 m4_popdef([b4_start])dnl
 360 m4_popdef([b4_end])dnl
 361 ])])
 362
 363 # b4_percent_define_get(VARIABLE)
 364 # -------------------------------
 365 # Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
 366 # the %define variable VARIABLE is defined, emit its value.  Also, record
 367 # Bison's usage of VARIABLE by defining
 368 # b4_percent_define_bison_variables(VARIABLE).
 369 #
 370 # For example:
 371 #
 372 #   b4_percent_define_get([[foo]])
 373 m4_define([b4_percent_define_get],
 374 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 375 m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
 376
 377 # b4_percent_define_get_loc(VARIABLE)
 378 # -----------------------------------
 379 # Mimic muscle_percent_define_get_loc in ../src/muscle_tab.h exactly.  That is,
 380 # if the %define variable VARIABLE is undefined, complain fatally since that's
 381 # a Bison or skeleton error.  Otherwise, return its definition location in a
 382 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 383 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 384 # reason to suspect that the user-supplied value has yet influenced the output.
 385 #
 386 # For example:
 387 #
 388 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 389 m4_define([b4_percent_define_get_loc],
 390 [m4_ifdef([b4_percent_define_loc(]$1[)],
 391           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 392 b4_loc[]dnl
 393 m4_popdef([b4_loc])],
 394           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 395
 396 # b4_percent_define_get_syncline(VARIABLE)
 397 # ----------------------------------------
 398 # Mimic muscle_percent_define_get_syncline in ../src/muscle_tab.h exactly.
 399 # That is, if the %define variable VARIABLE is undefined, complain fatally
 400 # since that's a Bison or skeleton error.  Otherwise, return its definition
 401 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 402 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 403 # influenced the output.
 404 #
 405 # For example:
 406 #
 407 #   b4_percent_define_get_syncline([[foo]])
 408 m4_define([b4_percent_define_get_syncline],
 409 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 410           [m4_indir([b4_percent_define_syncline(]$1[)])],
 411           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 412
 413 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 414 # ------------------------------------------------------
 415 # Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
 416 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 417 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 418 # b4_percent_define_bison_variables(VARIABLE).
 419 #
 420 # For example:
 421 #
 422 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 423 m4_define([b4_percent_define_ifdef],
 424 [m4_ifdef([b4_percent_define(]$1[)],
 425           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 426           [$3])])
 427
 428 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 429 # --------------------------------------------------------
 430 # Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
 431 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 432 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 433 # (a Bison or skeleton error since the default value should have been set
 434 # already) or defined to any other value (possibly a user error).  Also, record
 435 # Bison's usage of VARIABLE by defining
 436 # b4_percent_define_bison_variables(VARIABLE).
 437 #
 438 # For example:
 439 #
 440 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 441 m4_define([b4_percent_define_flag_if],
 442 [b4_percent_define_ifdef([$1],
 443   [m4_case(b4_percent_define_get([$1]),
 444            [], [$2], [true], [$2], [false], [$3],
 445            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 446                                            [[invalid value for %%define Boolean variable `%s']],
 447                                            [$1])],
 448                            [[b4_percent_define_flag_if($1)]])])],
 449   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 450
 451 # b4_percent_define_default(VARIABLE, DEFAULT)
 452 # --------------------------------------------
 453 # Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
 454 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 455 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 456 # suspect that the value has yet influenced the output.
 457 #
 458 # For example:
 459 #
 460 #   b4_percent_define_default([[foo]], [[default value]])
 461 m4_define([b4_percent_define_default],
 462 [m4_ifndef([b4_percent_define(]$1[)],
 463            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 464             m4_define([b4_percent_define_loc(]$1[)],
 465                       [[[[[Bison:b4_percent_define_default]:1.0]], [[[Bison:b4_percent_define_default]:1.0]]]])dnl
 466             m4_define([b4_percent_define_syncline(]$1[)],
 467                       [[]b4_syncline(1, [["[Bison:b4_percent_define_default]"]])[
 468 ]])])])
 469
 470 # b4_percent_define_check_values(VALUES)
 471 # --------------------------------------
 472 # Mimic muscle_percent_define_check_values in ../src/muscle_tab.h exactly
 473 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 474 # is a list of sublists of strings.  For each sublist, the first string is the
 475 # name of a %define variable, and all remaining strings in that sublist are the
 476 # valid values for that variable.  Complain if such a variable is undefined (a
 477 # Bison error since the default value should have been set already) or defined
 478 # to any other value (possibly a user error).  Don't record this as a Bison
 479 # usage of the variable as there's no reason to suspect that the value has yet
 480 # influenced the output.
 481 #
 482 # For example:
 483 #
 484 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 485 #                                  [[[[bar]], [[bar-value1]]]])
 486 m4_define([b4_percent_define_check_values],
 487 [m4_foreach([b4_sublist], m4_quote($@),
 488             [_b4_percent_define_check_values(b4_sublist)])])
 489
 490 m4_define([_b4_percent_define_check_values],
 491 [m4_ifdef([b4_percent_define(]$1[)],
 492   [m4_pushdef([b4_good_value], [0])dnl
 493    m4_if($#, 1, [],
 494          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 495                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 496                             [m4_define([b4_good_value], [1])])])])dnl
 497    m4_if(b4_good_value, [0],
 498          [b4_complain_at(b4_percent_define_get_loc([$1]),
 499                          [[invalid value for %%define variable `%s': `%s']],
 500                          [$1],
 501                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))])dnl
 502    m4_popdef([b4_good_value])],
 503   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 504
 505 # b4_percent_code_get([QUALIFIER])
 506 # --------------------------------
 507 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 508 # comment and ending with synclines and a newline.  If QUALIFIER is not
 509 # specified or empty, do this for the unqualified %code blocks.  Also, record
 510 # Bison's usage of QUALIFIER (if specified) by defining
 511 # b4_percent_code_bison_qualifiers(QUALIFIER).
 512 #
 513 # For example, to emit any unqualified %code blocks followed by any %code
 514 # blocks for the qualifier foo:
 515 #
 516 #   b4_percent_code_get
 517 #   b4_percent_code_get([[foo]])
 518 m4_define([b4_percent_code_get],
 519 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 520 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 521 m4_ifdef(b4_macro_name,
 522 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 523                    [[%code "]$1["]])[ blocks.]])
 524 b4_user_code([m4_indir(b4_macro_name)])
 525 ])dnl
 526 m4_popdef([b4_macro_name])])
 527
 528 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 529 # -----------------------------------------------------
 530 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 531 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 532 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 533 # b4_percent_code_bison_qualifiers(QUALIFIER).
 534 m4_define([b4_percent_code_ifdef],
 535 [m4_ifdef([b4_percent_code(]$1[)],
 536           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 537           [$3])])
 538
 539
 540 ## ----------------------------------------------------------- ##
 541 ## After processing the skeletons, check that all the user's   ##
 542 ## %define variables and %code qualifiers were used by Bison.  ##
 543 ## ----------------------------------------------------------- ##
 544
 545 m4_define([b4_check_user_names_wrap],
 546 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 547           [b4_check_user_names([[%]$1 $2],
 548                                [b4_percent_]$1[_user_]$2[s],
 549                                [[b4_percent_]$1[_bison_]$2[s]])])])
 550
 551 m4_wrap([
 552 b4_check_user_names_wrap([[define]], [[variable]])
 553 b4_check_user_names_wrap([[code]], [[qualifier]])
 554 ])