tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  41 # ------------------------------------------------
  42 # Don't interfere with caller's files.
  43 m4_divert_text([PREPARE_TESTS],
  44 [at_save_special_files ()
  45 {
  46   for at_save_file in stderr experr expout
  47   do
  48     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  49   done
  50 }
  51
  52 at_restore_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       mv at-bison-check-$at_save_file.bak $at_save_file
  58   done
  59 }
  60 ])
  61
  62 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  63 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  64
  65
  66
  67 ## ------------------------------- ##
  68 ## Macros decoding Bison options.  ##
  69 ## ------------------------------- ##
  70
  71 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  72 # ----------------------------------------------------------------
  73 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  74 m4_define([AT_LOC_PUSHDEF],
  75 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  76 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  77 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  78 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  79
  80 # AT_LOC_POPDEF
  81 # -------------
  82 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  83 m4_define([AT_LOC_POPDEF],
  84 [m4_popdef([AT_LOC_FIRST_LINE])
  85 m4_popdef([AT_LOC_FIRST_COLUMN])
  86 m4_popdef([AT_LOC_LAST_LINE])
  87 m4_popdef([AT_LOC_LAST_COLUMN])])
  88
  89
  90
  91 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  92 # -----------------------------------------
  93 m4_define([AT_BISON_OPTION_PUSHDEFS],
  94 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5-like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_GLR_IF],
 112 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 113 m4_pushdef([AT_LALR1_CC_IF],
 114 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 115 m4_pushdef([AT_GLR_CC_IF],
 116 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 117 # Using yacc.c?
 118 m4_pushdef([AT_YACC_IF],
 119 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 120 m4_pushdef([AT_LEXPARAM_IF],
 121 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 122 m4_pushdef([AT_LOCATION_IF],
 123 [m4_bmatch([$3], [%locations], [$1], [$2])])
 124 m4_pushdef([AT_LOCATION_TYPE_IF],
 125 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 126 m4_pushdef([AT_PARAM_IF],
 127 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 128 m4_pushdef([AT_PURE_IF],
 129 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 130            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 131            [$2])])
 132 m4_pushdef([AT_PURE_AND_LOC_IF],
 133 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 134 m4_pushdef([AT_GLR_OR_PARAM_IF],
 135 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 136 m4_pushdef([AT_NAME_PREFIX],
 137 [m4_bmatch([$3], [%name-prefix ".*"],
 138            [m4_bregexp([$3], [name-prefix "\([^""]*\)"], [\1])],
 139            [yy])])
 140 m4_pushdef([AT_API_PREFIX],
 141 [m4_bmatch([$3], [%define api\.prefix ".*"],
 142            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 143            [yy])])
 144 m4_pushdef([AT_TOKEN_PREFIX],
 145 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 146            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 147 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 148 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 149 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 150                     [$2])])
 151 # yyerror always sees the locations (when activated), except if
 152 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 153 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 154 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 155                                         [$1])],
 156                             [$1])],
 157                 [$2])])
 158
 159 # The interface is pure: either because %define api.pure, or because we
 160 # are using the C++ parsers.
 161 m4_pushdef([AT_PURE_LEX_IF],
 162 [AT_PURE_IF([$1],
 163             [AT_SKEL_CC_IF([$1], [$2])])])
 164
 165 AT_PURE_LEX_IF(
 166 [m4_pushdef([AT_LOC], [(*llocp)])
 167  m4_pushdef([AT_VAL], [(*lvalp)])
 168  m4_pushdef([AT_LEX_FORMALS],
 169             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 170  m4_pushdef([AT_LEX_ARGS],
 171             [lvalp[]AT_LOCATION_IF([, llocp])])
 172  m4_pushdef([AT_USE_LEX_ARGS],
 173             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 174  m4_pushdef([AT_LEX_PRE_FORMALS],
 175             [AT_LEX_FORMALS, ])
 176  m4_pushdef([AT_LEX_PRE_ARGS],
 177             [AT_LEX_ARGS, ])
 178 ],
 179 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 180  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 181  m4_pushdef([AT_LEX_FORMALS],     [void])
 182  m4_pushdef([AT_LEX_ARGS],        [])
 183  m4_pushdef([AT_USE_LEX_ARGS],    [])
 184  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 185  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 186 ])
 187
 188 # Handle the different types of location components.
 189
 190 AT_SKEL_CC_IF(
 191   [AT_LOCATION_TYPE_IF(
 192     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 193     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 194   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 195
 196
 197 AT_GLR_IF([AT_KEYWORDS([glr])])
 198 ])# _AT_BISON_OPTION_PUSHDEFS
 199
 200
 201 # AT_BISON_OPTION_POPDEFS
 202 # -----------------------
 203 m4_define([AT_BISON_OPTION_POPDEFS],
 204 [m4_popdef([AT_LEX_PRE_ARGS])
 205 m4_popdef([AT_LEX_PRE_FORMALS])
 206 m4_popdef([AT_USE_LEX_ARGS])
 207 m4_popdef([AT_LEX_ARGS])
 208 m4_popdef([AT_LEX_FORMALS])
 209 m4_popdef([AT_VAL])
 210 m4_popdef([AT_LOC])
 211 m4_popdef([AT_PURE_LEX_IF])
 212 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 213 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 214 m4_popdef([AT_API_PREFIX])
 215 m4_popdef([AT_NAME_PREFIX])
 216 m4_popdef([AT_GLR_OR_PARAM_IF])
 217 m4_popdef([AT_PURE_AND_LOC_IF])
 218 m4_popdef([AT_LOCATION_TYPE_IF])
 219 m4_popdef([AT_LOCATION_IF])
 220 m4_popdef([AT_PARAM_IF])
 221 m4_popdef([AT_LEXPARAM_IF])
 222 m4_popdef([AT_YACC_IF])
 223 m4_popdef([AT_GLR_IF])
 224 m4_popdef([AT_SKEL_CC_IF])
 225 m4_popdef([AT_SKEL_JAVA_IF])
 226 m4_popdef([AT_GLR_CC_IF])
 227 m4_popdef([AT_LALR1_CC_IF])
 228 m4_popdef([AT_DEFINES_IF])
 229 AT_LOC_POPDEF
 230 ])# AT_BISON_OPTION_POPDEFS
 231
 232
 233
 234 ## -------------------------- ##
 235 ## Generating Grammar Files.  ##
 236 ## -------------------------- ##
 237
 238 # AT_DATA_SOURCE_PROLOGUE
 239 # ------------------------
 240 # The prologue that should be included in any source code that is
 241 # meant to be compiled.
 242 m4_define([AT_DATA_SOURCE_PROLOGUE],
 243 [[#include <config.h>
 244 /* We don't need perfect functions for these tests. */
 245 #undef malloc
 246 #undef memcmp
 247 #undef realloc
 248 ]])
 249
 250 # AT_DATA_GRAMMAR_PROLOGUE
 251 # ------------------------
 252 # The prologue that should be included in any grammar which parser is
 253 # meant to be compiled.
 254 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 255 [[%code top {
 256 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 257 [}
 258 ]])
 259
 260 # AT_DATA_SOURCE(NAME, CONTENT)
 261 # -----------------------------
 262 # Generate the file NAME, which CONTENT is preceded by
 263 # AT_DATA_SOURCE_PROLOGUE.
 264 m4_define([AT_DATA_SOURCE],
 265 [AT_DATA([$1],
 266 [AT_DATA_SOURCE_PROLOGUE
 267 $2])
 268 ])
 269
 270 # AT_DATA_GRAMMAR(NAME, CONTENT)
 271 # ------------------------------
 272 # Generate the file NAME, which CONTENT is preceded by
 273 # AT_DATA_GRAMMAR_PROLOGUE.
 274 m4_define([AT_DATA_GRAMMAR],
 275 [AT_DATA([$1],
 276 [AT_DATA_GRAMMAR_PROLOGUE
 277 $2])
 278 ])
 279
 280 # AT_YYLEX_DECLARE_EXTERN
 281 # AT_YYLEX_DECLARE
 282 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 283 # ---------------------------------------
 284 m4_define([AT_YYLEX_DECLARE_EXTERN],
 285 [int AT_API_PREFIX[]lex (void);dnl
 286 ])
 287
 288 m4_define([AT_YYLEX_DECLARE],
 289 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 290 ])
 291
 292 m4_define([AT_YYLEX_DEFINE],
 293 [[#include <stdlib.h> /* abort */
 294 static int
 295 ]AT_API_PREFIX[lex (void)
 296 {
 297   static char const input[] = "$1";
 298   static size_t toknum = 0;
 299   int res;
 300   if (! (toknum < sizeof input))
 301     abort ();
 302   res = input[toknum++];
 303   ]$2;[]AT_LOCATION_IF([[
 304   ]AT_API_PREFIX[lloc.first_line = ]AT_API_PREFIX[lloc.last_line = 1;
 305   ]AT_API_PREFIX[lloc.first_column = ]AT_API_PREFIX[lloc.last_column = toknum;]])[
 306   return res;
 307 }]dnl
 308 ])
 309
 310 # AT_YYERROR_DECLARE_EXTERN
 311 # AT_YYERROR_DECLARE
 312 # AT_YYERROR_DEFINE
 313 # -------------------------
 314 # Beware that must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS
 315 # pair.
 316 m4_define([AT_YYERROR_DECLARE_EXTERN],
 317 [void AT_API_PREFIX[]error (const char *msg);dnl
 318 ])
 319
 320 m4_define([AT_YYERROR_DECLARE],
 321 [static AT_YYERROR_DECLARE_EXTERN[]dnl
 322 ])
 323
 324 m4_define([AT_YYERROR_DEFINE],
 325 [AT_SKEL_JAVA_IF([[public void yyerror (String msg)
 326 {
 327   System.err.println (msg);
 328 }]], [AT_SKEL_CC_IF([[void
 329 yy::parser::error (const yy::location &, std::string const &msg)
 330 {
 331   std::cerr << msg << std::endl;
 332 }]], [[#include <stdio.h>
 333 static void
 334 ]AT_API_PREFIX[error (char const *msg)
 335 {
 336   fprintf (stderr, "%s\n", msg);
 337 }]])])dnl
 338 ])
 339
 340 ## --------------- ##
 341 ## Running Bison.  ##
 342 ## --------------- ##
 343
 344 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 345 # -------------------------------------------------
 346 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 347 # shell constructs (such as redirection or pipes) that would prevent
 348 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 349 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 350 #
 351 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 352 # Bison in the test suite.  For now it ensures that:
 353 #
 354 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 355 #      a non-zero exit status since Bison doesn't always try to free all memory
 356 #      in that case.
 357 #
 358 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 359 #      --graph and --report=all output for every working grammar.
 360 #
 361 #   3. If stderr contains a warning, -Werror and --warnings=error
 362 #      convert the warning to an error.
 363 #
 364 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 365 m4_define([AT_BISON_CHECK],
 366 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 367        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 368 AT_BISON_CHECK_NO_XML($@)])
 369
 370 m4_define([AT_BISON_WERROR_MSG],
 371           [[bison: warnings being treated as errors]])
 372
 373 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 374 # --------------------------------------------------------
 375 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 376 # when a tortured grammar's XML is known to be too large for xsltproc to
 377 # handle.
 378 m4_define([AT_BISON_CHECK_NO_XML],
 379 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 380                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 381 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 382       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 383         # Defining POSIXLY_CORRECT causes bison to complain if options
 384         # are added after the grammar file name, so skip these checks
 385         # in that case.
 386         if test -z "${POSIXLY_CORRECT+set}"; then
 387           ]AT_SAVE_SPECIAL_FILES[
 388
 389           # To avoid expanding it repeatedly, store specified stdout.
 390           ]AT_DATA([expout], [$3])[
 391
 392           # Run with -Werror.
 393           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 394                     [[1]], [expout], [stderr])[
 395
 396           # Build expected stderr up to and including the "warnings being
 397           # treated as errors" message.
 398           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 399           at_bison_check_first=`sed -n \
 400             '/: warning: /{=;q;}' at-bison-check-warnings`
 401           : ${at_bison_check_first:=1}
 402           at_bison_check_first_tmp=`sed -n \
 403             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 404           : ${at_bison_check_first_tmp:=1}
 405           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 406             at_bison_check_first=$at_bison_check_first_tmp
 407           fi
 408           if test $at_bison_check_first -gt 1; then
 409             sed -n "1,`expr $at_bison_check_first - 1`"p \
 410               at-bison-check-warnings > experr
 411           fi
 412           echo ']AT_BISON_WERROR_MSG[' >> experr
 413
 414           # Finish building expected stderr and check.  Unlike warnings,
 415           # complaints cause bison to exit early.  Thus, with -Werror, bison
 416           # does not necessarily report all warnings that it does without
 417           # -Werror, but it at least reports one.
 418           at_bison_check_last=`sed -n '$=' stderr`
 419           : ${at_bison_check_last:=1}
 420           at_bison_check_last=`expr $at_bison_check_last - 1`
 421           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 422             at-bison-check-warnings >> experr
 423           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 424                       stderr 1>&2]], [[0]], [[]], [experr])[
 425
 426           # Now check --warnings=error.
 427           cp stderr experr
 428           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 429                     [[1]], [expout], [experr])[
 430
 431           # Now check -Wnone and --warnings=none by making sure that
 432           # -Werror doesn't change the exit status when -Wnone or
 433           # --warnings=none is specified.
 434           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 435                     [[0]], [expout])[
 436           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 437                     -Werror]], [[0]], [expout])[
 438
 439           ]AT_RESTORE_SPECIAL_FILES[
 440         fi
 441       ]])
 442 ])
 443
 444 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 445 # -----------------------------------------------------
 446 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 447 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 448 # have a non-zero exit status.
 449 m4_define([AT_BISON_CHECK_XML],
 450 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 451   AT_SAVE_SPECIAL_FILES
 452   [mkdir xml-tests]
 453   m4_pushdef([AT_BISON_ARGS],
 454              [m4_bpatsubsts([[$1]],
 455                             [--report(-file)?=[^][ ]*], [],
 456                             [--graph=[^][ ]*], [],
 457                             [--xml=[^][ ]*], [])])dnl
 458   # Don't combine these Bison invocations since we want to be sure that
 459   # --report=all isn't required to get the full XML file.
 460   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 461              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 462            [[0]], [ignore], [ignore])
 463   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 464            [[0]], [ignore], [ignore])
 465   m4_popdef([AT_BISON_ARGS])dnl
 466   [cp xml-tests/test.output expout]
 467   AT_CHECK([[$XSLTPROC \
 468              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 469              xml-tests/test.xml]], [[0]], [expout])
 470   [cp xml-tests/test.dot expout]
 471   AT_CHECK([[$XSLTPROC \
 472              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 473              xml-tests/test.xml]], [[0]], [expout])
 474   [rm -rf xml-tests expout]
 475   AT_RESTORE_SPECIAL_FILES
 476 [fi]])
 477
 478 # AT_QUELL_VALGRIND
 479 # -----------------
 480 # Put this before a Bison invocation to keep Valgrind from complaining about
 481 # reachable memory.
 482 #
 483 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 484 # The triple quoting below will cause test cases to fail if you do.  If you do
 485 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 486 # will then fail to shell-escape its contents when attempting to print them.
 487 # The testsuite verbose output, at least, will be incorrect, but nothing may
 488 # fail to make sure you notice.
 489 m4_define([AT_QUELL_VALGRIND],
 490 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 491
 492 ## ------------------------ ##
 493 ## Compiling C, C++ Files.  ##
 494 ## ------------------------ ##
 495
 496
 497 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 498 # ----------------------------------------
 499 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 500 # assume that we are linking too; this is a hack.
 501 m4_define([AT_COMPILE],
 502 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 503            0, [ignore], [ignore])])
 504
 505 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 506 # --------------------------------------------
 507 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 508 # assume that we are linking too; this is a hack.
 509 # If the C++ compiler does not work, ignore the test.
 510 m4_define([AT_COMPILE_CXX],
 511 [AT_KEYWORDS(c++)
 512 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 513 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 514          0, [ignore], [ignore])])
 515
 516 # AT_JAVA_COMPILE(SOURCES)
 517 # ------------------------
 518 # Compile SOURCES into Java class files.  Skip the test if java or javac
 519 # is not installed.
 520 m4_define([AT_JAVA_COMPILE],
 521 [AT_KEYWORDS(java)
 522 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 523            test -n "$CONF_JAVAC" || exit 77]])
 524 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 525          [[0]], [ignore], [ignore])])
 526
 527 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 528 # -------------------------------------------
 529 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 530 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 531 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 532 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 533 # AT_SKEL_JAVA_IF.
 534 m4_define([AT_FULL_COMPILE], [
 535   AT_SKEL_JAVA_IF([
 536     AT_BISON_CHECK([-o $1.java $1.y])
 537     AT_JAVA_COMPILE([$1.java],
 538                     m4_join([ ],
 539                             [$1.java],
 540                             m4_ifval($2, [[$1-$2.java]]),
 541                             m4_ifval($3, [[$1-$3.java]])))
 542   ], [
 543     AT_SKEL_CC_IF([
 544       AT_BISON_CHECK([-o $1.cc $1.y])
 545       AT_COMPILE_CXX([$1],
 546                      m4_join([ ],
 547                              [$1.cc],
 548                              m4_ifval($2, [[$1-$2.cc]]),
 549                              m4_ifval($3, [[$1-$3.cc]])))
 550     ], [
 551       AT_BISON_CHECK([-o $1.c $1.y])
 552       AT_COMPILE([$1],
 553                   m4_join([ ],
 554                           [$1.c],
 555                           m4_ifval($2, [[$1-$2.c]]),
 556                           m4_ifval($3, [[$1-$3.c]])))
 557     ])
 558   ])
 559 ])
 560
 561
 562 ## ---------------------------- ##
 563 ## Running a generated parser.  ##
 564 ## ---------------------------- ##
 565
 566
 567 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 568 # ------------------------------------------------------------
 569 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 570 #
 571 # Get rid of spurious messages when compiled with --coverage:
 572 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 573 m4_define([AT_PARSER_CHECK],
 574 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 575 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 576          [0], [], [$4])
 577 ])
 578
 579
 580 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 581 # -----------------------------------------------------------------
 582 m4_define([AT_JAVA_PARSER_CHECK],
 583 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 584
 585
 586 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 587 #                          DECLS, GRAMMAR, INPUT,
 588 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 589 #                          [OTHER-CHECKS],
 590 #                          [PARSER-EXIT-VALUE],
 591 #                          [PARSER-STDOUT], [PARSER-STDERR])
 592 # -------------------------------------------------------------
 593 # Using TITLE as the test group title, check the generated parser tables
 594 # and parser for a specified grammar file under a condition labeled by
 595 # COND-VALUE.
 596 #
 597 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 598 # recognized attribute is described below where it is relevant.
 599 #
 600 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 601 # the grammar file.  Insert basic yyerror, yylex, and main function
 602 # definitions as well.  Hardcode yylex to return the (possibly empty)
 603 # comma-delimited series of tokens in INPUT followed by token 0.
 604 #
 605 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 606 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 607 # On the bison command-line, specify `--report=all --defines'.  Check
 608 # that Bison exits with value 0, has no stdout, and has stderr
 609 # BISON-STDERR.
 610 #
 611 # If TEST-SPEC contains the attribute `last-state', check that the value
 612 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 613 # the grammar; in other words, check the number of states (minus one).
 614 # Otherwise, check that everything in the `.output' file starting with
 615 # the definition of state 0 is the same as the entire value of
 616 # TABLES-OR-LAST-STATE.
 617 #
 618 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 619 # `.output' file, which is named `input.output', and/or grammar file,
 620 # which is named `input.y'.
 621 #
 622 # Finally, compile the generated parser and then run it using
 623 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 624 # PARSER-STDERR as the 2nd-4th arguments.
 625 #
 626 # As a precondition, you must properly double-quote all arguments that
 627 # are to be interpreted as strings.
 628 #
 629 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 630 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 631 # first argument.  This is useful, for example, when wrapping multiple
 632 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 633 # condition, in another macro.
 634 #
 635 # For example:
 636 #
 637 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 638 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 639 #   # ---------------------------------------------------------------------
 640 #   m4_define([AT_TEST_SYNTAX_ERROR],
 641 #   [
 642 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 643 #                              [[last-state]],
 644 #                              [[%error-verbose ]$2], [$3], [$4],
 645 #                              [[]], [$5], [], [$6], [$7], [$8])
 646 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 647 #                              [[last-state]],
 648 #                              [$2], [$3], [$4],
 649 #                              [[]], [$5], [], [$6], [$7], [$8])
 650 #   ])
 651 #
 652 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 653 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 654 #                        [[3]],
 655 #                        [[1]], [[]],
 656 #                        [AT_COND_CASE([[no verbose]],
 657 #                                      [[syntax error
 658 #   ]],
 659 #                                      [[syntax error, unexpected 'b', expecting $end
 660 #   ]])])
 661 m4_define([AT_TEST_TABLES_AND_PARSE],
 662 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 663
 664 AT_SETUP([$1])
 665 AT_BISON_OPTION_PUSHDEFS([$4])
 666 AT_DATA_GRAMMAR([[input.y]],
 667 [[%code {
 668   #include <stdio.h>
 669   ]AT_YYERROR_DECLARE[
 670   ]AT_YYLEX_DECLARE[
 671 }
 672
 673 ]$4[
 674
 675 %%
 676
 677 ]$5[
 678
 679 %%
 680 ]AT_YYERROR_DEFINE[
 681 static int
 682 yylex (void)
 683 {
 684   static int const input[] = {
 685     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 686   };
 687   static int const *inputp = input;
 688   return *inputp++;
 689 }
 690
 691 int
 692 main (void)
 693 {
 694   return yyparse ();
 695 }
 696 ]])
 697
 698 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 699 # expanding macros, so it corrupts some special characters in the
 700 # macros.  To avoid this, expand now and pass it the result with proper
 701 # string quotation.  Assume args 7 through 12 expand to properly quoted
 702 # strings.
 703
 704 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 705       [AT_BISON_CHECK],
 706       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 707                                [0], [], m4_dquote($7))
 708
 709 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 710       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 711                 m4_dquote($8))],
 712       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 713                 m4_dquote($8)[[
 714 ]])])
 715
 716 $9
 717
 718 # Canonical LR generates very large tables, resulting in very long
 719 # files with #line directives that may overflow what the standards
 720 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 721 # will issue an error.
 722 #
 723 # There is no "" around `wc` since some indent the result.
 724 m4_bmatch([$4], [%define lr.type canonical-lr],
 725 [if test 32767 -lt `wc -l < input.c`; then
 726   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 727   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 728 fi])
 729 AT_COMPILE([[input]])
 730
 731 AT_PARSER_CHECK([[./input]],
 732                 m4_ifval([$10], [m4_dquote($10)]),
 733                 m4_ifval([$11], [m4_dquote($11)]),
 734                 m4_ifval([$12], [m4_dquote($12)]))
 735
 736 AT_BISON_OPTION_POPDEFS
 737 AT_CLEANUP
 738
 739 m4_popdef([AT_COND_CASE])])
 740
 741
 742
 743 ## ----------------------- ##
 744 ## Launch the test suite.  ##
 745 ## ----------------------- ##
 746
 747 AT_INIT
 748
 749 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 750 # options are processed, so we don't know the value of CXX and
 751 # CXXFLAGS yet.
 752 #
 753 # Note that it also means that command line values for CXX and
 754 # CXXFLAGS will not be propagated to CC and CFLAGS.
 755 AT_ARG_OPTION([compile-c-with-cxx],
 756               [compile C parsers with the C++ compiler])
 757
 758 AT_COLOR_TESTS
 759
 760 AT_TESTED([bison])