src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   4    Free Software Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 %option debug nodefault noinput nounput noyywrap never-interactive
  22 %option prefix="gram_" outfile="lex.yy.c"
  23
  24 %{
  25 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  26    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  27 #undef gram_wrap
  28 #define gram_wrap() 1
  29
  30 #define FLEX_PREFIX(Id) gram_ ## Id
  31 #include <src/flex-scanner.h>
  32
  33 #include <src/complain.h>
  34 #include <src/files.h>
  35 #include <src/gram.h>
  36 #include <quotearg.h>
  37 #include <src/reader.h>
  38 #include <src/uniqstr.h>
  39
  40 #include <mbswidth.h>
  41 #include <quote.h>
  42
  43 #include <src/scan-gram.h>
  44
  45 #define YY_DECL GRAM_LEX_DECL
  46
  47 #define YY_USER_INIT                                    \
  48    code_start = scanner_cursor = loc->start;            \
  49
  50 /* Location of scanner cursor.  */
  51 static boundary scanner_cursor;
  52
  53 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  54
  55 static size_t no_cr_read (FILE *, char *, size_t);
  56 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  57
  58 #define RETURN_PERCENT_FLAG(Value)              \
  59   do {                                          \
  60     val->uniqstr = uniqstr_new (Value);         \
  61     return PERCENT_FLAG;                        \
  62   } while (0)
  63
  64 #define ROLLBACK_CURRENT_TOKEN                                  \
  65   do {                                                          \
  66     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);     \
  67     yyless (0);                                                 \
  68   } while (0)
  69
  70 /* A string representing the most recently saved token.  */
  71 static char *last_string;
  72
  73 /* Bracketed identifier. */
  74 static uniqstr bracketed_id_str = 0;
  75 static location bracketed_id_loc;
  76 static boundary bracketed_id_start;
  77 static int bracketed_id_context_state = 0;
  78
  79 void
  80 gram_scanner_last_string_free (void)
  81 {
  82   STRING_FREE;
  83 }
  84
  85 static void handle_syncline (char *, location);
  86 static unsigned long int scan_integer (char const *p, int base, location loc);
  87 static int convert_ucn_to_byte (char const *hex_text);
  88 static void unexpected_eof (boundary, char const *);
  89 static void unexpected_newline (boundary, char const *);
  90
  91 %}
  92  /* A C-like comment in directives/rules. */
  93 %x SC_YACC_COMMENT
  94  /* Strings and characters in directives/rules. */
  95 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
  96  /* A identifier was just read in directives/rules.  Special state
  97     to capture the sequence `identifier :'. */
  98 %x SC_AFTER_IDENTIFIER
  99  /* A complex tag, with nested angles brackets. */
 100 %x SC_TAG
 101
 102  /* Three types of user code:
 103     - prologue (code between `%{' `%}' in the first section, before %%);
 104     - actions, printers, union, etc, (between braced in the middle section);
 105     - epilogue (everything after the second %%). */
 106 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE
 107  /* C and C++ comments in code. */
 108 %x SC_COMMENT SC_LINE_COMMENT
 109  /* Strings and characters in code. */
 110 %x SC_STRING SC_CHARACTER
 111  /* Bracketed identifiers support. */
 112 %x SC_BRACKETED_ID SC_RETURN_BRACKETED_ID
 113
 114 letter    [-.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
 115 id        {letter}({letter}|[0-9])*
 116 directive %{id}
 117 int       [0-9]+
 118
 119 /* POSIX says that a tag must be both an id and a C union member, but
 120    historically almost any character is allowed in a tag.  We disallow
 121    NUL, as this simplifies our implementation.  We disallow angle
 122    bracket to match them in nested pairs: several languages use them
 123    for generics/template types.  */
 124 tag      [^\0<>]+
 125
 126 /* Zero or more instances of backslash-newline.  Following GCC, allow
 127    white space between the backslash and the newline.  */
 128 splice   (\\[ \f\t\v]*\n)*
 129
 130 %%
 131 %{
 132   /* Nesting level.  Either for nested braces, or nested angle brackets
 133      (but not mixed).  */
 134   int nesting IF_LINT (= 0);
 135
 136   /* Parent context state, when applicable.  */
 137   int context_state IF_LINT (= 0);
 138
 139   /* Location of most recent identifier, when applicable.  */
 140   location id_loc IF_LINT (= empty_location);
 141
 142   /* Where containing code started, when applicable.  Its initial
 143      value is relevant only when yylex is invoked in the SC_EPILOGUE
 144      start condition.  */
 145   boundary code_start = scanner_cursor;
 146
 147   /* Where containing comment or string or character literal started,
 148      when applicable.  */
 149   boundary token_start IF_LINT (= scanner_cursor);
 150 %}
 151
 152
 153   /*-----------------------.
 154   | Scanning white space.  |
 155   `-----------------------*/
 156
 157 <INITIAL,SC_AFTER_IDENTIFIER,SC_BRACKETED_ID,SC_RETURN_BRACKETED_ID>
 158 {
 159   /* Comments and white space.  */
 160   ","          warn_at (*loc, _("stray `,' treated as white space"));
 161   [ \f\n\t\v]  |
 162   "//".*       ;
 163   "/*" {
 164     token_start = loc->start;
 165     context_state = YY_START;
 166     BEGIN SC_YACC_COMMENT;
 167   }
 168
 169   /* #line directives are not documented, and may be withdrawn or
 170      modified in future versions of Bison.  */
 171   ^"#line "{int}" \"".*"\"\n" {
 172     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 173   }
 174 }
 175
 176
 177   /*----------------------------.
 178   | Scanning Bison directives.  |
 179   `----------------------------*/
 180
 181   /* For directives that are also command line options, the regex must be
 182         "%..."
 183      after "[-_]"s are removed, and the directive must match the --long
 184      option name, with a single string argument.  Otherwise, add exceptions
 185      to ../build-aux/cross-options.pl.  */
 186
 187 <INITIAL>
 188 {
 189   "%binary"                         return PERCENT_NONASSOC;
 190   "%code"                           return PERCENT_CODE;
 191   "%debug"                          RETURN_PERCENT_FLAG("parse.trace");
 192   "%default"[-_]"prec"              return PERCENT_DEFAULT_PREC;
 193   "%define"                         return PERCENT_DEFINE;
 194   "%defines"                        return PERCENT_DEFINES;
 195   "%destructor"                     return PERCENT_DESTRUCTOR;
 196   "%dprec"                          return PERCENT_DPREC;
 197   "%error"[-_]"verbose"             return PERCENT_ERROR_VERBOSE;
 198   "%expect"                         return PERCENT_EXPECT;
 199   "%expect"[-_]"rr"                 return PERCENT_EXPECT_RR;
 200   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 201   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 202   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 203   "%glr-parser"                     return PERCENT_GLR_PARSER;
 204   "%language"                       return PERCENT_LANGUAGE;
 205   "%left"                           return PERCENT_LEFT;
 206   "%lex-param"                      return PERCENT_LEX_PARAM;
 207   "%locations"                      RETURN_PERCENT_FLAG("locations");
 208   "%merge"                          return PERCENT_MERGE;
 209   "%name"[-_]"prefix"               return PERCENT_NAME_PREFIX;
 210   "%no"[-_]"default"[-_]"prec"      return PERCENT_NO_DEFAULT_PREC;
 211   "%no"[-_]"lines"                  return PERCENT_NO_LINES;
 212   "%nonassoc"                       return PERCENT_NONASSOC;
 213   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 214   "%nterm"                          return PERCENT_NTERM;
 215   "%output"                         return PERCENT_OUTPUT;
 216   "%parse-param"                    return PERCENT_PARSE_PARAM;
 217   "%prec"                           return PERCENT_PREC;
 218   "%precedence"                     return PERCENT_PRECEDENCE;
 219   "%printer"                        return PERCENT_PRINTER;
 220   "%pure"[-_]"parser"               RETURN_PERCENT_FLAG("api.pure");
 221   "%require"                        return PERCENT_REQUIRE;
 222   "%right"                          return PERCENT_RIGHT;
 223   "%skeleton"                       return PERCENT_SKELETON;
 224   "%start"                          return PERCENT_START;
 225   "%term"                           return PERCENT_TOKEN;
 226   "%token"                          return PERCENT_TOKEN;
 227   "%token"[-_]"table"               return PERCENT_TOKEN_TABLE;
 228   "%type"                           return PERCENT_TYPE;
 229   "%union"                          return PERCENT_UNION;
 230   "%verbose"                        return PERCENT_VERBOSE;
 231   "%yacc"                           return PERCENT_YACC;
 232
 233   {directive} {
 234     complain_at (*loc, _("invalid directive: %s"), quote (yytext));
 235   }
 236
 237   "="                     return EQUAL;
 238   "|"                     return PIPE;
 239   ";"                     return SEMICOLON;
 240
 241   {id} {
 242     val->uniqstr = uniqstr_new (yytext);
 243     id_loc = *loc;
 244     bracketed_id_str = NULL;
 245     BEGIN SC_AFTER_IDENTIFIER;
 246   }
 247
 248   {int} {
 249     val->integer = scan_integer (yytext, 10, *loc);
 250     return INT;
 251   }
 252   0[xX][0-9abcdefABCDEF]+ {
 253     val->integer = scan_integer (yytext, 16, *loc);
 254     return INT;
 255   }
 256
 257   /* Identifiers may not start with a digit.  Yet, don't silently
 258      accept "1FOO" as "1 FOO".  */
 259   {int}{id} {
 260     complain_at (*loc, _("invalid identifier: %s"), quote (yytext));
 261   }
 262
 263   /* Characters.  */
 264   "'"         token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 265
 266   /* Strings. */
 267   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 268
 269   /* Prologue. */
 270   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 271
 272   /* Code in between braces.  */
 273   "{" {
 274     STRING_GROW;
 275     nesting = 0;
 276     code_start = loc->start;
 277     BEGIN SC_BRACED_CODE;
 278   }
 279
 280   /* A type. */
 281   "<*>"       return TAG_ANY;
 282   "<>"        return TAG_NONE;
 283   "<"{tag}">" {
 284     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 285     STRING_FINISH;
 286     val->uniqstr = uniqstr_new (last_string);
 287     STRING_FREE;
 288     return TAG;
 289   }
 290   "<"         {
 291     nesting = 0;
 292     token_start = loc->start;
 293     BEGIN SC_TAG;
 294   }
 295
 296   "%%" {
 297     static int percent_percent_count;
 298     if (++percent_percent_count == 2)
 299       BEGIN SC_EPILOGUE;
 300     return PERCENT_PERCENT;
 301   }
 302
 303   "[" {
 304     bracketed_id_str = NULL;
 305     bracketed_id_start = loc->start;
 306     bracketed_id_context_state = YY_START;
 307     BEGIN SC_BRACKETED_ID;
 308   }
 309
 310   . {
 311     complain_at (*loc, _("invalid character: %s"), quote (yytext));
 312   }
 313
 314   <<EOF>> {
 315     loc->start = loc->end = scanner_cursor;
 316     yyterminate ();
 317   }
 318 }
 319
 320
 321   /*--------------------------------------------------------------.
 322   | Supporting \0 complexifies our implementation for no expected |
 323   | added value.                                                  |
 324   `--------------------------------------------------------------*/
 325
 326 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING,SC_TAG>
 327 {
 328   \0        complain_at (*loc, _("invalid null character"));
 329 }
 330
 331
 332   /*-----------------------------------------------------------------.
 333   | Scanning after an identifier, checking whether a colon is next.  |
 334   `-----------------------------------------------------------------*/
 335
 336 <SC_AFTER_IDENTIFIER>
 337 {
 338   "[" {
 339     if (bracketed_id_str)
 340       {
 341         ROLLBACK_CURRENT_TOKEN;
 342         BEGIN SC_RETURN_BRACKETED_ID;
 343         *loc = id_loc;
 344         return ID;
 345       }
 346     else
 347       {
 348         bracketed_id_start = loc->start;
 349         bracketed_id_context_state = YY_START;
 350         BEGIN SC_BRACKETED_ID;
 351       }
 352   }
 353   ":" {
 354     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 355     *loc = id_loc;
 356     return ID_COLON;
 357   }
 358   . {
 359     ROLLBACK_CURRENT_TOKEN;
 360     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 361     *loc = id_loc;
 362     return ID;
 363   }
 364   <<EOF>> {
 365     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 366     *loc = id_loc;
 367     return ID;
 368   }
 369 }
 370
 371   /*--------------------------------.
 372   | Scanning bracketed identifiers. |
 373   `--------------------------------*/
 374
 375 <SC_BRACKETED_ID>
 376 {
 377   {id} {
 378     if (bracketed_id_str)
 379       {
 380         complain_at (*loc, _("unexpected identifier in bracketed name: %s"),
 381                      quote (yytext));
 382       }
 383     else
 384       {
 385         bracketed_id_str = uniqstr_new (yytext);
 386         bracketed_id_loc = *loc;
 387       }
 388   }
 389   "]" {
 390     BEGIN bracketed_id_context_state;
 391     if (bracketed_id_str)
 392       {
 393         if (INITIAL == bracketed_id_context_state)
 394           {
 395             val->uniqstr = bracketed_id_str;
 396             bracketed_id_str = 0;
 397             *loc = bracketed_id_loc;
 398             return BRACKETED_ID;
 399           }
 400       }
 401     else
 402       complain_at (*loc, _("an identifier expected"));
 403   }
 404   . {
 405     complain_at (*loc, _("invalid character in bracketed name: %s"),
 406                  quote (yytext));
 407   }
 408   <<EOF>> {
 409     BEGIN bracketed_id_context_state;
 410     unexpected_eof (bracketed_id_start, "]");
 411   }
 412 }
 413
 414 <SC_RETURN_BRACKETED_ID>
 415 {
 416   . {
 417     ROLLBACK_CURRENT_TOKEN;
 418     val->uniqstr = bracketed_id_str;
 419     bracketed_id_str = 0;
 420     *loc = bracketed_id_loc;
 421     BEGIN INITIAL;
 422     return BRACKETED_ID;
 423   }
 424 }
 425
 426
 427   /*---------------------------------------------------------------.
 428   | Scanning a Yacc comment.  The initial `/ *' is already eaten.  |
 429   `---------------------------------------------------------------*/
 430
 431 <SC_YACC_COMMENT>
 432 {
 433   "*/"     BEGIN context_state;
 434   .|\n     ;
 435   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 436 }
 437
 438
 439   /*------------------------------------------------------------.
 440   | Scanning a C comment.  The initial `/ *' is already eaten.  |
 441   `------------------------------------------------------------*/
 442
 443 <SC_COMMENT>
 444 {
 445   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 446   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 447 }
 448
 449
 450   /*--------------------------------------------------------------.
 451   | Scanning a line comment.  The initial `//' is already eaten.  |
 452   `--------------------------------------------------------------*/
 453
 454 <SC_LINE_COMMENT>
 455 {
 456   "\n"           STRING_GROW; BEGIN context_state;
 457   {splice}       STRING_GROW;
 458   <<EOF>>        BEGIN context_state;
 459 }
 460
 461
 462   /*------------------------------------------------.
 463   | Scanning a Bison string, including its escapes. |
 464   | The initial quote is already eaten.             |
 465   `------------------------------------------------*/
 466
 467 <SC_ESCAPED_STRING>
 468 {
 469   "\""|"\n" {
 470     if (yytext[0] == '\n')
 471       unexpected_newline (token_start, "\"");
 472     STRING_FINISH;
 473     loc->start = token_start;
 474     val->chars = last_string;
 475     BEGIN INITIAL;
 476     return STRING;
 477   }
 478   <<EOF>> {
 479     unexpected_eof (token_start, "\"");
 480     STRING_FINISH;
 481     loc->start = token_start;
 482     val->chars = last_string;
 483     BEGIN INITIAL;
 484     return STRING;
 485   }
 486 }
 487
 488   /*----------------------------------------------------------.
 489   | Scanning a Bison character literal, decoding its escapes. |
 490   | The initial quote is already eaten.                       |
 491   `----------------------------------------------------------*/
 492
 493 <SC_ESCAPED_CHARACTER>
 494 {
 495   "'"|"\n" {
 496     STRING_FINISH;
 497     loc->start = token_start;
 498     val->character = last_string[0];
 499     {
 500       /* FIXME: Eventually, make these errors.  */
 501       if (last_string[0] == '\0')
 502         {
 503           warn_at (*loc, _("empty character literal"));
 504           /* '\0' seems dangerous even if we are about to complain.  */
 505           val->character = '\'';
 506         }
 507       else if (last_string[1] != '\0')
 508         warn_at (*loc, _("extra characters in character literal"));
 509     }
 510     if (yytext[0] == '\n')
 511       unexpected_newline (token_start, "'");
 512     STRING_FREE;
 513     BEGIN INITIAL;
 514     return CHAR;
 515   }
 516   <<EOF>> {
 517     STRING_FINISH;
 518     loc->start = token_start;
 519     val->character = last_string[0];
 520     {
 521       /* FIXME: Eventually, make these errors.  */
 522       if (last_string[0] == '\0')
 523         {
 524           warn_at (*loc, _("empty character literal"));
 525           /* '\0' seems dangerous even if we are about to complain.  */
 526           val->character = '\'';
 527         }
 528       else if (last_string[1] != '\0')
 529         warn_at (*loc, _("extra characters in character literal"));
 530     }
 531     unexpected_eof (token_start, "'");
 532     STRING_FREE;
 533     BEGIN INITIAL;
 534     return CHAR;
 535   }
 536 }
 537
 538   /*-----------------------------------------------------------.
 539   | Scanning a Bison nested tag.  The initial angle bracket is |
 540   | already eaten.                                             |
 541   `-----------------------------------------------------------*/
 542
 543 <SC_TAG>
 544 {
 545   ">" {
 546     --nesting;
 547     if (nesting < 0)
 548       {
 549         STRING_FINISH;
 550         loc->start = token_start;
 551         val->uniqstr = uniqstr_new (last_string);
 552         STRING_FREE;
 553         BEGIN INITIAL;
 554         return TAG;
 555       }
 556     STRING_GROW;
 557   }
 558
 559   [^<>]+ STRING_GROW;
 560   "<"+   STRING_GROW; nesting += yyleng;
 561
 562   <<EOF>> {
 563     unexpected_eof (token_start, ">");
 564     STRING_FINISH;
 565     loc->start = token_start;
 566     val->uniqstr = uniqstr_new (last_string);
 567     STRING_FREE;
 568     BEGIN INITIAL;
 569     return TAG;
 570   }
 571 }
 572
 573   /*----------------------------.
 574   | Decode escaped characters.  |
 575   `----------------------------*/
 576
 577 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 578 {
 579   \\[0-7]{1,3} {
 580     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 581     if (UCHAR_MAX < c)
 582       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 583     else if (! c)
 584       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 585     else
 586       obstack_1grow (&obstack_for_string, c);
 587   }
 588
 589   \\x[0-9abcdefABCDEF]+ {
 590     verify (UCHAR_MAX < ULONG_MAX);
 591     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 592     if (UCHAR_MAX < c)
 593       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 594     else if (! c)
 595       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 596     else
 597       obstack_1grow (&obstack_for_string, c);
 598   }
 599
 600   \\a   obstack_1grow (&obstack_for_string, '\a');
 601   \\b   obstack_1grow (&obstack_for_string, '\b');
 602   \\f   obstack_1grow (&obstack_for_string, '\f');
 603   \\n   obstack_1grow (&obstack_for_string, '\n');
 604   \\r   obstack_1grow (&obstack_for_string, '\r');
 605   \\t   obstack_1grow (&obstack_for_string, '\t');
 606   \\v   obstack_1grow (&obstack_for_string, '\v');
 607
 608   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 609   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 610
 611   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 612     int c = convert_ucn_to_byte (yytext);
 613     if (c < 0)
 614       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 615     else if (! c)
 616       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 617     else
 618       obstack_1grow (&obstack_for_string, c);
 619   }
 620   \\(.|\n)      {
 621     complain_at (*loc, _("unrecognized escape sequence: %s"), quote (yytext));
 622     STRING_GROW;
 623   }
 624 }
 625
 626   /*--------------------------------------------.
 627   | Scanning user-code characters and strings.  |
 628   `--------------------------------------------*/
 629
 630 <SC_CHARACTER,SC_STRING>
 631 {
 632   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 633 }
 634
 635 <SC_CHARACTER>
 636 {
 637   "'"           STRING_GROW; BEGIN context_state;
 638   \n            unexpected_newline (token_start, "'"); BEGIN context_state;
 639   <<EOF>>       unexpected_eof (token_start, "'"); BEGIN context_state;
 640 }
 641
 642 <SC_STRING>
 643 {
 644   "\""          STRING_GROW; BEGIN context_state;
 645   \n            unexpected_newline (token_start, "\""); BEGIN context_state;
 646   <<EOF>>       unexpected_eof (token_start, "\""); BEGIN context_state;
 647 }
 648
 649
 650   /*---------------------------------------------------.
 651   | Strings, comments etc. can be found in user code.  |
 652   `---------------------------------------------------*/
 653
 654 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 655 {
 656   "'" {
 657     STRING_GROW;
 658     context_state = YY_START;
 659     token_start = loc->start;
 660     BEGIN SC_CHARACTER;
 661   }
 662   "\"" {
 663     STRING_GROW;
 664     context_state = YY_START;
 665     token_start = loc->start;
 666     BEGIN SC_STRING;
 667   }
 668   "/"{splice}"*" {
 669     STRING_GROW;
 670     context_state = YY_START;
 671     token_start = loc->start;
 672     BEGIN SC_COMMENT;
 673   }
 674   "/"{splice}"/" {
 675     STRING_GROW;
 676     context_state = YY_START;
 677     BEGIN SC_LINE_COMMENT;
 678   }
 679 }
 680
 681
 682
 683   /*-----------------------------------------------------------.
 684   | Scanning some code in braces (actions). The initial "{" is |
 685   | already eaten.                                             |
 686   `-----------------------------------------------------------*/
 687
 688 <SC_BRACED_CODE>
 689 {
 690   "{"|"<"{splice}"%"  STRING_GROW; nesting++;
 691   "%"{splice}">"      STRING_GROW; nesting--;
 692   "}" {
 693     obstack_1grow (&obstack_for_string, '}');
 694
 695     --nesting;
 696     if (nesting < 0)
 697       {
 698         STRING_FINISH;
 699         loc->start = code_start;
 700         val->code = last_string;
 701         BEGIN INITIAL;
 702         return BRACED_CODE;
 703       }
 704   }
 705
 706   /* Tokenize `<<%' correctly (as `<<' `%') rather than incorrrectly
 707      (as `<' `<%').  */
 708   "<"{splice}"<"  STRING_GROW;
 709
 710   <<EOF>> {
 711     unexpected_eof (code_start, "}");
 712     STRING_FINISH;
 713     loc->start = code_start;
 714     val->code = last_string;
 715     BEGIN INITIAL;
 716     return BRACED_CODE;
 717   }
 718 }
 719
 720
 721   /*--------------------------------------------------------------.
 722   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 723   `--------------------------------------------------------------*/
 724
 725 <SC_PROLOGUE>
 726 {
 727   "%}" {
 728     STRING_FINISH;
 729     loc->start = code_start;
 730     val->chars = last_string;
 731     BEGIN INITIAL;
 732     return PROLOGUE;
 733   }
 734
 735   <<EOF>> {
 736     unexpected_eof (code_start, "%}");
 737     STRING_FINISH;
 738     loc->start = code_start;
 739     val->chars = last_string;
 740     BEGIN INITIAL;
 741     return PROLOGUE;
 742   }
 743 }
 744
 745
 746   /*---------------------------------------------------------------.
 747   | Scanning the epilogue (everything after the second "%%", which |
 748   | has already been eaten).                                       |
 749   `---------------------------------------------------------------*/
 750
 751 <SC_EPILOGUE>
 752 {
 753   <<EOF>> {
 754     STRING_FINISH;
 755     loc->start = code_start;
 756     val->chars = last_string;
 757     BEGIN INITIAL;
 758     return EPILOGUE;
 759   }
 760 }
 761
 762
 763   /*-----------------------------------------------------.
 764   | By default, grow the string obstack with the input.  |
 765   `-----------------------------------------------------*/
 766
 767 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>.      |
 768 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>\n   STRING_GROW;
 769
 770 %%
 771
 772 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 773    number of bytes read.  Remove '\r' from input, treating \r\n
 774    and isolated \r as \n.  */
 775
 776 static size_t
 777 no_cr_read (FILE *fp, char *buf, size_t size)
 778 {
 779   size_t bytes_read = fread (buf, 1, size, fp);
 780   if (bytes_read)
 781     {
 782       char *w = memchr (buf, '\r', bytes_read);
 783       if (w)
 784         {
 785           char const *r = ++w;
 786           char const *lim = buf + bytes_read;
 787
 788           for (;;)
 789             {
 790               /* Found an '\r'.  Treat it like '\n', but ignore any
 791                  '\n' that immediately follows.  */
 792               w[-1] = '\n';
 793               if (r == lim)
 794                 {
 795                   int ch = getc (fp);
 796                   if (ch != '\n' && ungetc (ch, fp) != ch)
 797                     break;
 798                 }
 799               else if (*r == '\n')
 800                 r++;
 801
 802               /* Copy until the next '\r'.  */
 803               do
 804                 {
 805                   if (r == lim)
 806                     return w - buf;
 807                 }
 808               while ((*w++ = *r++) != '\r');
 809             }
 810
 811           return w - buf;
 812         }
 813     }
 814
 815   return bytes_read;
 816 }
 817
 818
 819
 820 /*------------------------------------------------------.
 821 | Scan NUMBER for a base-BASE integer at location LOC.  |
 822 `------------------------------------------------------*/
 823
 824 static unsigned long int
 825 scan_integer (char const *number, int base, location loc)
 826 {
 827   verify (INT_MAX < ULONG_MAX);
 828   unsigned long int num = strtoul (number, NULL, base);
 829
 830   if (INT_MAX < num)
 831     {
 832       complain_at (loc, _("integer out of range: %s"), quote (number));
 833       num = INT_MAX;
 834     }
 835
 836   return num;
 837 }
 838
 839
 840 /*------------------------------------------------------------------.
 841 | Convert universal character name UCN to a single-byte character,  |
 842 | and return that character.  Return -1 if UCN does not correspond  |
 843 | to a single-byte character.                                       |
 844 `------------------------------------------------------------------*/
 845
 846 static int
 847 convert_ucn_to_byte (char const *ucn)
 848 {
 849   verify (UCHAR_MAX <= INT_MAX);
 850   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 851
 852   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 853      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 854      non-ASCII hosts we support only the portable C character set.
 855      These limitations should be removed once we add support for
 856      multibyte characters.  */
 857
 858   if (UCHAR_MAX < code)
 859     return -1;
 860
 861 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 862   {
 863     /* A non-ASCII host.  Use CODE to index into a table of the C
 864        basic execution character set, which is guaranteed to exist on
 865        all Standard C platforms.  This table also includes '$', '@',
 866        and '`', which are not in the basic execution character set but
 867        which are unibyte characters on all the platforms that we know
 868        about.  */
 869     static signed char const table[] =
 870       {
 871         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 872         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 873           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 874           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 875          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 876          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 877          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 878          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 879          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 880          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 881          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 882          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 883          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 884          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 885          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 886          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 887       };
 888
 889     code = code < sizeof table ? table[code] : -1;
 890   }
 891 #endif
 892
 893   return code;
 894 }
 895
 896
 897 /*----------------------------------------------------------------.
 898 | Handle `#line INT "FILE"'.  ARGS has already skipped `#line '.  |
 899 `----------------------------------------------------------------*/
 900
 901 static void
 902 handle_syncline (char *args, location loc)
 903 {
 904   char *after_num;
 905   unsigned long int lineno = strtoul (args, &after_num, 10);
 906   char *file = strchr (after_num, '"') + 1;
 907   *strchr (file, '"') = '\0';
 908   if (INT_MAX <= lineno)
 909     {
 910       warn_at (loc, _("line number overflow"));
 911       lineno = INT_MAX;
 912     }
 913   current_file = uniqstr_new (file);
 914   boundary_set (&scanner_cursor, current_file, lineno, 1);
 915 }
 916
 917
 918 /*----------------------------------------------------------------.
 919 | For a token or comment starting at START, report message MSGID, |
 920 | which should say that an end marker was found before            |
 921 | the expected TOKEN_END.                                         |
 922 `----------------------------------------------------------------*/
 923
 924 static void
 925 unexpected_end (boundary start, char const *msgid, char const *token_end)
 926 {
 927   location loc;
 928   loc.start = start;
 929   loc.end = scanner_cursor;
 930   complain_at (loc, _(msgid), token_end);
 931 }
 932
 933
 934 /*------------------------------------------------------------------------.
 935 | Report an unexpected EOF in a token or comment starting at START.       |
 936 | An end of file was encountered and the expected TOKEN_END was missing.  |
 937 `------------------------------------------------------------------------*/
 938
 939 static void
 940 unexpected_eof (boundary start, char const *token_end)
 941 {
 942   unexpected_end (start, N_("missing `%s' at end of file"), token_end);
 943 }
 944
 945
 946 /*----------------------------------------.
 947 | Likewise, but for unexpected newlines.  |
 948 `----------------------------------------*/
 949
 950 static void
 951 unexpected_newline (boundary start, char const *token_end)
 952 {
 953   unexpected_end (start, N_("missing `%s' at end of line"), token_end);
 954 }
 955
 956
 957 /*-------------------------.
 958 | Initialize the scanner.  |
 959 `-------------------------*/
 960
 961 void
 962 gram_scanner_initialize (void)
 963 {
 964   obstack_init (&obstack_for_string);
 965 }
 966
 967
 968 /*-----------------------------------------------.
 969 | Free all the memory allocated to the scanner.  |
 970 `-----------------------------------------------*/
 971
 972 void
 973 gram_scanner_free (void)
 974 {
 975   obstack_free (&obstack_for_string, 0);
 976   /* Reclaim Flex's buffers.  */
 977   yylex_destroy ();
 978 }