data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008 Free Software
   5 # Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ## ---------------- ##
  21 ## Identification.  ##
  22 ## ---------------- ##
  23
  24 # b4_comment(TEXT)
  25 # ----------------
  26 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  27 # Avoid adding indentation to the first line, as the indentation comes
  28 # from "/*".  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  29 m4_define([b4_comment], [/* m4_bpatsubst([$1], [
  30 \(.\)], [
  31    \1])  */])
  32
  33 # b4_identification
  34 # -----------------
  35 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  36 # b4_pull_flag if they use the values of the %define variables api.pure or
  37 # api.push_pull.
  38 m4_define([b4_identification],
  39 [[/* Identify Bison output.  */
  40 #define YYBISON 1
  41
  42 /* Bison version.  */
  43 #define YYBISON_VERSION "]b4_version["
  44
  45 /* Skeleton name.  */
  46 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  47
  48 /* Pure parsers.  */
  49 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  50
  51 /* Push parsers.  */
  52 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  53
  54 /* Pull parsers.  */
  55 #define YYPULL ]b4_pull_flag])[
  56
  57 /* Using locations.  */
  58 #define YYLSP_NEEDED ]b4_locations_flag[
  59 ]])
  60
  61
  62 ## ---------------- ##
  63 ## Default values.  ##
  64 ## ---------------- ##
  65
  66 # If the %union is not named, its name is YYSTYPE.
  67 m4_define_default([b4_union_name], [YYSTYPE])
  68
  69 # If the %name-prefix is not given, it is yy.
  70 m4_define_default([b4_prefix], [yy])
  71
  72 ## ------------------------ ##
  73 ## Pure/impure interfaces.  ##
  74 ## ------------------------ ##
  75
  76 # b4_user_args
  77 # ------------
  78 m4_define([b4_user_args],
  79 [m4_ifset([b4_parse_param], [, b4_c_args(b4_parse_param)])])
  80
  81
  82 # b4_parse_param
  83 # --------------
  84 # If defined, b4_parse_param arrives double quoted, but below we prefer
  85 # it to be single quoted.
  86 m4_define([b4_parse_param],
  87 b4_parse_param)
  88
  89
  90 # b4_parse_param_for(DECL, FORMAL, BODY)
  91 # ---------------------------------------
  92 # Iterate over the user parameters, binding the declaration to DECL,
  93 # the formal name to FORMAL, and evaluating the BODY.
  94 m4_define([b4_parse_param_for],
  95 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
  96 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
  97 m4_pushdef([$2], m4_shift($1_$2))dnl
  98 $3[]dnl
  99 m4_popdef([$2])dnl
 100 m4_popdef([$1])dnl
 101 ])])
 102
 103 # b4_parse_param_use
 104 # ------------------
 105 # `YYUSE' all the parse-params.
 106 m4_define([b4_parse_param_use],
 107 [b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 108 ])dnl
 109 ])
 110
 111
 112 ## ------------ ##
 113 ## Data Types.  ##
 114 ## ------------ ##
 115
 116 # b4_int_type(MIN, MAX)
 117 # ---------------------
 118 # Return the smallest int type able to handle numbers ranging from
 119 # MIN to MAX (included).
 120 m4_define([b4_int_type],
 121 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 122        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 123
 124        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 125        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 126
 127        m4_eval([0 <= $1]),                [1], [unsigned int],
 128
 129                                                [int])])
 130
 131
 132 # b4_int_type_for(NAME)
 133 # ---------------------
 134 # Return the smallest int type able to handle numbers ranging from
 135 # `NAME_min' to `NAME_max' (included).
 136 m4_define([b4_int_type_for],
 137 [b4_int_type($1_min, $1_max)])
 138
 139
 140
 141 ## ---------##
 142 ## Values.  ##
 143 ## ---------##
 144
 145 # b4_null
 146 ---------
 147 # Return a null pointer constant.  NULL infringes on the user name
 148 # space in C, so use 0 rather than NULL.
 149 m4_define([b4_null], [0])
 150
 151
 152
 153
 154 ## ------------------------- ##
 155 ## Assigning token numbers.  ##
 156 ## ------------------------- ##
 157
 158 # b4_token_define(TOKEN-NAME, TOKEN-NUMBER)
 159 # -----------------------------------------
 160 # Output the definition of this token as #define.
 161 m4_define([b4_token_define],
 162 [#define b4_percent_define_get([token.prefix])$1 $2
 163 ])
 164
 165
 166 # b4_token_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 167 # -------------------------------------------------------
 168 # Output the definition of the tokens (if there are) as #defines.
 169 m4_define([b4_token_defines],
 170 [m4_if([$#$1], [1], [],
 171 [/* Tokens.  */
 172 m4_map([b4_token_define], [$@])])
 173 ])
 174
 175
 176 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 177 # ---------------------------------------
 178 # Output the definition of this token as an enum.
 179 m4_define([b4_token_enum],
 180 [b4_percent_define_get([token.prefix])$1 = $2])
 181
 182
 183 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 184 # -----------------------------------------------------
 185 # Output the definition of the tokens (if there are) as enums.
 186 m4_define([b4_token_enums],
 187 [m4_if([$#$1], [1], [],
 188 [/* Tokens.  */
 189 #ifndef YYTOKENTYPE
 190 # define YYTOKENTYPE
 191    /* Put the tokens into the symbol table, so that GDB and other debuggers
 192       know about them.  */
 193    enum yytokentype {
 194 m4_map_sep([     b4_token_enum], [,
 195 ],
 196            [$@])
 197    };
 198 #endif
 199 ])])
 200
 201
 202 # b4_token_enums_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 203 # -------------------------------------------------------------
 204 # Output the definition of the tokens (if there are any) as enums and, if POSIX
 205 # Yacc is enabled, as #defines.
 206 m4_define([b4_token_enums_defines],
 207 [b4_token_enums($@)b4_yacc_if([b4_token_defines($@)], [])
 208 ])
 209
 210
 211 ## ----------------- ##
 212 ## Semantic Values.  ##
 213 ## ----------------- ##
 214
 215
 216 # b4_symbol_value(VAL, [TYPE])
 217 # ----------------------------
 218 # Given a semantic value VAL ($$, $1 etc.), extract its value of type
 219 # TYPE if TYPE is given, otherwise just return VAL.  The result can be
 220 # used safetly, it is put in parens to avoid nasty precedence issues.
 221 # TYPE is *not* put in braces, provide some if needed.
 222 m4_define([b4_symbol_value],
 223 [($1[]m4_ifval([$2], [.$2]))])
 224
 225
 226
 227 ## --------------------------------------------- ##
 228 ## Defining C functions in both K&R and ANSI-C.  ##
 229 ## --------------------------------------------- ##
 230
 231
 232 # b4_modern_c
 233 # -----------
 234 # A predicate useful in #if to determine whether C is ancient or modern.
 235 #
 236 # If __STDC__ is defined, the compiler is modern.  IBM xlc 7.0 when run
 237 # as 'cc' doesn't define __STDC__ (or __STDC_VERSION__) for pedantic
 238 # reasons, but it defines __C99__FUNC__ so check that as well.
 239 # Microsoft C normally doesn't define these macros, but it defines _MSC_VER.
 240 # Consider a C++ compiler to be modern if it defines __cplusplus.
 241 #
 242 m4_define([b4_c_modern],
 243   [[(defined __STDC__ || defined __C99__FUNC__ \
 244      || defined __cplusplus || defined _MSC_VER)]])
 245
 246 # b4_c_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 247 # ----------------------------------------------------------
 248 # Declare the function NAME.
 249 m4_define([b4_c_function_def],
 250 [#if b4_c_modern
 251 b4_c_ansi_function_def($@)
 252 #else
 253 $2
 254 $1 (b4_c_knr_formal_names(m4_shift2($@)))
 255 b4_c_knr_formal_decls(m4_shift2($@))
 256 #endif[]dnl
 257 ])
 258
 259
 260 # b4_c_ansi_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 261 # ---------------------------------------------------------------
 262 # Declare the function NAME in ANSI.
 263 m4_define([b4_c_ansi_function_def],
 264 [$2
 265 $1 (b4_c_ansi_formals(m4_shift2($@)))[]dnl
 266 ])
 267
 268
 269 # b4_c_ansi_formals([DECL1, NAME1], ...)
 270 # --------------------------------------
 271 # Output the arguments ANSI-C definition.
 272 m4_define([b4_c_ansi_formals],
 273 [m4_if([$#], [0], [void],
 274        [$#$1], [1], [void],
 275                [m4_map_sep([b4_c_ansi_formal], [, ], [$@])])])
 276
 277 m4_define([b4_c_ansi_formal],
 278 [$1])
 279
 280
 281 # b4_c_knr_formal_names([DECL1, NAME1], ...)
 282 # ------------------------------------------
 283 # Output the argument names.
 284 m4_define([b4_c_knr_formal_names],
 285 [m4_map_sep([b4_c_knr_formal_name], [, ], [$@])])
 286
 287 m4_define([b4_c_knr_formal_name],
 288 [$2])
 289
 290
 291 # b4_c_knr_formal_decls([DECL1, NAME1], ...)
 292 # ------------------------------------------
 293 # Output the K&R argument declarations.
 294 m4_define([b4_c_knr_formal_decls],
 295 [m4_map_sep([b4_c_knr_formal_decl],
 296             [
 297 ],
 298             [$@])])
 299
 300 m4_define([b4_c_knr_formal_decl],
 301 [    $1;])
 302
 303
 304
 305 ## ------------------------------------------------------------ ##
 306 ## Declaring (prototyping) C functions in both K&R and ANSI-C.  ##
 307 ## ------------------------------------------------------------ ##
 308
 309
 310 # b4_c_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 311 # -----------------------------------------------------------
 312 # Declare the function NAME.
 313 m4_define([b4_c_function_decl],
 314 [#if defined __STDC__ || defined __cplusplus
 315 b4_c_ansi_function_decl($@)
 316 #else
 317 $2 $1 ();
 318 #endif[]dnl
 319 ])
 320
 321
 322 # b4_c_ansi_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 323 # ----------------------------------------------------------------
 324 # Declare the function NAME.
 325 m4_define([b4_c_ansi_function_decl],
 326 [$2 $1 (b4_c_ansi_formals(m4_shift2($@)));[]dnl
 327 ])
 328
 329
 330
 331
 332 ## --------------------- ##
 333 ## Calling C functions.  ##
 334 ## --------------------- ##
 335
 336
 337 # b4_c_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 338 # -----------------------------------------------------------
 339 # Call the function NAME with arguments NAME1, NAME2 etc.
 340 m4_define([b4_c_function_call],
 341 [$1 (b4_c_args(m4_shift2($@)))[]dnl
 342 ])
 343
 344
 345 # b4_c_args([DECL1, NAME1], ...)
 346 # ------------------------------
 347 # Output the arguments NAME1, NAME2...
 348 m4_define([b4_c_args],
 349 [m4_map_sep([b4_c_arg], [, ], [$@])])
 350
 351 m4_define([b4_c_arg],
 352 [$2])
 353
 354
 355 ## ----------- ##
 356 ## Synclines.  ##
 357 ## ----------- ##
 358
 359 # b4_sync_start(LINE, FILE)
 360 # -----------------------
 361 m4_define([b4_sync_start], [[#]line $1 $2])
 362
 363
 364 ## -------------- ##
 365 ## User actions.  ##
 366 ## -------------- ##
 367
 368 # b4_case(LABEL, STATEMENTS)
 369 # --------------------------
 370 m4_define([b4_case],
 371 [  case $1:
 372 $2
 373 b4_syncline([@oline@], [@ofile@])
 374     break;])
 375
 376 # b4_symbol_actions(FILENAME, LINENO,
 377 #                   SYMBOL-TAG, SYMBOL-NUM,
 378 #                   SYMBOL-ACTION, SYMBOL-TYPENAME)
 379 # -------------------------------------------------
 380 m4_define([b4_symbol_actions],
 381 [m4_pushdef([b4_dollar_dollar],
 382    [b4_symbol_value([(*yyvaluep)], [$6])])dnl
 383 m4_pushdef([b4_at_dollar], [(*yylocationp)])dnl
 384       case $4: /* $3 */
 385 b4_syncline([$2], [$1])
 386         $5;
 387 b4_syncline([@oline@], [@ofile@])
 388         break;
 389 m4_popdef([b4_at_dollar])dnl
 390 m4_popdef([b4_dollar_dollar])dnl
 391 ])
 392
 393
 394 # b4_yydestruct_generate(FUNCTION-DECLARATOR)
 395 # -------------------------------------------
 396 # Generate the "yydestruct" function, which declaration is issued using
 397 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 398 # or "b4_c_function_def" for K&R.
 399 m4_define_default([b4_yydestruct_generate],
 400 [[/*-----------------------------------------------.
 401 | Release the memory associated to this symbol.  |
 402 `-----------------------------------------------*/
 403
 404 /*ARGSUSED*/
 405 ]$1([yydestruct],
 406     [static void],
 407     [[const char *yymsg],    [yymsg]],
 408     [[int yytype],           [yytype]],
 409     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 410 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 411 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 412 {
 413   YYUSE (yyvaluep);
 414 ]b4_locations_if([  YYUSE (yylocationp);
 415 ])dnl
 416 b4_parse_param_use[]dnl
 417 [
 418   if (!yymsg)
 419     yymsg = "Deleting";
 420   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 421
 422   switch (yytype)
 423     {
 424 ]m4_map([b4_symbol_actions], m4_defn([b4_symbol_destructors]))[
 425       default:
 426         break;
 427     }
 428 }]dnl
 429 ])
 430
 431
 432 # b4_yy_symbol_print_generate(FUNCTION-DECLARATOR)
 433 # ------------------------------------------------
 434 # Generate the "yy_symbol_print" function, which declaration is issued using
 435 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 436 # or "b4_c_function_def" for K&R.
 437 m4_define_default([b4_yy_symbol_print_generate],
 438 [[
 439 /*--------------------------------.
 440 | Print this symbol on YYOUTPUT.  |
 441 `--------------------------------*/
 442
 443 /*ARGSUSED*/
 444 ]$1([yy_symbol_value_print],
 445     [static void],
 446                [[FILE *yyoutput],                       [yyoutput]],
 447                [[int yytype],                           [yytype]],
 448                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 449 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 450 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 451 {
 452   if (!yyvaluep)
 453     return;
 454 ]b4_locations_if([  YYUSE (yylocationp);
 455 ])dnl
 456 b4_parse_param_use[]dnl
 457 [# ifdef YYPRINT
 458   if (yytype < YYNTOKENS)
 459     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 460 # else
 461   YYUSE (yyoutput);
 462 # endif
 463   switch (yytype)
 464     {
 465 ]m4_map([b4_symbol_actions], m4_defn([b4_symbol_printers]))dnl
 466 [      default:
 467         break;
 468     }
 469 }
 470
 471
 472 /*--------------------------------.
 473 | Print this symbol on YYOUTPUT.  |
 474 `--------------------------------*/
 475
 476 ]$1([yy_symbol_print],
 477     [static void],
 478                [[FILE *yyoutput],                       [yyoutput]],
 479                [[int yytype],                           [yytype]],
 480                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 481 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 482 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 483 {
 484   if (yytype < YYNTOKENS)
 485     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 486   else
 487     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 488
 489 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 490   YYFPRINTF (yyoutput, ": ");
 491 ])dnl
 492 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 493 b4_locations_if([, yylocationp])[]b4_user_args[);
 494   YYFPRINTF (yyoutput, ")");
 495 }]dnl
 496 ])