configure.in

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  16 # 02111-1307  USA
  17
  18 # We need a recent Autoconf to run a recent Autotest.
  19 AC_PREREQ(2.52e)
  20
  21 AC_INIT([GNU Bison], [1.29f], [bug-bison@gnu.org])
  22 AC_CONFIG_AUX_DIR(config)
  23
  24 AM_INIT_AUTOMAKE([bison], [1.29f])
  25 AM_CONFIG_HEADER(config.h:config.hin)
  26
  27 # Initialize the test suite.
  28 AC_CONFIG_TESTDIR(tests)
  29 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
  30 # Needed by tests/atlocal.in.
  31 AC_SUBST([GCC])
  32
  33 # Checks for programs.
  34 AC_PROG_CC
  35 AC_MINIX
  36 AC_ISC_POSIX
  37 AM_PROG_CC_STDC
  38 AC_PROG_RANLIB
  39 AM_MISSING_PROG([AUTOM4TE], [autom4te])
  40
  41 AC_ARG_ENABLE(gcc-warnings,
  42 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  43 [case "${enableval}" in
  44    yes|no) ;;
  45    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  46  esac],
  47               [enableval=no])
  48 if test "${enableval}" = yes; then
  49   BISON_WARNING(-Wall)
  50   BISON_WARNING(-W)
  51   BISON_WARNING(-Wbad-function-cast)
  52   BISON_WARNING(-Wcast-align)
  53   BISON_WARNING(-Wcast-qual)
  54   BISON_WARNING(-Wformat)
  55   BISON_WARNING(-Wmissing-declarations)
  56   BISON_WARNING(-Wmissing-prototypes)
  57   BISON_WARNING(-Wnested-externs)
  58   BISON_WARNING(-Wshadow)
  59   BISON_WARNING(-Wstrict-prototypes)
  60   BISON_WARNING(-Wwrite-strings)
  61   CFLAGS="$CFLAGS $WARNING_CFLAGS"
  62 fi
  63
  64 # Checks for libraries.
  65 AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
  66
  67 # Checks for header files.
  68 AC_HEADER_STDC
  69 AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
  70
  71 # Checks for typedefs.
  72
  73 # Checks for structures.
  74
  75 # Checks for compiler characteristics.
  76 AC_C_CONST
  77 AC_C_INLINE
  78 AM_C_PROTOTYPES
  79
  80 # Checks for library functions.
  81 AC_FUNC_ALLOCA
  82 AC_CHECK_FUNCS(mkstemp setlocale)
  83 AC_CHECK_DECLS([stpcpy, strndup, strnlen, memchr])
  84 AC_REPLACE_FUNCS(stpcpy strndup strnlen strspn memchr)
  85 jm_FUNC_MALLOC
  86 jm_FUNC_REALLOC
  87 jm_PREREQ_QUOTEARG
  88 jm_PREREQ_ERROR
  89 AM_WITH_DMALLOC
  90
  91 ALL_LINGUAS="de es et fr ja nl tr ru"
  92 AM_GNU_GETTEXT
  93
  94 # This is necessary so that .o files in LIBOBJS are also built via
  95 # the ANSI2KNR-filtering rules.
  96 LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
  97 AC_SUBST(LIBOBJS)
  98
  99 AC_OUTPUT([Makefile
 100            config/Makefile
 101            intl/Makefile po/Makefile.in
 102            lib/Makefile src/Makefile doc/Makefile
 103            m4/Makefile
 104            tests/Makefile])