tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([$PERL -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       as_fn_error 1 "fatal error: back-up on top of a back-up"
  58     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  59   done
  60 }
  61
  62 at_restore_special_files ()
  63 {
  64   for at_save_file in stderr experr expout
  65   do
  66     test ! -f at-bison-check-$at_save_file.bak ||
  67       mv at-bison-check-$at_save_file.bak $at_save_file
  68   done
  69 }
  70 ])
  71
  72 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  73 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  74
  75
  76
  77 ## ------------------------------- ##
  78 ## Macros decoding Bison options.  ##
  79 ## ------------------------------- ##
  80
  81 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  82 # ----------------------------------------------------------------
  83 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  84 m4_define([AT_LOC_PUSHDEF],
  85 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  86 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  87 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  88 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  89
  90 # AT_LOC_POPDEF
  91 # -------------
  92 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  93 m4_define([AT_LOC_POPDEF],
  94 [m4_popdef([AT_LOC_FIRST_LINE])
  95 m4_popdef([AT_LOC_FIRST_COLUMN])
  96 m4_popdef([AT_LOC_LAST_LINE])
  97 m4_popdef([AT_LOC_LAST_COLUMN])])
  98
  99
 100
 101 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 102 # -----------------------------------------
 103 m4_define([AT_BISON_OPTION_PUSHDEFS],
 104 [m4_divert_text([KILL],
 105                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 106
 107
 108 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 109 # --------------------------------------------------
 110 # This macro works around the impossibility to define macros
 111 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 112 # This sucks hard, GNU M4 should really provide M5-like $$1.
 113 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 114 [m4_if([$1$2], $[1]$[2], [],
 115        [m4_fatal([$0: Invalid arguments: $@])])dnl
 116 m4_pushdef([AT_DEFINES_IF],
 117 [m4_bmatch([$3], [%defines], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_CC_IF],
 119 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 120 m4_pushdef([AT_SKEL_JAVA_IF],
 121 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 122 m4_pushdef([AT_LANG],
 123 [AT_SKEL_JAVA_IF([java],
 124                  [AT_SKEL_CC_IF([c++],
 125                                 [c])])])
 126 m4_pushdef([AT_GLR_IF],
 127 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 128 m4_pushdef([AT_LALR1_CC_IF],
 129 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 130 m4_pushdef([AT_GLR_CC_IF],
 131 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 132 # Using yacc.c?
 133 m4_pushdef([AT_YACC_IF],
 134 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 135 m4_pushdef([AT_LEXPARAM_IF],
 136 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 137 m4_pushdef([AT_LOCATION_IF],
 138 [m4_bmatch([$3], [%locations], [$1], [$2])])
 139 m4_pushdef([AT_LOCATION_TYPE_IF],
 140 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 141 m4_pushdef([AT_PARAM_IF],
 142 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 143 m4_pushdef([AT_PURE_IF],
 144 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 145            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 146            [$2])])
 147 m4_pushdef([AT_PURE_AND_LOC_IF],
 148 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 149 m4_pushdef([AT_GLR_OR_PARAM_IF],
 150 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 151 m4_pushdef([AT_NAME_PREFIX],
 152 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 153            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 154            [yy])])
 155 m4_pushdef([AT_TOKEN_CTOR_IF],
 156 [m4_bmatch([$3], [%define api.token.constructor], [$1], [$2])])
 157 m4_pushdef([AT_TOKEN_PREFIX],
 158 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 159            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 160 m4_pushdef([AT_API_prefix],
 161 [m4_bmatch([$3], [%define api\.prefix ".*"],
 162            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 163            [yy])])
 164 m4_pushdef([AT_API_PREFIX],
 165 [m4_toupper(AT_API_prefix)])
 166 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 167 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 168 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 169                     [$2])])
 170 # yyerror always sees the locations (when activated), except if
 171 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 172 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 173 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 174                                         [$1])],
 175                             [$1])],
 176                 [$2])])
 177
 178 # The interface is pure: either because %define api.pure, or because we
 179 # are using the C++ parsers.
 180 m4_pushdef([AT_PURE_LEX_IF],
 181 [AT_PURE_IF([$1],
 182             [AT_SKEL_CC_IF([$1], [$2])])])
 183
 184 m4_pushdef([AT_YYSTYPE],
 185 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 186                [AT_API_PREFIX[STYPE]])])
 187 m4_pushdef([AT_YYLTYPE],
 188 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 189                [AT_API_PREFIX[LTYPE]])])
 190
 191
 192 AT_PURE_LEX_IF(
 193 [m4_pushdef([AT_LOC], [(*llocp)])
 194  m4_pushdef([AT_VAL], [(*lvalp)])
 195  m4_pushdef([AT_YYLEX_FORMALS],
 196             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 197  m4_pushdef([AT_YYLEX_ARGS],
 198             [lvalp[]AT_LOCATION_IF([, llocp])])
 199  m4_pushdef([AT_USE_LEX_ARGS],
 200             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 201  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 202             [AT_YYLEX_FORMALS, ])
 203  m4_pushdef([AT_YYLEX_PRE_ARGS],
 204             [AT_YYLEX_ARGS, ])
 205 ],
 206 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 207  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 208  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 209  m4_pushdef([AT_YYLEX_ARGS],        [])
 210  m4_pushdef([AT_USE_LEX_ARGS],    [])
 211  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 212  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 213 ])
 214
 215 # Handle the different types of location components.
 216
 217 AT_SKEL_CC_IF(
 218   [AT_LOCATION_TYPE_IF(
 219     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 220     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 221   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 222
 223
 224 AT_GLR_IF([AT_KEYWORDS([glr])])
 225 ])# _AT_BISON_OPTION_PUSHDEFS
 226
 227
 228 # AT_BISON_OPTION_POPDEFS
 229 # -----------------------
 230 m4_define([AT_BISON_OPTION_POPDEFS],
 231 [m4_divert_text([KILL],
 232 [m4_popdef([AT_YYLEX_PRE_ARGS])
 233 m4_popdef([AT_YYLEX_PRE_FORMALS])
 234 m4_popdef([AT_USE_LEX_ARGS])
 235 m4_popdef([AT_YYLEX_ARGS])
 236 m4_popdef([AT_YYLEX_FORMALS])
 237 m4_popdef([AT_YYLTYPE])
 238 m4_popdef([AT_YYSTYPE])
 239 m4_popdef([AT_VAL])
 240 m4_popdef([AT_LOC])
 241 m4_popdef([AT_PURE_LEX_IF])
 242 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 243 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 244 m4_popdef([AT_API_PREFIX])
 245 m4_popdef([AT_API_prefix])
 246 m4_popdef([AT_TOKEN_PREFIX])
 247 m4_popdef([AT_TOKEN_CTOR_IF])
 248 m4_popdef([AT_NAME_PREFIX])
 249 m4_popdef([AT_GLR_OR_PARAM_IF])
 250 m4_popdef([AT_PURE_AND_LOC_IF])
 251 m4_popdef([AT_LOCATION_TYPE_IF])
 252 m4_popdef([AT_LOCATION_IF])
 253 m4_popdef([AT_PARAM_IF])
 254 m4_popdef([AT_LEXPARAM_IF])
 255 m4_popdef([AT_YACC_IF])
 256 m4_popdef([AT_GLR_IF])
 257 m4_popdef([AT_SKEL_CC_IF])
 258 m4_popdef([AT_LANG])
 259 m4_popdef([AT_SKEL_JAVA_IF])
 260 m4_popdef([AT_GLR_CC_IF])
 261 m4_popdef([AT_LALR1_CC_IF])
 262 m4_popdef([AT_DEFINES_IF])
 263 AT_LOC_POPDEF])dnl
 264 ])# AT_BISON_OPTION_POPDEFS
 265
 266
 267
 268 ## -------------------------- ##
 269 ## Generating Grammar Files.  ##
 270 ## -------------------------- ##
 271
 272 # AT_DATA_SOURCE_PROLOGUE
 273 # ------------------------
 274 # The prologue that should be included in any source code that is
 275 # meant to be compiled.
 276 m4_define([AT_DATA_SOURCE_PROLOGUE],
 277 [[#include <config.h>
 278 /* We don't need perfect functions for these tests. */
 279 #undef malloc
 280 #undef memcmp
 281 #undef realloc
 282 ]])
 283
 284 # AT_DATA_GRAMMAR_PROLOGUE
 285 # ------------------------
 286 # The prologue that should be included in any grammar which parser is
 287 # meant to be compiled.
 288 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 289 [[%code top {
 290 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 291 [}
 292 ]])
 293
 294 # AT_DATA_SOURCE(NAME, CONTENT)
 295 # -----------------------------
 296 # Generate the file NAME, which CONTENT is preceded by
 297 # AT_DATA_SOURCE_PROLOGUE.
 298 m4_define([AT_DATA_SOURCE],
 299 [AT_DATA([$1],
 300 [AT_DATA_SOURCE_PROLOGUE
 301 $2])
 302 ])
 303
 304 # AT_DATA_GRAMMAR(NAME, CONTENT)
 305 # ------------------------------
 306 # Generate the file NAME, which CONTENT is preceded by
 307 # AT_DATA_GRAMMAR_PROLOGUE.
 308 m4_define([AT_DATA_GRAMMAR],
 309 [AT_DATA([$1],
 310 [AT_DATA_GRAMMAR_PROLOGUE
 311 $2])
 312 ])
 313
 314 # AT_YYLEX_PROTOTYPE
 315 # AT_YYLEX_DECLARE_EXTERN
 316 # AT_YYLEX_DECLARE
 317 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 318 # ----------------------------------
 319 # INPUT can be empty, or in double quotes, or a list (in braces).
 320 # ACTION may compute yylval for instance, using "res" as token type,
 321 # and "toknum" as the number of calls to yylex (starting at 0).
 322 m4_define([AT_YYLEX_PROTOTYPE],
 323 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 324 ])
 325
 326 m4_define([AT_YYLEX_DECLARE_EXTERN],
 327 [AT_YYLEX_PROTOTYPE;dnl
 328 ])
 329
 330 m4_define([AT_YYLEX_DECLARE],
 331 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 332 ])
 333
 334 m4_define([AT_YYLEX_DEFINE],
 335 [[#include <assert.h>
 336 static
 337 ]AT_YYLEX_PROTOTYPE[
 338 {
 339   ]m4_bmatch([$1], [^\(".*"\)?$],
 340              [[static char const input[] = ]m4_default([$1], [""])],
 341              [[static int const input[] = ]$1])[;
 342   static size_t toknum = 0;
 343   int res;
 344   ]AT_USE_LEX_ARGS[;
 345   assert (toknum < sizeof input / sizeof input[0]);
 346   res = input[toknum++];
 347   ]$2[;]AT_LOCATION_IF([[
 348   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 349   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 350   return res;
 351 }]dnl
 352 ])
 353
 354 # AT_YYERROR_PROTOTYPE
 355 # AT_YYERROR_DECLARE_EXTERN
 356 # AT_YYERROR_DECLARE
 357 # AT_YYERROR_DEFINE
 358 # -------------------------
 359 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 360 m4_define([AT_YYERROR_FORMALS],
 361 [m4_case(AT_LANG,
 362 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])[const char *msg]])[]dnl
 363 ])
 364
 365 m4_define([AT_YYERROR_PROTOTYPE],
 366 [m4_case(AT_LANG,
 367 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 368 ])
 369
 370 m4_define([AT_YYERROR_DECLARE_EXTERN],
 371 [m4_case(AT_LANG,
 372 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 373 ])
 374
 375 m4_define([AT_YYERROR_DECLARE],
 376 [m4_case(AT_LANG,
 377 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 378 ])
 379
 380 m4_define([AT_YYERROR_DEFINE],
 381 [m4_case(AT_LANG,
 382 [c], [[#include <stdio.h>
 383 /* A C error reporting function.  */
 384 static
 385 ]AT_YYERROR_PROTOTYPE[
 386 {
 387 ]AT_YYERROR_SEES_LOC_IF([[
 388   fprintf (stderr, "%d.%d",
 389            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 390   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 391     fprintf (stderr, "-%d.%d",
 392              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 393   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 394     fprintf (stderr, "-%d",
 395              ]AT_LOC_LAST_COLUMN[ - 1);
 396   fprintf (stderr, ": ");]])[
 397   fprintf (stderr, "%s\n", msg);
 398 }]],
 399 [c++], [[/* A C++ error reporting function.  */
 400 void
 401 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 402 {  std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 403 }]],
 404 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 405 {
 406     if (l == null)
 407       System.err.println (s);
 408     else
 409       System.err.println (l + ": " + s);
 410   }
 411 ]], [[
 412   public void yyerror (String s)
 413   {
 414     System.err.println (s);
 415   }]])],
 416 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 417 ])
 418
 419
 420 ## --------------- ##
 421 ## Running Bison.  ##
 422 ## --------------- ##
 423
 424 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 425 # -------------------------------------------------
 426 # High-level routine that may call bison several times, under different
 427 # conditions.
 428 #
 429 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 430 # shell constructs (such as redirection or pipes) that would prevent
 431 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 432 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 433 #
 434 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 435 # Bison in the test suite.  For now it ensures that:
 436 #
 437 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 438 #      a non-zero exit status since Bison doesn't always try to free all memory
 439 #      in that case.
 440 #
 441 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 442 #      --graph and --report=all output for every working grammar.
 443 #
 444 #   3. If stderr contains a warning, -Werror and --warnings=error
 445 #      convert the warning to an error.
 446 #
 447 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 448 m4_define([AT_BISON_CHECK],
 449 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 450 AT_BISON_CHECK_NO_XML($@)])
 451
 452 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 453 # --------------------------------------------------
 454 # Low-level macro to run bison once.
 455 m4_define([AT_BISON_CHECK_],
 456 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 457
 458
 459 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 460 # ----------------------------------------------------------
 461 # Check that warnings (if some are expected) are correctly
 462 # turned into errors with -Werror, etc.
 463 m4_define([AT_BISON_CHECK_WARNINGS],
 464 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 465       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 466
 467 m4_define([AT_BISON_CHECK_WARNINGS_],
 468 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 469 # added after the grammar file name, so skip these checks in that
 470 # case.
 471 #
 472 # Don't just check if $POSIXLY_CORRECT is set, as Bash, when launched
 473 # as /bin/sh, sets the shell variable POSIXLY_CORRECT to y, but not
 474 # the environment variable.
 475 if env | grep '^POSIXLY_CORRECT=' >/dev/null; then :; else
 476           ]AT_SAVE_SPECIAL_FILES[
 477
 478   # To avoid expanding it repeatedly, store specified stdout.
 479   ]AT_DATA([expout], [$3])[
 480
 481   # Run with -Werror.
 482   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 483
 484   # Build expected stderr up to and including the "warnings being
 485   # treated as errors" message.
 486   ]AT_DATA([[experr]], [$4])[
 487   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 488                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 489   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 490
 491   # Now check --warnings=error.
 492   cp stderr experr
 493   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 494
 495   # Now check -Wnone and --warnings=none by making sure that
 496   # -Werror doesn't change the exit status when -Wnone or
 497   # --warnings=none is specified.
 498   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 499   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 500
 501   ]AT_RESTORE_SPECIAL_FILES[
 502 fi]dnl
 503 ])
 504
 505 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 506 # --------------------------------------------------------
 507 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 508 # when a tortured grammar's XML is known to be too large for xsltproc to
 509 # handle.
 510 m4_define([AT_BISON_CHECK_NO_XML],
 511 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 512 AT_BISON_CHECK_WARNINGS($@)])
 513
 514 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 515 # -----------------------------------------------------
 516 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 517 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 518 # have a non-zero exit status.
 519 m4_define([AT_BISON_CHECK_XML],
 520 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 521   AT_SAVE_SPECIAL_FILES
 522   [mkdir xml-tests]
 523   m4_pushdef([AT_BISON_ARGS],
 524              [m4_bpatsubsts([[$1]],
 525                             [--report(-file)?=[^][ ]*], [],
 526                             [--graph=[^][ ]*], [],
 527                             [--xml=[^][ ]*], [])])dnl
 528   # Don't combine these Bison invocations since we want to be sure that
 529   # --report=all isn't required to get the full XML file.
 530   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 531              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 532            [[0]], [ignore], [ignore])
 533   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 534            [[0]], [ignore], [ignore])
 535   m4_popdef([AT_BISON_ARGS])dnl
 536   [cp xml-tests/test.output expout]
 537   AT_CHECK([[$XSLTPROC \
 538              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 539              xml-tests/test.xml]], [[0]], [expout])
 540   [cp xml-tests/test.dot expout]
 541   AT_CHECK([[$XSLTPROC \
 542              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 543              xml-tests/test.xml]], [[0]], [expout])
 544   [rm -rf xml-tests expout]
 545   AT_RESTORE_SPECIAL_FILES
 546 [fi]])
 547
 548 # AT_QUELL_VALGRIND
 549 # -----------------
 550 # Put this before a Bison invocation to keep Valgrind from complaining about
 551 # reachable memory.
 552 #
 553 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 554 # The triple quoting below will cause test cases to fail if you do.  If you do
 555 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 556 # will then fail to shell-escape its contents when attempting to print them.
 557 # The testsuite verbose output, at least, will be incorrect, but nothing may
 558 # fail to make sure you notice.
 559 m4_define([AT_QUELL_VALGRIND],
 560 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 561
 562
 563
 564 ## ------------------------ ##
 565 ## Compiling C, C++ Files.  ##
 566 ## ------------------------ ##
 567
 568
 569 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 570 # ----------------------------------------
 571 # Compile SOURCES into OUTPUT.
 572 #
 573 # If OUTPUT does not contain '.', assume that we are linking too,
 574 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 575 # with trailing .o removed, and ".c" appended.
 576 m4_define([AT_COMPILE],
 577 [AT_CHECK(m4_join([ ],
 578                   [$CC $CFLAGS $CPPFLAGS],
 579                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 580                   [-o $1],
 581                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 582                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 583            0, [ignore], [ignore])])
 584
 585 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 586 # ---------------------------------------------
 587 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 588 # ignore the test.
 589 #
 590 # If OUTPUT does not contain '.', assume that we are linking too,
 591 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 592 # with trailing .o removed, and ".cc" appended.
 593 m4_define([AT_COMPILE_CXX],
 594 [AT_KEYWORDS(c++)
 595 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 596 AT_CHECK(m4_join([ ],
 597                  [$CXX $CXXFLAGS $CPPFLAGS],
 598                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 599                  [-o $1],
 600                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 601                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 602          0, [ignore], [ignore])])
 603
 604 # AT_JAVA_COMPILE(SOURCES)
 605 # ------------------------
 606 # Compile SOURCES into Java class files.  Skip the test if java or javac
 607 # is not installed.
 608 m4_define([AT_JAVA_COMPILE],
 609 [AT_KEYWORDS(java)
 610 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 611 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 612 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 613          [[0]], [ignore], [ignore])])
 614
 615 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 616 # --------------------------------------------
 617 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 618 #
 619 # If OUTPUT does not contain '.', assume that we are linking too,
 620 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 621 # with trailing .o removed, and ".c"/".cc" appended.
 622 m4_define([AT_LANG_COMPILE],
 623 [m4_case(AT_LANG,
 624 [c],    [AT_COMPILE([$1], [$2])],
 625 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 626 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 627         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 628 ])
 629
 630 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 631 # -------------------------------------------
 632 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 633 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 634 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 635 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 636 # AT_SKEL_JAVA_IF.
 637 m4_define([AT_FULL_COMPILE],
 638 [m4_case(AT_LANG,
 639 [java],
 640   [AT_BISON_CHECK([-o $1.java $1.y])
 641    AT_LANG_COMPILE([$1],
 642                     m4_join([ ],
 643                             [$1.java],
 644                             m4_ifval($2, [[$1-$2.java]]),
 645                            m4_ifval($3, [[$1-$3.java]])))],
 646 [c++],
 647   [AT_BISON_CHECK([-o $1.cc $1.y])
 648    AT_LANG_COMPILE([$1],
 649                      m4_join([ ],
 650                              [$1.cc],
 651                              m4_ifval($2, [[$1-$2.cc]]),
 652                            m4_ifval($3, [[$1-$3.cc]])))],
 653 [c],
 654   [AT_BISON_CHECK([-o $1.c $1.y])
 655    AT_LANG_COMPILE([$1],
 656                   m4_join([ ],
 657                           [$1.c],
 658                           m4_ifval($2, [[$1-$2.c]]),
 659                            m4_ifval($3, [[$1-$3.c]])))])
 660 ])
 661
 662
 663 ## ---------------------------- ##
 664 ## Running a generated parser.  ##
 665 ## ---------------------------- ##
 666
 667
 668 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 669 # ------------------------------------------------------------
 670 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 671 #
 672 # Get rid of spurious messages when compiled with --coverage:
 673 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 674 m4_define([AT_PARSER_CHECK],
 675 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 676 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 677          [0], [], [$4])
 678 ])
 679
 680
 681 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 682 # -----------------------------------------------------------------
 683 m4_define([AT_JAVA_PARSER_CHECK],
 684 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 685
 686
 687 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 688 #                          DECLS, GRAMMAR, INPUT,
 689 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 690 #                          [OTHER-CHECKS],
 691 #                          [PARSER-EXIT-VALUE],
 692 #                          [PARSER-STDOUT], [PARSER-STDERR])
 693 # -------------------------------------------------------------
 694 # Using TITLE as the test group title, check the generated parser tables
 695 # and parser for a specified grammar file under a condition labeled by
 696 # COND-VALUE.
 697 #
 698 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 699 # recognized attribute is described below where it is relevant.
 700 #
 701 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 702 # the grammar file.  Insert basic yyerror, yylex, and main function
 703 # definitions as well.  Hardcode yylex to return the (possibly empty)
 704 # comma-delimited series of tokens in INPUT followed by token 0.
 705 #
 706 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 707 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 708 # On the bison command-line, specify `--report=all --defines'.  Check
 709 # that Bison exits with value 0, has no stdout, and has stderr
 710 # BISON-STDERR.
 711 #
 712 # If TEST-SPEC contains the attribute `last-state', check that the value
 713 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 714 # the grammar; in other words, check the number of states (minus one).
 715 # Otherwise, check that everything in the `.output' file starting with
 716 # the definition of state 0 is the same as the entire value of
 717 # TABLES-OR-LAST-STATE.
 718 #
 719 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 720 # `.output' file, which is named `input.output', and/or grammar file,
 721 # which is named `input.y'.
 722 #
 723 # Finally, compile the generated parser and then run it using
 724 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 725 # PARSER-STDERR as the 2nd-4th arguments.
 726 #
 727 # As a precondition, you must properly double-quote all arguments that
 728 # are to be interpreted as strings.
 729 #
 730 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 731 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 732 # first argument.  This is useful, for example, when wrapping multiple
 733 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 734 # condition, in another macro.
 735 #
 736 # For example:
 737 #
 738 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 739 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 740 #   # ---------------------------------------------------------------------
 741 #   m4_define([AT_TEST_SYNTAX_ERROR],
 742 #   [
 743 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 744 #                              [[last-state]],
 745 #                              [[%error-verbose ]$2], [$3], [$4],
 746 #                              [[]], [$5], [], [$6], [$7], [$8])
 747 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 748 #                              [[last-state]],
 749 #                              [$2], [$3], [$4],
 750 #                              [[]], [$5], [], [$6], [$7], [$8])
 751 #   ])
 752 #
 753 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 754 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 755 #                        [[3]],
 756 #                        [[1]], [[]],
 757 #                        [AT_COND_CASE([[no verbose]],
 758 #                                      [[syntax error
 759 #   ]],
 760 #                                      [[syntax error, unexpected 'b', expecting $end
 761 #   ]])])
 762 m4_define([AT_TEST_TABLES_AND_PARSE],
 763 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 764
 765 AT_SETUP([$1])
 766 AT_BISON_OPTION_PUSHDEFS([$4])
 767 AT_DATA_GRAMMAR([[input.y]],
 768 [[%code {
 769   #include <stdio.h>
 770   ]AT_YYERROR_DECLARE[
 771   ]AT_YYLEX_DECLARE[
 772 }
 773
 774 ]$4[
 775
 776 %%
 777
 778 ]$5[
 779
 780 %%
 781 ]AT_YYERROR_DEFINE[
 782 static int
 783 yylex (void)
 784 {
 785   static int const input[] = {
 786     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 787   };
 788   static int const *inputp = input;
 789   return *inputp++;
 790 }
 791
 792 int
 793 main (void)
 794 {
 795   return yyparse ();
 796 }
 797 ]])
 798
 799 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 800 # expanding macros, so it corrupts some special characters in the
 801 # macros.  To avoid this, expand now and pass it the result with proper
 802 # string quotation.  Assume args 7 through 12 expand to properly quoted
 803 # strings.
 804
 805 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 806       [AT_BISON_CHECK],
 807       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 808                                [0], [], m4_dquote($7))
 809
 810 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 811       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 812                 m4_dquote($8))],
 813       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 814                 m4_dquote($8)[[
 815 ]])])
 816
 817 $9
 818
 819 # Canonical LR generates very large tables, resulting in very long
 820 # files with #line directives that may overflow what the standards
 821 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 822 # will issue an error.
 823 #
 824 # There is no "" around `wc` since some indent the result.
 825 m4_bmatch([$4], [%define lr.type canonical-lr],
 826 [if test 32767 -lt `wc -l < input.c`; then
 827   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 828   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 829 fi])
 830 AT_COMPILE([[input]])
 831
 832 AT_PARSER_CHECK([[./input]],
 833                 m4_ifval([$10], [m4_dquote($10)]),
 834                 m4_ifval([$11], [m4_dquote($11)]),
 835                 m4_ifval([$12], [m4_dquote($12)]))
 836
 837 AT_BISON_OPTION_POPDEFS
 838 AT_CLEANUP
 839
 840 m4_popdef([AT_COND_CASE])])
 841
 842
 843
 844 ## ----------------------- ##
 845 ## Launch the test suite.  ##
 846 ## ----------------------- ##
 847
 848 AT_INIT
 849
 850 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 851 # options are processed, so we don't know the value of CXX and
 852 # CXXFLAGS yet.
 853 #
 854 # Note that it also means that command line values for CXX and
 855 # CXXFLAGS will not be propagated to CC and CFLAGS.
 856 AT_ARG_OPTION([compile-c-with-cxx],
 857               [compile C parsers with the C++ compiler])
 858
 859 AT_COLOR_TESTS
 860
 861 AT_TESTED([bison])