tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([$PERL -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       as_fn_error 1 "fatal error: back-up on top of a back-up"
  58     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  59   done
  60 }
  61
  62 at_restore_special_files ()
  63 {
  64   for at_save_file in stderr experr expout
  65   do
  66     test ! -f at-bison-check-$at_save_file.bak ||
  67       mv at-bison-check-$at_save_file.bak $at_save_file
  68   done
  69 }
  70 ])
  71
  72 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  73 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  74
  75
  76
  77 ## ------------------------------- ##
  78 ## Macros decoding Bison options.  ##
  79 ## ------------------------------- ##
  80
  81 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  82 # ----------------------------------------------------------------
  83 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  84 m4_define([AT_LOC_PUSHDEF],
  85 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  86 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  87 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  88 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  89
  90 # AT_LOC_POPDEF
  91 # -------------
  92 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  93 m4_define([AT_LOC_POPDEF],
  94 [m4_popdef([AT_LOC_FIRST_LINE])
  95 m4_popdef([AT_LOC_FIRST_COLUMN])
  96 m4_popdef([AT_LOC_LAST_LINE])
  97 m4_popdef([AT_LOC_LAST_COLUMN])])
  98
  99
 100
 101 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 102 # -----------------------------------------
 103 m4_define([AT_BISON_OPTION_PUSHDEFS],
 104 [m4_divert_text([KILL],
 105                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 106
 107
 108 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 109 # --------------------------------------------------
 110 # This macro works around the impossibility to define macros
 111 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 112 # This sucks hard, GNU M4 should really provide M5-like $$1.
 113 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 114 [m4_if([$1$2], $[1]$[2], [],
 115        [m4_fatal([$0: Invalid arguments: $@])])dnl
 116 m4_pushdef([AT_DEFINES_IF],
 117 [m4_bmatch([$3], [%defines], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_CC_IF],
 119 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 120 m4_pushdef([AT_SKEL_JAVA_IF],
 121 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 122 # The target language: "c", "c++", or "java".
 123 m4_pushdef([AT_LANG],
 124 [AT_SKEL_JAVA_IF([java],
 125                  [AT_SKEL_CC_IF([c++],
 126                                 [c])])])
 127 m4_pushdef([AT_GLR_IF],
 128 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 129 m4_pushdef([AT_LALR1_CC_IF],
 130 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 131 m4_pushdef([AT_GLR_CC_IF],
 132 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 133 # Using yacc.c?
 134 m4_pushdef([AT_YACC_IF],
 135 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 136 m4_pushdef([AT_LEXPARAM_IF],
 137 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 138 m4_pushdef([AT_LOCATION_IF],
 139 [m4_bmatch([$3], [%locations], [$1], [$2])])
 140 m4_pushdef([AT_LOCATION_TYPE_IF],
 141 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 142 m4_pushdef([AT_PARAM_IF],
 143 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 144 # Comma-terminated list of formals parse-parameters.
 145 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 146 # FIXME: Support grouped parse-param.
 147 m4_pushdef([AT_PARSE_PARAMS])
 148 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 149              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 150
 151 m4_pushdef([AT_PURE_IF],
 152 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 153            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 154            [$2])])
 155 m4_pushdef([AT_PURE_AND_LOC_IF],
 156 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 157 m4_pushdef([AT_GLR_OR_PARAM_IF],
 158 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 159 m4_pushdef([AT_NAME_PREFIX],
 160 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 161            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 162            [yy])])
 163 m4_pushdef([AT_TOKEN_CTOR_IF],
 164 [m4_bmatch([$3], [%define api.token.constructor], [$1], [$2])])
 165 m4_pushdef([AT_TOKEN_PREFIX],
 166 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 167            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 168 m4_pushdef([AT_API_prefix],
 169 [m4_bmatch([$3], [%define api\.prefix ".*"],
 170            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 171            [yy])])
 172 m4_pushdef([AT_API_PREFIX],
 173 [m4_toupper(AT_API_prefix)])
 174 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 175 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 176 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 177                     [$2])])
 178 # yyerror always sees the locations (when activated), except if
 179 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 180 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 181 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 182                                         [$1])],
 183                             [$1])],
 184                 [$2])])
 185
 186 # The interface is pure: either because %define api.pure, or because we
 187 # are using the C++ parsers.
 188 m4_pushdef([AT_PURE_LEX_IF],
 189 [AT_PURE_IF([$1],
 190             [AT_SKEL_CC_IF([$1], [$2])])])
 191
 192 m4_pushdef([AT_YYSTYPE],
 193 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 194                [AT_API_PREFIX[STYPE]])])
 195 m4_pushdef([AT_YYLTYPE],
 196 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 197                [AT_API_PREFIX[LTYPE]])])
 198
 199
 200 AT_PURE_LEX_IF(
 201 [m4_pushdef([AT_LOC], [(*llocp)])
 202  m4_pushdef([AT_VAL], [(*lvalp)])
 203  m4_pushdef([AT_YYLEX_FORMALS],
 204             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 205  m4_pushdef([AT_YYLEX_ARGS],
 206             [lvalp[]AT_LOCATION_IF([, llocp])])
 207  m4_pushdef([AT_USE_LEX_ARGS],
 208             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 209  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 210             [AT_YYLEX_FORMALS, ])
 211  m4_pushdef([AT_YYLEX_PRE_ARGS],
 212             [AT_YYLEX_ARGS, ])
 213 ],
 214 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 215  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 216  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 217  m4_pushdef([AT_YYLEX_ARGS],        [])
 218  m4_pushdef([AT_USE_LEX_ARGS],    [])
 219  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 220  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 221 ])
 222
 223 # Handle the different types of location components.
 224
 225 AT_SKEL_CC_IF(
 226   [AT_LOCATION_TYPE_IF(
 227     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 228     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 229   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 230
 231
 232 AT_GLR_IF([AT_KEYWORDS([glr])])
 233 ])# _AT_BISON_OPTION_PUSHDEFS
 234
 235
 236 # AT_BISON_OPTION_POPDEFS
 237 # -----------------------
 238 m4_define([AT_BISON_OPTION_POPDEFS],
 239 [m4_divert_text([KILL],
 240 [m4_popdef([AT_YYLEX_PRE_ARGS])
 241 m4_popdef([AT_YYLEX_PRE_FORMALS])
 242 m4_popdef([AT_USE_LEX_ARGS])
 243 m4_popdef([AT_YYLEX_ARGS])
 244 m4_popdef([AT_YYLEX_FORMALS])
 245 m4_popdef([AT_YYLTYPE])
 246 m4_popdef([AT_YYSTYPE])
 247 m4_popdef([AT_VAL])
 248 m4_popdef([AT_LOC])
 249 m4_popdef([AT_PURE_LEX_IF])
 250 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 251 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 252 m4_popdef([AT_API_PREFIX])
 253 m4_popdef([AT_API_prefix])
 254 m4_popdef([AT_TOKEN_PREFIX])
 255 m4_popdef([AT_TOKEN_CTOR_IF])
 256 m4_popdef([AT_NAME_PREFIX])
 257 m4_popdef([AT_GLR_OR_PARAM_IF])
 258 m4_popdef([AT_PURE_AND_LOC_IF])
 259 m4_popdef([AT_LOCATION_TYPE_IF])
 260 m4_popdef([AT_LOCATION_IF])
 261 m4_popdef([AT_PARSE_PARAMS])
 262 m4_popdef([AT_PARAM_IF])
 263 m4_popdef([AT_LEXPARAM_IF])
 264 m4_popdef([AT_YACC_IF])
 265 m4_popdef([AT_GLR_IF])
 266 m4_popdef([AT_SKEL_CC_IF])
 267 m4_popdef([AT_LANG])
 268 m4_popdef([AT_SKEL_JAVA_IF])
 269 m4_popdef([AT_GLR_CC_IF])
 270 m4_popdef([AT_LALR1_CC_IF])
 271 m4_popdef([AT_DEFINES_IF])
 272 AT_LOC_POPDEF])dnl
 273 ])# AT_BISON_OPTION_POPDEFS
 274
 275
 276
 277 ## -------------------------- ##
 278 ## Generating Grammar Files.  ##
 279 ## -------------------------- ##
 280
 281 # AT_DATA_SOURCE_PROLOGUE
 282 # ------------------------
 283 # The prologue that should be included in any source code that is
 284 # meant to be compiled.
 285 m4_define([AT_DATA_SOURCE_PROLOGUE],
 286 [[#include <config.h>
 287 /* We don't need perfect functions for these tests. */
 288 #undef malloc
 289 #undef memcmp
 290 #undef realloc
 291 ]])
 292
 293 # AT_DATA_GRAMMAR_PROLOGUE
 294 # ------------------------
 295 # The prologue that should be included in any grammar which parser is
 296 # meant to be compiled.
 297 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 298 [[%code top {
 299 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 300 [}
 301 ]])
 302
 303 # AT_DATA_SOURCE(NAME, CONTENT)
 304 # -----------------------------
 305 # Generate the file NAME, which CONTENT is preceded by
 306 # AT_DATA_SOURCE_PROLOGUE.
 307 m4_define([AT_DATA_SOURCE],
 308 [AT_DATA([$1],
 309 [AT_DATA_SOURCE_PROLOGUE
 310 $2])
 311 ])
 312
 313 # AT_DATA_GRAMMAR(NAME, CONTENT)
 314 # ------------------------------
 315 # Generate the file NAME, which CONTENT is preceded by
 316 # AT_DATA_GRAMMAR_PROLOGUE.
 317 m4_define([AT_DATA_GRAMMAR],
 318 [AT_DATA([$1],
 319 [AT_DATA_GRAMMAR_PROLOGUE
 320 $2])
 321 ])
 322
 323 # AT_YYLEX_PROTOTYPE
 324 # AT_YYLEX_DECLARE_EXTERN
 325 # AT_YYLEX_DECLARE
 326 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 327 # ----------------------------------
 328 # INPUT can be empty, or in double quotes, or a list (in braces).
 329 # ACTION may compute yylval for instance, using "res" as token type,
 330 # and "toknum" as the number of calls to yylex (starting at 0).
 331 m4_define([AT_YYLEX_PROTOTYPE],
 332 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 333 ])
 334
 335 m4_define([AT_YYLEX_DECLARE_EXTERN],
 336 [AT_YYLEX_PROTOTYPE;dnl
 337 ])
 338
 339 m4_define([AT_YYLEX_DECLARE],
 340 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 341 ])
 342
 343 m4_define([AT_YYLEX_DEFINE],
 344 [[#include <assert.h>
 345 static
 346 ]AT_YYLEX_PROTOTYPE[
 347 {
 348   ]m4_bmatch([$1], [^\(".*"\)?$],
 349              [[static char const input[] = ]m4_default([$1], [""])],
 350              [[static int const input[] = ]$1])[;
 351   static size_t toknum = 0;
 352   int res;
 353   ]AT_USE_LEX_ARGS[;
 354   assert (toknum < sizeof input / sizeof input[0]);
 355   res = input[toknum++];
 356   ]$2[;]AT_LOCATION_IF([[
 357   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 358   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 359   return res;
 360 }]dnl
 361 ])
 362
 363 # AT_YYERROR_PROTOTYPE
 364 # AT_YYERROR_DECLARE_EXTERN
 365 # AT_YYERROR_DECLARE
 366 # AT_YYERROR_DEFINE
 367 # -------------------------
 368 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 369 m4_define([AT_YYERROR_FORMALS],
 370 [m4_case(AT_LANG,
 371 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 372 ])
 373
 374 m4_define([AT_YYERROR_PROTOTYPE],
 375 [m4_case(AT_LANG,
 376 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 377 ])
 378
 379 m4_define([AT_YYERROR_DECLARE_EXTERN],
 380 [m4_case(AT_LANG,
 381 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 382 ])
 383
 384 m4_define([AT_YYERROR_DECLARE],
 385 [m4_case(AT_LANG,
 386 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 387 ])
 388
 389 m4_define([AT_YYERROR_DEFINE],
 390 [m4_case(AT_LANG,
 391 [c], [[#include <stdio.h>
 392 /* A C error reporting function.  */
 393 static
 394 ]AT_YYERROR_PROTOTYPE[
 395 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 396               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 397   YYUSE(\1);])dnl
 398 AT_YYERROR_SEES_LOC_IF([[
 399   YY_LOCATION_PRINT (stderr, ]AT_LOC[);
 400   fprintf (stderr, ": ");]])[
 401   fprintf (stderr, "%s\n", msg);
 402 }]],
 403 [c++], [[/* A C++ error reporting function.  */
 404 void
 405 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 406 {  std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 407 }]],
 408 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 409 {
 410     if (l == null)
 411       System.err.println (s);
 412     else
 413       System.err.println (l + ": " + s);
 414   }
 415 ]], [[
 416   public void yyerror (String s)
 417   {
 418     System.err.println (s);
 419   }]])],
 420 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 421 ])
 422
 423
 424 ## --------------- ##
 425 ## Running Bison.  ##
 426 ## --------------- ##
 427
 428 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 429 # -------------------------------------------------
 430 # High-level routine that may call bison several times, under different
 431 # conditions.
 432 #
 433 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 434 # shell constructs (such as redirection or pipes) that would prevent
 435 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 436 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 437 #
 438 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 439 # Bison in the test suite.  For now it ensures that:
 440 #
 441 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 442 #      a non-zero exit status since Bison doesn't always try to free all memory
 443 #      in that case.
 444 #
 445 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 446 #      --graph and --report=all output for every working grammar.
 447 #
 448 #   3. If stderr contains a warning, -Werror and --warnings=error
 449 #      convert the warning to an error.
 450 #
 451 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 452 m4_define([AT_BISON_CHECK],
 453 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 454 AT_BISON_CHECK_NO_XML($@)])
 455
 456 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 457 # --------------------------------------------------
 458 # Low-level macro to run bison once.
 459 m4_define([AT_BISON_CHECK_],
 460 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 461
 462
 463 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 464 # ----------------------------------------------------------
 465 # Check that warnings (if some are expected) are correctly
 466 # turned into errors with -Werror, etc.
 467 m4_define([AT_BISON_CHECK_WARNINGS],
 468 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 469       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 470
 471 m4_define([AT_BISON_CHECK_WARNINGS_],
 472 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 473 # added after the grammar file name, so skip these checks in that
 474 # case.
 475 #
 476 # Don't just check if $POSIXLY_CORRECT is set, as Bash, when launched
 477 # as /bin/sh, sets the shell variable POSIXLY_CORRECT to y, but not
 478 # the environment variable.
 479 if env | grep '^POSIXLY_CORRECT=' >/dev/null; then :; else
 480           ]AT_SAVE_SPECIAL_FILES[
 481
 482   # To avoid expanding it repeatedly, store specified stdout.
 483   ]AT_DATA([expout], [$3])[
 484
 485   # Run with -Werror.
 486   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 487
 488   # Build expected stderr up to and including the "warnings being
 489   # treated as errors" message.
 490   ]AT_DATA([[experr]], [$4])[
 491   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 492                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 493   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 494
 495   # Now check --warnings=error.
 496   cp stderr experr
 497   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 498
 499   # Now check -Wnone and --warnings=none by making sure that
 500   # -Werror doesn't change the exit status when -Wnone or
 501   # --warnings=none is specified.
 502   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 503   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 504
 505   ]AT_RESTORE_SPECIAL_FILES[
 506 fi]dnl
 507 ])
 508
 509 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 510 # --------------------------------------------------------
 511 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 512 # when a tortured grammar's XML is known to be too large for xsltproc to
 513 # handle.
 514 m4_define([AT_BISON_CHECK_NO_XML],
 515 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 516 AT_BISON_CHECK_WARNINGS($@)])
 517
 518 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 519 # -----------------------------------------------------
 520 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 521 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 522 # have a non-zero exit status.
 523 m4_define([AT_BISON_CHECK_XML],
 524 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 525   AT_SAVE_SPECIAL_FILES
 526   [mkdir xml-tests]
 527   m4_pushdef([AT_BISON_ARGS],
 528              [m4_bpatsubsts([[$1]],
 529                             [--report(-file)?=[^][ ]*], [],
 530                             [--graph=[^][ ]*], [],
 531                             [--xml=[^][ ]*], [])])dnl
 532   # Don't combine these Bison invocations since we want to be sure that
 533   # --report=all isn't required to get the full XML file.
 534   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 535              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 536            [[0]], [ignore], [ignore])
 537   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 538            [[0]], [ignore], [ignore])
 539   m4_popdef([AT_BISON_ARGS])dnl
 540   [cp xml-tests/test.output expout]
 541   AT_CHECK([[$XSLTPROC \
 542              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 543              xml-tests/test.xml]], [[0]], [expout])
 544   [cp xml-tests/test.dot expout]
 545   AT_CHECK([[$XSLTPROC \
 546              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 547              xml-tests/test.xml]], [[0]], [expout])
 548   [rm -rf xml-tests expout]
 549   AT_RESTORE_SPECIAL_FILES
 550 [fi]])
 551
 552 # AT_QUELL_VALGRIND
 553 # -----------------
 554 # Put this before a Bison invocation to keep Valgrind from complaining about
 555 # reachable memory.
 556 #
 557 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 558 # The triple quoting below will cause test cases to fail if you do.  If you do
 559 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 560 # will then fail to shell-escape its contents when attempting to print them.
 561 # The testsuite verbose output, at least, will be incorrect, but nothing may
 562 # fail to make sure you notice.
 563 m4_define([AT_QUELL_VALGRIND],
 564 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 565
 566
 567
 568 ## ------------------------ ##
 569 ## Compiling C, C++ Files.  ##
 570 ## ------------------------ ##
 571
 572
 573 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 574 # ----------------------------------------
 575 # Compile SOURCES into OUTPUT.
 576 #
 577 # If OUTPUT does not contain '.', assume that we are linking too,
 578 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 579 # with trailing .o removed, and ".c" appended.
 580 m4_define([AT_COMPILE],
 581 [AT_CHECK(m4_join([ ],
 582                   [$CC $CFLAGS $CPPFLAGS],
 583                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 584                   [-o $1],
 585                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 586                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 587            0, [ignore], [ignore])])
 588
 589 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 590 # ---------------------------------------------
 591 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 592 # ignore the test.
 593 #
 594 # If OUTPUT does not contain '.', assume that we are linking too,
 595 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 596 # with trailing .o removed, and ".cc" appended.
 597 m4_define([AT_COMPILE_CXX],
 598 [AT_KEYWORDS(c++)
 599 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 600 AT_CHECK(m4_join([ ],
 601                  [$CXX $CXXFLAGS $CPPFLAGS],
 602                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 603                  [-o $1],
 604                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 605                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 606          0, [ignore], [ignore])])
 607
 608 # AT_JAVA_COMPILE(SOURCES)
 609 # ------------------------
 610 # Compile SOURCES into Java class files.  Skip the test if java or javac
 611 # is not installed.
 612 m4_define([AT_JAVA_COMPILE],
 613 [AT_KEYWORDS(java)
 614 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 615 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 616 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 617          [[0]], [ignore], [ignore])])
 618
 619 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 620 # --------------------------------------------
 621 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 622 #
 623 # If OUTPUT does not contain '.', assume that we are linking too,
 624 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 625 # with trailing .o removed, and ".c"/".cc" appended.
 626 m4_define([AT_LANG_COMPILE],
 627 [m4_case(AT_LANG,
 628 [c],    [AT_COMPILE([$1], [$2])],
 629 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 630 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 631         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 632 ])
 633
 634 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 635 # -------------------------------------------
 636 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 637 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 638 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 639 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 640 # AT_SKEL_JAVA_IF.
 641 m4_define([AT_FULL_COMPILE],
 642 [m4_case(AT_LANG,
 643 [java],
 644   [AT_BISON_CHECK([-o $1.java $1.y])
 645    AT_LANG_COMPILE([$1],
 646                     m4_join([ ],
 647                             [$1.java],
 648                             m4_ifval($2, [[$1-$2.java]]),
 649                            m4_ifval($3, [[$1-$3.java]])))],
 650 [c++],
 651   [AT_BISON_CHECK([-o $1.cc $1.y])
 652    AT_LANG_COMPILE([$1],
 653                      m4_join([ ],
 654                              [$1.cc],
 655                              m4_ifval($2, [[$1-$2.cc]]),
 656                            m4_ifval($3, [[$1-$3.cc]])))],
 657 [c],
 658   [AT_BISON_CHECK([-o $1.c $1.y])
 659    AT_LANG_COMPILE([$1],
 660                   m4_join([ ],
 661                           [$1.c],
 662                           m4_ifval($2, [[$1-$2.c]]),
 663                            m4_ifval($3, [[$1-$3.c]])))])
 664 ])
 665
 666
 667
 668 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 669 # --------------------------------
 670 # Check that we can link together C and C++ objects.
 671 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 672 [AT_DATA([c-and-cxx.h],
 673 [[#ifdef __cplusplus
 674 extern "C"
 675 {
 676 #endif
 677   int fortytwo (void);
 678 #ifdef __cplusplus
 679 }
 680 #endif
 681 ]])
 682 AT_DATA([c-only.c],
 683 [[#include "c-and-cxx.h"
 684 int
 685 main (void)
 686 {
 687   return fortytwo () == 42 ? 0 : 1;
 688 }
 689 ]])
 690 AT_DATA([cxx-only.cc],
 691 [[#include "c-and-cxx.h"
 692 int fortytwo ()
 693 {
 694   return 42;
 695 }
 696 ]])
 697 AT_COMPILE([c-only.o], [c-only.c])
 698 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 699 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 700           exit 77], [ignore], [ignore])
 701 AT_CHECK([./c-and-cxx])
 702 ])
 703
 704
 705 ## ---------------------------- ##
 706 ## Running a generated parser.  ##
 707 ## ---------------------------- ##
 708
 709
 710 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 711 # ------------------------------------------------------------
 712 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 713 #
 714 # Get rid of spurious messages when compiled with --coverage:
 715 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 716 m4_define([AT_PARSER_CHECK],
 717 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 718 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 719          [0], [], [$4])
 720 ])
 721
 722
 723 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 724 # -----------------------------------------------------------------
 725 m4_define([AT_JAVA_PARSER_CHECK],
 726 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 727
 728
 729 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 730 #                          DECLS, GRAMMAR, INPUT,
 731 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 732 #                          [OTHER-CHECKS],
 733 #                          [PARSER-EXIT-VALUE],
 734 #                          [PARSER-STDOUT], [PARSER-STDERR])
 735 # -------------------------------------------------------------
 736 # Using TITLE as the test group title, check the generated parser tables
 737 # and parser for a specified grammar file under a condition labeled by
 738 # COND-VALUE.
 739 #
 740 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 741 # recognized attribute is described below where it is relevant.
 742 #
 743 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 744 # the grammar file.  Insert basic yyerror, yylex, and main function
 745 # definitions as well.  Hardcode yylex to return the (possibly empty)
 746 # comma-delimited series of tokens in INPUT followed by token 0.
 747 #
 748 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 749 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 750 # On the bison command-line, specify `--report=all --defines'.  Check
 751 # that Bison exits with value 0, has no stdout, and has stderr
 752 # BISON-STDERR.
 753 #
 754 # If TEST-SPEC contains the attribute `last-state', check that the value
 755 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 756 # the grammar; in other words, check the number of states (minus one).
 757 # Otherwise, check that everything in the `.output' file starting with
 758 # the definition of state 0 is the same as the entire value of
 759 # TABLES-OR-LAST-STATE.
 760 #
 761 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 762 # `.output' file, which is named `input.output', and/or grammar file,
 763 # which is named `input.y'.
 764 #
 765 # Finally, compile the generated parser and then run it using
 766 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 767 # PARSER-STDERR as the 2nd-4th arguments.
 768 #
 769 # As a precondition, you must properly double-quote all arguments that
 770 # are to be interpreted as strings.
 771 #
 772 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 773 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 774 # first argument.  This is useful, for example, when wrapping multiple
 775 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 776 # condition, in another macro.
 777 #
 778 # For example:
 779 #
 780 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 781 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 782 #   # ---------------------------------------------------------------------
 783 #   m4_define([AT_TEST_SYNTAX_ERROR],
 784 #   [
 785 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 786 #                              [[last-state]],
 787 #                              [[%error-verbose ]$2], [$3], [$4],
 788 #                              [[]], [$5], [], [$6], [$7], [$8])
 789 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 790 #                              [[last-state]],
 791 #                              [$2], [$3], [$4],
 792 #                              [[]], [$5], [], [$6], [$7], [$8])
 793 #   ])
 794 #
 795 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 796 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 797 #                        [[3]],
 798 #                        [[1]], [[]],
 799 #                        [AT_COND_CASE([[no verbose]],
 800 #                                      [[syntax error
 801 #   ]],
 802 #                                      [[syntax error, unexpected 'b', expecting $end
 803 #   ]])])
 804 m4_define([AT_TEST_TABLES_AND_PARSE],
 805 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 806
 807 AT_SETUP([$1])
 808 AT_BISON_OPTION_PUSHDEFS([$4])
 809 AT_DATA_GRAMMAR([[input.y]],
 810 [[%code {
 811   #include <stdio.h>
 812   ]AT_YYERROR_DECLARE[
 813   ]AT_YYLEX_DECLARE[
 814 }
 815
 816 ]$4[
 817
 818 %%
 819
 820 ]$5[
 821
 822 %%
 823 ]AT_YYERROR_DEFINE[
 824 static int
 825 yylex (void)
 826 {
 827   static int const input[] = {
 828     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 829   };
 830   static int const *inputp = input;
 831   return *inputp++;
 832 }
 833
 834 int
 835 main (void)
 836 {
 837   return yyparse ();
 838 }
 839 ]])
 840
 841 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 842 # expanding macros, so it corrupts some special characters in the
 843 # macros.  To avoid this, expand now and pass it the result with proper
 844 # string quotation.  Assume args 7 through 12 expand to properly quoted
 845 # strings.
 846
 847 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 848       [AT_BISON_CHECK],
 849       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 850                                [0], [], m4_dquote($7))
 851
 852 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 853       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 854                 m4_dquote($8))],
 855       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 856                 m4_dquote($8)[[
 857 ]])])
 858
 859 $9
 860
 861 # Canonical LR generates very large tables, resulting in very long
 862 # files with #line directives that may overflow what the standards
 863 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 864 # will issue an error.
 865 #
 866 # There is no "" around `wc` since some indent the result.
 867 m4_bmatch([$4], [%define lr.type canonical-lr],
 868 [if test 32767 -lt `wc -l < input.c`; then
 869   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 870   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 871 fi])
 872 AT_COMPILE([[input]])
 873
 874 AT_PARSER_CHECK([[./input]],
 875                 m4_ifval([$10], [m4_dquote($10)]),
 876                 m4_ifval([$11], [m4_dquote($11)]),
 877                 m4_ifval([$12], [m4_dquote($12)]))
 878
 879 AT_BISON_OPTION_POPDEFS
 880 AT_CLEANUP
 881
 882 m4_popdef([AT_COND_CASE])])
 883
 884
 885
 886 ## ----------------------- ##
 887 ## Launch the test suite.  ##
 888 ## ----------------------- ##
 889
 890 AT_INIT
 891
 892 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 893 # options are processed, so we don't know the value of CXX and
 894 # CXXFLAGS yet.
 895 #
 896 # Note that it also means that command line values for CXX and
 897 # CXXFLAGS will not be propagated to CC and CFLAGS.
 898 AT_ARG_OPTION([compile-c-with-cxx],
 899               [compile C parsers with the C++ compiler])
 900
 901 AT_COLOR_TESTS
 902
 903 AT_TESTED([bison])