tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  41 # ------------------------------------------------
  42 # Don't interfere with caller's files.
  43 m4_divert_text([PREPARE_TESTS],
  44 [at_save_special_files ()
  45 {
  46   for at_save_file in stderr experr expout
  47   do
  48     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  49   done
  50 }
  51
  52 at_restore_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f at-bison-check-$at_save_file.bak ||
  57       mv at-bison-check-$at_save_file.bak $at_save_file
  58   done
  59 }
  60 ])
  61
  62 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  63 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  64
  65
  66
  67 ## ------------------------------- ##
  68 ## Macros decoding Bison options.  ##
  69 ## ------------------------------- ##
  70
  71 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  72 # ----------------------------------------------------------------
  73 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  74 m4_define([AT_LOC_PUSHDEF],
  75 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  76 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  77 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  78 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  79
  80 # AT_LOC_POPDEF
  81 # -------------
  82 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  83 m4_define([AT_LOC_POPDEF],
  84 [m4_popdef([AT_LOC_FIRST_LINE])
  85 m4_popdef([AT_LOC_FIRST_COLUMN])
  86 m4_popdef([AT_LOC_LAST_LINE])
  87 m4_popdef([AT_LOC_LAST_COLUMN])])
  88
  89
  90
  91 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  92 # -----------------------------------------
  93 m4_define([AT_BISON_OPTION_PUSHDEFS],
  94 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  95
  96
  97 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  98 # --------------------------------------------------
  99 # This macro works around the impossibility to define macros
 100 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 101 # This sucks hard, GNU M4 should really provide M5 like $$1.
 102 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 103 [m4_if([$1$2], $[1]$[2], [],
 104        [m4_fatal([$0: Invalid arguments: $@])])dnl
 105 m4_pushdef([AT_DEFINES_IF],
 106 [m4_bmatch([$3], [%defines], [$1], [$2])])
 107 m4_pushdef([AT_SKEL_CC_IF],
 108 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 109 m4_pushdef([AT_SKEL_JAVA_IF],
 110 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 111 m4_pushdef([AT_GLR_IF],
 112 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 113 m4_pushdef([AT_LALR1_CC_IF],
 114 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 115 m4_pushdef([AT_GLR_CC_IF],
 116 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 117 # Using yacc.c?
 118 m4_pushdef([AT_YACC_IF],
 119 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 120 m4_pushdef([AT_LEXPARAM_IF],
 121 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 122 m4_pushdef([AT_LOCATION_IF],
 123 [m4_bmatch([$3], [%locations], [$1], [$2])])
 124 m4_pushdef([AT_LOCATION_TYPE_IF],
 125 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 126 m4_pushdef([AT_PARAM_IF],
 127 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 128 m4_pushdef([AT_PURE_IF],
 129 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 130            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 131            [$2])])
 132 m4_pushdef([AT_PURE_AND_LOC_IF],
 133 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 134 m4_pushdef([AT_GLR_OR_PARAM_IF],
 135 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 136 m4_pushdef([AT_NAME_PREFIX],
 137 [m4_bmatch([$3], [%name-prefix ".*"],
 138            [m4_bregexp([$3], [name-prefix "\([^""]*\)"], [\1])],
 139            [yy])])
 140 m4_pushdef([AT_API_PREFIX],
 141 [m4_bmatch([$3], [%define api\.prefix ".*"],
 142            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 143            [yy])])
 144 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 145 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 146 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 147                     [$2])])
 148 # yyerror always sees the locations (when activated), except if
 149 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 150 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 151 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 152                                         [$1])],
 153                             [$1])],
 154                 [$2])])
 155
 156 # The interface is pure: either because %define api.pure, or because we
 157 # are using the C++ parsers.
 158 m4_pushdef([AT_PURE_LEX_IF],
 159 [AT_PURE_IF([$1],
 160             [AT_SKEL_CC_IF([$1], [$2])])])
 161
 162 AT_PURE_LEX_IF(
 163 [m4_pushdef([AT_LOC], [(*llocp)])
 164  m4_pushdef([AT_VAL], [(*lvalp)])
 165  m4_pushdef([AT_LEX_FORMALS],
 166             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 167  m4_pushdef([AT_LEX_ARGS],
 168             [lvalp[]AT_LOCATION_IF([, llocp])])
 169  m4_pushdef([AT_USE_LEX_ARGS],
 170             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 171  m4_pushdef([AT_LEX_PRE_FORMALS],
 172             [AT_LEX_FORMALS, ])
 173  m4_pushdef([AT_LEX_PRE_ARGS],
 174             [AT_LEX_ARGS, ])
 175 ],
 176 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 177  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 178  m4_pushdef([AT_LEX_FORMALS],     [void])
 179  m4_pushdef([AT_LEX_ARGS],        [])
 180  m4_pushdef([AT_USE_LEX_ARGS],    [])
 181  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 182  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 183 ])
 184
 185 # Handle the different types of location components.
 186
 187 AT_SKEL_CC_IF(
 188   [AT_LOCATION_TYPE_IF(
 189     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 190     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 191   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 192
 193 ])# _AT_BISON_OPTION_PUSHDEFS
 194
 195
 196 # AT_BISON_OPTION_POPDEFS
 197 # -----------------------
 198 m4_define([AT_BISON_OPTION_POPDEFS],
 199 [m4_popdef([AT_LEX_PRE_ARGS])
 200 m4_popdef([AT_LEX_PRE_FORMALS])
 201 m4_popdef([AT_USE_LEX_ARGS])
 202 m4_popdef([AT_LEX_ARGS])
 203 m4_popdef([AT_LEX_FORMALS])
 204 m4_popdef([AT_VAL])
 205 m4_popdef([AT_LOC])
 206 m4_popdef([AT_PURE_LEX_IF])
 207 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 208 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 209 m4_popdef([AT_API_PREFIX])
 210 m4_popdef([AT_NAME_PREFIX])
 211 m4_popdef([AT_GLR_OR_PARAM_IF])
 212 m4_popdef([AT_PURE_AND_LOC_IF])
 213 m4_popdef([AT_LOCATION_TYPE_IF])
 214 m4_popdef([AT_LOCATION_IF])
 215 m4_popdef([AT_PARAM_IF])
 216 m4_popdef([AT_LEXPARAM_IF])
 217 m4_popdef([AT_YACC_IF])
 218 m4_popdef([AT_GLR_IF])
 219 m4_popdef([AT_SKEL_CC_IF])
 220 m4_popdef([AT_SKEL_JAVA_IF])
 221 m4_popdef([AT_GLR_CC_IF])
 222 m4_popdef([AT_LALR1_CC_IF])
 223 m4_popdef([AT_DEFINES_IF])
 224 AT_LOC_POPDEF
 225 ])# AT_BISON_OPTION_POPDEFS
 226
 227
 228
 229 ## -------------------------- ##
 230 ## Generating Grammar Files.  ##
 231 ## -------------------------- ##
 232
 233 # AT_DATA_SOURCE_PROLOGUE
 234 # ------------------------
 235 # The prologue that should be included in any source code that is
 236 # meant to be compiled.
 237 m4_define([AT_DATA_SOURCE_PROLOGUE],
 238 [[#include <config.h>
 239 /* We don't need perfect functions for these tests. */
 240 #undef malloc
 241 #undef memcmp
 242 #undef realloc
 243 ]])
 244
 245 # AT_DATA_GRAMMAR_PROLOGUE
 246 # ------------------------
 247 # The prologue that should be included in any grammar which parser is
 248 # meant to be compiled.
 249 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 250 [[%code top {
 251 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 252 [}
 253 ]])
 254
 255 # AT_DATA_SOURCE(NAME, CONTENT)
 256 # -----------------------------
 257 # Generate the file NAME, which CONTENT is preceded by
 258 # AT_DATA_SOURCE_PROLOGUE.
 259 m4_define([AT_DATA_SOURCE],
 260 [AT_DATA([$1],
 261 [AT_DATA_SOURCE_PROLOGUE
 262 $2])
 263 ])
 264
 265 # AT_DATA_GRAMMAR(NAME, CONTENT)
 266 # ------------------------------
 267 # Generate the file NAME, which CONTENT is preceded by
 268 # AT_DATA_GRAMMAR_PROLOGUE.
 269 m4_define([AT_DATA_GRAMMAR],
 270 [AT_DATA([$1],
 271 [AT_DATA_GRAMMAR_PROLOGUE
 272 $2])
 273 ])
 274
 275 # AT_YYLEX_DECLARE_EXTERN
 276 # AT_YYLEX_DECLARE
 277 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 278 # ---------------------------------------
 279 m4_define([AT_YYLEX_DECLARE_EXTERN],
 280 [int AT_API_PREFIX[]lex (void);dnl
 281 ])
 282
 283 m4_define([AT_YYLEX_DECLARE],
 284 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 285 ])
 286
 287 m4_define([AT_YYLEX_DEFINE],
 288 [[#include <stdlib.h> /* abort */
 289 static int
 290 ]AT_API_PREFIX[lex (void)
 291 {
 292   static char const input[] = "$1";
 293   static size_t toknum = 0;
 294   int res;
 295   if (! (toknum < sizeof input))
 296     abort ();
 297   res = input[toknum++];
 298   ]$2;[]AT_LOCATION_IF([[
 299   ]AT_API_PREFIX[lloc.first_line = ]AT_API_PREFIX[lloc.last_line = 1;
 300   ]AT_API_PREFIX[lloc.first_column = ]AT_API_PREFIX[lloc.last_column = toknum;]])[
 301   return res;
 302 }]dnl
 303 ])
 304
 305 # AT_YYERROR_DECLARE_EXTERN
 306 # AT_YYERROR_DECLARE
 307 # AT_YYERROR_DEFINE
 308 # -------------------------
 309 # Beware that must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS
 310 # pair.
 311 m4_define([AT_YYERROR_DECLARE_EXTERN],
 312 [void AT_API_PREFIX[]error (const char *msg);dnl
 313 ])
 314
 315 m4_define([AT_YYERROR_DECLARE],
 316 [static AT_YYERROR_DECLARE_EXTERN[]dnl
 317 ])
 318
 319 m4_define([AT_YYERROR_DEFINE],
 320 [AT_SKEL_JAVA_IF([[public void yyerror (String msg)
 321 {
 322   System.err.println (msg);
 323 }]], [AT_SKEL_CC_IF([[void
 324 yy::parser::error (const yy::location &, std::string const &msg)
 325 {
 326   std::cerr << msg << std::endl;
 327 }]], [[#include <stdio.h>
 328 static void
 329 ]AT_API_PREFIX[error (char const *msg)
 330 {
 331   fprintf (stderr, "%s\n", msg);
 332 }]])])dnl
 333 ])
 334
 335 ## --------------- ##
 336 ## Running Bison.  ##
 337 ## --------------- ##
 338
 339 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 340 # -------------------------------------------------
 341 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 342 # shell constructs (such as redirection or pipes) that would prevent
 343 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 344 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 345 #
 346 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 347 # Bison in the test suite.  For now it ensures that:
 348 #
 349 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 350 #      a non-zero exit status since Bison doesn't always try to free all memory
 351 #      in that case.
 352 #
 353 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 354 #      --graph and --report=all output for every working grammar.
 355 #
 356 #   3. If stderr contains a warning, -Werror and --warnings=error
 357 #      convert the warning to an error.
 358 #
 359 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 360 m4_define([AT_BISON_CHECK],
 361 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 362        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 363 AT_BISON_CHECK_NO_XML($@)])
 364
 365 m4_define([AT_BISON_WERROR_MSG],
 366           [[bison: warnings being treated as errors]])
 367
 368 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 369 # --------------------------------------------------------
 370 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 371 # when a tortured grammar's XML is known to be too large for xsltproc to
 372 # handle.
 373 m4_define([AT_BISON_CHECK_NO_XML],
 374 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 375                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 376 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 377       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 378         # Defining POSIXLY_CORRECT causes bison to complain if options
 379         # are added after the grammar file name, so skip these checks
 380         # in that case.
 381         if test -z "${POSIXLY_CORRECT+set}"; then
 382           ]AT_SAVE_SPECIAL_FILES[
 383
 384           # To avoid expanding it repeatedly, store specified stdout.
 385           ]AT_DATA([expout], [$3])[
 386
 387           # Run with -Werror.
 388           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 389                     [[1]], [expout], [stderr])[
 390
 391           # Build expected stderr up to and including the "warnings being
 392           # treated as errors" message.
 393           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 394           at_bison_check_first=`sed -n \
 395             '/: warning: /{=;q;}' at-bison-check-warnings`
 396           : ${at_bison_check_first:=1}
 397           at_bison_check_first_tmp=`sed -n \
 398             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 399           : ${at_bison_check_first_tmp:=1}
 400           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 401             at_bison_check_first=$at_bison_check_first_tmp
 402           fi
 403           if test $at_bison_check_first -gt 1; then
 404             sed -n "1,`expr $at_bison_check_first - 1`"p \
 405               at-bison-check-warnings > experr
 406           fi
 407           echo ']AT_BISON_WERROR_MSG[' >> experr
 408
 409           # Finish building expected stderr and check.  Unlike warnings,
 410           # complaints cause bison to exit early.  Thus, with -Werror, bison
 411           # does not necessarily report all warnings that it does without
 412           # -Werror, but it at least reports one.
 413           at_bison_check_last=`sed -n '$=' stderr`
 414           : ${at_bison_check_last:=1}
 415           at_bison_check_last=`expr $at_bison_check_last - 1`
 416           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 417             at-bison-check-warnings >> experr
 418           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 419                       stderr 1>&2]], [[0]], [[]], [experr])[
 420
 421           # Now check --warnings=error.
 422           cp stderr experr
 423           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 424                     [[1]], [expout], [experr])[
 425
 426           # Now check -Wnone and --warnings=none by making sure that
 427           # -Werror doesn't change the exit status when -Wnone or
 428           # --warnings=none is specified.
 429           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 430                     [[0]], [expout])[
 431           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 432                     -Werror]], [[0]], [expout])[
 433
 434           ]AT_RESTORE_SPECIAL_FILES[
 435         fi
 436       ]])
 437 ])
 438
 439 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 440 # -----------------------------------------------------
 441 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 442 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 443 # have a non-zero exit status.
 444 m4_define([AT_BISON_CHECK_XML],
 445 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 446   AT_SAVE_SPECIAL_FILES
 447   [mkdir xml-tests]
 448   m4_pushdef([AT_BISON_ARGS],
 449              [m4_bpatsubsts([[$1]],
 450                             [--report(-file)?=[^][ ]*], [],
 451                             [--graph=[^][ ]*], [],
 452                             [--xml=[^][ ]*], [])])dnl
 453   # Don't combine these Bison invocations since we want to be sure that
 454   # --report=all isn't required to get the full XML file.
 455   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 456              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 457            [[0]], [ignore], [ignore])
 458   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 459            [[0]], [ignore], [ignore])
 460   m4_popdef([AT_BISON_ARGS])dnl
 461   [cp xml-tests/test.output expout]
 462   AT_CHECK([[$XSLTPROC \
 463              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 464              xml-tests/test.xml]], [[0]], [expout])
 465   [cp xml-tests/test.dot expout]
 466   AT_CHECK([[$XSLTPROC \
 467              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 468              xml-tests/test.xml]], [[0]], [expout])
 469   [rm -rf xml-tests expout]
 470   AT_RESTORE_SPECIAL_FILES
 471 [fi]])
 472
 473 # AT_QUELL_VALGRIND
 474 # -----------------
 475 # Put this before a Bison invocation to keep Valgrind from complaining about
 476 # reachable memory.
 477 #
 478 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 479 # The triple quoting below will cause test cases to fail if you do.  If you do
 480 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 481 # will then fail to shell-escape its contents when attempting to print them.
 482 # The testsuite verbose output, at least, will be incorrect, but nothing may
 483 # fail to make sure you notice.
 484 m4_define([AT_QUELL_VALGRIND],
 485 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 486
 487 ## ------------------------ ##
 488 ## Compiling C, C++ Files.  ##
 489 ## ------------------------ ##
 490
 491
 492 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 493 # ----------------------------------------
 494 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 495 # assume that we are linking too; this is a hack.
 496 m4_define([AT_COMPILE],
 497 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 498            0, [ignore], [ignore])])
 499
 500 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 501 # --------------------------------------------
 502 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 503 # assume that we are linking too; this is a hack.
 504 # If the C++ compiler does not work, ignore the test.
 505 m4_define([AT_COMPILE_CXX],
 506 [AT_KEYWORDS(c++)
 507 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 508 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 509          0, [ignore], [ignore])])
 510
 511 # AT_JAVA_COMPILE(SOURCES)
 512 # ------------------------
 513 # Compile SOURCES into Java class files.  Skip the test if java or javac
 514 # is not installed.
 515 m4_define([AT_JAVA_COMPILE],
 516 [AT_KEYWORDS(java)
 517 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 518            test -n "$CONF_JAVAC" || exit 77]])
 519 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 520          [[0]], [ignore], [ignore])])
 521
 522 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 523 # -------------------------------------------
 524 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 525 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 526 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 527 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 528 # AT_SKEL_JAVA_IF.
 529 m4_define([AT_FULL_COMPILE], [
 530   AT_SKEL_JAVA_IF([
 531     AT_BISON_CHECK([-o $1.java $1.y])
 532     AT_JAVA_COMPILE([$1.java],
 533                     m4_join([ ],
 534                             [$1.java],
 535                             m4_ifval($2, [[$1-$2.java]]),
 536                             m4_ifval($3, [[$1-$3.java]])))
 537   ], [
 538     AT_SKEL_CC_IF([
 539       AT_BISON_CHECK([-o $1.cc $1.y])
 540       AT_COMPILE_CXX([$1],
 541                      m4_join([ ],
 542                              [$1.cc],
 543                              m4_ifval($2, [[$1-$2.cc]]),
 544                              m4_ifval($3, [[$1-$3.cc]])))
 545     ], [
 546       AT_BISON_CHECK([-o $1.c $1.y])
 547       AT_COMPILE([$1],
 548                   m4_join([ ],
 549                           [$1.c],
 550                           m4_ifval($2, [[$1-$2.c]]),
 551                           m4_ifval($3, [[$1-$3.c]])))
 552     ])
 553   ])
 554 ])
 555
 556
 557 ## ---------------------------- ##
 558 ## Running a generated parser.  ##
 559 ## ---------------------------- ##
 560
 561
 562 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 563 # ------------------------------------------------------------
 564 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 565 #
 566 # Get rid of spurious messages when compiled with --coverage:
 567 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 568 m4_define([AT_PARSER_CHECK],
 569 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 570 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 571          [0], [], [$4])
 572 ])
 573
 574
 575 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 576 # -----------------------------------------------------------------
 577 m4_define([AT_JAVA_PARSER_CHECK],
 578 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 579
 580
 581 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 582 #                          DECLS, GRAMMAR, INPUT,
 583 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 584 #                          [OTHER-CHECKS],
 585 #                          [PARSER-EXIT-VALUE],
 586 #                          [PARSER-STDOUT], [PARSER-STDERR])
 587 # -------------------------------------------------------------
 588 # Using TITLE as the test group title, check the generated parser tables
 589 # and parser for a specified grammar file under a condition labeled by
 590 # COND-VALUE.
 591 #
 592 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 593 # recognized attribute is described below where it is relevant.
 594 #
 595 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 596 # the grammar file.  Insert basic yyerror, yylex, and main function
 597 # definitions as well.  Hardcode yylex to return the (possibly empty)
 598 # comma-delimited series of tokens in INPUT followed by token 0.
 599 #
 600 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 601 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 602 # On the bison command-line, specify `--report=all --defines'.  Check
 603 # that Bison exits with value 0, has no stdout, and has stderr
 604 # BISON-STDERR.
 605 #
 606 # If TEST-SPEC contains the attribute `last-state', check that the value
 607 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 608 # the grammar; in other words, check the number of states (minus one).
 609 # Otherwise, check that everything in the `.output' file starting with
 610 # the definition of state 0 is the same as the entire value of
 611 # TABLES-OR-LAST-STATE.
 612 #
 613 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 614 # `.output' file, which is named `input.output', and/or grammar file,
 615 # which is named `input.y'.
 616 #
 617 # Finally, compile the generated parser and then run it using
 618 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 619 # PARSER-STDERR as the 2nd-4th arguments.
 620 #
 621 # As a precondition, you must properly double-quote all arguments that
 622 # are to be interpreted as strings.
 623 #
 624 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 625 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 626 # first argument.  This is useful, for example, when wrapping multiple
 627 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 628 # condition, in another macro.
 629 #
 630 # For example:
 631 #
 632 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 633 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 634 #   # ---------------------------------------------------------------------
 635 #   m4_define([AT_TEST_SYNTAX_ERROR],
 636 #   [
 637 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 638 #                              [[last-state]],
 639 #                              [[%error-verbose ]$2], [$3], [$4],
 640 #                              [[]], [$5], [], [$6], [$7], [$8])
 641 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 642 #                              [[last-state]],
 643 #                              [$2], [$3], [$4],
 644 #                              [[]], [$5], [], [$6], [$7], [$8])
 645 #   ])
 646 #
 647 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 648 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 649 #                        [[3]],
 650 #                        [[1]], [[]],
 651 #                        [AT_COND_CASE([[no verbose]],
 652 #                                      [[syntax error
 653 #   ]],
 654 #                                      [[syntax error, unexpected 'b', expecting $end
 655 #   ]])])
 656 m4_define([AT_TEST_TABLES_AND_PARSE],
 657 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 658
 659 AT_SETUP([$1])
 660 AT_BISON_OPTION_PUSHDEFS([$4])
 661 AT_DATA_GRAMMAR([[input.y]],
 662 [[%code {
 663   #include <stdio.h>
 664   ]AT_YYERROR_DECLARE[
 665   ]AT_YYLEX_DECLARE[
 666 }
 667
 668 ]$4[
 669
 670 %%
 671
 672 ]$5[
 673
 674 %%
 675 ]AT_YYERROR_DEFINE[
 676 static int
 677 yylex (void)
 678 {
 679   static int const input[] = {
 680     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 681   };
 682   static int const *inputp = input;
 683   return *inputp++;
 684 }
 685
 686 int
 687 main (void)
 688 {
 689   return yyparse ();
 690 }
 691 ]])
 692
 693 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 694 # expanding macros, so it corrupts some special characters in the
 695 # macros.  To avoid this, expand now and pass it the result with proper
 696 # string quotation.  Assume args 7 through 12 expand to properly quoted
 697 # strings.
 698
 699 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 700       [AT_BISON_CHECK],
 701       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 702                                [0], [], m4_dquote($7))
 703
 704 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 705       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 706                 m4_dquote($8))],
 707       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 708                 m4_dquote($8)[[
 709 ]])])
 710
 711 $9
 712
 713 # Canonical LR generates very large tables, resulting in very long
 714 # files with #line directives that may overflow what the standards
 715 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 716 # will issue an error.
 717 #
 718 # There is no "" around `wc` since some indent the result.
 719 m4_bmatch([$4], [%define lr.type canonical-lr],
 720 [if test 32767 -lt `wc -l < input.c`; then
 721   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 722   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 723 fi])
 724 AT_COMPILE([[input]])
 725
 726 AT_PARSER_CHECK([[./input]],
 727                 m4_ifval([$10], [m4_dquote($10)]),
 728                 m4_ifval([$11], [m4_dquote($11)]),
 729                 m4_ifval([$12], [m4_dquote($12)]))
 730
 731 AT_BISON_OPTION_POPDEFS
 732 AT_CLEANUP
 733
 734 m4_popdef([AT_COND_CASE])])
 735
 736
 737
 738 ## ----------------------- ##
 739 ## Launch the test suite.  ##
 740 ## ----------------------- ##
 741
 742 AT_INIT
 743
 744 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 745 # options are processed, so we don't know the value of CXX and
 746 # CXXFLAGS yet.
 747 #
 748 # Note that it also means that command line values for CXX and
 749 # CXXFLAGS will not be propagated to CC and CFLAGS.
 750 AT_ARG_OPTION([compile-c-with-cxx],
 751               [compile C parsers with the C++ compiler])
 752
 753 AT_COLOR_TESTS
 754
 755 AT_TESTED([bison])