tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003-2010 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 ## ------------------------------- ##
  40 ## Macros decoding Bison options.  ##
  41 ## ------------------------------- ##
  42
  43 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  44 # ----------------------------------------------------------------
  45 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  46 m4_define([AT_LOC_PUSHDEF],
  47 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  48 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  49 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  50 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  51
  52 # AT_LOC_POPDEF
  53 # -------------
  54 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  55 m4_define([AT_LOC_POPDEF],
  56 [m4_popdef([AT_LOC_FIRST_LINE])
  57 m4_popdef([AT_LOC_FIRST_COLUMN])
  58 m4_popdef([AT_LOC_LAST_LINE])
  59 m4_popdef([AT_LOC_LAST_COLUMN])])
  60
  61
  62
  63 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  64 # -----------------------------------------
  65 m4_define([AT_BISON_OPTION_PUSHDEFS],
  66 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  67
  68
  69 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  70 # --------------------------------------------------
  71 # This macro works around the impossibility to define macros
  72 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  73 # This sucks hard, GNU M4 should really provide M5 like $$1.
  74 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  75 [m4_if([$1$2], $[1]$[2], [],
  76        [m4_fatal([$0: Invalid arguments: $@])])dnl
  77 m4_pushdef([AT_DEFINES_IF],
  78 [m4_bmatch([$3], [%defines], [$1], [$2])])
  79 m4_pushdef([AT_SKEL_CC_IF],
  80 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  81 m4_pushdef([AT_GLR_IF],
  82 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  83 m4_pushdef([AT_LALR1_CC_IF],
  84 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  85 m4_pushdef([AT_GLR_CC_IF],
  86 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  87 # Using yacc.c?
  88 m4_pushdef([AT_YACC_IF],
  89 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  90 m4_pushdef([AT_LEXPARAM_IF],
  91 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  92 m4_pushdef([AT_LOCATION_IF],
  93 [m4_bmatch([$3], [%locations], [$1], [$2])])
  94 m4_pushdef([AT_LOCATION_TYPE_IF],
  95 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  96 m4_pushdef([AT_PARAM_IF],
  97 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  98 m4_pushdef([AT_PURE_IF],
  99 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 100            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 101            [$2])])
 102 m4_pushdef([AT_PURE_AND_LOC_IF],
 103 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 104 m4_pushdef([AT_GLR_OR_PARAM_IF],
 105 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 106 m4_pushdef([AT_NAME_PREFIX],
 107 [m4_bmatch([$3], [%name-prefix ".*"],
 108            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 109            [yy])])
 110 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 111 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 112 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 113                     [$2])])
 114 # yyerror always sees the locations (when activated), except if
 115 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 116 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 117 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 118                                         [$1])],
 119                             [$1])],
 120                 [$2])])
 121
 122 # The interface is pure: either because %define api.pure, or because we
 123 # are using the C++ parsers.
 124 m4_pushdef([AT_PURE_LEX_IF],
 125 [AT_PURE_IF([$1],
 126             [AT_SKEL_CC_IF([$1], [$2])])])
 127
 128 AT_PURE_LEX_IF(
 129 [m4_pushdef([AT_LOC], [(*llocp)])
 130  m4_pushdef([AT_VAL], [(*lvalp)])
 131  m4_pushdef([AT_LEX_FORMALS],
 132             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 133  m4_pushdef([AT_LEX_ARGS],
 134             [lvalp[]AT_LOCATION_IF([, llocp])])
 135  m4_pushdef([AT_USE_LEX_ARGS],
 136             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 137  m4_pushdef([AT_LEX_PRE_FORMALS],
 138             [AT_LEX_FORMALS, ])
 139  m4_pushdef([AT_LEX_PRE_ARGS],
 140             [AT_LEX_ARGS, ])
 141 ],
 142 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 143  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 144  m4_pushdef([AT_LEX_FORMALS],     [void])
 145  m4_pushdef([AT_LEX_ARGS],        [])
 146  m4_pushdef([AT_USE_LEX_ARGS],    [])
 147  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 148  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 149 ])
 150
 151 # Handle the different types of location components.
 152
 153 AT_SKEL_CC_IF(
 154   [AT_LOCATION_TYPE_IF(
 155     [AT_LOC_PUSHDEF([begin.l], [begin.c], [end.l], [end.c])],
 156     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 157   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 158
 159 ])# _AT_BISON_OPTION_PUSHDEFS
 160
 161
 162 # AT_BISON_OPTION_POPDEFS
 163 # -----------------------
 164 m4_define([AT_BISON_OPTION_POPDEFS],
 165 [m4_popdef([AT_LEX_PRE_ARGS])
 166 m4_popdef([AT_LEX_PRE_FORMALS])
 167 m4_popdef([AT_USE_LEX_ARGS])
 168 m4_popdef([AT_LEX_ARGS])
 169 m4_popdef([AT_LEX_FORMALS])
 170 m4_popdef([AT_VAL])
 171 m4_popdef([AT_LOC])
 172 m4_popdef([AT_PURE_LEX_IF])
 173 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 174 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 175 m4_popdef([AT_NAME_PREFIX])
 176 m4_popdef([AT_GLR_OR_PARAM_IF])
 177 m4_popdef([AT_PURE_AND_LOC_IF])
 178 m4_popdef([AT_LOCATION_TYPE_IF])
 179 m4_popdef([AT_LOCATION_IF])
 180 m4_popdef([AT_PARAM_IF])
 181 m4_popdef([AT_LEXPARAM_IF])
 182 m4_popdef([AT_YACC_IF])
 183 m4_popdef([AT_GLR_IF])
 184 m4_popdef([AT_SKEL_CC_IF])
 185 m4_popdef([AT_GLR_CC_IF])
 186 m4_popdef([AT_LALR1_CC_IF])
 187 m4_popdef([AT_DEFINES_IF])
 188 AT_LOC_POPDEF
 189 ])# AT_BISON_OPTION_POPDEFS
 190
 191
 192
 193 ## -------------------------- ##
 194 ## Generating Grammar Files.  ##
 195 ## -------------------------- ##
 196
 197 # AT_DATA_SOURCE_PROLOGUE
 198 # ------------------------
 199 # The prologue that should be included in any source code that is
 200 # meant to be compiled.
 201 m4_define([AT_DATA_SOURCE_PROLOGUE],
 202 [[#include <config.h>
 203 /* We don't need perfect functions for these tests. */
 204 #undef malloc
 205 #undef memcmp
 206 #undef realloc
 207 ]])
 208
 209 # AT_DATA_GRAMMAR_PROLOGUE
 210 # ------------------------
 211 # The prologue that should be included in any grammar which parser is
 212 # meant to be compiled.
 213 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 214 [[%code top {
 215 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 216 [}
 217 ]])
 218
 219 # AT_DATA_SOURCE(NAME, CONTENT)
 220 # -----------------------------
 221 # Generate the file NAME, which CONTENT is preceded by
 222 # AT_DATA_SOURCE_PROLOGUE.
 223 m4_define([AT_DATA_SOURCE],
 224 [AT_DATA([$1],
 225 [AT_DATA_SOURCE_PROLOGUE
 226 $2])
 227 ])
 228
 229 # AT_DATA_GRAMMAR(NAME, CONTENT)
 230 # ------------------------------
 231 # Generate the file NAME, which CONTENT is preceded by
 232 # AT_DATA_GRAMMAR_PROLOGUE.
 233 m4_define([AT_DATA_GRAMMAR],
 234 [AT_DATA([$1],
 235 [AT_DATA_GRAMMAR_PROLOGUE
 236 $2])
 237 ])
 238
 239 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 240 # -------------------------------------------------
 241 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 242 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 243 #
 244 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 245 # Bison in the test suite.  For now it ensures that:
 246 #
 247 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 248 #      a non-zero exit status since Bison doesn't always try to free all memory
 249 #      in that case.
 250 #
 251 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 252 #      --graph and --report=all output for every working grammar.
 253 m4_define([AT_BISON_CHECK],
 254 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 255        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 256 AT_BISON_CHECK_NO_XML($@)])
 257
 258 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 259 # --------------------------------------------------------
 260 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 261 # when a tortured grammar's XML is known to be too large for xsltproc to
 262 # handle.
 263 m4_define([AT_BISON_CHECK_NO_XML],
 264 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 265                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 266
 267 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 268 # -----------------------------------------------------
 269 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 270 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 271 # have a non-zero exit status.
 272 m4_define([AT_BISON_CHECK_XML],
 273 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 274   mkdir xml-tests]
 275   m4_pushdef([AT_BISON_ARGS],
 276              [m4_bpatsubsts([[$1]],
 277                             [--report(-file)?=[^][ ]*], [],
 278                             [--graph=[^][ ]*], [],
 279                             [--xml=[^][ ]*], [])])dnl
 280   # Don't combine these Bison invocations since we want to be sure that
 281   # --report=all isn't required to get the full XML file.
 282   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 283              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 284            [[0]], [ignore], [ignore])
 285   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 286            [[0]], [ignore], [ignore])
 287   m4_popdef([AT_BISON_ARGS])dnl
 288   [cp xml-tests/test.output expout]
 289   AT_CHECK([[$XSLTPROC \
 290              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 291              xml-tests/test.xml]], [[0]], [expout])
 292   [cp xml-tests/test.dot expout]
 293   AT_CHECK([[$XSLTPROC \
 294              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 295              xml-tests/test.xml]], [[0]], [expout])
 296   [rm -rf xml-tests expout
 297 fi]])
 298
 299 # AT_QUELL_VALGRIND
 300 # -----------------
 301 # Put this before a Bison invocation to keep Valgrind from complaining about
 302 # reachable memory.
 303 #
 304 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 305 # The triple quoting below will cause test cases to fail if you do.  If you do
 306 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 307 # will then fail to shell-escape its contents when attempting to print them.
 308 # The testsuite verbose output, at least, will be incorrect, but nothing may
 309 # fail to make sure you notice.
 310 m4_define([AT_QUELL_VALGRIND],
 311 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 312
 313 ## ------------------------ ##
 314 ## Compiling C, C++ Files.  ##
 315 ## ------------------------ ##
 316
 317
 318 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 319 # ----------------------------------------
 320 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 321 # assume that we are linking too; this is a hack.
 322 m4_define([AT_COMPILE],
 323 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 324            0, [ignore], [ignore])])
 325
 326 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 327 # --------------------------------------------
 328 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 329 # assume that we are linking too; this is a hack.
 330 # If the C++ compiler does not work, ignore the test.
 331 m4_define([AT_COMPILE_CXX],
 332 [AT_KEYWORDS(c++)
 333 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 334 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 335          0, [ignore], [ignore])])
 336
 337
 338 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 339 # --------------------------------
 340 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 341 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 342 # along with it.
 343 # Relies on AT_SKEL_CC_IF.
 344 m4_define([AT_FULL_COMPILE],
 345 [AT_SKEL_CC_IF(
 346   [AT_BISON_CHECK([-o $1.cc $1.y])
 347    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 348   [AT_BISON_CHECK([-o $1.c $1.y])
 349    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 350 ])
 351
 352
 353 ## ---------------------------- ##
 354 ## Running a generated parser.  ##
 355 ## ---------------------------- ##
 356
 357 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 358 # ------------------------------------------------------------
 359 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 360 m4_define([AT_PARSER_CHECK],
 361 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 362
 363 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 364 #                          DECLS, GRAMMAR, INPUT,
 365 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 366 #                          [OTHER-CHECKS],
 367 #                          [PARSER-EXIT-VALUE],
 368 #                          [PARSER-STDOUT], [PARSER-STDERR])
 369 # -------------------------------------------------------------
 370 # Using TITLE as the test group title, check the generated parser tables
 371 # and parser for a specified grammar file under a condition labeled by
 372 # COND-VALUE.
 373 #
 374 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 375 # recognized attribute is described below where it is relevant.
 376 #
 377 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 378 # the grammar file.  Insert basic yyerror, yylex, and main function
 379 # definitions as well.  Hardcode yylex to return the (possibly empty)
 380 # comma-delimited series of tokens in INPUT followed by token 0.
 381 #
 382 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 383 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 384 # On the bison command-line, specify `--report=all --defines'.  Check
 385 # that Bison exits with value 0, has no stdout, and has stderr
 386 # BISON-STDERR.
 387 #
 388 # If TEST-SPEC contains the attribute `last-state', check that the value
 389 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 390 # the grammar; in other words, check the number of states (minus one).
 391 # Otherwise, check that everything in the `.output' file starting with
 392 # the definition of state 0 is the same as the entire value of
 393 # TABLES-OR-LAST-STATE.
 394 #
 395 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 396 # `.output' file, which is named `input.output', and/or grammar file,
 397 # which is named `input.y'.
 398 #
 399 # Finally, compile the generated parser and then run it using
 400 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 401 # PARSER-STDERR as the 2nd-4th arguments.
 402 #
 403 # As a precondition, you must properly double-quote all arguments that
 404 # are to be interpreted as strings.
 405 #
 406 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 407 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 408 # first argument.  This is useful, for example, when wrapping multiple
 409 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 410 # condition, in another macro.
 411 #
 412 # For example:
 413 #
 414 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 415 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 416 #   # ---------------------------------------------------------------------
 417 #   m4_define([AT_TEST_SYNTAX_ERROR],
 418 #   [
 419 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 420 #                              [[last-state]],
 421 #                              [[%error-verbose ]$2], [$3], [$4],
 422 #                              [[]], [$5], [], [$6], [$7], [$8])
 423 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 424 #                              [[last-state]],
 425 #                              [$2], [$3], [$4],
 426 #                              [[]], [$5], [], [$6], [$7], [$8])
 427 #   ])
 428 #
 429 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 430 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 431 #                        [[3]],
 432 #                        [[1]], [[]],
 433 #                        [AT_COND_CASE([[no verbose]],
 434 #                                      [[syntax error
 435 #   ]],
 436 #                                      [[syntax error, unexpected 'b', expecting $end
 437 #   ]])])
 438 m4_define([AT_TEST_TABLES_AND_PARSE],
 439 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 440
 441 AT_SETUP([$1])
 442
 443 AT_DATA_GRAMMAR([[input.y]],
 444 [[%code {
 445   #include <stdio.h>
 446   static void yyerror (char const *msg);
 447   static int yylex (void);
 448 }
 449
 450 ]$4[
 451
 452 %%
 453
 454 ]$5[
 455
 456 %%
 457
 458 static void
 459 yyerror (char const *msg)
 460 {
 461   fprintf (stderr, "%s\n", msg);
 462 }
 463
 464 static int
 465 yylex (void)
 466 {
 467   static int const input[] = {
 468     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 469   };
 470   static int const *inputp = input;
 471   return *inputp++;
 472 }
 473
 474 int
 475 main (void)
 476 {
 477   return yyparse ();
 478 }
 479 ]])
 480
 481 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 482 # expanding macros, so it corrupts some special characters in the
 483 # macros.  To avoid this, expand now and pass it the result with proper
 484 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 485 # strings.
 486
 487 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 488       [AT_BISON_CHECK],
 489       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 490                                [0], [], m4_dquote($7))
 491
 492 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 493       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 494                 m4_dquote($8))],
 495       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 496                 m4_dquote($8)[[
 497 ]])])
 498
 499 $9
 500
 501 AT_COMPILE([[input]])
 502
 503 AT_PARSER_CHECK([[./input]],
 504                 m4_ifval([$10], [m4_dquote($10)]),
 505                 m4_ifval([$11], [m4_dquote($11)]),
 506                 m4_ifval([$12], [m4_dquote($12)]))
 507
 508 AT_CLEANUP
 509
 510 m4_popdef([AT_COND_CASE])])
 511
 512
 513
 514 ## ----------------------- ##
 515 ## Launch the test suite.  ##
 516 ## ----------------------- ##
 517
 518 AT_INIT
 519
 520 AT_TESTED([bison])